/[slime]/slime/swank-lispworks.lisp
ViewVC logotype

Contents of /slime/swank-lispworks.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.138 - (show annotations)
Tue Nov 2 12:32:10 2010 UTC (3 years, 5 months ago) by msimmons
Branch: MAIN
Changes since 1.137: +13 -19 lines
* swank-lispworks.lisp (list-callers-internal): Revert to previous
low level implementation, fixed for LW6.
(list-callees-internal): Reimplement using low level instead of
the compiler's xref.
1 ;;; -*- indent-tabs-mode: nil -*-
2 ;;;
3 ;;; swank-lispworks.lisp --- LispWorks specific code for SLIME.
4 ;;;
5 ;;; Created 2003, Helmut Eller
6 ;;;
7 ;;; This code has been placed in the Public Domain. All warranties
8 ;;; are disclaimed.
9 ;;;
10
11 (in-package :swank-backend)
12
13 (eval-when (:compile-toplevel :load-toplevel :execute)
14 (require "comm")
15 (import-from :stream *gray-stream-symbols* :swank-backend))
16
17 (import-swank-mop-symbols :clos '(:slot-definition-documentation
18 :slot-boundp-using-class
19 :slot-value-using-class
20 :slot-makunbound-using-class
21 :eql-specializer
22 :eql-specializer-object
23 :compute-applicable-methods-using-classes))
24
25 (defun swank-mop:slot-definition-documentation (slot)
26 (documentation slot t))
27
28 (defun swank-mop:slot-boundp-using-class (class object slotd)
29 (clos:slot-boundp-using-class class object
30 (clos:slot-definition-name slotd)))
31
32 (defun swank-mop:slot-value-using-class (class object slotd)
33 (clos:slot-value-using-class class object
34 (clos:slot-definition-name slotd)))
35
36 (defun (setf swank-mop:slot-value-using-class) (value class object slotd)
37 (setf (clos:slot-value-using-class class object
38 (clos:slot-definition-name slotd))
39 value))
40
41 (defun swank-mop:slot-makunbound-using-class (class object slotd)
42 (clos:slot-makunbound-using-class class object
43 (clos:slot-definition-name slotd)))
44
45 (defun swank-mop:compute-applicable-methods-using-classes (gf classes)
46 (clos::compute-applicable-methods-from-classes gf classes))
47
48 ;; lispworks doesn't have the eql-specializer class, it represents
49 ;; them as a list of `(EQL ,OBJECT)
50 (deftype swank-mop:eql-specializer () 'cons)
51
52 (defun swank-mop:eql-specializer-object (eql-spec)
53 (second eql-spec))
54
55 (eval-when (:compile-toplevel :execute :load-toplevel)
56 (defvar *original-defimplementation* (macro-function 'defimplementation))
57 (defmacro defimplementation (&whole whole name args &body body
58 &environment env)
59 (declare (ignore args body))
60 `(progn
61 (dspec:record-definition '(defun ,name) (dspec:location)
62 :check-redefinition-p nil)
63 ,(funcall *original-defimplementation* whole env))))
64
65 ;;; TCP server
66
67 (defimplementation preferred-communication-style ()
68 :spawn)
69
70 (defun socket-fd (socket)
71 (etypecase socket
72 (fixnum socket)
73 (comm:socket-stream (comm:socket-stream-socket socket))))
74
75 (defimplementation create-socket (host port)
76 (multiple-value-bind (socket where errno)
77 #-(or lispworks4.1 (and macosx lispworks4.3))
78 (comm::create-tcp-socket-for-service port :address host)
79 #+(or lispworks4.1 (and macosx lispworks4.3))
80 (comm::create-tcp-socket-for-service port)
81 (cond (socket socket)
82 (t (error 'network-error
83 :format-control "~A failed: ~A (~D)"
84 :format-arguments (list where
85 (list #+unix (lw:get-unix-error errno))
86 errno))))))
87
88 (defimplementation local-port (socket)
89 (nth-value 1 (comm:get-socket-address (socket-fd socket))))
90
91 (defimplementation close-socket (socket)
92 (comm::close-socket (socket-fd socket)))
93
94 (defimplementation accept-connection (socket
95 &key external-format buffering timeout)
96 (declare (ignore buffering))
97 (let* ((fd (comm::get-fd-from-socket socket)))
98 (assert (/= fd -1))
99 (assert (valid-external-format-p external-format))
100 (cond ((member (first external-format) '(:latin-1 :ascii))
101 (make-instance 'comm:socket-stream
102 :socket fd
103 :direction :io
104 :read-timeout timeout
105 :element-type 'base-char))
106 (t
107 (make-flexi-stream
108 (make-instance 'comm:socket-stream
109 :socket fd
110 :direction :io
111 :read-timeout timeout
112 :element-type '(unsigned-byte 8))
113 external-format)))))
114
115 (defun make-flexi-stream (stream external-format)
116 (unless (member :flexi-streams *features*)
117 (error "Cannot use external format ~A without having installed flexi-streams in the inferior-lisp."
118 external-format))
119 (funcall (read-from-string "FLEXI-STREAMS:MAKE-FLEXI-STREAM")
120 stream
121 :external-format
122 (apply (read-from-string "FLEXI-STREAMS:MAKE-EXTERNAL-FORMAT")
123 external-format)))
124
125 ;;; Coding Systems
126
127 (defun valid-external-format-p (external-format)
128 (member external-format *external-format-to-coding-system*
129 :test #'equal :key #'car))
130
131 (defvar *external-format-to-coding-system*
132 '(((:latin-1 :eol-style :lf)
133 "latin-1-unix" "iso-latin-1-unix" "iso-8859-1-unix")
134 ((:latin-1)
135 "latin-1" "iso-latin-1" "iso-8859-1")
136 ((:utf-8) "utf-8")
137 ((:utf-8 :eol-style :lf) "utf-8-unix")
138 ((:euc-jp) "euc-jp")
139 ((:euc-jp :eol-style :lf) "euc-jp-unix")
140 ((:ascii) "us-ascii")
141 ((:ascii :eol-style :lf) "us-ascii-unix")))
142
143 (defimplementation find-external-format (coding-system)
144 (car (rassoc-if (lambda (x) (member coding-system x :test #'equal))
145 *external-format-to-coding-system*)))
146
147 ;;; Unix signals
148
149 (defun sigint-handler ()
150 (with-simple-restart (continue "Continue from SIGINT handler.")
151 (invoke-debugger "SIGINT")))
152
153 (defun make-sigint-handler (process)
154 (lambda (&rest args)
155 (declare (ignore args))
156 (mp:process-interrupt process #'sigint-handler)))
157
158 (defun set-sigint-handler ()
159 ;; Set SIGINT handler on Swank request handler thread.
160 #-win32
161 (sys::set-signal-handler +sigint+
162 (make-sigint-handler mp:*current-process*)))
163
164 #-win32
165 (defimplementation install-sigint-handler (handler)
166 (sys::set-signal-handler +sigint+
167 (let ((self mp:*current-process*))
168 (lambda (&rest args)
169 (declare (ignore args))
170 (mp:process-interrupt self handler)))))
171
172 (defimplementation getpid ()
173 #+win32 (win32:get-current-process-id)
174 #-win32 (system::getpid))
175
176 (defimplementation lisp-implementation-type-name ()
177 "lispworks")
178
179 (defimplementation set-default-directory (directory)
180 (namestring (hcl:change-directory directory)))
181
182 ;;;; Documentation
183
184 (defun map-list (function list)
185 "Map over proper and not proper lists."
186 (loop for (car . cdr) on list
187 collect (funcall function car) into result
188 when (null cdr) return result
189 when (atom cdr) return (nconc result (funcall function cdr))))
190
191 (defun replace-strings-with-symbols (tree)
192 (map-list
193 (lambda (x)
194 (typecase x
195 (list
196 (replace-strings-with-symbols x))
197 (symbol
198 x)
199 (string
200 (intern x))
201 (t
202 (intern (write-to-string x)))))
203 tree))
204
205 (defimplementation arglist (symbol-or-function)
206 (let ((arglist (lw:function-lambda-list symbol-or-function)))
207 (etypecase arglist
208 ((member :dont-know)
209 :not-available)
210 (list
211 (replace-strings-with-symbols arglist)))))
212
213 (defimplementation function-name (function)
214 (nth-value 2 (function-lambda-expression function)))
215
216 (defimplementation macroexpand-all (form)
217 (walker:walk-form form))
218
219 (defun generic-function-p (object)
220 (typep object 'generic-function))
221
222 (defimplementation describe-symbol-for-emacs (symbol)
223 "Return a plist describing SYMBOL.
224 Return NIL if the symbol is unbound."
225 (let ((result '()))
226 (labels ((first-line (string)
227 (let ((pos (position #\newline string)))
228 (if (null pos) string (subseq string 0 pos))))
229 (doc (kind &optional (sym symbol))
230 (let ((string (or (documentation sym kind))))
231 (if string
232 (first-line string)
233 :not-documented)))
234 (maybe-push (property value)
235 (when value
236 (setf result (list* property value result)))))
237 (maybe-push
238 :variable (when (boundp symbol)
239 (doc 'variable)))
240 (maybe-push
241 :generic-function (if (and (fboundp symbol)
242 (generic-function-p (fdefinition symbol)))
243 (doc 'function)))
244 (maybe-push
245 :function (if (and (fboundp symbol)
246 (not (generic-function-p (fdefinition symbol))))
247 (doc 'function)))
248 (maybe-push
249 :setf (let ((setf-name (sys:underlying-setf-name `(setf ,symbol))))
250 (if (fboundp setf-name)
251 (doc 'setf))))
252 (maybe-push
253 :class (if (find-class symbol nil)
254 (doc 'class)))
255 result)))
256
257 (defimplementation describe-definition (symbol type)
258 (ecase type
259 (:variable (describe-symbol symbol))
260 (:class (describe (find-class symbol)))
261 ((:function :generic-function) (describe-function symbol))
262 (:setf (describe-function (sys:underlying-setf-name `(setf ,symbol))))))
263
264 (defun describe-function (symbol)
265 (cond ((fboundp symbol)
266 (format t "(~A ~/pprint-fill/)~%~%~:[(not documented)~;~:*~A~]~%"
267 symbol
268 (lispworks:function-lambda-list symbol)
269 (documentation symbol 'function))
270 (describe (fdefinition symbol)))
271 (t (format t "~S is not fbound" symbol))))
272
273 (defun describe-symbol (sym)
274 (format t "~A is a symbol in package ~A." sym (symbol-package sym))
275 (when (boundp sym)
276 (format t "~%~%Value: ~A" (symbol-value sym)))
277 (let ((doc (documentation sym 'variable)))
278 (when doc
279 (format t "~%~%Variable documentation:~%~A" doc)))
280 (when (fboundp sym)
281 (describe-function sym)))
282
283 ;;; Debugging
284
285 (defclass slime-env (env:environment)
286 ((debugger-hook :initarg :debugger-hoook)))
287
288 (defun slime-env (hook io-bindings)
289 (make-instance 'slime-env :name "SLIME Environment"
290 :io-bindings io-bindings
291 :debugger-hoook hook))
292
293 (defmethod env-internals:environment-display-notifier
294 ((env slime-env) &key restarts condition)
295 (declare (ignore restarts condition))
296 (funcall (swank-sym :swank-debugger-hook) condition *debugger-hook*)
297 ;; nil
298 )
299
300 (defmethod env-internals:environment-display-debugger ((env slime-env))
301 *debug-io*)
302
303 (defmethod env-internals:confirm-p ((e slime-env) &optional msg &rest args)
304 (apply (swank-sym :y-or-n-p-in-emacs) msg args))
305
306 (defimplementation call-with-debugger-hook (hook fun)
307 (let ((*debugger-hook* hook))
308 (env:with-environment ((slime-env hook '()))
309 (funcall fun))))
310
311 (defimplementation install-debugger-globally (function)
312 (setq *debugger-hook* function)
313 (setf (env:environment) (slime-env function '())))
314
315 (defvar *sldb-top-frame*)
316
317 (defun interesting-frame-p (frame)
318 (cond ((or (dbg::call-frame-p frame)
319 (dbg::derived-call-frame-p frame)
320 (dbg::foreign-frame-p frame)
321 (dbg::interpreted-call-frame-p frame))
322 t)
323 ((dbg::catch-frame-p frame) dbg:*print-catch-frames*)
324 ((dbg::binding-frame-p frame) dbg:*print-binding-frames*)
325 ((dbg::handler-frame-p frame) dbg:*print-handler-frames*)
326 ((dbg::restart-frame-p frame) dbg:*print-restart-frames*)
327 (t nil)))
328
329 (defun nth-next-frame (frame n)
330 "Unwind FRAME N times."
331 (do ((frame frame (dbg::frame-next frame))
332 (i n (if (interesting-frame-p frame) (1- i) i)))
333 ((or (not frame)
334 (and (interesting-frame-p frame) (zerop i)))
335 frame)))
336
337 (defun nth-frame (index)
338 (nth-next-frame *sldb-top-frame* index))
339
340 (defun find-top-frame ()
341 "Return the most suitable top-frame for the debugger."
342 (or (do ((frame (dbg::debugger-stack-current-frame dbg::*debugger-stack*)
343 (nth-next-frame frame 1)))
344 ((or (null frame) ; no frame found!
345 (and (dbg::call-frame-p frame)
346 (eq (dbg::call-frame-function-name frame)
347 'invoke-debugger)))
348 (nth-next-frame frame 1)))
349 ;; if we can't find a invoke-debugger frame, take any old frame at the top
350 (dbg::debugger-stack-current-frame dbg::*debugger-stack*)))
351
352 (defimplementation call-with-debugging-environment (fn)
353 (dbg::with-debugger-stack ()
354 (let ((*sldb-top-frame* (find-top-frame)))
355 (funcall fn))))
356
357 (defimplementation compute-backtrace (start end)
358 (let ((end (or end most-positive-fixnum))
359 (backtrace '()))
360 (do ((frame (nth-frame start) (dbg::frame-next frame))
361 (i start))
362 ((or (not frame) (= i end)) (nreverse backtrace))
363 (when (interesting-frame-p frame)
364 (incf i)
365 (push frame backtrace)))))
366
367 (defun frame-actual-args (frame)
368 (let ((*break-on-signals* nil))
369 (mapcar (lambda (arg)
370 (case arg
371 ((&rest &optional &key) arg)
372 (t
373 (handler-case (dbg::dbg-eval arg frame)
374 (error (e) (format nil "<~A>" arg))))))
375 (dbg::call-frame-arglist frame))))
376
377 (defimplementation print-frame (frame stream)
378 (cond ((dbg::call-frame-p frame)
379 (format stream "~S ~S"
380 (dbg::call-frame-function-name frame)
381 (frame-actual-args frame)))
382 (t (princ frame stream))))
383
384 (defun frame-vars (frame)
385 (first (dbg::frame-locals-format-list frame #'list 75 0)))
386
387 (defimplementation frame-locals (n)
388 (let ((frame (nth-frame n)))
389 (if (dbg::call-frame-p frame)
390 (mapcar (lambda (var)
391 (destructuring-bind (name value symbol location) var
392 (declare (ignore name location))
393 (list :name symbol :id 0
394 :value value)))
395 (frame-vars frame)))))
396
397 (defimplementation frame-var-value (frame var)
398 (let ((frame (nth-frame frame)))
399 (destructuring-bind (_n value _s _l) (nth var (frame-vars frame))
400 (declare (ignore _n _s _l))
401 value)))
402
403 (defimplementation frame-source-location (frame)
404 (let ((frame (nth-frame frame))
405 (callee (if (plusp frame) (nth-frame (1- frame)))))
406 (if (dbg::call-frame-p frame)
407 (let ((dspec (dbg::call-frame-function-name frame))
408 (cname (and (dbg::call-frame-p callee)
409 (dbg::call-frame-function-name callee))))
410 (if dspec
411 (frame-location dspec cname))))))
412
413 (defimplementation eval-in-frame (form frame-number)
414 (let ((frame (nth-frame frame-number)))
415 (dbg::dbg-eval form frame)))
416
417 (defimplementation return-from-frame (frame-number form)
418 (let* ((frame (nth-frame frame-number))
419 (return-frame (dbg::find-frame-for-return frame)))
420 (dbg::dbg-return-from-call-frame frame form return-frame
421 dbg::*debugger-stack*)))
422
423 (defimplementation restart-frame (frame-number)
424 (let ((frame (nth-frame frame-number)))
425 (dbg::restart-frame frame :same-args t)))
426
427 (defimplementation disassemble-frame (frame-number)
428 (let* ((frame (nth-frame frame-number)))
429 (when (dbg::call-frame-p frame)
430 (let ((function (dbg::get-call-frame-function frame)))
431 (disassemble function)))))
432
433 ;;; Definition finding
434
435 (defun frame-location (dspec callee-name)
436 (let ((infos (dspec:find-dspec-locations dspec)))
437 (cond (infos
438 (destructuring-bind ((rdspec location) &rest _) infos
439 (declare (ignore _))
440 (let ((name (and callee-name (symbolp callee-name)
441 (string callee-name))))
442 (make-dspec-location rdspec location
443 `(:call-site ,name)))))
444 (t
445 (list :error (format nil "Source location not available for: ~S"
446 dspec))))))
447
448 (defimplementation find-definitions (name)
449 (let ((locations (dspec:find-name-locations dspec:*dspec-classes* name)))
450 (loop for (dspec location) in locations
451 collect (list dspec (make-dspec-location dspec location)))))
452
453
454 ;;; Compilation
455
456 (defmacro with-swank-compilation-unit ((location &rest options) &body body)
457 (lw:rebinding (location)
458 `(let ((compiler::*error-database* '()))
459 (with-compilation-unit ,options
460 (multiple-value-prog1 (progn ,@body)
461 (signal-error-data-base compiler::*error-database*
462 ,location)
463 (signal-undefined-functions compiler::*unknown-functions*
464 ,location))))))
465
466 (defimplementation swank-compile-file (input-file output-file
467 load-p external-format
468 &key policy)
469 (declare (ignore policy))
470 (with-swank-compilation-unit (input-file)
471 (compile-file input-file
472 :output-file output-file
473 :load load-p
474 :external-format external-format)))
475
476 (defvar *within-call-with-compilation-hooks* nil
477 "Whether COMPILE-FILE was called from within CALL-WITH-COMPILATION-HOOKS.")
478
479 (defvar *undefined-functions-hash* nil
480 "Hash table to map info about undefined functions to pathnames.")
481
482 (lw:defadvice (compile-file compile-file-and-collect-notes :around)
483 (pathname &rest rest)
484 (multiple-value-prog1 (apply #'lw:call-next-advice pathname rest)
485 (when *within-call-with-compilation-hooks*
486 (maphash (lambda (unfun dspecs)
487 (dolist (dspec dspecs)
488 (let ((unfun-info (list unfun dspec)))
489 (unless (gethash unfun-info *undefined-functions-hash*)
490 (setf (gethash unfun-info *undefined-functions-hash*)
491 pathname)))))
492 compiler::*unknown-functions*))))
493
494 (defimplementation call-with-compilation-hooks (function)
495 (let ((compiler::*error-database* '())
496 (*undefined-functions-hash* (make-hash-table :test 'equal))
497 (*within-call-with-compilation-hooks* t))
498 (with-compilation-unit ()
499 (prog1 (funcall function)
500 (signal-error-data-base compiler::*error-database*)
501 (signal-undefined-functions compiler::*unknown-functions*)))))
502
503 (defun map-error-database (database fn)
504 (loop for (filename . defs) in database do
505 (loop for (dspec . conditions) in defs do
506 (dolist (c conditions)
507 (funcall fn filename dspec (if (consp c) (car c) c))))))
508
509 (defun lispworks-severity (condition)
510 (cond ((not condition) :warning)
511 (t (etypecase condition
512 (error :error)
513 (style-warning :warning)
514 (warning :warning)))))
515
516 (defun signal-compiler-condition (message location condition)
517 (check-type message string)
518 (signal
519 (make-instance 'compiler-condition :message message
520 :severity (lispworks-severity condition)
521 :location location
522 :original-condition condition)))
523
524 (defvar *temp-file-format* '(:utf-8 :eol-style :lf))
525
526 (defun compile-from-temp-file (string filename)
527 (unwind-protect
528 (progn
529 (with-open-file (s filename :direction :output
530 :if-exists :supersede
531 :external-format *temp-file-format*)
532
533 (write-string string s)
534 (finish-output s))
535 (multiple-value-bind (binary-filename warnings? failure?)
536 (compile-file filename :load t
537 :external-format *temp-file-format*)
538 (declare (ignore warnings?))
539 (when binary-filename
540 (delete-file binary-filename))
541 (not failure?)))
542 (delete-file filename)))
543
544 (defun dspec-function-name-position (dspec fallback)
545 (etypecase dspec
546 (cons (let ((name (dspec:dspec-primary-name dspec)))
547 (typecase name
548 ((or symbol string)
549 (list :function-name (string name)))
550 (t fallback))))
551 (null fallback)
552 (symbol (list :function-name (string dspec)))))
553
554 (defmacro with-fairly-standard-io-syntax (&body body)
555 "Like WITH-STANDARD-IO-SYNTAX but preserve *PACKAGE* and *READTABLE*."
556 (let ((package (gensym))
557 (readtable (gensym)))
558 `(let ((,package *package*)
559 (,readtable *readtable*))
560 (with-standard-io-syntax
561 (let ((*package* ,package)
562 (*readtable* ,readtable))
563 ,@body)))))
564
565 (defun skip-comments (stream)
566 (let ((pos0 (file-position stream)))
567 (cond ((equal (ignore-errors (list (read-delimited-list #\( stream)))
568 '(()))
569 (file-position stream (1- (file-position stream))))
570 (t (file-position stream pos0)))))
571
572 #-(or lispworks4.1 lispworks4.2) ; no dspec:parse-form-dspec prior to 4.3
573 (defun dspec-stream-position (stream dspec)
574 (with-fairly-standard-io-syntax
575 (loop (let* ((pos (progn (skip-comments stream) (file-position stream)))
576 (form (read stream nil '#1=#:eof)))
577 (when (eq form '#1#)
578 (return nil))
579 (labels ((check-dspec (form)
580 (when (consp form)
581 (let ((operator (car form)))
582 (case operator
583 ((progn)
584 (mapcar #'check-dspec
585 (cdr form)))
586 ((eval-when locally macrolet symbol-macrolet)
587 (mapcar #'check-dspec
588 (cddr form)))
589 ((in-package)
590 (let ((package (find-package (second form))))
591 (when package
592 (setq *package* package))))
593 (otherwise
594 (let ((form-dspec (dspec:parse-form-dspec form)))
595 (when (dspec:dspec-equal dspec form-dspec)
596 (return pos)))))))))
597 (check-dspec form))))))
598
599 (defun dspec-file-position (file dspec)
600 (let* ((*compile-file-pathname* (pathname file))
601 (*compile-file-truename* (truename *compile-file-pathname*))
602 (*load-pathname* *compile-file-pathname*)
603 (*load-truename* *compile-file-truename*))
604 (with-open-file (stream file)
605 (let ((pos
606 #-(or lispworks4.1 lispworks4.2)
607 (dspec-stream-position stream dspec)))
608 (if pos
609 (list :position (1+ pos))
610 (dspec-function-name-position dspec `(:position 1)))))))
611
612 (defun emacs-buffer-location-p (location)
613 (and (consp location)
614 (eq (car location) :emacs-buffer)))
615
616 (defun make-dspec-location (dspec location &optional hints)
617 (etypecase location
618 ((or pathname string)
619 (multiple-value-bind (file err)
620 (ignore-errors (namestring (truename location)))
621 (if err
622 (list :error (princ-to-string err))
623 (make-location `(:file ,file)
624 (dspec-file-position file dspec)
625 hints))))
626 (symbol
627 `(:error ,(format nil "Cannot resolve location: ~S" location)))
628 ((satisfies emacs-buffer-location-p)
629 (destructuring-bind (_ buffer offset string) location
630 (declare (ignore _ string))
631 (make-location `(:buffer ,buffer)
632 (dspec-function-name-position dspec `(:offset ,offset 0))
633 hints)))))
634
635 (defun make-dspec-progenitor-location (dspec location)
636 (let ((canon-dspec (dspec:canonicalize-dspec dspec)))
637 (make-dspec-location
638 (if canon-dspec
639 (if (dspec:local-dspec-p canon-dspec)
640 (dspec:dspec-progenitor canon-dspec)
641 canon-dspec)
642 nil)
643 location)))
644
645 (defun signal-error-data-base (database &optional location)
646 (map-error-database
647 database
648 (lambda (filename dspec condition)
649 (signal-compiler-condition
650 (format nil "~A" condition)
651 (make-dspec-progenitor-location dspec (or location filename))
652 condition))))
653
654 (defun unmangle-unfun (symbol)
655 "Converts symbols like 'SETF::|\"CL-USER\" \"GET\"| to
656 function names like \(SETF GET)."
657 (cond ((sys::setf-symbol-p symbol)
658 (sys::setf-pair-from-underlying-name symbol))
659 (t symbol)))
660
661 (defun signal-undefined-functions (htab &optional filename)
662 (maphash (lambda (unfun dspecs)
663 (dolist (dspec dspecs)
664 (signal-compiler-condition
665 (format nil "Undefined function ~A" (unmangle-unfun unfun))
666 (make-dspec-progenitor-location dspec
667 (or filename
668 (gethash (list unfun dspec)
669 *undefined-functions-hash*)))
670 nil)))
671 htab))
672
673 (defimplementation swank-compile-string (string &key buffer position filename
674 policy)
675 (declare (ignore filename policy))
676 (assert buffer)
677 (assert position)
678 (let* ((location (list :emacs-buffer buffer position string))
679 (tmpname (hcl:make-temp-file nil "lisp")))
680 (with-swank-compilation-unit (location)
681 (compile-from-temp-file
682 (with-output-to-string (s)
683 (let ((*print-radix* t))
684 (print `(eval-when (:compile-toplevel)
685 (setq dspec::*location* (list ,@location)))
686 s))
687 (write-string string s))
688 tmpname))))
689
690 ;;; xref
691
692 (defmacro defxref (name function)
693 `(defimplementation ,name (name)
694 (xref-results (,function name))))
695
696 (defxref who-calls hcl:who-calls)
697 (defxref who-macroexpands hcl:who-calls) ; macros are in the calls table too
698 (defxref calls-who hcl:calls-who)
699 (defxref list-callers list-callers-internal)
700 (defxref list-callees list-callees-internal)
701
702 (defun list-callers-internal (name)
703 (let ((callers (make-array 100
704 :fill-pointer 0
705 :adjustable t)))
706 (hcl:sweep-all-objects
707 #'(lambda (object)
708 (when (and #+Harlequin-PC-Lisp (low:compiled-code-p object)
709 #+Harlequin-Unix-Lisp (sys:callablep object)
710 #-(or Harlequin-PC-Lisp Harlequin-Unix-Lisp) (sys:compiled-code-p object)
711 (system::find-constant$funcallable name object))
712 (vector-push-extend object callers))))
713 ;; Delay dspec:object-dspec until after sweep-all-objects
714 ;; to reduce allocation problems.
715 (loop for object across callers
716 collect (if (symbolp object)
717 (list 'function object)
718 (or (dspec:object-dspec object) object)))))
719
720 (defun list-callees-internal (name)
721 (let ((callees '()))
722 (system::find-constant$funcallable
723 'junk name
724 :test #'(lambda (junk constant)
725 (declare (ignore junk))
726 (when (and (symbolp constant)
727 (fboundp constant))
728 (pushnew (list 'function constant) callees :test 'equal))
729 ;; Return nil so we iterate over all constants.
730 nil))
731 callees))
732
733 ;; only for lispworks 4.2 and above
734 #-lispworks4.1
735 (progn
736 (defxref who-references hcl:who-references)
737 (defxref who-binds hcl:who-binds)
738 (defxref who-sets hcl:who-sets))
739
740 (defimplementation who-specializes (classname)
741 (let ((methods (clos:class-direct-methods (find-class classname))))
742 (xref-results (mapcar #'dspec:object-dspec methods))))
743
744 (defun xref-results (dspecs)
745 (flet ((frob-locs (dspec locs)
746 (cond (locs
747 (loop for (name loc) in locs
748 collect (list name (make-dspec-location name loc))))
749 (t `((,dspec (:error "Source location not available")))))))
750 (loop for dspec in dspecs
751 append (frob-locs dspec (dspec:dspec-definition-locations dspec)))))
752
753 ;;; Inspector
754
755 (defmethod emacs-inspect ((o t))
756 (lispworks-inspect o))
757
758 (defmethod emacs-inspect ((o function))
759 (lispworks-inspect o))
760
761 ;; FIXME: slot-boundp-using-class in LW works with names so we can't
762 ;; use our method in swank.lisp.
763 (defmethod emacs-inspect ((o standard-object))
764 (lispworks-inspect o))
765
766 (defun lispworks-inspect (o)
767 (multiple-value-bind (names values _getter _setter type)
768 (lw:get-inspector-values o nil)
769 (declare (ignore _getter _setter))
770 (append
771 (label-value-line "Type" type)
772 (loop for name in names
773 for value in values
774 append (label-value-line name value)))))
775
776 ;;; Miscellaneous
777
778 (defimplementation quit-lisp ()
779 (lispworks:quit))
780
781 ;;; Tracing
782
783 (defun parse-fspec (fspec)
784 "Return a dspec for FSPEC."
785 (ecase (car fspec)
786 ((:defmethod) `(method ,(cdr fspec)))))
787
788 (defun tracedp (dspec)
789 (member dspec (eval '(trace)) :test #'equal))
790
791 (defun toggle-trace-aux (dspec)
792 (cond ((tracedp dspec)
793 (eval `(untrace ,dspec))
794 (format nil "~S is now untraced." dspec))
795 (t
796 (eval `(trace (,dspec)))
797 (format nil "~S is now traced." dspec))))
798
799 (defimplementation toggle-trace (fspec)
800 (toggle-trace-aux (parse-fspec fspec)))
801
802 ;;; Multithreading
803
804 (defimplementation initialize-multiprocessing (continuation)
805 (cond ((not mp::*multiprocessing*)
806 (push (list "Initialize SLIME" '() continuation)
807 mp:*initial-processes*)
808 (mp:initialize-multiprocessing))
809 (t (funcall continuation))))
810
811 (defimplementation spawn (fn &key name)
812 (mp:process-run-function name () fn))
813
814 (defvar *id-lock* (mp:make-lock))
815 (defvar *thread-id-counter* 0)
816
817 (defimplementation thread-id (thread)
818 (mp:with-lock (*id-lock*)
819 (or (getf (mp:process-plist thread) 'id)
820 (setf (getf (mp:process-plist thread) 'id)
821 (incf *thread-id-counter*)))))
822
823 (defimplementation find-thread (id)
824 (find id (mp:list-all-processes)
825 :key (lambda (p) (getf (mp:process-plist p) 'id))))
826
827 (defimplementation thread-name (thread)
828 (mp:process-name thread))
829
830 (defimplementation thread-status (thread)
831 (format nil "~A ~D"
832 (mp:process-whostate thread)
833 (mp:process-priority thread)))
834
835 (defimplementation make-lock (&key name)
836 (mp:make-lock :name name))
837
838 (defimplementation call-with-lock-held (lock function)
839 (mp:with-lock (lock) (funcall function)))
840
841 (defimplementation current-thread ()
842 mp:*current-process*)
843
844 (defimplementation all-threads ()
845 (mp:list-all-processes))
846
847 (defimplementation interrupt-thread (thread fn)
848 (mp:process-interrupt thread fn))
849
850 (defimplementation kill-thread (thread)
851 (mp:process-kill thread))
852
853 (defimplementation thread-alive-p (thread)
854 (mp:process-alive-p thread))
855
856 (defstruct (mailbox (:conc-name mailbox.))
857 (mutex (mp:make-lock :name "thread mailbox"))
858 (queue '() :type list))
859
860 (defvar *mailbox-lock* (mp:make-lock))
861
862 (defun mailbox (thread)
863 (mp:with-lock (*mailbox-lock*)
864 (or (getf (mp:process-plist thread) 'mailbox)
865 (setf (getf (mp:process-plist thread) 'mailbox)
866 (make-mailbox)))))
867
868 (defimplementation receive-if (test &optional timeout)
869 (let* ((mbox (mailbox mp:*current-process*))
870 (lock (mailbox.mutex mbox)))
871 (assert (or (not timeout) (eq timeout t)))
872 (loop
873 (check-slime-interrupts)
874 (mp:with-lock (lock "receive-if/try")
875 (let* ((q (mailbox.queue mbox))
876 (tail (member-if test q)))
877 (when tail
878 (setf (mailbox.queue mbox) (nconc (ldiff q tail) (cdr tail)))
879 (return (car tail)))))
880 (when (eq timeout t) (return (values nil t)))
881 (mp:process-wait-with-timeout
882 "receive-if" 0.3 (lambda () (some test (mailbox.queue mbox)))))))
883
884 (defimplementation send (thread message)
885 (let ((mbox (mailbox thread)))
886 (mp:with-lock ((mailbox.mutex mbox))
887 (setf (mailbox.queue mbox)
888 (nconc (mailbox.queue mbox) (list message))))))
889
890 (defimplementation set-default-initial-binding (var form)
891 (setq mp:*process-initial-bindings*
892 (acons var `(eval (quote ,form))
893 mp:*process-initial-bindings* )))
894
895 (defimplementation thread-attributes (thread)
896 (list :priority (mp:process-priority thread)
897 :idle (mp:process-idle-time thread)))
898
899 ;;; Some intergration with the lispworks environment
900
901 (defun swank-sym (name) (find-symbol (string name) :swank))
902
903
904 ;;;; Weak hashtables
905
906 (defimplementation make-weak-key-hash-table (&rest args)
907 (apply #'make-hash-table :weak-kind :key args))
908
909 (defimplementation make-weak-value-hash-table (&rest args)
910 (apply #'make-hash-table :weak-kind :value args))

  ViewVC Help
Powered by ViewVC 1.1.5