/[slime]/slime/swank-cmucl.lisp
ViewVC logotype

Contents of /slime/swank-cmucl.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.165 - (show annotations)
Fri Oct 20 00:14:39 2006 UTC (7 years, 6 months ago) by mbaringer
Branch: MAIN
Changes since 1.164: +3 -2 lines
(initialize-multiprocessing): Update for new API.
1 ;;; -*- indent-tabs-mode: nil; outline-regexp: ";;;;+" -*-
2 ;;;
3 ;;; License: Public Domain
4 ;;;
5 ;;;; Introduction
6 ;;;
7 ;;; This is the CMUCL implementation of the `swank-backend' package.
8
9 (in-package :swank-backend)
10
11 (import-swank-mop-symbols :pcl '(:slot-definition-documentation))
12
13 (defun swank-mop:slot-definition-documentation (slot)
14 (documentation slot t))
15
16 ;;;; "Hot fixes"
17 ;;;
18 ;;; Here are necessary bugfixes to the oldest supported version of
19 ;;; CMUCL (currently 18e). Any fixes placed here should also be
20 ;;; submitted to the `cmucl-imp' mailing list and confirmed as
21 ;;; good. When a new release is made that includes the fixes we should
22 ;;; promptly delete them from here. It is enough to be compatible with
23 ;;; the latest release.
24
25 (in-package :lisp)
26
27 ;;; `READ-SEQUENCE' with large sequences has problems in 18e. This new
28 ;;; definition works better.
29
30 #-cmu19
31 (progn
32 (let ((s (find-symbol (string :*enable-package-locked-errors*) :lisp)))
33 (when s
34 (setf (symbol-value s) nil)))
35
36 (defun read-into-simple-string (s stream start end)
37 (declare (type simple-string s))
38 (declare (type stream stream))
39 (declare (type index start end))
40 (unless (subtypep (stream-element-type stream) 'character)
41 (error 'type-error
42 :datum (read-char stream nil #\Null)
43 :expected-type (stream-element-type stream)
44 :format-control "Trying to read characters from a binary stream."))
45 ;; Let's go as low level as it seems reasonable.
46 (let* ((numbytes (- end start))
47 (total-bytes 0))
48 ;; read-n-bytes may return fewer bytes than requested, so we need
49 ;; to keep trying.
50 (loop while (plusp numbytes) do
51 (let ((bytes-read (system:read-n-bytes stream s start numbytes nil)))
52 (when (zerop bytes-read)
53 (return-from read-into-simple-string total-bytes))
54 (incf total-bytes bytes-read)
55 (incf start bytes-read)
56 (decf numbytes bytes-read)))
57 total-bytes))
58
59 (let ((s (find-symbol (string :*enable-package-locked-errors*) :lisp)))
60 (when s
61 (setf (symbol-value s) t)))
62
63 )
64
65 (in-package :swank-backend)
66
67
68 ;;;; TCP server
69 ;;;
70 ;;; In CMUCL we support all communication styles. By default we use
71 ;;; `:SIGIO' because it is the most responsive, but it's somewhat
72 ;;; dangerous: CMUCL is not in general "signal safe", and you don't
73 ;;; know for sure what you'll be interrupting. Both `:FD-HANDLER' and
74 ;;; `:SPAWN' are reasonable alternatives.
75
76 (defimplementation preferred-communication-style ()
77 :sigio)
78
79 #-(or ppc mips)
80 (defimplementation create-socket (host port)
81 (let* ((addr (resolve-hostname host))
82 (addr (if (not (find-symbol "SOCKET-ERROR" :ext))
83 (ext:htonl addr)
84 addr)))
85 (ext:create-inet-listener port :stream :reuse-address t :host addr)))
86
87 ;; There seems to be a bug in create-inet-listener on Mac/OSX and Irix.
88 #+(or ppc mips)
89 (defimplementation create-socket (host port)
90 (declare (ignore host))
91 (ext:create-inet-listener port :stream :reuse-address t))
92
93 (defimplementation local-port (socket)
94 (nth-value 1 (ext::get-socket-host-and-port (socket-fd socket))))
95
96 (defimplementation close-socket (socket)
97 (let ((fd (socket-fd socket)))
98 (sys:invalidate-descriptor fd)
99 (ext:close-socket fd)))
100
101 (defimplementation accept-connection (socket &key
102 external-format buffering timeout)
103 (declare (ignore timeout))
104 (let ((ef (or external-format :iso-latin-1-unix))
105 (buffering (or buffering :full)))
106 (unless (eq ef ':iso-latin-1-unix)
107 (remove-fd-handlers socket)
108 (remove-sigio-handlers socket)
109 (error "External format ~S not supported" ef))
110 (make-socket-io-stream (ext:accept-tcp-connection socket) buffering)))
111
112 ;;;;; Sockets
113
114 (defun socket-fd (socket)
115 "Return the filedescriptor for the socket represented by SOCKET."
116 (etypecase socket
117 (fixnum socket)
118 (sys:fd-stream (sys:fd-stream-fd socket))))
119
120 (defun resolve-hostname (hostname)
121 "Return the IP address of HOSTNAME as an integer (in host byte-order)."
122 (let ((hostent (ext:lookup-host-entry hostname)))
123 (car (ext:host-entry-addr-list hostent))))
124
125 (defun make-socket-io-stream (fd buffering)
126 "Create a new input/output fd-stream for FD."
127 (sys:make-fd-stream fd :input t :output t :element-type 'base-char
128 :buffering buffering))
129
130 ;;;;; Signal-driven I/O
131
132 (defvar *sigio-handlers* '()
133 "List of (key . function) pairs.
134 All functions are called on SIGIO, and the key is used for removing
135 specific functions.")
136
137 (defun set-sigio-handler ()
138 (sys:enable-interrupt :sigio (lambda (signal code scp)
139 (sigio-handler signal code scp))))
140
141 (defun sigio-handler (signal code scp)
142 (declare (ignore signal code scp))
143 (mapc #'funcall (mapcar #'cdr *sigio-handlers*)))
144
145 (defun fcntl (fd command arg)
146 "fcntl(2) - manipulate a file descriptor."
147 (multiple-value-bind (ok error) (unix:unix-fcntl fd command arg)
148 (unless ok (error "fcntl: ~A" (unix:get-unix-error-msg error)))))
149
150 (defimplementation add-sigio-handler (socket fn)
151 (set-sigio-handler)
152 (let ((fd (socket-fd socket)))
153 (fcntl fd unix:f-setown (unix:unix-getpid))
154 (fcntl fd unix:f-setfl unix:fasync)
155 (push (cons fd fn) *sigio-handlers*)))
156
157 (defimplementation remove-sigio-handlers (socket)
158 (let ((fd (socket-fd socket)))
159 (setf *sigio-handlers* (remove fd *sigio-handlers* :key #'car))
160 (sys:invalidate-descriptor fd)))
161
162 ;;;;; SERVE-EVENT
163
164 (defimplementation add-fd-handler (socket fn)
165 (let ((fd (socket-fd socket)))
166 (sys:add-fd-handler fd :input (lambda (_) _ (funcall fn)))))
167
168 (defimplementation remove-fd-handlers (socket)
169 (sys:invalidate-descriptor (socket-fd socket)))
170
171
172 ;;;; Stream handling
173 ;;; XXX: How come we don't use Gray streams in CMUCL too? -luke (15/May/2004)
174
175 (defimplementation make-fn-streams (input-fn output-fn)
176 (let* ((output (make-slime-output-stream output-fn))
177 (input (make-slime-input-stream input-fn output)))
178 (values input output)))
179
180 (defstruct (slime-output-stream
181 (:include lisp::lisp-stream
182 (lisp::misc #'sos/misc)
183 (lisp::out #'sos/out)
184 (lisp::sout #'sos/sout))
185 (:conc-name sos.)
186 (:print-function %print-slime-output-stream)
187 (:constructor make-slime-output-stream (output-fn)))
188 (output-fn nil :type function)
189 (buffer (make-string 8000) :type string)
190 (index 0 :type kernel:index)
191 (column 0 :type kernel:index)
192 (last-flush-time (get-internal-real-time) :type unsigned-byte))
193
194 (defun %print-slime-output-stream (s stream d)
195 (declare (ignore d))
196 (print-unreadable-object (s stream :type t :identity t)))
197
198 (defun sos/out (stream char)
199 (system:without-interrupts
200 (let ((buffer (sos.buffer stream))
201 (index (sos.index stream)))
202 (setf (schar buffer index) char)
203 (setf (sos.index stream) (1+ index))
204 (incf (sos.column stream))
205 (when (char= #\newline char)
206 (setf (sos.column stream) 0)
207 (force-output stream))
208 (when (= index (1- (length buffer)))
209 (finish-output stream)))
210 char))
211
212 (defun sos/sout (stream string start end)
213 (system:without-interrupts
214 (loop for i from start below end
215 do (sos/out stream (aref string i)))))
216
217 (defun log-stream-op (stream operation)
218 stream operation
219 #+(or)
220 (progn
221 (format sys:*tty* "~S @ ~D ~A~%" operation
222 (sos.index stream)
223 (/ (- (get-internal-real-time) (sos.last-flush-time stream))
224 (coerce internal-time-units-per-second 'double-float)))
225 (finish-output sys:*tty*)))
226
227 (defun sos/misc (stream operation &optional arg1 arg2)
228 (declare (ignore arg1 arg2))
229 (case operation
230 (:finish-output
231 (log-stream-op stream operation)
232 (system:without-interrupts
233 (let ((end (sos.index stream)))
234 (unless (zerop end)
235 (let ((s (subseq (sos.buffer stream) 0 end)))
236 (setf (sos.index stream) 0)
237 (funcall (sos.output-fn stream) s))
238 (setf (sos.last-flush-time stream) (get-internal-real-time)))))
239 nil)
240 (:force-output
241 (log-stream-op stream operation)
242 (sos/misc-force-output stream)
243 nil)
244 (:charpos (sos.column stream))
245 (:line-length 75)
246 (:file-position nil)
247 (:element-type 'base-char)
248 (:get-command nil)
249 (:close nil)
250 (t (format *terminal-io* "~&~Astream: ~S~%" stream operation))))
251
252 (defun sos/misc-force-output (stream)
253 (system:without-interrupts
254 (unless (or (zerop (sos.index stream))
255 (loop with buffer = (sos.buffer stream)
256 for i from 0 below (sos.index stream)
257 always (char= (aref buffer i) #\newline)))
258 (let ((last (sos.last-flush-time stream))
259 (now (get-internal-real-time)))
260 (when (> (/ (- now last)
261 (coerce internal-time-units-per-second 'double-float))
262 0.1)
263 (finish-output stream))))))
264
265 (defstruct (slime-input-stream
266 (:include string-stream
267 (lisp::in #'sis/in)
268 (lisp::misc #'sis/misc))
269 (:conc-name sis.)
270 (:print-function %print-slime-output-stream)
271 (:constructor make-slime-input-stream (input-fn sos)))
272 (input-fn nil :type function)
273 ;; We know our sibling output stream, so that we can force it before
274 ;; requesting input.
275 (sos nil :type slime-output-stream)
276 (buffer "" :type string)
277 (index 0 :type kernel:index))
278
279 (defun sis/in (stream eof-errorp eof-value)
280 (finish-output (sis.sos stream))
281 (let ((index (sis.index stream))
282 (buffer (sis.buffer stream)))
283 (when (= index (length buffer))
284 (let ((string (funcall (sis.input-fn stream))))
285 (cond ((zerop (length string))
286 (return-from sis/in
287 (if eof-errorp
288 (error (make-condition 'end-of-file :stream stream))
289 eof-value)))
290 (t
291 (setf buffer string)
292 (setf (sis.buffer stream) buffer)
293 (setf index 0)))))
294 (prog1 (aref buffer index)
295 (setf (sis.index stream) (1+ index)))))
296
297 (defun sis/misc (stream operation &optional arg1 arg2)
298 (declare (ignore arg2))
299 (ecase operation
300 (:file-position nil)
301 (:file-length nil)
302 (:unread (setf (aref (sis.buffer stream)
303 (decf (sis.index stream)))
304 arg1))
305 (:clear-input
306 (setf (sis.index stream) 0
307 (sis.buffer stream) ""))
308 (:listen (< (sis.index stream) (length (sis.buffer stream))))
309 (:charpos nil)
310 (:line-length nil)
311 (:get-command nil)
312 (:element-type 'base-char)
313 (:close nil)
314 (:interactive-p t)))
315
316
317 ;;;; Compilation Commands
318
319 (defvar *previous-compiler-condition* nil
320 "Used to detect duplicates.")
321
322 (defvar *previous-context* nil
323 "Previous compiler error context.")
324
325 (defvar *buffer-name* nil
326 "The name of the Emacs buffer we are compiling from.
327 NIL if we aren't compiling from a buffer.")
328
329 (defvar *buffer-start-position* nil)
330 (defvar *buffer-substring* nil)
331
332 (defimplementation call-with-compilation-hooks (function)
333 (let ((*previous-compiler-condition* nil)
334 (*previous-context* nil)
335 (*print-readably* nil))
336 (handler-bind ((c::compiler-error #'handle-notification-condition)
337 (c::style-warning #'handle-notification-condition)
338 (c::warning #'handle-notification-condition))
339 (funcall function))))
340
341 (defimplementation swank-compile-file (filename load-p
342 &optional external-format)
343 (declare (ignore external-format))
344 (clear-xref-info filename)
345 (with-compilation-hooks ()
346 (let ((*buffer-name* nil)
347 (ext:*ignore-extra-close-parentheses* nil))
348 (multiple-value-bind (output-file warnings-p failure-p)
349 (compile-file filename)
350 (unless failure-p
351 ;; Cache the latest source file for definition-finding.
352 (source-cache-get filename (file-write-date filename))
353 (when load-p (load output-file)))
354 (values output-file warnings-p failure-p)))))
355
356 (defimplementation swank-compile-string (string &key buffer position directory)
357 (declare (ignore directory))
358 (with-compilation-hooks ()
359 (let ((*buffer-name* buffer)
360 (*buffer-start-position* position)
361 (*buffer-substring* string))
362 (with-input-from-string (stream string)
363 (ext:compile-from-stream
364 stream
365 :source-info `(:emacs-buffer ,buffer
366 :emacs-buffer-offset ,position
367 :emacs-buffer-string ,string))))))
368
369
370 ;;;;; Trapping notes
371 ;;;
372 ;;; We intercept conditions from the compiler and resignal them as
373 ;;; `SWANK:COMPILER-CONDITION's.
374
375 (defun handle-notification-condition (condition)
376 "Handle a condition caused by a compiler warning."
377 (unless (eq condition *previous-compiler-condition*)
378 (let ((context (c::find-error-context nil)))
379 (setq *previous-compiler-condition* condition)
380 (setq *previous-context* context)
381 (signal-compiler-condition condition context))))
382
383 (defun signal-compiler-condition (condition context)
384 (signal (make-condition
385 'compiler-condition
386 :original-condition condition
387 :severity (severity-for-emacs condition)
388 :short-message (brief-compiler-message-for-emacs condition)
389 :message (long-compiler-message-for-emacs condition context)
390 :location (if (read-error-p condition)
391 (read-error-location condition)
392 (compiler-note-location context)))))
393
394 (defun severity-for-emacs (condition)
395 "Return the severity of CONDITION."
396 (etypecase condition
397 ((satisfies read-error-p) :read-error)
398 (c::compiler-error :error)
399 (c::style-warning :note)
400 (c::warning :warning)))
401
402 (defun read-error-p (condition)
403 (eq (type-of condition) 'c::compiler-read-error))
404
405 (defun brief-compiler-message-for-emacs (condition)
406 "Briefly describe a compiler error for Emacs.
407 When Emacs presents the message it already has the source popped up
408 and the source form highlighted. This makes much of the information in
409 the error-context redundant."
410 (princ-to-string condition))
411
412 (defun long-compiler-message-for-emacs (condition error-context)
413 "Describe a compiler error for Emacs including context information."
414 (declare (type (or c::compiler-error-context null) error-context))
415 (multiple-value-bind (enclosing source)
416 (if error-context
417 (values (c::compiler-error-context-enclosing-source error-context)
418 (c::compiler-error-context-source error-context)))
419 (format nil "~@[--> ~{~<~%--> ~1:;~A~> ~}~%~]~@[~{==>~%~A~^~%~}~]~A"
420 enclosing source condition)))
421
422 (defun read-error-location (condition)
423 (let* ((finfo (car (c::source-info-current-file c::*source-info*)))
424 (file (c::file-info-name finfo))
425 (pos (c::compiler-read-error-position condition)))
426 (cond ((and (eq file :stream) *buffer-name*)
427 (make-location (list :buffer *buffer-name*)
428 (list :position (+ *buffer-start-position* pos))))
429 ((and (pathnamep file) (not *buffer-name*))
430 (make-location (list :file (unix-truename file))
431 (list :position (1+ pos))))
432 (t (break)))))
433
434 (defun compiler-note-location (context)
435 "Derive the location of a complier message from its context.
436 Return a `location' record, or (:error REASON) on failure."
437 (if (null context)
438 (note-error-location)
439 (let ((file (c::compiler-error-context-file-name context))
440 (source (c::compiler-error-context-original-source context))
441 (path
442 (reverse (c::compiler-error-context-original-source-path context))))
443 (or (locate-compiler-note file source path)
444 (note-error-location)))))
445
446 (defun note-error-location ()
447 "Pseudo-location for notes that can't be located."
448 (list :error "No error location available."))
449
450 (defun locate-compiler-note (file source source-path)
451 (cond ((and (eq file :stream) *buffer-name*)
452 ;; Compiling from a buffer
453 (let ((position (+ *buffer-start-position*
454 (source-path-string-position
455 source-path *buffer-substring*))))
456 (make-location (list :buffer *buffer-name*)
457 (list :position position))))
458 ((and (pathnamep file) (null *buffer-name*))
459 ;; Compiling from a file
460 (make-location (list :file (unix-truename file))
461 (list :position
462 (1+ (source-path-file-position
463 source-path file)))))
464 ((and (eq file :lisp) (stringp source))
465 ;; No location known, but we have the source form.
466 ;; XXX How is this case triggered? -luke (16/May/2004)
467 ;; This can happen if the compiler needs to expand a macro
468 ;; but the macro-expander is not yet compiled. Calling the
469 ;; (interpreted) macro-expander triggers IR1 conversion of
470 ;; the lambda expression for the expander and invokes the
471 ;; compiler recursively.
472 (make-location (list :source-form source)
473 (list :position 1)))))
474
475 (defun unix-truename (pathname)
476 (ext:unix-namestring (truename pathname)))
477
478
479 ;;;; XREF
480 ;;;
481 ;;; Cross-reference support is based on the standard CMUCL `XREF'
482 ;;; package. This package has some caveats: XREF information is
483 ;;; recorded during compilation and not preserved in fasl files, and
484 ;;; XREF recording is disabled by default. Redefining functions can
485 ;;; also cause duplicate references to accumulate, but
486 ;;; `swank-compile-file' will automatically clear out any old records
487 ;;; from the same filename.
488 ;;;
489 ;;; To enable XREF recording, set `c:*record-xref-info*' to true. To
490 ;;; clear out the XREF database call `xref:init-xref-database'.
491
492 (defmacro defxref (name function)
493 `(defimplementation ,name (name)
494 (xref-results (,function name))))
495
496 (defxref who-calls xref:who-calls)
497 (defxref who-references xref:who-references)
498 (defxref who-binds xref:who-binds)
499 (defxref who-sets xref:who-sets)
500
501 ;;; More types of XREF information were added since 18e:
502 ;;;
503 #+cmu19
504 (progn
505 (defxref who-macroexpands xref:who-macroexpands)
506 ;; XXX
507 (defimplementation who-specializes (symbol)
508 (let* ((methods (xref::who-specializes (find-class symbol)))
509 (locations (mapcar #'method-location methods)))
510 (mapcar #'list methods locations))))
511
512 (defun xref-results (contexts)
513 (mapcar (lambda (xref)
514 (list (xref:xref-context-name xref)
515 (resolve-xref-location xref)))
516 contexts))
517
518 (defun resolve-xref-location (xref)
519 (let ((name (xref:xref-context-name xref))
520 (file (xref:xref-context-file xref))
521 (source-path (xref:xref-context-source-path xref)))
522 (cond ((and file source-path)
523 (let ((position (source-path-file-position source-path file)))
524 (make-location (list :file (unix-truename file))
525 (list :position (1+ position)))))
526 (file
527 (make-location (list :file (unix-truename file))
528 (list :function-name (string name))))
529 (t
530 `(:error ,(format nil "Unknown source location: ~S ~S ~S "
531 name file source-path))))))
532
533 (defun clear-xref-info (namestring)
534 "Clear XREF notes pertaining to NAMESTRING.
535 This is a workaround for a CMUCL bug: XREF records are cumulative."
536 (when c:*record-xref-info*
537 (let ((filename (truename namestring)))
538 (dolist (db (list xref::*who-calls*
539 #+cmu19 xref::*who-is-called*
540 #+cmu19 xref::*who-macroexpands*
541 xref::*who-references*
542 xref::*who-binds*
543 xref::*who-sets*))
544 (maphash (lambda (target contexts)
545 ;; XXX update during traversal?
546 (setf (gethash target db)
547 (delete filename contexts
548 :key #'xref:xref-context-file
549 :test #'equalp)))
550 db)))))
551
552
553 ;;;; Find callers and callees
554 ;;;
555 ;;; Find callers and callees by looking at the constant pool of
556 ;;; compiled code objects. We assume every fdefn object in the
557 ;;; constant pool corresponds to a call to that function. A better
558 ;;; strategy would be to use the disassembler to find actual
559 ;;; call-sites.
560
561 (declaim (inline map-code-constants))
562 (defun map-code-constants (code fn)
563 "Call FN for each constant in CODE's constant pool."
564 (check-type code kernel:code-component)
565 (loop for i from vm:code-constants-offset below (kernel:get-header-data code)
566 do (funcall fn (kernel:code-header-ref code i))))
567
568 (defun function-callees (function)
569 "Return FUNCTION's callees as a list of functions."
570 (let ((callees '()))
571 (map-code-constants
572 (vm::find-code-object function)
573 (lambda (obj)
574 (when (kernel:fdefn-p obj)
575 (push (kernel:fdefn-function obj) callees))))
576 callees))
577
578 (declaim (ext:maybe-inline map-allocated-code-components))
579 (defun map-allocated-code-components (spaces fn)
580 "Call FN for each allocated code component in one of SPACES. FN
581 receives the object as argument. SPACES should be a list of the
582 symbols :dynamic, :static, or :read-only."
583 (dolist (space spaces)
584 (declare (inline vm::map-allocated-objects)
585 (optimize (ext:inhibit-warnings 3)))
586 (vm::map-allocated-objects
587 (lambda (obj header size)
588 (declare (type fixnum size) (ignore size))
589 (when (= vm:code-header-type header)
590 (funcall fn obj)))
591 space)))
592
593 (declaim (ext:maybe-inline map-caller-code-components))
594 (defun map-caller-code-components (function spaces fn)
595 "Call FN for each code component with a fdefn for FUNCTION in its
596 constant pool."
597 (let ((function (coerce function 'function)))
598 (declare (inline map-allocated-code-components))
599 (map-allocated-code-components
600 spaces
601 (lambda (obj)
602 (map-code-constants
603 obj
604 (lambda (constant)
605 (when (and (kernel:fdefn-p constant)
606 (eq (kernel:fdefn-function constant)
607 function))
608 (funcall fn obj))))))))
609
610 (defun function-callers (function &optional (spaces '(:read-only :static
611 :dynamic)))
612 "Return FUNCTION's callers. The result is a list of code-objects."
613 (let ((referrers '()))
614 (declare (inline map-caller-code-components))
615 ;;(ext:gc :full t)
616 (map-caller-code-components function spaces
617 (lambda (code) (push code referrers)))
618 referrers))
619
620 (defun debug-info-definitions (debug-info)
621 "Return the defintions for a debug-info. This should only be used
622 for code-object without entry points, i.e., byte compiled
623 code (are theree others?)"
624 ;; This mess has only been tested with #'ext::skip-whitespace, a
625 ;; byte-compiled caller of #'read-char .
626 (check-type debug-info (and (not c::compiled-debug-info) c::debug-info))
627 (let ((name (c::debug-info-name debug-info))
628 (source (c::debug-info-source debug-info)))
629 (destructuring-bind (first) source
630 (ecase (c::debug-source-from first)
631 (:file
632 (list (list name
633 (make-location
634 (list :file (unix-truename (c::debug-source-name first)))
635 (list :function-name (string name))))))))))
636
637 (defun code-component-entry-points (code)
638 "Return a list ((NAME LOCATION) ...) of function definitons for
639 the code omponent CODE."
640 (let ((names '()))
641 (do ((f (kernel:%code-entry-points code) (kernel::%function-next f)))
642 ((not f))
643 (let ((name (kernel:%function-name f)))
644 (when (ext:valid-function-name-p name)
645 (push (list name (function-location f)) names))))
646 names))
647
648 (defimplementation list-callers (symbol)
649 "Return a list ((NAME LOCATION) ...) of callers."
650 (let ((components (function-callers symbol))
651 (xrefs '()))
652 (dolist (code components)
653 (let* ((entry (kernel:%code-entry-points code))
654 (defs (if entry
655 (code-component-entry-points code)
656 ;; byte compiled stuff
657 (debug-info-definitions
658 (kernel:%code-debug-info code)))))
659 (setq xrefs (nconc defs xrefs))))
660 xrefs))
661
662 (defimplementation list-callees (symbol)
663 (let ((fns (function-callees symbol)))
664 (mapcar (lambda (fn)
665 (list (kernel:%function-name fn)
666 (function-location fn)))
667 fns)))
668
669
670 ;;;; Resolving source locations
671 ;;;
672 ;;; Our mission here is to "resolve" references to code locations into
673 ;;; actual file/buffer names and character positions. The references
674 ;;; we work from come out of the compiler's statically-generated debug
675 ;;; information, such as `code-location''s and `debug-source''s. For
676 ;;; more details, see the "Debugger Programmer's Interface" section of
677 ;;; the CMUCL manual.
678 ;;;
679 ;;; The first step is usually to find the corresponding "source-path"
680 ;;; for the location. Once we have the source-path we can pull up the
681 ;;; source file and `READ' our way through to the right position. The
682 ;;; main source-code groveling work is done in
683 ;;; `swank-source-path-parser.lisp'.
684
685 (defvar *debug-definition-finding* nil
686 "When true don't handle errors while looking for definitions.
687 This is useful when debugging the definition-finding code.")
688
689 (defvar *source-snippet-size* 256
690 "Maximum number of characters in a snippet of source code.
691 Snippets at the beginning of definitions are used to tell Emacs what
692 the definitions looks like, so that it can accurately find them by
693 text search.")
694
695 (defmacro safe-definition-finding (&body body)
696 "Execute BODY and return the source-location it returns.
697 If an error occurs and `*debug-definition-finding*' is false, then
698 return an error pseudo-location.
699
700 The second return value is NIL if no error occurs, otherwise it is the
701 condition object."
702 `(flet ((body () ,@body))
703 (if *debug-definition-finding*
704 (body)
705 (handler-case (values (progn ,@body) nil)
706 (error (c) (values (list :error (princ-to-string c)) c))))))
707
708 (defun code-location-source-location (code-location)
709 "Safe wrapper around `code-location-from-source-location'."
710 (safe-definition-finding
711 (source-location-from-code-location code-location)))
712
713 (defun source-location-from-code-location (code-location)
714 "Return the source location for CODE-LOCATION."
715 (let ((debug-fun (di:code-location-debug-function code-location)))
716 (when (di::bogus-debug-function-p debug-fun)
717 ;; Those lousy cheapskates! They've put in a bogus debug source
718 ;; because the code was compiled at a low debug setting.
719 (error "Bogus debug function: ~A" debug-fun)))
720 (let* ((debug-source (di:code-location-debug-source code-location))
721 (from (di:debug-source-from debug-source))
722 (name (di:debug-source-name debug-source)))
723 (ecase from
724 (:file
725 (location-in-file name code-location debug-source))
726 (:stream
727 (location-in-stream code-location debug-source))
728 (:lisp
729 ;; The location comes from a form passed to `compile'.
730 ;; The best we can do is return the form itself for printing.
731 (make-location
732 (list :source-form (with-output-to-string (*standard-output*)
733 (debug::print-code-location-source-form
734 code-location 100 t)))
735 (list :position 1))))))
736
737 (defun location-in-file (filename code-location debug-source)
738 "Resolve the source location for CODE-LOCATION in FILENAME."
739 (let* ((code-date (di:debug-source-created debug-source))
740 (source-code (get-source-code filename code-date)))
741 (with-input-from-string (s source-code)
742 (make-location (list :file (unix-truename filename))
743 (list :position (1+ (code-location-stream-position
744 code-location s)))
745 `(:snippet ,(read-snippet s))))))
746
747 (defun location-in-stream (code-location debug-source)
748 "Resolve the source location for a CODE-LOCATION from a stream.
749 This only succeeds if the code was compiled from an Emacs buffer."
750 (unless (debug-source-info-from-emacs-buffer-p debug-source)
751 (error "The code is compiled from a non-SLIME stream."))
752 (let* ((info (c::debug-source-info debug-source))
753 (string (getf info :emacs-buffer-string))
754 (position (code-location-string-offset
755 code-location
756 string)))
757 (make-location
758 (list :buffer (getf info :emacs-buffer))
759 (list :position (+ (getf info :emacs-buffer-offset) position))
760 (list :snippet (with-input-from-string (s string)
761 (file-position s position)
762 (read-snippet s))))))
763
764 ;;;;; Function-name locations
765 ;;;
766 (defun debug-info-function-name-location (debug-info)
767 "Return a function-name source-location for DEBUG-INFO.
768 Function-name source-locations are a fallback for when precise
769 positions aren't available."
770 (with-struct (c::debug-info- (fname name) source) debug-info
771 (with-struct (c::debug-source- info from name) (car source)
772 (ecase from
773 (:file
774 (make-location (list :file (namestring (truename name)))
775 (list :function-name (string fname))))
776 (:stream
777 (assert (debug-source-info-from-emacs-buffer-p (car source)))
778 (make-location (list :buffer (getf info :emacs-buffer))
779 (list :function-name (string fname))))
780 (:lisp
781 (make-location (list :source-form (princ-to-string (aref name 0)))
782 (list :position 1)))))))
783
784 (defun debug-source-info-from-emacs-buffer-p (debug-source)
785 "Does the `info' slot of DEBUG-SOURCE contain an Emacs buffer location?
786 This is true for functions that were compiled directly from buffers."
787 (info-from-emacs-buffer-p (c::debug-source-info debug-source)))
788
789 (defun info-from-emacs-buffer-p (info)
790 (and info
791 (consp info)
792 (eq :emacs-buffer (car info))))
793
794
795 ;;;;; Groveling source-code for positions
796
797 (defun code-location-stream-position (code-location stream)
798 "Return the byte offset of CODE-LOCATION in STREAM. Extract the
799 toplevel-form-number and form-number from CODE-LOCATION and use that
800 to find the position of the corresponding form.
801
802 Finish with STREAM positioned at the start of the code location."
803 (let* ((location (debug::maybe-block-start-location code-location))
804 (tlf-offset (di:code-location-top-level-form-offset location))
805 (form-number (di:code-location-form-number location)))
806 (let ((pos (form-number-stream-position tlf-offset form-number stream)))
807 (file-position stream pos)
808 pos)))
809
810 (defun form-number-stream-position (tlf-number form-number stream)
811 "Return the starting character position of a form in STREAM.
812 TLF-NUMBER is the top-level-form number.
813 FORM-NUMBER is an index into a source-path table for the TLF."
814 (multiple-value-bind (tlf position-map) (read-source-form tlf-number stream)
815 (let* ((path-table (di:form-number-translations tlf 0))
816 (source-path
817 (if (<= (length path-table) form-number) ; source out of sync?
818 (list 0) ; should probably signal a condition
819 (reverse (cdr (aref path-table form-number))))))
820 (source-path-source-position source-path tlf position-map))))
821
822 (defun code-location-string-offset (code-location string)
823 "Return the byte offset of CODE-LOCATION in STRING.
824 See CODE-LOCATION-STREAM-POSITION."
825 (with-input-from-string (s string)
826 (code-location-stream-position code-location s)))
827
828
829 ;;;; Finding definitions
830
831 ;;; There are a great many different types of definition for us to
832 ;;; find. We search for definitions of every kind and return them in a
833 ;;; list.
834
835 (defimplementation find-definitions (name)
836 (append (function-definitions name)
837 (setf-definitions name)
838 (variable-definitions name)
839 (class-definitions name)
840 (type-definitions name)
841 (compiler-macro-definitions name)
842 (source-transform-definitions name)
843 (function-info-definitions name)
844 (ir1-translator-definitions name)))
845
846 ;;;;; Functions, macros, generic functions, methods
847 ;;;
848 ;;; We make extensive use of the compile-time debug information that
849 ;;; CMUCL records, in particular "debug functions" and "code
850 ;;; locations." Refer to the "Debugger Programmer's Interface" section
851 ;;; of the CMUCL manual for more details.
852
853 (defun function-definitions (name)
854 "Return definitions for NAME in the \"function namespace\", i.e.,
855 regular functions, generic functions, methods and macros.
856 NAME can any valid function name (e.g, (setf car))."
857 (let ((macro? (and (symbolp name) (macro-function name)))
858 (special? (and (symbolp name) (special-operator-p name)))
859 (function? (and (ext:valid-function-name-p name)
860 (ext:info :function :definition name)
861 (if (symbolp name) (fboundp name) t))))
862 (cond (macro?
863 (list `((defmacro ,name)
864 ,(function-location (macro-function name)))))
865 (special?
866 (list `((:special-operator ,name)
867 (:error ,(format nil "Special operator: ~S" name)))))
868 (function?
869 (let ((function (fdefinition name)))
870 (if (genericp function)
871 (generic-function-definitions name function)
872 (list (list `(function ,name)
873 (function-location function)))))))))
874
875 ;;;;;; Ordinary (non-generic/macro/special) functions
876 ;;;
877 ;;; First we test if FUNCTION is a closure created by defstruct, and
878 ;;; if so extract the defstruct-description (`dd') from the closure
879 ;;; and find the constructor for the struct. Defstruct creates a
880 ;;; defun for the default constructor and we use that as an
881 ;;; approximation to the source location of the defstruct.
882 ;;;
883 ;;; For an ordinary function we return the source location of the
884 ;;; first code-location we find.
885 ;;;
886 (defun function-location (function)
887 "Return the source location for FUNCTION."
888 (cond ((struct-closure-p function)
889 (struct-closure-location function))
890 ((c::byte-function-or-closure-p function)
891 (byte-function-location function))
892 (t
893 (compiled-function-location function))))
894
895 (defun compiled-function-location (function)
896 "Return the location of a regular compiled function."
897 (multiple-value-bind (code-location error)
898 (safe-definition-finding (function-first-code-location function))
899 (cond (error (list :error (princ-to-string error)))
900 (t (code-location-source-location code-location)))))
901
902 (defun function-first-code-location (function)
903 "Return the first code-location we can find for FUNCTION."
904 (and (function-has-debug-function-p function)
905 (di:debug-function-start-location
906 (di:function-debug-function function))))
907
908 (defun function-has-debug-function-p (function)
909 (di:function-debug-function function))
910
911 (defun function-code-object= (closure function)
912 (and (eq (vm::find-code-object closure)
913 (vm::find-code-object function))
914 (not (eq closure function))))
915
916
917 (defun byte-function-location (fn)
918 "Return the location of the byte-compiled function FN."
919 (etypecase fn
920 ((or c::hairy-byte-function c::simple-byte-function)
921 (let* ((component (c::byte-function-component fn))
922 (debug-info (kernel:%code-debug-info component)))
923 (debug-info-function-name-location debug-info)))
924 (c::byte-closure
925 (byte-function-location (c::byte-closure-function fn)))))
926
927 ;;; Here we deal with structure accessors. Note that `dd' is a
928 ;;; "defstruct descriptor" structure in CMUCL. A `dd' describes a
929 ;;; `defstruct''d structure.
930
931 (defun struct-closure-p (function)
932 "Is FUNCTION a closure created by defstruct?"
933 (or (function-code-object= function #'kernel::structure-slot-accessor)
934 (function-code-object= function #'kernel::structure-slot-setter)
935 (function-code-object= function #'kernel::%defstruct)))
936
937 (defun struct-closure-location (function)
938 "Return the location of the structure that FUNCTION belongs to."
939 (assert (struct-closure-p function))
940 (safe-definition-finding
941 (dd-location (struct-closure-dd function))))
942
943 (defun struct-closure-dd (function)
944 "Return the defstruct-definition (dd) of FUNCTION."
945 (assert (= (kernel:get-type function) vm:closure-header-type))
946 (flet ((find-layout (function)
947 (sys:find-if-in-closure
948 (lambda (x)
949 (let ((value (if (di::indirect-value-cell-p x)
950 (c:value-cell-ref x)
951 x)))
952 (when (kernel::layout-p value)
953 (return-from find-layout value))))
954 function)))
955 (kernel:layout-info (find-layout function))))
956
957 (defun dd-location (dd)
958 "Return the location of a `defstruct'."
959 ;; Find the location in a constructor.
960 (function-location (struct-constructor dd)))
961
962 (defun struct-constructor (dd)
963 "Return a constructor function from a defstruct definition.
964 Signal an error if no constructor can be found."
965 (let ((constructor (or (kernel:dd-default-constructor dd)
966 (car (kernel::dd-constructors dd)))))
967 (when (or (null constructor)
968 (and (consp constructor) (null (car constructor))))
969 (error "Cannot find structure's constructor: ~S"
970 (kernel::dd-name dd)))
971 (coerce (if (consp constructor) (first constructor) constructor)
972 'function)))
973
974 ;;;;;; Generic functions and methods
975
976 (defun generic-function-definitions (name function)
977 "Return the definitions of a generic function and its methods."
978 (cons (list `(defgeneric ,name) (gf-location function))
979 (gf-method-definitions function)))
980
981 (defun gf-location (gf)
982 "Return the location of the generic function GF."
983 (definition-source-location gf (pcl::generic-function-name gf)))
984
985 (defun gf-method-definitions (gf)
986 "Return the locations of all methods of the generic function GF."
987 (mapcar #'method-definition (pcl::generic-function-methods gf)))
988
989 (defun method-definition (method)
990 (list (method-dspec method)
991 (method-location method)))
992
993 (defun method-dspec (method)
994 "Return a human-readable \"definition specifier\" for METHOD."
995 (let* ((gf (pcl:method-generic-function method))
996 (name (pcl:generic-function-name gf))
997 (specializers (pcl:method-specializers method))
998 (qualifiers (pcl:method-qualifiers method)))
999 `(method ,name ,@qualifiers ,(pcl::unparse-specializers specializers))))
1000
1001 ;; XXX maybe special case setters/getters
1002 (defun method-location (method)
1003 (function-location (or (pcl::method-fast-function method)
1004 (pcl:method-function method))))
1005
1006 (defun genericp (fn)
1007 (typep fn 'generic-function))
1008
1009 ;;;;;; Types and classes
1010
1011 (defun type-definitions (name)
1012 "Return `deftype' locations for type NAME."
1013 (maybe-make-definition (ext:info :type :expander name) 'deftype name))
1014
1015 (defun maybe-make-definition (function kind name)
1016 "If FUNCTION is non-nil then return its definition location."
1017 (if function
1018 (list (list `(,kind ,name) (function-location function)))))
1019
1020 (defun class-definitions (name)
1021 "Return the definition locations for the class called NAME."
1022 (if (symbolp name)
1023 (let ((class (kernel::find-class name nil)))
1024 (etypecase class
1025 (null '())
1026 (kernel::structure-class
1027 (list (list `(defstruct ,name) (dd-location (find-dd name)))))
1028 #+(or)
1029 (conditions::condition-class
1030 (list (list `(define-condition ,name)
1031 (condition-class-location class))))
1032 (kernel::standard-class
1033 (list (list `(defclass ,name)
1034 (class-location (find-class name)))))
1035 ((or kernel::built-in-class
1036 conditions::condition-class
1037 kernel:funcallable-structure-class)
1038 (list (list `(kernel::define-type-class ,name)
1039 `(:error
1040 ,(format nil "No source info for ~A" name)))))))))
1041
1042 (defun class-location (class)
1043 "Return the `defclass' location for CLASS."
1044 (definition-source-location class (pcl:class-name class)))
1045
1046 (defun find-dd (name)
1047 "Find the defstruct-definition by the name of its structure-class."
1048 (let ((layout (ext:info :type :compiler-layout name)))
1049 (if layout
1050 (kernel:layout-info layout))))
1051
1052 (defun condition-class-location (class)
1053 (let ((slots (conditions::condition-class-slots class))
1054 (name (conditions::condition-class-name class)))
1055 (cond ((null slots)
1056 `(:error ,(format nil "No location info for condition: ~A" name)))
1057 (t
1058 ;; Find the class via one of its slot-reader methods.
1059 (let* ((slot (first slots))
1060 (gf (fdefinition
1061 (first (conditions::condition-slot-readers slot)))))
1062 (method-location
1063 (first
1064 (pcl:compute-applicable-methods-using-classes
1065 gf (list (find-class name))))))))))
1066
1067 (defun make-name-in-file-location (file string)
1068 (multiple-value-bind (filename c)
1069 (ignore-errors
1070 (unix-truename (merge-pathnames (make-pathname :type "lisp")
1071 file)))
1072 (cond (filename (make-location `(:file ,filename)
1073 `(:function-name ,(string string))))
1074 (t (list :error (princ-to-string c))))))
1075
1076 (defun source-location-form-numbers (location)
1077 (c::decode-form-numbers (c::form-numbers-form-numbers location)))
1078
1079 (defun source-location-tlf-number (location)
1080 (nth-value 0 (source-location-form-numbers location)))
1081
1082 (defun source-location-form-number (location)
1083 (nth-value 1 (source-location-form-numbers location)))
1084
1085 (defun resolve-file-source-location (location)
1086 (let ((filename (c::file-source-location-pathname location))
1087 (tlf-number (source-location-tlf-number location))
1088 (form-number (source-location-form-number location)))
1089 (with-open-file (s filename)
1090 (let ((pos (form-number-stream-position tlf-number form-number s)))
1091 (make-location `(:file ,(unix-truename filename))
1092 `(:position ,(1+ pos)))))))
1093
1094 (defun resolve-stream-source-location (location)
1095 (let ((info (c::stream-source-location-user-info location))
1096 (tlf-number (source-location-tlf-number location))
1097 (form-number (source-location-form-number location)))
1098 ;; XXX duplication in frame-source-location
1099 (assert (info-from-emacs-buffer-p info))
1100 (destructuring-bind (&key emacs-buffer emacs-buffer-string
1101 emacs-buffer-offset) info
1102 (with-input-from-string (s emacs-buffer-string)
1103 (let ((pos (form-number-stream-position tlf-number form-number s)))
1104 (make-location `(:buffer ,emacs-buffer)
1105 `(:position ,(+ emacs-buffer-offset pos))))))))
1106
1107 ;; XXX predicates for 18e backward compatibilty. Remove them when
1108 ;; we're 19a only.
1109 (defun file-source-location-p (object)
1110 (when (fboundp 'c::file-source-location-p)
1111 (c::file-source-location-p object)))
1112
1113 (defun stream-source-location-p (object)
1114 (when (fboundp 'c::stream-source-location-p)
1115 (c::stream-source-location-p object)))
1116
1117 (defun source-location-p (object)
1118 (or (file-source-location-p object)
1119 (stream-source-location-p object)))
1120
1121 (defun resolve-source-location (location)
1122 (etypecase location
1123 ((satisfies file-source-location-p)
1124 (resolve-file-source-location location))
1125 ((satisfies stream-source-location-p)
1126 (resolve-stream-source-location location))))
1127
1128 (defun definition-source-location (object name)
1129 (let ((source (pcl::definition-source object)))
1130 (etypecase source
1131 (null
1132 `(:error ,(format nil "No source info for: ~A" object)))
1133 ((satisfies source-location-p)
1134 (resolve-source-location source))
1135 (pathname
1136 (make-name-in-file-location source name))
1137 (cons
1138 (destructuring-bind ((dg name) pathname) source
1139 (declare (ignore dg))
1140 (etypecase pathname
1141 (pathname (make-name-in-file-location pathname (string name)))
1142 (null `(:error ,(format nil "Cannot resolve: ~S" source)))))))))
1143
1144 (defun setf-definitions (name)
1145 (let ((function (or (ext:info :setf :inverse name)
1146 (ext:info :setf :expander name))))
1147 (if function
1148 (list (list `(setf ,name)
1149 (function-location (coerce function 'function)))))))
1150
1151
1152 (defun variable-location (symbol)
1153 (multiple-value-bind (location foundp)
1154 ;; XXX for 18e compatibilty. rewrite this when we drop 18e
1155 ;; support.
1156 (ignore-errors (eval `(ext:info :source-location :defvar ',symbol)))
1157 (if (and foundp location)
1158 (resolve-source-location location)
1159 `(:error ,(format nil "No source info for variable ~S" symbol)))))
1160
1161 (defun variable-definitions (name)
1162 (if (symbolp name)
1163 (multiple-value-bind (kind recorded-p) (ext:info :variable :kind name)
1164 (if recorded-p
1165 (list (list `(variable ,kind ,name)
1166 (variable-location name)))))))
1167
1168 (defun compiler-macro-definitions (symbol)
1169 (maybe-make-definition (compiler-macro-function symbol)
1170 'define-compiler-macro
1171 symbol))
1172
1173 (defun source-transform-definitions (name)
1174 (maybe-make-definition (ext:info :function :source-transform name)
1175 'c:def-source-transform
1176 name))
1177
1178 (defun function-info-definitions (name)
1179 (let ((info (ext:info :function :info name)))
1180 (if info
1181 (append (loop for transform in (c::function-info-transforms info)
1182 collect (list `(c:deftransform ,name
1183 ,(c::type-specifier
1184 (c::transform-type transform)))
1185 (function-location (c::transform-function
1186 transform))))
1187 (maybe-make-definition (c::function-info-derive-type info)
1188 'c::derive-type name)
1189 (maybe-make-definition (c::function-info-optimizer info)
1190 'c::optimizer name)
1191 (maybe-make-definition (c::function-info-ltn-annotate info)
1192 'c::ltn-annotate name)
1193 (maybe-make-definition (c::function-info-ir2-convert info)
1194 'c::ir2-convert name)
1195 (loop for template in (c::function-info-templates info)
1196 collect (list `(c::vop ,(c::template-name template))
1197 (function-location
1198 (c::vop-info-generator-function
1199 template))))))))
1200
1201 (defun ir1-translator-definitions (name)
1202 (maybe-make-definition (ext:info :function :ir1-convert name)
1203 'c:def-ir1-translator name))
1204
1205
1206 ;;;; Documentation.
1207
1208 (defimplementation describe-symbol-for-emacs (symbol)
1209 (let ((result '()))
1210 (flet ((doc (kind)
1211 (or (documentation symbol kind) :not-documented))
1212 (maybe-push (property value)
1213 (when value
1214 (setf result (list* property value result)))))
1215 (maybe-push
1216 :variable (multiple-value-bind (kind recorded-p)
1217 (ext:info variable kind symbol)
1218 (declare (ignore kind))
1219 (if (or (boundp symbol) recorded-p)
1220 (doc 'variable))))
1221 (when (fboundp symbol)
1222 (maybe-push
1223 (cond ((macro-function symbol) :macro)
1224 ((special-operator-p symbol) :special-operator)
1225 ((genericp (fdefinition symbol)) :generic-function)
1226 (t :function))
1227 (doc 'function)))
1228 (maybe-push
1229 :setf (if (or (ext:info setf inverse symbol)
1230 (ext:info setf expander symbol))
1231 (doc 'setf)))
1232 (maybe-push
1233 :type (if (ext:info type kind symbol)
1234 (doc 'type)))
1235 (maybe-push
1236 :class (if (find-class symbol nil)
1237 (doc 'class)))
1238 (maybe-push
1239 :alien-type (if (not (eq (ext:info alien-type kind symbol) :unknown))
1240 (doc 'alien-type)))
1241 (maybe-push
1242 :alien-struct (if (ext:info alien-type struct symbol)
1243 (doc nil)))
1244 (maybe-push
1245 :alien-union (if (ext:info alien-type union symbol)
1246 (doc nil)))
1247 (maybe-push
1248 :alien-enum (if (ext:info alien-type enum symbol)
1249 (doc nil)))
1250 result)))
1251
1252 (defimplementation describe-definition (symbol namespace)
1253 (describe (ecase namespace
1254 (:variable
1255 symbol)
1256 ((:function :generic-function)
1257 (symbol-function symbol))
1258 (:setf
1259 (or (ext:info setf inverse symbol)
1260 (ext:info setf expander symbol)))
1261 (:type
1262 (kernel:values-specifier-type symbol))
1263 (:class
1264 (find-class symbol))
1265 (:alien-struct
1266 (ext:info :alien-type :struct symbol))
1267 (:alien-union
1268 (ext:info :alien-type :union symbol))
1269 (:alien-enum
1270 (ext:info :alien-type :enum symbol))
1271 (:alien-type
1272 (ecase (ext:info :alien-type :kind symbol)
1273 (:primitive
1274 (let ((alien::*values-type-okay* t))
1275 (funcall (ext:info :alien-type :translator symbol)
1276 (list symbol))))
1277 ((:defined)
1278 (ext:info :alien-type :definition symbol))
1279 (:unknown :unkown))))))
1280
1281 ;;;;; Argument lists
1282
1283 (defimplementation arglist (fun)
1284 (etypecase fun
1285 (function (function-arglist fun))
1286 (symbol (function-arglist (or (macro-function fun)
1287 (symbol-function fun))))))
1288
1289 (defun function-arglist (fun)
1290 (let ((arglist
1291 (cond ((eval:interpreted-function-p fun)
1292 (eval:interpreted-function-arglist fun))
1293 ((pcl::generic-function-p fun)
1294 (pcl:generic-function-lambda-list fun))
1295 ((c::byte-function-or-closure-p fun)
1296 (byte-code-function-arglist fun))
1297 ((kernel:%function-arglist (kernel:%function-self fun))
1298 (handler-case (read-arglist fun)
1299 (error () :not-available)))
1300 ;; this should work both for compiled-debug-function
1301 ;; and for interpreted-debug-function
1302 (t
1303 (handler-case (debug-function-arglist
1304 (di::function-debug-function fun))
1305 (di:unhandled-condition () :not-available))))))
1306 (check-type arglist (or list (member :not-available)))
1307 arglist))
1308
1309 (defimplementation function-name (function)
1310 (cond ((eval:interpreted-function-p function)
1311 (eval:interpreted-function-name function))
1312 ((pcl::generic-function-p function)
1313 (pcl::generic-function-name function))
1314 ((c::byte-function-or-closure-p function)
1315 (c::byte-function-name function))
1316 (t (kernel:%function-name (kernel:%function-self function)))))
1317
1318 ;;; A simple case: the arglist is available as a string that we can
1319 ;;; `read'.
1320
1321 (defun read-arglist (fn)
1322 "Parse the arglist-string of the function object FN."
1323 (let ((string (kernel:%function-arglist
1324 (kernel:%function-self fn)))
1325 (package (find-package
1326 (c::compiled-debug-info-package
1327 (kernel:%code-debug-info
1328 (vm::find-code-object fn))))))
1329 (with-standard-io-syntax
1330 (let ((*package* (or package *package*)))
1331 (read-from-string string)))))
1332
1333 ;;; A harder case: an approximate arglist is derived from available
1334 ;;; debugging information.
1335
1336 (defun debug-function-arglist (debug-function)
1337 "Derive the argument list of DEBUG-FUNCTION from debug info."
1338 (let ((args (di::debug-function-lambda-list debug-function))
1339 (required '())
1340 (optional '())
1341 (rest '())
1342 (key '()))
1343 ;; collect the names of debug-vars
1344 (dolist (arg args)
1345 (etypecase arg
1346 (di::debug-variable
1347 (push (di::debug-variable-symbol arg) required))
1348 ((member :deleted)
1349 (push ':deleted required))
1350 (cons
1351 (ecase (car arg)
1352 (:keyword
1353 (push (second arg) key))
1354 (:optional
1355 (push (debug-variable-symbol-or-deleted (second arg)) optional))
1356 (:rest
1357 (push (debug-variable-symbol-or-deleted (second arg)) rest))))))
1358 ;; intersperse lambda keywords as needed
1359 (append (nreverse required)
1360 (if optional (cons '&optional (nreverse optional)))
1361 (if rest (cons '&rest (nreverse rest)))
1362 (if key (cons '&key (nreverse key))))))
1363
1364 (defun debug-variable-symbol-or-deleted (var)
1365 (etypecase var
1366 (di:debug-variable
1367 (di::debug-variable-symbol var))
1368 ((member :deleted)
1369 '#:deleted)))
1370
1371 (defun symbol-debug-function-arglist (fname)
1372 "Return FNAME's debug-function-arglist and %function-arglist.
1373 A utility for debugging DEBUG-FUNCTION-ARGLIST."
1374 (let ((fn (fdefinition fname)))
1375 (values (debug-function-arglist (di::function-debug-function fn))
1376 (kernel:%function-arglist (kernel:%function-self fn)))))
1377
1378 ;;; Deriving arglists for byte-compiled functions:
1379 ;;;
1380 (defun byte-code-function-arglist (fn)
1381 ;; There doesn't seem to be much arglist information around for
1382 ;; byte-code functions. Use the arg-count and return something like
1383 ;; (arg0 arg1 ...)
1384 (etypecase fn
1385 (c::simple-byte-function
1386 (loop for i from 0 below (c::simple-byte-function-num-args fn)
1387 collect (make-arg-symbol i)))
1388 (c::hairy-byte-function
1389 (hairy-byte-function-arglist fn))
1390 (c::byte-closure
1391 (byte-code-function-arglist (c::byte-closure-function fn)))))
1392
1393 (defun make-arg-symbol (i)
1394 (make-symbol (format nil "~A~D" (string 'arg) i)))
1395
1396 ;;; A "hairy" byte-function is one that takes a variable number of
1397 ;;; arguments. `hairy-byte-function' is a type from the bytecode
1398 ;;; interpreter.
1399 ;;;
1400 (defun hairy-byte-function-arglist (fn)
1401 (let ((counter -1))
1402 (flet ((next-arg () (make-arg-symbol (incf counter))))
1403 (with-struct (c::hairy-byte-function- min-args max-args rest-arg-p
1404 keywords-p keywords) fn
1405 (let ((arglist '())
1406 (optional (- max-args min-args)))
1407 ;; XXX isn't there a better way to write this?
1408 ;; (Looks fine to me. -luke)
1409 (dotimes (i min-args)
1410 (push (next-arg) arglist))
1411 (when (plusp optional)
1412 (push '&optional arglist)
1413 (dotimes (i optional)
1414 (push (next-arg) arglist)))
1415 (when rest-arg-p
1416 (push '&rest arglist)
1417 (push (next-arg) arglist))
1418 (when keywords-p
1419 (push '&key arglist)
1420 (loop for (key _ __) in keywords
1421 do (push key arglist))
1422 (when (eq keywords-p :allow-others)
1423 (push '&allow-other-keys arglist)))
1424 (nreverse arglist))))))
1425
1426
1427 ;;;; Miscellaneous.
1428
1429 (defimplementation macroexpand-all (form)
1430 (walker:macroexpand-all form))
1431
1432 (defimplementation compiler-macroexpand-1 (form &optional env)
1433 (ext:compiler-macroexpand-1 form env))
1434
1435 (defimplementation compiler-macroexpand (form &optional env)
1436 (ext:compiler-macroexpand form env))
1437
1438 (defimplementation set-default-directory (directory)
1439 (setf (ext:default-directory) (namestring directory))
1440 ;; Setting *default-pathname-defaults* to an absolute directory
1441 ;; makes the behavior of MERGE-PATHNAMES a bit more intuitive.
1442 (setf *default-pathname-defaults* (pathname (ext:default-directory)))
1443 (default-directory))
1444
1445 (defimplementation default-directory ()
1446 (namestring (ext:default-directory)))
1447
1448 (defimplementation call-without-interrupts (fn)
1449 (sys:without-interrupts (funcall fn)))
1450
1451 (defimplementation getpid ()
1452 (unix:unix-getpid))
1453
1454 (defimplementation lisp-implementation-type-name ()
1455 "cmucl")
1456
1457 (defimplementation quit-lisp ()
1458 (ext::quit))
1459
1460 ;;; source-path-{stream,file,string,etc}-position moved into
1461 ;;; swank-source-path-parser
1462
1463
1464 ;;;; Debugging
1465
1466 (defvar *sldb-stack-top*)
1467
1468 (defimplementation call-with-debugging-environment (debugger-loop-fn)
1469 (unix:unix-sigsetmask 0)
1470 (let* ((*sldb-stack-top* (or debug:*stack-top-hint* (di:top-frame)))
1471 (debug:*stack-top-hint* nil)
1472 (kernel:*current-level* 0))
1473 (handler-bind ((di::unhandled-condition
1474 (lambda (condition)
1475 (error (make-condition
1476 'sldb-condition
1477 :original-condition condition)))))
1478 (funcall debugger-loop-fn))))
1479
1480 (defun frame-down (frame)
1481 (handler-case (di:frame-down frame)
1482 (di:no-debug-info () nil)))
1483
1484 (defun nth-frame (index)
1485 (do ((frame *sldb-stack-top* (frame-down frame))
1486 (i index (1- i)))
1487 ((zerop i) frame)))
1488
1489 (defimplementation compute-backtrace (start end)
1490 (let ((end (or end most-positive-fixnum)))
1491 (loop for f = (nth-frame start) then (frame-down f)
1492 for i from start below end
1493 while f
1494 collect f)))
1495
1496 (defimplementation print-frame (frame stream)
1497 (let ((*standard-output* stream))
1498 (handler-case
1499 (debug::print-frame-call frame :verbosity 1 :number nil)
1500 (error (e)
1501 (ignore-errors (princ e stream))))))
1502
1503 (defimplementation frame-source-location-for-emacs (index)
1504 (code-location-source-location (di:frame-code-location (nth-frame index))))
1505
1506 (defimplementation eval-in-frame (form index)
1507 (di:eval-in-frame (nth-frame index) form))
1508
1509 (defun frame-debug-vars (frame)
1510 "Return a vector of debug-variables in frame."
1511 (di::debug-function-debug-variables (di:frame-debug-function frame)))
1512
1513 (defun debug-var-value (var frame location)
1514 (let ((validity (di:debug-variable-validity var location)))
1515 (ecase validity
1516 (:valid (di:debug-variable-value var frame))
1517 ((:invalid :unknown) (make-symbol (string validity))))))
1518
1519 (defimplementation frame-locals (index)
1520 (let* ((frame (nth-frame index))
1521 (loc (di:frame-code-location frame))
1522 (vars (frame-debug-vars frame)))
1523 (loop for v across vars collect
1524 (list :name (di:debug-variable-symbol v)
1525 :id (di:debug-variable-id v)
1526 :value (debug-var-value v frame loc)))))
1527
1528 (defimplementation frame-var-value (frame var)
1529 (let* ((frame (nth-frame frame))
1530 (dvar (aref (frame-debug-vars frame) var)))
1531 (debug-var-value dvar frame (di:frame-code-location frame))))
1532
1533 (defimplementation frame-catch-tags (index)
1534 (mapcar #'car (di:frame-catches (nth-frame index))))
1535
1536 (defimplementation return-from-frame (index form)
1537 (let ((sym (find-symbol (string 'find-debug-tag-for-frame)
1538 :debug-internals)))
1539 (if sym
1540 (let* ((frame (nth-frame index))
1541 (probe (funcall sym frame)))
1542 (cond (probe (throw (car probe) (eval-in-frame form index)))
1543 (t (format nil "Cannot return from frame: ~S" frame))))
1544 "return-from-frame is not implemented in this version of CMUCL.")))
1545
1546 (defimplementation activate-stepping (frame)
1547 (set-step-breakpoints (nth-frame frame)))
1548
1549 (defimplementation sldb-break-on-return (frame)
1550 (break-on-return (nth-frame frame)))
1551
1552 ;;; We set the breakpoint in the caller which might be a bit confusing.
1553 ;;;
1554 (defun break-on-return (frame)
1555 (let* ((caller (di:frame-down frame))
1556 (cl (di:frame-code-location caller)))
1557 (flet ((hook (frame bp)
1558 (when (frame-pointer= frame caller)
1559 (di:delete-breakpoint bp)
1560 (signal-breakpoint bp frame))))
1561 (let* ((info (ecase (di:code-location-kind cl)
1562 ((:single-value-return :unknown-return) nil)
1563 (:known-return (debug-function-returns
1564 (di:frame-debug-function frame)))))
1565 (bp (di:make-breakpoint #'hook cl :kind :code-location
1566 :info info)))
1567 (di:activate-breakpoint bp)
1568 `(:ok ,(format nil "Set breakpoint in ~A" caller))))))
1569
1570 (defun frame-pointer= (frame1 frame2)
1571 "Return true if the frame pointers of FRAME1 and FRAME2 are the same."
1572 (sys:sap= (di::frame-pointer frame1) (di::frame-pointer frame2)))
1573
1574 ;;; The PC in escaped frames at a single-return-value point is
1575 ;;; actually vm:single-value-return-byte-offset bytes after the
1576 ;;; position given in the debug info. Here we try to recognize such
1577 ;;; cases.
1578 ;;;
1579 (defun next-code-locations (frame code-location)
1580 "Like `debug::next-code-locations' but be careful in escaped frames."
1581 (let ((next (debug::next-code-locations code-location)))
1582 (flet ((adjust-pc ()
1583 (let ((cl (di::copy-compiled-code-location code-location)))
1584 (incf (di::compiled-code-location-pc cl)
1585 vm:single-value-return-byte-offset)
1586 cl)))
1587 (cond ((and (di::compiled-frame-escaped frame)
1588 (eq (di:code-location-kind code-location)
1589 :single-value-return)
1590 (= (length next) 1)
1591 (di:code-location= (car next) (adjust-pc)))
1592 (debug::next-code-locations (car next)))
1593 (t
1594 next)))))
1595
1596 (defun set-step-breakpoints (frame)
1597 (let ((cl (di:frame-code-location frame)))
1598 (when (di:debug-block-elsewhere-p (di:code-location-debug-block cl))
1599 (error "Cannot step in elsewhere code"))
1600 (let* ((debug::*bad-code-location-types*
1601 (remove :call-site debug::*bad-code-location-types*))
1602 (next (next-code-locations frame cl)))
1603 (cond (next
1604 (let ((steppoints '()))
1605 (flet ((hook (bp-frame bp)
1606 (signal-breakpoint bp bp-frame)
1607 (mapc #'di:delete-breakpoint steppoints)))
1608 (dolist (code-location next)
1609 (let ((bp (di:make-breakpoint #'hook code-location
1610 :kind :code-location)))
1611 (di:activate-breakpoint bp)
1612 (push bp steppoints))))))
1613 (t
1614 (break-on-return frame))))))
1615
1616
1617 ;; XXX the return values at return breakpoints should be passed to the
1618 ;; user hooks. debug-int.lisp should be changed to do this cleanly.
1619
1620 ;;; The sigcontext and the PC for a breakpoint invocation are not
1621 ;;; passed to user hook functions, but we need them to extract return
1622 ;;; values. So we advice di::handle-breakpoint and bind the values to
1623 ;;; special variables.
1624 ;;;
1625 (defvar *breakpoint-sigcontext*)
1626 (defvar *breakpoint-pc*)
1627
1628 ;; XXX don't break old versions without fwrappers. Remove this one day.
1629 #+#.(cl:if (cl:find-package :fwrappers) '(and) '(or))
1630 (progn
1631 (fwrappers:define-fwrapper bind-breakpoint-sigcontext (offset c sigcontext)
1632 (let ((*breakpoint-sigcontext* sigcontext)
1633 (*breakpoint-pc* offset))
1634 (fwrappers:call-next-function)))
1635 (fwrappers:set-fwrappers 'di::handle-breakpoint '())
1636 (fwrappers:fwrap 'di::handle-breakpoint #'bind-breakpoint-sigcontext))
1637
1638 (defun sigcontext-object (sc index)
1639 "Extract the lisp object in sigcontext SC at offset INDEX."
1640 (kernel:make-lisp-obj (vm:sigcontext-register sc index)))
1641
1642 (defun known-return-point-values (sigcontext sc-offsets)
1643 (let ((fp (system:int-sap (vm:sigcontext-register sigcontext
1644 vm::cfp-offset))))
1645 (system:without-gcing
1646 (loop for sc-offset across sc-offsets
1647 collect (di::sub-access-debug-var-slot fp sc-offset sigcontext)))))
1648
1649 ;;; CMUCL returns the first few values in registers and the rest on
1650 ;;; the stack. In the multiple value case, the number of values is
1651 ;;; stored in a dedicated register. The values of the registers can be
1652 ;;; accessed in the sigcontext for the breakpoint. There are 3 kinds
1653 ;;; of return conventions: :single-value-return, :unknown-return, and
1654 ;;; :known-return.
1655 ;;;
1656 ;;; The :single-value-return convention returns the value in a
1657 ;;; register without setting the nargs registers.
1658 ;;;
1659 ;;; The :unknown-return variant is used for multiple values. A
1660 ;;; :unknown-return point consists actually of 2 breakpoints: one for
1661 ;;; the single value case and one for the general case. The single
1662 ;;; value breakpoint comes vm:single-value-return-byte-offset after
1663 ;;; the multiple value breakpoint.
1664 ;;;
1665 ;;; The :known-return convention is used by local functions.
1666 ;;; :known-return is currently not supported because we don't know
1667 ;;; where the values are passed.
1668 ;;;
1669 (defun breakpoint-values (breakpoint)
1670 "Return the list of return values for a return point."
1671 (flet ((1st (sc) (sigcontext-object sc (car vm::register-arg-offsets))))
1672 (let ((sc (locally (declare (optimize (ext:inhibit-warnings 3)))
1673 (alien:sap-alien *breakpoint-sigcontext* (* unix:sigcontext))))
1674 (cl (di:breakpoint-what breakpoint)))
1675 (ecase (di:code-location-kind cl)
1676 (:single-value-return
1677 (list (1st sc)))
1678 (:known-return
1679 (let ((info (di:breakpoint-info breakpoint)))
1680 (if (vectorp info)
1681 (known-return-point-values sc info)
1682 (progn
1683 ;;(break)
1684 (list "<<known-return convention not supported>>" info)))))
1685 (:unknown-return
1686 (let ((mv-return-pc (di::compiled-code-location-pc cl)))
1687 (if (= mv-return-pc *breakpoint-pc*)
1688 (mv-function-end-breakpoint-values sc)
1689 (list (1st sc)))))))))
1690
1691 ;; XXX: di::get-function-end-breakpoint-values takes 2 arguments in
1692 ;; newer versions of CMUCL (after ~March 2005).
1693 (defun mv-function-end-breakpoint-values (sigcontext)
1694 (let ((sym (find-symbol "FUNCTION-END-BREAKPOINT-VALUES/STANDARD" :di)))
1695 (cond (sym (funcall sym sigcontext))
1696 (t (di::get-function-end-breakpoint-values sigcontext)))))
1697
1698 (defun debug-function-returns (debug-fun)
1699 "Return the return style of DEBUG-FUN."
1700 (let* ((cdfun (di::compiled-debug-function-compiler-debug-fun debug-fun)))
1701 (c::compiled-debug-function-returns cdfun)))
1702
1703 (define-condition breakpoint (simple-condition)
1704 ((message :initarg :message :reader breakpoint.message)
1705 (values :initarg :values :reader breakpoint.values))
1706 (:report (lambda (c stream) (princ (breakpoint.message c) stream))))
1707
1708 (defimplementation condition-extras (condition)
1709 (typecase condition
1710 (breakpoint
1711 ;; pop up the source buffer
1712 `((:short-frame-source 0)))
1713 (t '())))
1714
1715 (defun signal-breakpoint (breakpoint frame)
1716 "Signal a breakpoint condition for BREAKPOINT in FRAME.
1717 Try to create a informative message."
1718 (flet ((brk (values fstring &rest args)
1719 (let ((msg (apply #'format nil fstring args))
1720 (debug:*stack-top-hint* frame))
1721 (break 'breakpoint :message msg :values values))))
1722 (with-struct (di::breakpoint- kind what) breakpoint
1723 (case kind
1724 (:code-location
1725 (case (di:code-location-kind what)
1726 ((:single-value-return :known-return :unknown-return)
1727 (let ((values (breakpoint-values breakpoint)))
1728 (brk values "Return value: ~{~S ~}" values)))
1729 (t
1730 #+(or)
1731 (when (eq (di:code-location-kind what) :call-site)
1732 (call-site-function breakpoint frame))
1733 (brk nil "Breakpoint: ~S ~S"
1734 (di:code-location-kind what)
1735 (di::compiled-code-location-pc what)))))
1736 (:function-start
1737 (brk nil "Function start breakpoint"))
1738 (t (brk nil "Breakpoint: ~A in ~A" breakpoint frame))))))
1739
1740 (defimplementation sldb-break-at-start (fname)
1741 (let ((debug-fun (di:function-debug-function (coerce fname 'function))))
1742 (cond ((not debug-fun)
1743 `(:error ,(format nil "~S has no debug-function" fname)))
1744 (t
1745 (flet ((hook (frame bp &optional args cookie)
1746 (declare (ignore args cookie))
1747 (signal-breakpoint bp frame)))
1748 (let ((bp (di:make-breakpoint #'hook debug-fun
1749 :kind :function-start)))
1750 (di:activate-breakpoint bp)
1751 `(:ok ,(format nil "Set breakpoint in ~S" fname))))))))
1752
1753 (defun frame-cfp (frame)
1754 "Return the Control-Stack-Frame-Pointer for FRAME."
1755 (etypecase frame
1756 (di::compiled-frame (di::frame-pointer frame))
1757 ((or di::interpreted-frame null) -1)))
1758
1759 (defun frame-ip (frame)
1760 "Return the (absolute) instruction pointer and the relative pc of FRAME."
1761 (if (not frame)
1762 -1
1763 (let ((debug-fun (di::frame-debug-function frame)))
1764 (etypecase debug-fun
1765 (di::compiled-debug-function
1766 (let* ((code-loc (di:frame-code-location frame))
1767 (component (di::compiled-debug-function-component debug-fun))
1768 (pc (di::compiled-code-location-pc code-loc))
1769 (ip (sys:without-gcing
1770 (sys:sap-int
1771 (sys:sap+ (kernel:code-instructions component) pc)))))
1772 (values ip pc)))
1773 ((or di::bogus-debug-function di::interpreted-debug-function)
1774 -1)))))
1775
1776 (defun frame-registers (frame)
1777 "Return the lisp registers CSP, CFP, IP, OCFP, LRA for FRAME-NUMBER."
1778 (let* ((cfp (frame-cfp frame))
1779 (csp (frame-cfp (di::frame-up frame)))
1780 (ip (frame-ip frame))
1781 (ocfp (frame-cfp (di::frame-down frame)))
1782 (lra (frame-ip (di::frame-down frame))))
1783 (values csp cfp ip ocfp lra)))
1784
1785 (defun print-frame-registers (frame-number)
1786 (let ((frame (di::frame-real-frame (nth-frame frame-number))))
1787 (flet ((fixnum (p) (etypecase p
1788 (integer p)
1789 (sys:system-area-pointer (sys:sap-int p)))))
1790 (apply #'format t "~
1791 CSP = ~X
1792 CFP = ~X
1793 IP = ~X
1794 OCFP = ~X
1795 LRA = ~X~%" (mapcar #'fixnum
1796 (multiple-value-list (frame-registers frame)))))))
1797
1798
1799 (defimplementation disassemble-frame (frame-number)
1800 "Return a string with the disassembly of frames code."
1801 (print-frame-registers frame-number)
1802 (terpri)
1803 (let* ((frame (di::frame-real-frame (nth-frame frame-number)))
1804 (debug-fun (di::frame-debug-function frame)))
1805 (etypecase debug-fun
1806 (di::compiled-debug-function
1807 (let* ((component (di::compiled-debug-function-component debug-fun))
1808 (fun (di:debug-function-function debug-fun)))
1809 (if fun
1810 (disassemble fun)
1811 (disassem:disassemble-code-component component))))
1812 (di::bogus-debug-function
1813 (format t "~%[Disassembling bogus frames not implemented]")))))
1814
1815
1816 ;;;; Inspecting
1817
1818 (defclass cmucl-inspector (inspector)
1819 ())
1820
1821 (defimplementation make-default-inspector ()
1822 (make-instance 'cmucl-inspector))
1823
1824 (defconstant +lowtag-symbols+
1825 '(vm:even-fixnum-type
1826 vm:function-pointer-type
1827 vm:other-immediate-0-type
1828 vm:list-pointer-type
1829 vm:odd-fixnum-type
1830 vm:instance-pointer-type
1831 vm:other-immediate-1-type
1832 vm:other-pointer-type)
1833 "Names of the constants that specify type tags.
1834 The `symbol-value' of each element is a type tag.")
1835
1836 (defconstant +header-type-symbols+
1837 (labels ((suffixp (suffix string)
1838 (and (>= (length string) (length suffix))
1839 (string= string suffix :start1 (- (length string)
1840 (length suffix)))))
1841 (header-type-symbol-p (x)
1842 (and (suffixp "-TYPE" (symbol-name x))
1843 (not (member x +lowtag-symbols+))
1844 (boundp x)
1845 (typep (symbol-value x) 'fixnum))))
1846 (remove-if-not #'header-type-symbol-p
1847 (append (apropos-list "-TYPE" "VM")
1848 (apropos-list "-TYPE" "BIGNUM"))))
1849 "A list of names of the type codes in boxed objects.")
1850
1851 (defimplementation describe-primitive-type (object)
1852 (with-output-to-string (*standard-output*)
1853 (let* ((lowtag (kernel:get-lowtag object))
1854 (lowtag-symbol (find lowtag +lowtag-symbols+ :key #'symbol-value)))
1855 (format t "lowtag: ~A" lowtag-symbol)
1856 (when (member lowtag (list vm:other-pointer-type
1857 vm:function-pointer-type
1858 vm:other-immediate-0-type
1859 vm:other-immediate-1-type
1860 ))
1861 (let* ((type (kernel:get-type object))
1862 (type-symbol (find type +header-type-symbols+
1863 :key #'symbol-value)))
1864 (format t ", type: ~A" type-symbol))))))
1865
1866 (defmethod inspect-for-emacs ((o t) (inspector cmucl-inspector))
1867 (cond ((di::indirect-value-cell-p o)
1868 (values (format nil "~A is a value cell." o)
1869 `("Value: " (:value ,(c:value-cell-ref o)))))
1870 ((alien::alien-value-p o)
1871 (inspect-alien-value o))
1872 (t
1873 (cmucl-inspect o))))
1874
1875 (defun cmucl-inspect (o)
1876 (destructuring-bind (text labeledp . parts) (inspect::describe-parts o)
1877 (values (format nil "~A~%" text)
1878 (if labeledp
1879 (loop for (label . value) in parts
1880 append (label-value-line label value))
1881 (loop for value in parts for i from 0
1882 append (label-value-line i value))))))
1883
1884 (defmethod inspect-for-emacs ((o function) (inspector cmucl-inspector))
1885 (declare (ignore inspector))
1886 (let ((header (kernel:get-type o)))
1887 (cond ((= header vm:function-header-type)
1888 (values (format nil "~A is a function." o)
1889 (append (label-value-line*
1890 ("Self" (kernel:%function-self o))
1891 ("Next" (kernel:%function-next o))
1892 ("Name" (kernel:%function-name o))
1893 ("Arglist" (kernel:%function-arglist o))
1894 ("Type" (kernel:%function-type o))
1895 ("Code" (kernel:function-code-header o)))
1896 (list
1897 (with-output-to-string (s)
1898 (disassem:disassemble-function o :stream s))))))
1899 ((= header vm:closure-header-type)
1900 (values (format nil "~A is a closure" o)
1901 (append
1902 (label-value-line "Function" (kernel:%closure-function o))
1903 `("Environment:" (:newline))
1904 (loop for i from 0 below (1- (kernel:get-closure-length o))
1905 append (label-value-line
1906 i (kernel:%closure-index-ref o i))))))
1907 ((eval::interpreted-function-p o)
1908 (cmucl-inspect o))
1909 (t
1910 (call-next-method)))))
1911
1912 (defmethod inspect-for-emacs ((o kernel:funcallable-instance)
1913 (i cmucl-inspector))
1914 (declare (ignore i))
1915 (values
1916 (format nil "~A is a funcallable-instance." o)
1917 (append (label-value-line*
1918 (:function (kernel:%funcallable-instance-function o))
1919 (:lexenv (kernel:%funcallable-instance-lexenv o))
1920 (:layout (kernel:%funcallable-instance-layout o)))
1921 (nth-value 1 (cmucl-inspect o)))))
1922
1923 (defmethod inspect-for-emacs ((o kernel:code-component) (_ cmucl-inspector))
1924 (declare (ignore _))
1925 (values (format nil "~A is a code data-block." o)
1926 (append
1927 (label-value-line*
1928 ("code-size" (kernel:%code-code-size o))
1929 ("entry-points" (kernel:%code-entry-points o))
1930 ("debug-info" (kernel:%code-debug-info o))
1931 ("trace-table-offset" (kernel:code-header-ref
1932 o vm:code-trace-table-offset-slot)))
1933 `("Constants:" (:newline))
1934 (loop for i from vm:code-constants-offset
1935 below (kernel:get-header-data o)
1936 append (label-value-line i (kernel:code-header-ref o i)))
1937 `("Code:" (:newline)
1938 , (with-output-to-string (s)
1939 (cond ((kernel:%code-debug-info o)
1940 (disassem:disassemble-code-component o :stream s))
1941 (t
1942 (disassem:disassemble-memory
1943 (disassem::align
1944 (+ (logandc2 (kernel:get-lisp-obj-address o)
1945 vm:lowtag-mask)
1946 (* vm:code-constants-offset vm:word-bytes))
1947 (ash 1 vm:lowtag-bits))
1948 (ash (kernel:%code-code-size o) vm:word-shift)
1949 :stream s))))))))
1950
1951 (defmethod inspect-for-emacs ((o kernel:fdefn) (inspector cmucl-inspector))
1952 (declare (ignore inspector))
1953 (values (format nil "~A is a fdenf object." o)
1954 (label-value-line*
1955 ("name" (kernel:fdefn-name o))
1956 ("function" (kernel:fdefn-function o))
1957 ("raw-addr" (sys:sap-ref-32
1958 (sys:int-sap (kernel:get-lisp-obj-address o))
1959 (* vm:fdefn-raw-addr-slot vm:word-bytes))))))
1960
1961 (defmethod inspect-for-emacs ((o array) (inspector cmucl-inspector))
1962 inspector
1963 (if (typep o 'simple-array)
1964 (call-next-method)
1965 (values (format nil "~A is an array." o)
1966 (label-value-line*
1967 (:header (describe-primitive-type o))
1968 (:rank (array-rank o))
1969 (:fill-pointer (kernel:%array-fill-pointer o))
1970 (:fill-pointer-p (kernel:%array-fill-pointer-p o))
1971 (:elements (kernel:%array-available-elements o))
1972 (:data (kernel:%array-data-vector o))
1973 (:displacement (kernel:%array-displacement o))
1974 (:displaced-p (kernel:%array-displaced-p o))
1975 (:dimensions (array-dimensions o))))))
1976
1977 (defmethod inspect-for-emacs ((o simple-vector) (inspector cmucl-inspector))
1978 inspector
1979 (values (format nil "~A is a simple-vector." o)
1980 (append
1981 (label-value-line*
1982 (:header (describe-primitive-type o))
1983 (:length (c::vector-length o)))
1984 (loop for i below (length o)
1985 append (label-value-line i (aref o i))))))
1986
1987 (defun inspect-alien-record (alien)
1988 (values
1989 (format nil "~A is an alien value." alien)
1990 (with-struct (alien::alien-value- sap type) alien
1991 (with-struct (alien::alien-record-type- kind name fields) type
1992 (append
1993 (label-value-line*
1994 (:sap sap)
1995 (:kind kind)
1996 (:name name))
1997 (loop for field in fields
1998 append (let ((slot (alien::alien-record-field-name field)))
1999 (label-value-line slot (alien:slot alien slot)))))))))
2000
2001 (defun inspect-alien-pointer (alien)
2002 (values
2003 (format nil "~A is an alien value." alien)
2004 (with-struct (alien::alien-value- sap type) alien
2005 (label-value-line*
2006 (:sap sap)
2007 (:type type)
2008 (:to (alien::deref alien))))))
2009
2010 (defun inspect-alien-value (alien)
2011 (typecase (alien::alien-value-type alien)
2012 (alien::alien-record-type (inspect-alien-record alien))
2013 (alien::alien-pointer-type (inspect-alien-pointer alien))
2014 (t (cmucl-inspect alien))))
2015
2016 ;;;; Profiling
2017 (defimplementation profile (fname)
2018 (eval `(profile:profile ,fname)))
2019
2020 (defimplementation unprofile (fname)
2021 (eval `(profile:unprofile ,fname)))
2022
2023 (defimplementation unprofile-all ()
2024 (eval `(profile:unprofile))
2025 "All functions unprofiled.")
2026
2027 (defimplementation profile-report ()
2028 (eval `(profile:report-time)))
2029
2030 (defimplementation profile-reset ()
2031 (eval `(profile:reset-time))
2032 "Reset profiling counters.")
2033
2034 (defimplementation profiled-functions ()
2035 profile:*timed-functions*)
2036
2037 (defimplementation profile-package (package callers methods)
2038 (profile:profile-all :package package
2039 :callers-p callers
2040 #-cmu18e :methods #-cmu18e methods))
2041
2042
2043 ;;;; Multiprocessing
2044
2045 #+mp
2046 (progn
2047 (defimplementation initialize-multiprocessing (continuation)
2048 (mp::init-multi-processing)
2049 (funcall continuation))
2050
2051 (defimplementation startup-idle-and-top-level-loops ()
2052 ;; Threads magic: this never returns! But top-level becomes
2053 ;; available again.
2054 (unless mp::*initial-process*
2055 (mp::startup-idle-and-top-level-loops)))
2056
2057 (defimplementation spawn (fn &key name)
2058 (mp:make-process fn :name (or name "Anonymous")))
2059
2060 (defvar *thread-id-counter* 0)
2061
2062 (defimplementation thread-id (thread)
2063 (or (getf (mp:process-property-list thread) 'id)
2064 (setf (getf (mp:process-property-list thread) 'id)
2065 (incf *thread-id-counter*))))
2066
2067 (defimplementation find-thread (id)
2068 (find id (all-threads)
2069 :key (lambda (p) (getf (mp:process-property-list p) 'id))))
2070
2071 (defimplementation thread-name (thread)
2072 (mp:process-name thread))
2073
2074 (defimplementation thread-status (thread)
2075 (mp:process-whostate thread))
2076
2077 (defimplementation current-thread ()
2078 mp:*current-process*)
2079
2080 (defimplementation all-threads ()
2081 (copy-list mp:*all-processes*))
2082
2083 (defimplementation interrupt-thread (thread fn)
2084 (mp:process-interrupt thread fn))
2085
2086 (defimplementation kill-thread (thread)
2087 (mp:destroy-process thread))
2088
2089 (defvar *mailbox-lock* (mp:make-lock "mailbox lock"))
2090
2091 (defstruct (mailbox (:conc-name mailbox.))
2092 (mutex (mp:make-lock "process mailbox"))
2093 (queue '() :type list))
2094
2095 (defun mailbox (thread)
2096 "Return THREAD's mailbox."
2097 (mp:with-lock-held (*mailbox-lock*)
2098 (or (getf (mp:process-property-list thread) 'mailbox)
2099 (setf (getf (mp:process-property-list thread) 'mailbox)
2100 (make-mailbox)))))
2101
2102 (defimplementation send (thread message)
2103 (let* ((mbox (mailbox thread))
2104 (mutex (mailbox.mutex mbox)))
2105 (mp:with-lock-held (mutex)
2106 (setf (mailbox.queue mbox)
2107 (nconc (mailbox.queue mbox) (list message))))))
2108
2109 (defimplementation receive ()
2110 (let* ((mbox (mailbox mp:*current-process*))
2111 (mutex (mailbox.mutex mbox)))
2112 (mp:process-wait "receive" #'mailbox.queue mbox)
2113 (mp:with-lock-held (mutex)
2114 (pop (mailbox.queue mbox)))))
2115
2116 ) ;; #+mp
2117
2118
2119
2120 ;;;; GC hooks
2121 ;;;
2122 ;;; Display GC messages in the echo area to avoid cluttering the
2123 ;;; normal output.
2124 ;;;
2125
2126 ;; this should probably not be here, but where else?
2127 (defun background-message (message)
2128 (funcall (find-symbol (string :background-message) :swank)
2129 message))
2130
2131 (defun print-bytes (nbytes &optional stream)
2132 "Print the number NBYTES to STREAM in KB, MB, or GB units."
2133 (let ((names '((0 bytes) (10 kb) (20 mb) (30 gb) (40 tb) (50 eb))))
2134 (multiple-value-bind (power name)
2135 (loop for ((p1 n1) (p2 n2)) on names
2136 while n2 do
2137 (when (<= (expt 2 p1) nbytes (1- (expt 2 p2)))
2138 (return (values p1 n1))))
2139 (cond (name
2140 (format stream "~,1F ~A" (/ nbytes (expt 2 power)) name))
2141 (t
2142 (format stream "~:D bytes" nbytes))))))
2143
2144 (defconstant gc-generations 6)
2145
2146 #+gencgc
2147 (defun generation-stats ()
2148 "Return a string describing the size distribution among the generations."
2149 (let* ((alloc (loop for i below gc-generations
2150 collect (lisp::gencgc-stats i)))
2151 (sum (coerce (reduce #'+ alloc) 'float)))
2152 (format nil "~{~3F~^/~}"
2153 (mapcar (lambda (size) (/ size sum))
2154 alloc))))
2155
2156 (defvar *gc-start-time* 0)
2157
2158 (defun pre-gc-hook (bytes-in-use)
2159 (setq *gc-start-time* (get-internal-real-time))
2160 (let ((msg (format nil "[Commencing GC with ~A in use.]"
2161 (print-bytes bytes-in-use))))
2162 (background-message msg)))
2163
2164 (defun post-gc-hook (bytes-retained bytes-freed trigger)
2165 (declare (ignore trigger))
2166 (let* ((seconds (/ (- (get-internal-real-time) *gc-start-time*)
2167 internal-time-units-per-second))
2168 (msg (format nil "[GC done. ~A freed ~A retained ~A ~4F sec]"
2169 (print-bytes bytes-freed)
2170 (print-bytes bytes-retained)
2171 #+gencgc(generation-stats)
2172 #-gencgc""
2173 seconds)))
2174 (background-message msg)))
2175
2176 (defun install-gc-hooks ()
2177 (setq ext:*gc-notify-before* #'pre-gc-hook)
2178 (setq ext:*gc-notify-after* #'post-gc-hook))
2179
2180 (defun remove-gc-hooks ()
2181 (setq ext:*gc-notify-before* nil)
2182 (setq ext:*gc-notify-after* nil))
2183
2184 (defvar *install-gc-hooks* t
2185 "If non-nil install GC hooks")
2186
2187 (defimplementation emacs-connected ()
2188 (when *install-gc-hooks*
2189 (install-gc-hooks)))
2190
2191 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2192 ;;Trace implementations
2193 ;;In CMUCL, we have:
2194 ;; (trace <name>)
2195 ;; (trace (method <name> <qualifier>? (<specializer>+)))
2196 ;; (trace :methods t '<name>) ;;to trace all methods of the gf <name>
2197 ;; <name> can be a normal name or a (setf name)
2198
2199 (defun tracedp (spec)
2200 (member spec (eval '(trace)) :test #'equal))
2201
2202 (defun toggle-trace-aux (spec &rest options)
2203 (cond ((tracedp spec)
2204 (eval `(untrace ,spec))
2205 (format nil "~S is now untraced." spec))
2206 (t
2207 (eval `(trace ,spec ,@options))
2208 (format nil "~S is now traced." spec))))
2209
2210 (defimplementation toggle-trace (spec)
2211 (ecase (car spec)
2212 ((setf)
2213 (toggle-trace-aux spec))
2214 ((:defgeneric)
2215 (let ((name (second spec)))
2216 (toggle-trace-aux name :methods name)))
2217 ((:defmethod)
2218 (cond ((fboundp `(method ,@(cdr spec)))
2219 (toggle-trace-aux `(method ,(cdr spec))))
2220 ;; Man, is this ugly
2221 ((fboundp `(pcl::fast-method ,@(cdr spec)))
2222 (toggle-trace-aux `(pcl::fast-method ,@(cdr spec))))
2223 (t
2224 (error 'undefined-function :name (cdr spec)))))
2225 ((:call)
2226 (destructuring-bind (caller callee) (cdr spec)
2227 (toggle-trace-aux (process-fspec callee)
2228 :wherein (list (process-fspec caller)))))))
2229
2230 (defun process-fspec (fspec)
2231 (cond ((consp fspec)
2232 (ecase (first fspec)
2233 ((:defun :defgeneric) (second fspec))
2234 ((:defmethod)
2235 `(method ,(second fspec) ,@(third fspec) ,(fourth fspec)))
2236 ;; this isn't actually supported
2237 ((:labels) `(labels ,(process-fspec (second fspec)) ,(third fspec)))
2238 ((:flet) `(flet ,(process-fspec (second fspec)) ,(third fspec)))))
2239 (t
2240 fspec)))
2241
2242 ;;; Weak datastructures
2243
2244 (defimplementation make-weak-key-hash-table (&rest args)
2245 (apply #'make-hash-table :weak-p t args))
2246
2247 ;; Local Variables:
2248 ;; pbook-heading-regexp: "^;;;\\(;+\\)"
2249 ;; pbook-commentary-regexp: "^;;;\\($\\|[^;]\\)"
2250 ;; End:

  ViewVC Help
Powered by ViewVC 1.1.5