/[slime]/slime/swank-lispworks.lisp
ViewVC logotype

Contents of /slime/swank-lispworks.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.140 - (show annotations)
Sat Nov 13 11:18:03 2010 UTC (3 years, 5 months ago) by heller
Branch: MAIN
Changes since 1.139: +17 -12 lines
Improve source locations for compiler messages in Lispworks.

* swank-lispworks.lisp (map-error-database)
(signal-error-data-base, make-dspec-progenitor-location): Pass the
edit-path along.
(signal-undefined-functions): No edit-path available so just use
nil.
1 ;;; -*- indent-tabs-mode: nil -*-
2 ;;;
3 ;;; swank-lispworks.lisp --- LispWorks specific code for SLIME.
4 ;;;
5 ;;; Created 2003, Helmut Eller
6 ;;;
7 ;;; This code has been placed in the Public Domain. All warranties
8 ;;; are disclaimed.
9 ;;;
10
11 (in-package :swank-backend)
12
13 (eval-when (:compile-toplevel :load-toplevel :execute)
14 (require "comm")
15 (import-from :stream *gray-stream-symbols* :swank-backend))
16
17 (import-swank-mop-symbols :clos '(:slot-definition-documentation
18 :slot-boundp-using-class
19 :slot-value-using-class
20 :slot-makunbound-using-class
21 :eql-specializer
22 :eql-specializer-object
23 :compute-applicable-methods-using-classes))
24
25 (defun swank-mop:slot-definition-documentation (slot)
26 (documentation slot t))
27
28 (defun swank-mop:slot-boundp-using-class (class object slotd)
29 (clos:slot-boundp-using-class class object
30 (clos:slot-definition-name slotd)))
31
32 (defun swank-mop:slot-value-using-class (class object slotd)
33 (clos:slot-value-using-class class object
34 (clos:slot-definition-name slotd)))
35
36 (defun (setf swank-mop:slot-value-using-class) (value class object slotd)
37 (setf (clos:slot-value-using-class class object
38 (clos:slot-definition-name slotd))
39 value))
40
41 (defun swank-mop:slot-makunbound-using-class (class object slotd)
42 (clos:slot-makunbound-using-class class object
43 (clos:slot-definition-name slotd)))
44
45 (defun swank-mop:compute-applicable-methods-using-classes (gf classes)
46 (clos::compute-applicable-methods-from-classes gf classes))
47
48 ;; lispworks doesn't have the eql-specializer class, it represents
49 ;; them as a list of `(EQL ,OBJECT)
50 (deftype swank-mop:eql-specializer () 'cons)
51
52 (defun swank-mop:eql-specializer-object (eql-spec)
53 (second eql-spec))
54
55 (eval-when (:compile-toplevel :execute :load-toplevel)
56 (defvar *original-defimplementation* (macro-function 'defimplementation))
57 (defmacro defimplementation (&whole whole name args &body body
58 &environment env)
59 (declare (ignore args body))
60 `(progn
61 (dspec:record-definition '(defun ,name) (dspec:location)
62 :check-redefinition-p nil)
63 ,(funcall *original-defimplementation* whole env))))
64
65 ;;; TCP server
66
67 (defimplementation preferred-communication-style ()
68 :spawn)
69
70 (defun socket-fd (socket)
71 (etypecase socket
72 (fixnum socket)
73 (comm:socket-stream (comm:socket-stream-socket socket))))
74
75 (defimplementation create-socket (host port)
76 (multiple-value-bind (socket where errno)
77 #-(or lispworks4.1 (and macosx lispworks4.3))
78 (comm::create-tcp-socket-for-service port :address host)
79 #+(or lispworks4.1 (and macosx lispworks4.3))
80 (comm::create-tcp-socket-for-service port)
81 (cond (socket socket)
82 (t (error 'network-error
83 :format-control "~A failed: ~A (~D)"
84 :format-arguments (list where
85 (list #+unix (lw:get-unix-error errno))
86 errno))))))
87
88 (defimplementation local-port (socket)
89 (nth-value 1 (comm:get-socket-address (socket-fd socket))))
90
91 (defimplementation close-socket (socket)
92 (comm::close-socket (socket-fd socket)))
93
94 (defimplementation accept-connection (socket
95 &key external-format buffering timeout)
96 (declare (ignore buffering))
97 (let* ((fd (comm::get-fd-from-socket socket)))
98 (assert (/= fd -1))
99 (assert (valid-external-format-p external-format))
100 (cond ((member (first external-format) '(:latin-1 :ascii))
101 (make-instance 'comm:socket-stream
102 :socket fd
103 :direction :io
104 :read-timeout timeout
105 :element-type 'base-char))
106 (t
107 (make-flexi-stream
108 (make-instance 'comm:socket-stream
109 :socket fd
110 :direction :io
111 :read-timeout timeout
112 :element-type '(unsigned-byte 8))
113 external-format)))))
114
115 (defun make-flexi-stream (stream external-format)
116 (unless (member :flexi-streams *features*)
117 (error "Cannot use external format ~A without having installed flexi-streams in the inferior-lisp."
118 external-format))
119 (funcall (read-from-string "FLEXI-STREAMS:MAKE-FLEXI-STREAM")
120 stream
121 :external-format
122 (apply (read-from-string "FLEXI-STREAMS:MAKE-EXTERNAL-FORMAT")
123 external-format)))
124
125 ;;; Coding Systems
126
127 (defun valid-external-format-p (external-format)
128 (member external-format *external-format-to-coding-system*
129 :test #'equal :key #'car))
130
131 (defvar *external-format-to-coding-system*
132 '(((:latin-1 :eol-style :lf)
133 "latin-1-unix" "iso-latin-1-unix" "iso-8859-1-unix")
134 ((:latin-1)
135 "latin-1" "iso-latin-1" "iso-8859-1")
136 ((:utf-8) "utf-8")
137 ((:utf-8 :eol-style :lf) "utf-8-unix")
138 ((:euc-jp) "euc-jp")
139 ((:euc-jp :eol-style :lf) "euc-jp-unix")
140 ((:ascii) "us-ascii")
141 ((:ascii :eol-style :lf) "us-ascii-unix")))
142
143 (defimplementation find-external-format (coding-system)
144 (car (rassoc-if (lambda (x) (member coding-system x :test #'equal))
145 *external-format-to-coding-system*)))
146
147 ;;; Unix signals
148
149 (defun sigint-handler ()
150 (with-simple-restart (continue "Continue from SIGINT handler.")
151 (invoke-debugger "SIGINT")))
152
153 (defun make-sigint-handler (process)
154 (lambda (&rest args)
155 (declare (ignore args))
156 (mp:process-interrupt process #'sigint-handler)))
157
158 (defun set-sigint-handler ()
159 ;; Set SIGINT handler on Swank request handler thread.
160 #-win32
161 (sys::set-signal-handler +sigint+
162 (make-sigint-handler mp:*current-process*)))
163
164 #-win32
165 (defimplementation install-sigint-handler (handler)
166 (sys::set-signal-handler +sigint+
167 (let ((self mp:*current-process*))
168 (lambda (&rest args)
169 (declare (ignore args))
170 (mp:process-interrupt self handler)))))
171
172 (defimplementation getpid ()
173 #+win32 (win32:get-current-process-id)
174 #-win32 (system::getpid))
175
176 (defimplementation lisp-implementation-type-name ()
177 "lispworks")
178
179 (defimplementation set-default-directory (directory)
180 (namestring (hcl:change-directory directory)))
181
182 ;;;; Documentation
183
184 (defun map-list (function list)
185 "Map over proper and not proper lists."
186 (loop for (car . cdr) on list
187 collect (funcall function car) into result
188 when (null cdr) return result
189 when (atom cdr) return (nconc result (funcall function cdr))))
190
191 (defun replace-strings-with-symbols (tree)
192 (map-list
193 (lambda (x)
194 (typecase x
195 (list
196 (replace-strings-with-symbols x))
197 (symbol
198 x)
199 (string
200 (intern x))
201 (t
202 (intern (write-to-string x)))))
203 tree))
204
205 (defimplementation arglist (symbol-or-function)
206 (let ((arglist (lw:function-lambda-list symbol-or-function)))
207 (etypecase arglist
208 ((member :dont-know)
209 :not-available)
210 (list
211 (replace-strings-with-symbols arglist)))))
212
213 (defimplementation function-name (function)
214 (nth-value 2 (function-lambda-expression function)))
215
216 (defimplementation macroexpand-all (form)
217 (walker:walk-form form))
218
219 (defun generic-function-p (object)
220 (typep object 'generic-function))
221
222 (defimplementation describe-symbol-for-emacs (symbol)
223 "Return a plist describing SYMBOL.
224 Return NIL if the symbol is unbound."
225 (let ((result '()))
226 (labels ((first-line (string)
227 (let ((pos (position #\newline string)))
228 (if (null pos) string (subseq string 0 pos))))
229 (doc (kind &optional (sym symbol))
230 (let ((string (or (documentation sym kind))))
231 (if string
232 (first-line string)
233 :not-documented)))
234 (maybe-push (property value)
235 (when value
236 (setf result (list* property value result)))))
237 (maybe-push
238 :variable (when (boundp symbol)
239 (doc 'variable)))
240 (maybe-push
241 :generic-function (if (and (fboundp symbol)
242 (generic-function-p (fdefinition symbol)))
243 (doc 'function)))
244 (maybe-push
245 :function (if (and (fboundp symbol)
246 (not (generic-function-p (fdefinition symbol))))
247 (doc 'function)))
248 (maybe-push
249 :setf (let ((setf-name (sys:underlying-setf-name `(setf ,symbol))))
250 (if (fboundp setf-name)
251 (doc 'setf))))
252 (maybe-push
253 :class (if (find-class symbol nil)
254 (doc 'class)))
255 result)))
256
257 (defimplementation describe-definition (symbol type)
258 (ecase type
259 (:variable (describe-symbol symbol))
260 (:class (describe (find-class symbol)))
261 ((:function :generic-function) (describe-function symbol))
262 (:setf (describe-function (sys:underlying-setf-name `(setf ,symbol))))))
263
264 (defun describe-function (symbol)
265 (cond ((fboundp symbol)
266 (format t "(~A ~/pprint-fill/)~%~%~:[(not documented)~;~:*~A~]~%"
267 symbol
268 (lispworks:function-lambda-list symbol)
269 (documentation symbol 'function))
270 (describe (fdefinition symbol)))
271 (t (format t "~S is not fbound" symbol))))
272
273 (defun describe-symbol (sym)
274 (format t "~A is a symbol in package ~A." sym (symbol-package sym))
275 (when (boundp sym)
276 (format t "~%~%Value: ~A" (symbol-value sym)))
277 (let ((doc (documentation sym 'variable)))
278 (when doc
279 (format t "~%~%Variable documentation:~%~A" doc)))
280 (when (fboundp sym)
281 (describe-function sym)))
282
283 ;;; Debugging
284
285 (defclass slime-env (env:environment)
286 ((debugger-hook :initarg :debugger-hoook)))
287
288 (defun slime-env (hook io-bindings)
289 (make-instance 'slime-env :name "SLIME Environment"
290 :io-bindings io-bindings
291 :debugger-hoook hook))
292
293 (defmethod env-internals:environment-display-notifier
294 ((env slime-env) &key restarts condition)
295 (declare (ignore restarts condition))
296 (funcall (swank-sym :swank-debugger-hook) condition *debugger-hook*)
297 ;; nil
298 )
299
300 (defmethod env-internals:environment-display-debugger ((env slime-env))
301 *debug-io*)
302
303 (defmethod env-internals:confirm-p ((e slime-env) &optional msg &rest args)
304 (apply (swank-sym :y-or-n-p-in-emacs) msg args))
305
306 (defimplementation call-with-debugger-hook (hook fun)
307 (let ((*debugger-hook* hook))
308 (env:with-environment ((slime-env hook '()))
309 (funcall fun))))
310
311 (defimplementation install-debugger-globally (function)
312 (setq *debugger-hook* function)
313 (setf (env:environment) (slime-env function '())))
314
315 (defvar *sldb-top-frame*)
316
317 (defun interesting-frame-p (frame)
318 (cond ((or (dbg::call-frame-p frame)
319 (dbg::derived-call-frame-p frame)
320 (dbg::foreign-frame-p frame)
321 (dbg::interpreted-call-frame-p frame))
322 t)
323 ((dbg::catch-frame-p frame) dbg:*print-catch-frames*)
324 ((dbg::binding-frame-p frame) dbg:*print-binding-frames*)
325 ((dbg::handler-frame-p frame) dbg:*print-handler-frames*)
326 ((dbg::restart-frame-p frame) dbg:*print-restart-frames*)
327 (t nil)))
328
329 (defun nth-next-frame (frame n)
330 "Unwind FRAME N times."
331 (do ((frame frame (dbg::frame-next frame))
332 (i n (if (interesting-frame-p frame) (1- i) i)))
333 ((or (not frame)
334 (and (interesting-frame-p frame) (zerop i)))
335 frame)))
336
337 (defun nth-frame (index)
338 (nth-next-frame *sldb-top-frame* index))
339
340 (defun find-top-frame ()
341 "Return the most suitable top-frame for the debugger."
342 (or (do ((frame (dbg::debugger-stack-current-frame dbg::*debugger-stack*)
343 (nth-next-frame frame 1)))
344 ((or (null frame) ; no frame found!
345 (and (dbg::call-frame-p frame)
346 (eq (dbg::call-frame-function-name frame)
347 'invoke-debugger)))
348 (nth-next-frame frame 1)))
349 ;; if we can't find a invoke-debugger frame, take any old frame at the top
350 (dbg::debugger-stack-current-frame dbg::*debugger-stack*)))
351
352 (defimplementation call-with-debugging-environment (fn)
353 (dbg::with-debugger-stack ()
354 (let ((*sldb-top-frame* (find-top-frame)))
355 (funcall fn))))
356
357 (defimplementation compute-backtrace (start end)
358 (let ((end (or end most-positive-fixnum))
359 (backtrace '()))
360 (do ((frame (nth-frame start) (dbg::frame-next frame))
361 (i start))
362 ((or (not frame) (= i end)) (nreverse backtrace))
363 (when (interesting-frame-p frame)
364 (incf i)
365 (push frame backtrace)))))
366
367 (defun frame-actual-args (frame)
368 (let ((*break-on-signals* nil))
369 (mapcar (lambda (arg)
370 (case arg
371 ((&rest &optional &key) arg)
372 (t
373 (handler-case (dbg::dbg-eval arg frame)
374 (error (e) (format nil "<~A>" arg))))))
375 (dbg::call-frame-arglist frame))))
376
377 (defimplementation print-frame (frame stream)
378 (cond ((dbg::call-frame-p frame)
379 (format stream "~S ~S"
380 (dbg::call-frame-function-name frame)
381 (frame-actual-args frame)))
382 (t (princ frame stream))))
383
384 (defun frame-vars (frame)
385 (first (dbg::frame-locals-format-list frame #'list 75 0)))
386
387 (defimplementation frame-locals (n)
388 (let ((frame (nth-frame n)))
389 (if (dbg::call-frame-p frame)
390 (mapcar (lambda (var)
391 (destructuring-bind (name value symbol location) var
392 (declare (ignore name location))
393 (list :name symbol :id 0
394 :value value)))
395 (frame-vars frame)))))
396
397 (defimplementation frame-var-value (frame var)
398 (let ((frame (nth-frame frame)))
399 (destructuring-bind (_n value _s _l) (nth var (frame-vars frame))
400 (declare (ignore _n _s _l))
401 value)))
402
403 (defimplementation frame-source-location (frame)
404 (let ((frame (nth-frame frame))
405 (callee (if (plusp frame) (nth-frame (1- frame)))))
406 (if (dbg::call-frame-p frame)
407 (let ((dspec (dbg::call-frame-function-name frame))
408 (cname (and (dbg::call-frame-p callee)
409 (dbg::call-frame-function-name callee)))
410 (path (and (dbg::call-frame-p frame)
411 (dbg::call-frame-edit-path frame))))
412 (if dspec
413 (frame-location dspec cname path))))))
414
415 (defimplementation eval-in-frame (form frame-number)
416 (let ((frame (nth-frame frame-number)))
417 (dbg::dbg-eval form frame)))
418
419 (defimplementation return-from-frame (frame-number form)
420 (let* ((frame (nth-frame frame-number))
421 (return-frame (dbg::find-frame-for-return frame)))
422 (dbg::dbg-return-from-call-frame frame form return-frame
423 dbg::*debugger-stack*)))
424
425 (defimplementation restart-frame (frame-number)
426 (let ((frame (nth-frame frame-number)))
427 (dbg::restart-frame frame :same-args t)))
428
429 (defimplementation disassemble-frame (frame-number)
430 (let* ((frame (nth-frame frame-number)))
431 (when (dbg::call-frame-p frame)
432 (let ((function (dbg::get-call-frame-function frame)))
433 (disassemble function)))))
434
435 ;;; Definition finding
436
437 (defun frame-location (dspec callee-name edit-path)
438 (let ((infos (dspec:find-dspec-locations dspec)))
439 (cond (infos
440 (destructuring-bind ((rdspec location) &rest _) infos
441 (declare (ignore _))
442 (let ((name (and callee-name (symbolp callee-name)
443 (string callee-name)))
444 (path (edit-path-to-cmucl-source-path edit-path)))
445 (make-dspec-location rdspec location
446 `(:call-site ,name :edit-path ,path)))))
447 (t
448 (list :error (format nil "Source location not available for: ~S"
449 dspec))))))
450
451 ;; dbg::call-frame-edit-path is not documented but lets assume the
452 ;; binary representation of the integer EDIT-PATH should be
453 ;; interpreted as a sequence of CAR or CDR. #b1111010 is roughly the
454 ;; same as cadadddr. Something is odd with the highest bit.
455 (defun edit-path-to-cmucl-source-path (edit-path)
456 (and edit-path
457 (cons 0
458 (let ((n -1))
459 (loop for i from (1- (integer-length edit-path)) downto 0
460 if (logbitp i edit-path) do (incf n)
461 else collect (prog1 n (setq n 0)))))))
462
463 ;; (edit-path-to-cmucl-source-path #b1111010) => (0 3 1)
464
465 (defimplementation find-definitions (name)
466 (let ((locations (dspec:find-name-locations dspec:*dspec-classes* name)))
467 (loop for (dspec location) in locations
468 collect (list dspec (make-dspec-location dspec location)))))
469
470
471 ;;; Compilation
472
473 (defmacro with-swank-compilation-unit ((location &rest options) &body body)
474 (lw:rebinding (location)
475 `(let ((compiler::*error-database* '()))
476 (with-compilation-unit ,options
477 (multiple-value-prog1 (progn ,@body)
478 (signal-error-data-base compiler::*error-database*
479 ,location)
480 (signal-undefined-functions compiler::*unknown-functions*
481 ,location))))))
482
483 (defimplementation swank-compile-file (input-file output-file
484 load-p external-format
485 &key policy)
486 (declare (ignore policy))
487 (with-swank-compilation-unit (input-file)
488 (compile-file input-file
489 :output-file output-file
490 :load load-p
491 :external-format external-format)))
492
493 (defvar *within-call-with-compilation-hooks* nil
494 "Whether COMPILE-FILE was called from within CALL-WITH-COMPILATION-HOOKS.")
495
496 (defvar *undefined-functions-hash* nil
497 "Hash table to map info about undefined functions to pathnames.")
498
499 (lw:defadvice (compile-file compile-file-and-collect-notes :around)
500 (pathname &rest rest)
501 (multiple-value-prog1 (apply #'lw:call-next-advice pathname rest)
502 (when *within-call-with-compilation-hooks*
503 (maphash (lambda (unfun dspecs)
504 (dolist (dspec dspecs)
505 (let ((unfun-info (list unfun dspec)))
506 (unless (gethash unfun-info *undefined-functions-hash*)
507 (setf (gethash unfun-info *undefined-functions-hash*)
508 pathname)))))
509 compiler::*unknown-functions*))))
510
511 (defimplementation call-with-compilation-hooks (function)
512 (let ((compiler::*error-database* '())
513 (*undefined-functions-hash* (make-hash-table :test 'equal))
514 (*within-call-with-compilation-hooks* t))
515 (with-compilation-unit ()
516 (prog1 (funcall function)
517 (signal-error-data-base compiler::*error-database*)
518 (signal-undefined-functions compiler::*unknown-functions*)))))
519
520 (defun map-error-database (database fn)
521 (loop for (filename . defs) in database do
522 (loop for (dspec . conditions) in defs do
523 (dolist (c conditions)
524 (multiple-value-bind (condition path)
525 (if (consp c) (values (car c) (cdr c)) (values c nil))
526 (funcall fn filename dspec condition path))))))
527
528 (defun lispworks-severity (condition)
529 (cond ((not condition) :warning)
530 (t (etypecase condition
531 (error :error)
532 (style-warning :warning)
533 (warning :warning)))))
534
535 (defun signal-compiler-condition (message location condition)
536 (check-type message string)
537 (signal
538 (make-instance 'compiler-condition :message message
539 :severity (lispworks-severity condition)
540 :location location
541 :original-condition condition)))
542
543 (defvar *temp-file-format* '(:utf-8 :eol-style :lf))
544
545 (defun compile-from-temp-file (string filename)
546 (unwind-protect
547 (progn
548 (with-open-file (s filename :direction :output
549 :if-exists :supersede
550 :external-format *temp-file-format*)
551
552 (write-string string s)
553 (finish-output s))
554 (multiple-value-bind (binary-filename warnings? failure?)
555 (compile-file filename :load t
556 :external-format *temp-file-format*)
557 (declare (ignore warnings?))
558 (when binary-filename
559 (delete-file binary-filename))
560 (not failure?)))
561 (delete-file filename)))
562
563 (defun dspec-function-name-position (dspec fallback)
564 (etypecase dspec
565 (cons (let ((name (dspec:dspec-primary-name dspec)))
566 (typecase name
567 ((or symbol string)
568 (list :function-name (string name)))
569 (t fallback))))
570 (null fallback)
571 (symbol (list :function-name (string dspec)))))
572
573 (defmacro with-fairly-standard-io-syntax (&body body)
574 "Like WITH-STANDARD-IO-SYNTAX but preserve *PACKAGE* and *READTABLE*."
575 (let ((package (gensym))
576 (readtable (gensym)))
577 `(let ((,package *package*)
578 (,readtable *readtable*))
579 (with-standard-io-syntax
580 (let ((*package* ,package)
581 (*readtable* ,readtable))
582 ,@body)))))
583
584 (defun skip-comments (stream)
585 (let ((pos0 (file-position stream)))
586 (cond ((equal (ignore-errors (list (read-delimited-list #\( stream)))
587 '(()))
588 (file-position stream (1- (file-position stream))))
589 (t (file-position stream pos0)))))
590
591 #-(or lispworks4.1 lispworks4.2) ; no dspec:parse-form-dspec prior to 4.3
592 (defun dspec-stream-position (stream dspec)
593 (with-fairly-standard-io-syntax
594 (loop (let* ((pos (progn (skip-comments stream) (file-position stream)))
595 (form (read stream nil '#1=#:eof)))
596 (when (eq form '#1#)
597 (return nil))
598 (labels ((check-dspec (form)
599 (when (consp form)
600 (let ((operator (car form)))
601 (case operator
602 ((progn)
603 (mapcar #'check-dspec
604 (cdr form)))
605 ((eval-when locally macrolet symbol-macrolet)
606 (mapcar #'check-dspec
607 (cddr form)))
608 ((in-package)
609 (let ((package (find-package (second form))))
610 (when package
611 (setq *package* package))))
612 (otherwise
613 (let ((form-dspec (dspec:parse-form-dspec form)))
614 (when (dspec:dspec-equal dspec form-dspec)
615 (return pos)))))))))
616 (check-dspec form))))))
617
618 (defun dspec-file-position (file dspec)
619 (let* ((*compile-file-pathname* (pathname file))
620 (*compile-file-truename* (truename *compile-file-pathname*))
621 (*load-pathname* *compile-file-pathname*)
622 (*load-truename* *compile-file-truename*))
623 (with-open-file (stream file)
624 (let ((pos
625 #-(or lispworks4.1 lispworks4.2)
626 (dspec-stream-position stream dspec)))
627 (if pos
628 (list :position (1+ pos))
629 (dspec-function-name-position dspec `(:position 1)))))))
630
631 (defun emacs-buffer-location-p (location)
632 (and (consp location)
633 (eq (car location) :emacs-buffer)))
634
635 (defun make-dspec-location (dspec location &optional hints)
636 (etypecase location
637 ((or pathname string)
638 (multiple-value-bind (file err)
639 (ignore-errors (namestring (truename location)))
640 (if err
641 (list :error (princ-to-string err))
642 (make-location `(:file ,file)
643 (dspec-file-position file dspec)
644 hints))))
645 (symbol
646 `(:error ,(format nil "Cannot resolve location: ~S" location)))
647 ((satisfies emacs-buffer-location-p)
648 (destructuring-bind (_ buffer offset string) location
649 (declare (ignore _ string))
650 (make-location `(:buffer ,buffer)
651 (dspec-function-name-position dspec `(:offset ,offset 0))
652 hints)))))
653
654 (defun make-dspec-progenitor-location (dspec location edit-path)
655 (let ((canon-dspec (dspec:canonicalize-dspec dspec)))
656 (make-dspec-location
657 (if canon-dspec
658 (if (dspec:local-dspec-p canon-dspec)
659 (dspec:dspec-progenitor canon-dspec)
660 canon-dspec)
661 nil)
662 location
663 (if edit-path
664 (list :edit-path (edit-path-to-cmucl-source-path edit-path))))))
665
666 (defun signal-error-data-base (database &optional location)
667 (map-error-database
668 database
669 (lambda (filename dspec condition edit-path)
670 (signal-compiler-condition
671 (format nil "~A" condition)
672 (make-dspec-progenitor-location dspec (or location filename) edit-path)
673 condition))))
674
675 (defun unmangle-unfun (symbol)
676 "Converts symbols like 'SETF::|\"CL-USER\" \"GET\"| to
677 function names like \(SETF GET)."
678 (cond ((sys::setf-symbol-p symbol)
679 (sys::setf-pair-from-underlying-name symbol))
680 (t symbol)))
681
682 (defun signal-undefined-functions (htab &optional filename)
683 (maphash (lambda (unfun dspecs)
684 (dolist (dspec dspecs)
685 (signal-compiler-condition
686 (format nil "Undefined function ~A" (unmangle-unfun unfun))
687 (make-dspec-progenitor-location
688 dspec
689 (or filename
690 (gethash (list unfun dspec) *undefined-functions-hash*))
691 nil)
692 nil)))
693 htab))
694
695 (defimplementation swank-compile-string (string &key buffer position filename
696 policy)
697 (declare (ignore filename policy))
698 (assert buffer)
699 (assert position)
700 (let* ((location (list :emacs-buffer buffer position string))
701 (tmpname (hcl:make-temp-file nil "lisp")))
702 (with-swank-compilation-unit (location)
703 (compile-from-temp-file
704 (with-output-to-string (s)
705 (let ((*print-radix* t))
706 (print `(eval-when (:compile-toplevel)
707 (setq dspec::*location* (list ,@location)))
708 s))
709 (write-string string s))
710 tmpname))))
711
712 ;;; xref
713
714 (defmacro defxref (name function)
715 `(defimplementation ,name (name)
716 (xref-results (,function name))))
717
718 (defxref who-calls hcl:who-calls)
719 (defxref who-macroexpands hcl:who-calls) ; macros are in the calls table too
720 (defxref calls-who hcl:calls-who)
721 (defxref list-callers list-callers-internal)
722 (defxref list-callees list-callees-internal)
723
724 (defun list-callers-internal (name)
725 (let ((callers (make-array 100
726 :fill-pointer 0
727 :adjustable t)))
728 (hcl:sweep-all-objects
729 #'(lambda (object)
730 (when (and #+Harlequin-PC-Lisp (low:compiled-code-p object)
731 #+Harlequin-Unix-Lisp (sys:callablep object)
732 #-(or Harlequin-PC-Lisp Harlequin-Unix-Lisp) (sys:compiled-code-p object)
733 (system::find-constant$funcallable name object))
734 (vector-push-extend object callers))))
735 ;; Delay dspec:object-dspec until after sweep-all-objects
736 ;; to reduce allocation problems.
737 (loop for object across callers
738 collect (if (symbolp object)
739 (list 'function object)
740 (or (dspec:object-dspec object) object)))))
741
742 (defun list-callees-internal (name)
743 (let ((callees '()))
744 (system::find-constant$funcallable
745 'junk name
746 :test #'(lambda (junk constant)
747 (declare (ignore junk))
748 (when (and (symbolp constant)
749 (fboundp constant))
750 (pushnew (list 'function constant) callees :test 'equal))
751 ;; Return nil so we iterate over all constants.
752 nil))
753 callees))
754
755 ;; only for lispworks 4.2 and above
756 #-lispworks4.1
757 (progn
758 (defxref who-references hcl:who-references)
759 (defxref who-binds hcl:who-binds)
760 (defxref who-sets hcl:who-sets))
761
762 (defimplementation who-specializes (classname)
763 (let ((methods (clos:class-direct-methods (find-class classname))))
764 (xref-results (mapcar #'dspec:object-dspec methods))))
765
766 (defun xref-results (dspecs)
767 (flet ((frob-locs (dspec locs)
768 (cond (locs
769 (loop for (name loc) in locs
770 collect (list name (make-dspec-location name loc))))
771 (t `((,dspec (:error "Source location not available")))))))
772 (loop for dspec in dspecs
773 append (frob-locs dspec (dspec:dspec-definition-locations dspec)))))
774
775 ;;; Inspector
776
777 (defmethod emacs-inspect ((o t))
778 (lispworks-inspect o))
779
780 (defmethod emacs-inspect ((o function))
781 (lispworks-inspect o))
782
783 ;; FIXME: slot-boundp-using-class in LW works with names so we can't
784 ;; use our method in swank.lisp.
785 (defmethod emacs-inspect ((o standard-object))
786 (lispworks-inspect o))
787
788 (defun lispworks-inspect (o)
789 (multiple-value-bind (names values _getter _setter type)
790 (lw:get-inspector-values o nil)
791 (declare (ignore _getter _setter))
792 (append
793 (label-value-line "Type" type)
794 (loop for name in names
795 for value in values
796 append (label-value-line name value)))))
797
798 ;;; Miscellaneous
799
800 (defimplementation quit-lisp ()
801 (lispworks:quit))
802
803 ;;; Tracing
804
805 (defun parse-fspec (fspec)
806 "Return a dspec for FSPEC."
807 (ecase (car fspec)
808 ((:defmethod) `(method ,(cdr fspec)))))
809
810 (defun tracedp (dspec)
811 (member dspec (eval '(trace)) :test #'equal))
812
813 (defun toggle-trace-aux (dspec)
814 (cond ((tracedp dspec)
815 (eval `(untrace ,dspec))
816 (format nil "~S is now untraced." dspec))
817 (t
818 (eval `(trace (,dspec)))
819 (format nil "~S is now traced." dspec))))
820
821 (defimplementation toggle-trace (fspec)
822 (toggle-trace-aux (parse-fspec fspec)))
823
824 ;;; Multithreading
825
826 (defimplementation initialize-multiprocessing (continuation)
827 (cond ((not mp::*multiprocessing*)
828 (push (list "Initialize SLIME" '() continuation)
829 mp:*initial-processes*)
830 (mp:initialize-multiprocessing))
831 (t (funcall continuation))))
832
833 (defimplementation spawn (fn &key name)
834 (mp:process-run-function name () fn))
835
836 (defvar *id-lock* (mp:make-lock))
837 (defvar *thread-id-counter* 0)
838
839 (defimplementation thread-id (thread)
840 (mp:with-lock (*id-lock*)
841 (or (getf (mp:process-plist thread) 'id)
842 (setf (getf (mp:process-plist thread) 'id)
843 (incf *thread-id-counter*)))))
844
845 (defimplementation find-thread (id)
846 (find id (mp:list-all-processes)
847 :key (lambda (p) (getf (mp:process-plist p) 'id))))
848
849 (defimplementation thread-name (thread)
850 (mp:process-name thread))
851
852 (defimplementation thread-status (thread)
853 (format nil "~A ~D"
854 (mp:process-whostate thread)
855 (mp:process-priority thread)))
856
857 (defimplementation make-lock (&key name)
858 (mp:make-lock :name name))
859
860 (defimplementation call-with-lock-held (lock function)
861 (mp:with-lock (lock) (funcall function)))
862
863 (defimplementation current-thread ()
864 mp:*current-process*)
865
866 (defimplementation all-threads ()
867 (mp:list-all-processes))
868
869 (defimplementation interrupt-thread (thread fn)
870 (mp:process-interrupt thread fn))
871
872 (defimplementation kill-thread (thread)
873 (mp:process-kill thread))
874
875 (defimplementation thread-alive-p (thread)
876 (mp:process-alive-p thread))
877
878 (defstruct (mailbox (:conc-name mailbox.))
879 (mutex (mp:make-lock :name "thread mailbox"))
880 (queue '() :type list))
881
882 (defvar *mailbox-lock* (mp:make-lock))
883
884 (defun mailbox (thread)
885 (mp:with-lock (*mailbox-lock*)
886 (or (getf (mp:process-plist thread) 'mailbox)
887 (setf (getf (mp:process-plist thread) 'mailbox)
888 (make-mailbox)))))
889
890 (defimplementation receive-if (test &optional timeout)
891 (let* ((mbox (mailbox mp:*current-process*))
892 (lock (mailbox.mutex mbox)))
893 (assert (or (not timeout) (eq timeout t)))
894 (loop
895 (check-slime-interrupts)
896 (mp:with-lock (lock "receive-if/try")
897 (let* ((q (mailbox.queue mbox))
898 (tail (member-if test q)))
899 (when tail
900 (setf (mailbox.queue mbox) (nconc (ldiff q tail) (cdr tail)))
901 (return (car tail)))))
902 (when (eq timeout t) (return (values nil t)))
903 (mp:process-wait-with-timeout
904 "receive-if" 0.3 (lambda () (some test (mailbox.queue mbox)))))))
905
906 (defimplementation send (thread message)
907 (let ((mbox (mailbox thread)))
908 (mp:with-lock ((mailbox.mutex mbox))
909 (setf (mailbox.queue mbox)
910 (nconc (mailbox.queue mbox) (list message))))))
911
912 (defimplementation set-default-initial-binding (var form)
913 (setq mp:*process-initial-bindings*
914 (acons var `(eval (quote ,form))
915 mp:*process-initial-bindings* )))
916
917 (defimplementation thread-attributes (thread)
918 (list :priority (mp:process-priority thread)
919 :idle (mp:process-idle-time thread)))
920
921 ;;; Some intergration with the lispworks environment
922
923 (defun swank-sym (name) (find-symbol (string name) :swank))
924
925
926 ;;;; Weak hashtables
927
928 (defimplementation make-weak-key-hash-table (&rest args)
929 (apply #'make-hash-table :weak-kind :key args))
930
931 (defimplementation make-weak-value-hash-table (&rest args)
932 (apply #'make-hash-table :weak-kind :value args))

  ViewVC Help
Powered by ViewVC 1.1.5