/[slime]/slime/swank-backend.lisp
ViewVC logotype

Contents of /slime/swank-backend.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.196 - (show annotations)
Tue Mar 2 12:38:06 2010 UTC (4 years, 1 month ago) by sboukarev
Branch: MAIN
Changes since 1.195: +7 -2 lines
* slime.el (slime-compile-and-load-file): Accept C-u arguments for
compilation policy the same way as slime-compile-defun.

* swank.lisp (compile-file-for-emacs): Take an additional policy argument.
* swank-backend.lisp (swank-compile-file): Ditto.

* swank-sbcl.lisp (compiler-policy, (setf compiler-policy)):
rename from get/set-compiler-policy.
(with-compiler-policy): New macro.
(swank-compile-file): Use with-compiler-policy.
(swank-compile-string): Ditto.
1 ;;; -*- Mode: lisp; indent-tabs-mode: nil; outline-regexp: ";;;;;*" -*-
2 ;;;
3 ;;; slime-backend.lisp --- SLIME backend interface.
4 ;;;
5 ;;; Created by James Bielman in 2003. Released into the public domain.
6 ;;;
7 ;;;; Frontmatter
8 ;;;
9 ;;; This file defines the functions that must be implemented
10 ;;; separately for each Lisp. Each is declared as a generic function
11 ;;; for which swank-<implementation>.lisp provides methods.
12
13 (defpackage :swank-backend
14 (:use :common-lisp)
15 (:export #:*debug-swank-backend*
16 #:sldb-condition
17 #:compiler-condition
18 #:original-condition
19 #:message
20 #:source-context
21 #:condition
22 #:severity
23 #:with-compilation-hooks
24 #:location
25 #:location-p
26 #:location-buffer
27 #:location-position
28 #:position-p
29 #:position-pos
30 #:print-output-to-string
31 #:quit-lisp
32 #:references
33 #:unbound-slot-filler
34 #:declaration-arglist
35 #:type-specifier-arglist
36 #:with-struct
37 #:when-let
38 ;; interrupt macro for the backend
39 #:*pending-slime-interrupts*
40 #:check-slime-interrupts
41 #:*interrupt-queued-handler*
42 ;; inspector related symbols
43 #:emacs-inspect
44 #:label-value-line
45 #:label-value-line*
46 #:with-symbol))
47
48 (defpackage :swank-mop
49 (:use)
50 (:export
51 ;; classes
52 #:standard-generic-function
53 #:standard-slot-definition
54 #:standard-method
55 #:standard-class
56 #:eql-specializer
57 #:eql-specializer-object
58 ;; standard-class readers
59 #:class-default-initargs
60 #:class-direct-default-initargs
61 #:class-direct-slots
62 #:class-direct-subclasses
63 #:class-direct-superclasses
64 #:class-finalized-p
65 #:class-name
66 #:class-precedence-list
67 #:class-prototype
68 #:class-slots
69 #:specializer-direct-methods
70 ;; generic function readers
71 #:generic-function-argument-precedence-order
72 #:generic-function-declarations
73 #:generic-function-lambda-list
74 #:generic-function-methods
75 #:generic-function-method-class
76 #:generic-function-method-combination
77 #:generic-function-name
78 ;; method readers
79 #:method-generic-function
80 #:method-function
81 #:method-lambda-list
82 #:method-specializers
83 #:method-qualifiers
84 ;; slot readers
85 #:slot-definition-allocation
86 #:slot-definition-documentation
87 #:slot-definition-initargs
88 #:slot-definition-initform
89 #:slot-definition-initfunction
90 #:slot-definition-name
91 #:slot-definition-type
92 #:slot-definition-readers
93 #:slot-definition-writers
94 #:slot-boundp-using-class
95 #:slot-value-using-class
96 #:slot-makunbound-using-class
97 ;; generic function protocol
98 #:compute-applicable-methods-using-classes
99 #:finalize-inheritance))
100
101 (in-package :swank-backend)
102
103
104 ;;;; Metacode
105
106 (defparameter *debug-swank-backend* nil
107 "If this is true, backends should not catch errors but enter the
108 debugger where appropriate. Also, they should not perform backtrace
109 magic but really show every frame including SWANK related ones.")
110
111 (defparameter *interface-functions* '()
112 "The names of all interface functions.")
113
114 (defparameter *unimplemented-interfaces* '()
115 "List of interface functions that are not implemented.
116 DEFINTERFACE adds to this list and DEFIMPLEMENTATION removes.")
117
118 (defmacro definterface (name args documentation &rest default-body)
119 "Define an interface function for the backend to implement.
120 A function is defined with NAME, ARGS, and DOCUMENTATION. This
121 function first looks for a function to call in NAME's property list
122 that is indicated by 'IMPLEMENTATION; failing that, it looks for a
123 function indicated by 'DEFAULT. If neither is present, an error is
124 signaled.
125
126 If a DEFAULT-BODY is supplied, then a function with the same body and
127 ARGS will be added to NAME's property list as the property indicated
128 by 'DEFAULT.
129
130 Backends implement these functions using DEFIMPLEMENTATION."
131 (check-type documentation string "a documentation string")
132 (assert (every #'symbolp args) ()
133 "Complex lambda-list not supported: ~S ~S" name args)
134 (labels ((gen-default-impl ()
135 `(setf (get ',name 'default) (lambda ,args ,@default-body)))
136 (args-as-list (args)
137 (destructuring-bind (req opt key rest) (parse-lambda-list args)
138 `(,@req ,@opt
139 ,@(loop for k in key append `(,(kw k) ,k))
140 ,@(or rest '(())))))
141 (parse-lambda-list (args)
142 (parse args '(&optional &key &rest)
143 (make-array 4 :initial-element nil)))
144 (parse (args keywords vars)
145 (cond ((null args)
146 (reverse (map 'list #'reverse vars)))
147 ((member (car args) keywords)
148 (parse (cdr args) (cdr (member (car args) keywords)) vars))
149 (t (push (car args) (aref vars (length keywords)))
150 (parse (cdr args) keywords vars))))
151 (kw (s) (intern (string s) :keyword)))
152 `(progn
153 (defun ,name ,args
154 ,documentation
155 (let ((f (or (get ',name 'implementation)
156 (get ',name 'default))))
157 (cond (f (apply f ,@(args-as-list args)))
158 (t (error "~S not implemented" ',name)))))
159 (pushnew ',name *interface-functions*)
160 ,(if (null default-body)
161 `(pushnew ',name *unimplemented-interfaces*)
162 (gen-default-impl))
163 ;; see <http://www.franz.com/support/documentation/6.2/doc/pages/variables/compiler/s_cltl1-compile-file-toplevel-compatibility-p_s.htm>
164 (eval-when (:compile-toplevel :load-toplevel :execute)
165 (export ',name :swank-backend))
166 ',name)))
167
168 (defmacro defimplementation (name args &body body)
169 (assert (every #'symbolp args) ()
170 "Complex lambda-list not supported: ~S ~S" name args)
171 `(progn
172 (setf (get ',name 'implementation)
173 ;; For implicit BLOCK. FLET because of interplay w/ decls.
174 (flet ((,name ,args ,@body)) #',name))
175 (if (member ',name *interface-functions*)
176 (setq *unimplemented-interfaces*
177 (remove ',name *unimplemented-interfaces*))
178 (warn "DEFIMPLEMENTATION of undefined interface (~S)" ',name))
179 ',name))
180
181 (defun warn-unimplemented-interfaces ()
182 "Warn the user about unimplemented backend features.
183 The portable code calls this function at startup."
184 (let ((*print-pretty* t))
185 (warn "These Swank interfaces are unimplemented:~% ~:<~{~A~^ ~:_~}~:>"
186 (list (sort (copy-list *unimplemented-interfaces*) #'string<)))))
187
188 (defun import-to-swank-mop (symbol-list)
189 (dolist (sym symbol-list)
190 (let* ((swank-mop-sym (find-symbol (symbol-name sym) :swank-mop)))
191 (when swank-mop-sym
192 (unintern swank-mop-sym :swank-mop))
193 (import sym :swank-mop)
194 (export sym :swank-mop))))
195
196 (defun import-swank-mop-symbols (package except)
197 "Import the mop symbols from PACKAGE to SWANK-MOP.
198 EXCEPT is a list of symbol names which should be ignored."
199 (do-symbols (s :swank-mop)
200 (unless (member s except :test #'string=)
201 (let ((real-symbol (find-symbol (string s) package)))
202 (assert real-symbol () "Symbol ~A not found in package ~A" s package)
203 (unintern s :swank-mop)
204 (import real-symbol :swank-mop)
205 (export real-symbol :swank-mop)))))
206
207 (defvar *gray-stream-symbols*
208 '(:fundamental-character-output-stream
209 :stream-write-char
210 :stream-write-string
211 :stream-fresh-line
212 :stream-force-output
213 :stream-finish-output
214 :fundamental-character-input-stream
215 :stream-read-char
216 :stream-peek-char
217 :stream-read-line
218 ;; STREAM-FILE-POSITION is not available on all implementations, or
219 ;; partially under a different name.
220 ; :stream-file-posiion
221 :stream-listen
222 :stream-unread-char
223 :stream-clear-input
224 :stream-line-column
225 :stream-read-char-no-hang
226 ;; STREAM-LINE-LENGTH is an extension to gray streams that's apparently
227 ;; supported by CMUCL, OpenMCL, SBCL and SCL.
228 #+(or cmu openmcl sbcl scl)
229 :stream-line-length))
230
231 (defun import-from (package symbol-names &optional (to-package *package*))
232 "Import the list of SYMBOL-NAMES found in the package PACKAGE."
233 (dolist (name symbol-names)
234 (multiple-value-bind (symbol found) (find-symbol (string name) package)
235 (assert found () "Symbol ~A not found in package ~A" name package)
236 (import symbol to-package))))
237
238
239 ;;;; Utilities
240
241 (defmacro with-struct ((conc-name &rest names) obj &body body)
242 "Like with-slots but works only for structs."
243 (flet ((reader (slot) (intern (concatenate 'string
244 (symbol-name conc-name)
245 (symbol-name slot))
246 (symbol-package conc-name))))
247 (let ((tmp (gensym "OO-")))
248 ` (let ((,tmp ,obj))
249 (symbol-macrolet
250 ,(loop for name in names collect
251 (typecase name
252 (symbol `(,name (,(reader name) ,tmp)))
253 (cons `(,(first name) (,(reader (second name)) ,tmp)))
254 (t (error "Malformed syntax in WITH-STRUCT: ~A" name))))
255 ,@body)))))
256
257 (defmacro when-let ((var value) &body body)
258 `(let ((,var ,value))
259 (when ,var ,@body)))
260
261 (defun with-symbol (name package)
262 "Generate a form suitable for testing with #+."
263 (if (find-symbol (string name) (string package))
264 '(:and)
265 '(:or)))
266
267
268 ;;;; TCP server
269
270 (definterface create-socket (host port)
271 "Create a listening TCP socket on interface HOST and port PORT .")
272
273 (definterface local-port (socket)
274 "Return the local port number of SOCKET.")
275
276 (definterface close-socket (socket)
277 "Close the socket SOCKET.")
278
279 (definterface accept-connection (socket &key external-format
280 buffering timeout)
281 "Accept a client connection on the listening socket SOCKET.
282 Return a stream for the new connection.")
283
284 (definterface add-sigio-handler (socket fn)
285 "Call FN whenever SOCKET is readable.")
286
287 (definterface remove-sigio-handlers (socket)
288 "Remove all sigio handlers for SOCKET.")
289
290 (definterface add-fd-handler (socket fn)
291 "Call FN when Lisp is waiting for input and SOCKET is readable.")
292
293 (definterface remove-fd-handlers (socket)
294 "Remove all fd-handlers for SOCKET.")
295
296 (definterface preferred-communication-style ()
297 "Return one of the symbols :spawn, :sigio, :fd-handler, or NIL."
298 nil)
299
300 (definterface set-stream-timeout (stream timeout)
301 "Set the 'stream 'timeout. The timeout is either the real number
302 specifying the timeout in seconds or 'nil for no timeout."
303 (declare (ignore stream timeout))
304 nil)
305
306 ;;; Base condition for networking errors.
307 (define-condition network-error (simple-error) ())
308
309 (definterface emacs-connected ()
310 "Hook called when the first connection from Emacs is established.
311 Called from the INIT-FN of the socket server that accepts the
312 connection.
313
314 This is intended for setting up extra context, e.g. to discover
315 that the calling thread is the one that interacts with Emacs."
316 nil)
317
318
319 ;;;; Unix signals
320
321 (defconstant +sigint+ 2)
322
323 (definterface getpid ()
324 "Return the (Unix) process ID of this superior Lisp.")
325
326 (definterface install-sigint-handler (function)
327 "Call FUNCTION on SIGINT (instead of invoking the debugger).
328 Return old signal handler."
329 (declare (ignore function))
330 nil)
331
332 (definterface call-with-user-break-handler (handler function)
333 "Install the break handler HANDLER while executing FUNCTION."
334 (let ((old-handler (install-sigint-handler handler)))
335 (unwind-protect (funcall function)
336 (install-sigint-handler old-handler))))
337
338 (definterface quit-lisp ()
339 "Exit the current lisp image.")
340
341 (definterface lisp-implementation-type-name ()
342 "Return a short name for the Lisp implementation."
343 (lisp-implementation-type))
344
345 (definterface socket-fd (socket-stream)
346 "Return the file descriptor for SOCKET-STREAM.")
347
348 (definterface make-fd-stream (fd external-format)
349 "Create a character stream for the file descriptor FD.")
350
351 (definterface dup (fd)
352 "Duplicate a file descriptor.
353 If the syscall fails, signal a condition.
354 See dup(2).")
355
356 (definterface exec-image (image-file args)
357 "Replace the current process with a new process image.
358 The new image is created by loading the previously dumped
359 core file IMAGE-FILE.
360 ARGS is a list of strings passed as arguments to
361 the new image.
362 This is thin wrapper around exec(3).")
363
364 (definterface command-line-args ()
365 "Return a list of strings as passed by the OS.")
366
367
368 ;; pathnames are sooo useless
369
370 (definterface filename-to-pathname (filename)
371 "Return a pathname for FILENAME.
372 A filename in Emacs may for example contain asterisks which should not
373 be translated to wildcards."
374 (parse-namestring filename))
375
376 (definterface pathname-to-filename (pathname)
377 "Return the filename for PATHNAME."
378 (namestring pathname))
379
380 (definterface default-directory ()
381 "Return the default directory."
382 (directory-namestring (truename *default-pathname-defaults*)))
383
384 (definterface set-default-directory (directory)
385 "Set the default directory.
386 This is used to resolve filenames without directory component."
387 (setf *default-pathname-defaults* (truename (merge-pathnames directory)))
388 (default-directory))
389
390
391 (definterface call-with-syntax-hooks (fn)
392 "Call FN with hooks to handle special syntax."
393 (funcall fn))
394
395 (definterface default-readtable-alist ()
396 "Return a suitable initial value for SWANK:*READTABLE-ALIST*."
397 '())
398
399
400 ;;;; Compilation
401
402 (definterface call-with-compilation-hooks (func)
403 "Call FUNC with hooks to record compiler conditions.")
404
405 (defmacro with-compilation-hooks ((&rest ignore) &body body)
406 "Execute BODY as in CALL-WITH-COMPILATION-HOOKS."
407 (declare (ignore ignore))
408 `(call-with-compilation-hooks (lambda () (progn ,@body))))
409
410 (definterface swank-compile-string (string &key buffer position filename
411 policy)
412 "Compile source from STRING.
413 During compilation, compiler conditions must be trapped and
414 resignalled as COMPILER-CONDITIONs.
415
416 If supplied, BUFFER and POSITION specify the source location in Emacs.
417
418 Additionally, if POSITION is supplied, it must be added to source
419 positions reported in compiler conditions.
420
421 If FILENAME is specified it may be used by certain implementations to
422 rebind *DEFAULT-PATHNAME-DEFAULTS* which may improve the recording of
423 source information.
424
425 If POLICY is supplied, and non-NIL, it may be used by certain
426 implementations to compile with optimization qualities of its
427 value.
428
429 Should return T on successfull compilation, NIL otherwise.
430 ")
431
432 (definterface swank-compile-file (input-file output-file load-p
433 external-format
434 &key policy)
435 "Compile INPUT-FILE signalling COMPILE-CONDITIONs.
436 If LOAD-P is true, load the file after compilation.
437 EXTERNAL-FORMAT is a value returned by find-external-format or
438 :default.
439
440 If POLICY is supplied, and non-NIL, it may be used by certain
441 implementations to compile with optimization qualities of its
442 value.
443
444 Should return OUTPUT-TRUENAME, WARNINGS-P and FAILURE-p
445 like `compile-file'")
446
447 (deftype severity ()
448 '(member :error :read-error :warning :style-warning :note :redefinition))
449
450 ;; Base condition type for compiler errors, warnings and notes.
451 (define-condition compiler-condition (condition)
452 ((original-condition
453 ;; The original condition thrown by the compiler if appropriate.
454 ;; May be NIL if a compiler does not report using conditions.
455 :type (or null condition)
456 :initarg :original-condition
457 :accessor original-condition)
458
459 (severity :type severity
460 :initarg :severity
461 :accessor severity)
462
463 (message :initarg :message
464 :accessor message)
465
466 ;; Macro expansion history etc. which may be helpful in some cases
467 ;; but is often very verbose.
468 (source-context :initarg :source-context
469 :type (or null string)
470 :initform nil
471 :accessor source-context)
472
473 (references :initarg :references
474 :initform nil
475 :accessor references)
476
477 (location :initarg :location
478 :accessor location)))
479
480 (definterface find-external-format (coding-system)
481 "Return a \"external file format designator\" for CODING-SYSTEM.
482 CODING-SYSTEM is Emacs-style coding system name (a string),
483 e.g. \"latin-1-unix\"."
484 (if (equal coding-system "iso-latin-1-unix")
485 :default
486 nil))
487
488 (definterface guess-external-format (pathname)
489 "Detect the external format for the file with name pathname.
490 Return nil if the file contains no special markers."
491 ;; Look for a Emacs-style -*- coding: ... -*- or Local Variable: section.
492 (with-open-file (s pathname :if-does-not-exist nil
493 :external-format (or (find-external-format "latin-1-unix")
494 :default))
495 (if s
496 (or (let* ((line (read-line s nil))
497 (p (search "-*-" line)))
498 (when p
499 (let* ((start (+ p (length "-*-")))
500 (end (search "-*-" line :start2 start)))
501 (when end
502 (%search-coding line start end)))))
503 (let* ((len (file-length s))
504 (buf (make-string (min len 3000))))
505 (file-position s (- len (length buf)))
506 (read-sequence buf s)
507 (let ((start (search "Local Variables:" buf :from-end t))
508 (end (search "End:" buf :from-end t)))
509 (and start end (< start end)
510 (%search-coding buf start end))))))))
511
512 (defun %search-coding (str start end)
513 (let ((p (search "coding:" str :start2 start :end2 end)))
514 (when p
515 (incf p (length "coding:"))
516 (loop while (and (< p end)
517 (member (aref str p) '(#\space #\tab)))
518 do (incf p))
519 (let ((end (position-if (lambda (c) (find c '(#\space #\tab #\newline)))
520 str :start p)))
521 (find-external-format (subseq str p end))))))
522
523
524 ;;;; Streams
525
526 (definterface make-output-stream (write-string)
527 "Return a new character output stream.
528 The stream calls WRITE-STRING when output is ready.")
529
530 (definterface make-input-stream (read-string)
531 "Return a new character input stream.
532 The stream calls READ-STRING when input is needed.")
533
534
535 ;;;; Documentation
536
537 (definterface arglist (name)
538 "Return the lambda list for the symbol NAME. NAME can also be
539 a lisp function object, on lisps which support this.
540
541 The result can be a list or the :not-available keyword if the
542 arglist cannot be determined."
543 (declare (ignore name))
544 :not-available)
545
546 (defgeneric declaration-arglist (decl-identifier)
547 (:documentation
548 "Return the argument list of the declaration specifier belonging to the
549 declaration identifier DECL-IDENTIFIER. If the arglist cannot be determined,
550 the keyword :NOT-AVAILABLE is returned.
551
552 The different SWANK backends can specialize this generic function to
553 include implementation-dependend declaration specifiers, or to provide
554 additional information on the specifiers defined in ANSI Common Lisp.")
555 (:method (decl-identifier)
556 (case decl-identifier
557 (dynamic-extent '(&rest variables))
558 (ignore '(&rest variables))
559 (ignorable '(&rest variables))
560 (special '(&rest variables))
561 (inline '(&rest function-names))
562 (notinline '(&rest function-names))
563 (declaration '(&rest names))
564 (optimize '(&any compilation-speed debug safety space speed))
565 (type '(type-specifier &rest args))
566 (ftype '(type-specifier &rest function-names))
567 (otherwise
568 (flet ((typespec-p (symbol) (member :type (describe-symbol-for-emacs symbol))))
569 (cond ((and (symbolp decl-identifier) (typespec-p decl-identifier))
570 '(&rest variables))
571 ((and (listp decl-identifier) (typespec-p (first decl-identifier)))
572 '(&rest variables))
573 (t :not-available)))))))
574
575 (defgeneric type-specifier-arglist (typespec-operator)
576 (:documentation
577 "Return the argument list of the type specifier belonging to
578 TYPESPEC-OPERATOR.. If the arglist cannot be determined, the keyword
579 :NOT-AVAILABLE is returned.
580
581 The different SWANK backends can specialize this generic function to
582 include implementation-dependend declaration specifiers, or to provide
583 additional information on the specifiers defined in ANSI Common Lisp.")
584 (:method (typespec-operator)
585 (declare (special *type-specifier-arglists*)) ; defined at end of file.
586 (typecase typespec-operator
587 (symbol (or (cdr (assoc typespec-operator *type-specifier-arglists*))
588 :not-available))
589 (t :not-available))))
590
591 (definterface function-name (function)
592 "Return the name of the function object FUNCTION.
593
594 The result is either a symbol, a list, or NIL if no function name is available."
595 (declare (ignore function))
596 nil)
597
598 (definterface macroexpand-all (form)
599 "Recursively expand all macros in FORM.
600 Return the resulting form.")
601
602 (definterface compiler-macroexpand-1 (form &optional env)
603 "Call the compiler-macro for form.
604 If FORM is a function call for which a compiler-macro has been
605 defined, invoke the expander function using *macroexpand-hook* and
606 return the results and T. Otherwise, return the original form and
607 NIL."
608 (let ((fun (and (consp form) (compiler-macro-function (car form)))))
609 (if fun
610 (let ((result (funcall *macroexpand-hook* fun form env)))
611 (values result (not (eq result form))))
612 (values form nil))))
613
614 (definterface compiler-macroexpand (form &optional env)
615 "Repetitively call `compiler-macroexpand-1'."
616 (labels ((frob (form expanded)
617 (multiple-value-bind (new-form newly-expanded)
618 (compiler-macroexpand-1 form env)
619 (if newly-expanded
620 (frob new-form t)
621 (values new-form expanded)))))
622 (frob form env)))
623
624 (definterface format-string-expand (control-string)
625 "Expand the format string CONTROL-STRING."
626 (macroexpand `(formatter ,control-string)))
627
628 (definterface describe-symbol-for-emacs (symbol)
629 "Return a property list describing SYMBOL.
630
631 The property list has an entry for each interesting aspect of the
632 symbol. The recognised keys are:
633
634 :VARIABLE :FUNCTION :SETF :SPECIAL-OPERATOR :MACRO :COMPILER-MACRO
635 :TYPE :CLASS :ALIEN-TYPE :ALIEN-STRUCT :ALIEN-UNION :ALIEN-ENUM
636
637 The value of each property is the corresponding documentation string,
638 or :NOT-DOCUMENTED. It is legal to include keys not listed here (but
639 slime-print-apropos in Emacs must know about them).
640
641 Properties should be included if and only if they are applicable to
642 the symbol. For example, only (and all) fbound symbols should include
643 the :FUNCTION property.
644
645 Example:
646 \(describe-symbol-for-emacs 'vector)
647 => (:CLASS :NOT-DOCUMENTED
648 :TYPE :NOT-DOCUMENTED
649 :FUNCTION \"Constructs a simple-vector from the given objects.\")")
650
651 (definterface describe-definition (name type)
652 "Describe the definition NAME of TYPE.
653 TYPE can be any value returned by DESCRIBE-SYMBOL-FOR-EMACS.
654
655 Return a documentation string, or NIL if none is available.")
656
657
658 ;;;; Debugging
659
660 (definterface install-debugger-globally (function)
661 "Install FUNCTION as the debugger for all threads/processes. This
662 usually involves setting *DEBUGGER-HOOK* and, if the implementation
663 permits, hooking into BREAK as well."
664 (setq *debugger-hook* function))
665
666 (definterface call-with-debugging-environment (debugger-loop-fn)
667 "Call DEBUGGER-LOOP-FN in a suitable debugging environment.
668
669 This function is called recursively at each debug level to invoke the
670 debugger loop. The purpose is to setup any necessary environment for
671 other debugger callbacks that will be called within the debugger loop.
672
673 For example, this is a reasonable place to compute a backtrace, switch
674 to safe reader/printer settings, and so on.")
675
676 (definterface call-with-debugger-hook (hook fun)
677 "Call FUN and use HOOK as debugger hook. HOOK can be NIL.
678
679 HOOK should be called for both BREAK and INVOKE-DEBUGGER."
680 (let ((*debugger-hook* hook))
681 (funcall fun)))
682
683 (define-condition sldb-condition (condition)
684 ((original-condition
685 :initarg :original-condition
686 :accessor original-condition))
687 (:report (lambda (condition stream)
688 (format stream "Condition in debugger code~@[: ~A~]"
689 (original-condition condition))))
690 (:documentation
691 "Wrapper for conditions that should not be debugged.
692
693 When a condition arises from the internals of the debugger, it is not
694 desirable to debug it -- we'd risk entering an endless loop trying to
695 debug the debugger! Instead, such conditions can be reported to the
696 user without (re)entering the debugger by wrapping them as
697 `sldb-condition's."))
698
699 ;;; The following functions in this section are supposed to be called
700 ;;; within the dynamic contour of CALL-WITH-DEBUGGING-ENVIRONMENT only.
701
702 (definterface compute-backtrace (start end)
703 "Returns a backtrace of the condition currently being debugged,
704 that is an ordered list consisting of frames. ``Ordered list''
705 means that an integer I can be mapped back to the i-th frame of this
706 backtrace.
707
708 START and END are zero-based indices constraining the number of frames
709 returned. Frame zero is defined as the frame which invoked the
710 debugger. If END is nil, return the frames from START to the end of
711 the stack.")
712
713 (definterface print-frame (frame stream)
714 "Print frame to stream.")
715
716 (definterface frame-restartable-p (frame)
717 "Is the frame FRAME restartable?.
718 Return T if `restart-frame' can safely be called on the frame."
719 (declare (ignore frame))
720 nil)
721
722 (definterface frame-source-location (frame-number)
723 "Return the source location for the frame associated to FRAME-NUMBER.")
724
725 (definterface frame-catch-tags (frame-number)
726 "Return a list of catch tags for being printed in a debugger stack
727 frame."
728 (declare (ignore frame-number))
729 '())
730
731 (definterface frame-locals (frame-number)
732 "Return a list of ((&key NAME ID VALUE) ...) where each element of
733 the list represents a local variable in the stack frame associated to
734 FRAME-NUMBER.
735
736 NAME, a symbol; the name of the local variable.
737
738 ID, an integer; used as primary key for the local variable, unique
739 relatively to the frame under operation.
740
741 value, an object; the value of the local variable.")
742
743 (definterface frame-var-value (frame-number var-id)
744 "Return the value of the local variable associated to VAR-ID
745 relatively to the frame associated to FRAME-NUMBER.")
746
747 (definterface disassemble-frame (frame-number)
748 "Disassemble the code for the FRAME-NUMBER.
749 The output should be written to standard output.
750 FRAME-NUMBER is a non-negative integer.")
751
752 (definterface eval-in-frame (form frame-number)
753 "Evaluate a Lisp form in the lexical context of a stack frame
754 in the debugger.
755
756 FRAME-NUMBER must be a positive integer with 0 indicating the
757 frame which invoked the debugger.
758
759 The return value is the result of evaulating FORM in the
760 appropriate context.")
761
762 (definterface frame-call (frame-number)
763 "Return a string representing a call to the entry point of a frame.")
764
765 (definterface return-from-frame (frame-number form)
766 "Unwind the stack to the frame FRAME-NUMBER and return the value(s)
767 produced by evaluating FORM in the frame context to its caller.
768
769 Execute any clean-up code from unwind-protect forms above the frame
770 during unwinding.
771
772 Return a string describing the error if it's not possible to return
773 from the frame.")
774
775 (definterface restart-frame (frame-number)
776 "Restart execution of the frame FRAME-NUMBER with the same arguments
777 as it was called originally.")
778
779 (definterface format-sldb-condition (condition)
780 "Format a condition for display in SLDB."
781 (princ-to-string condition))
782
783 (definterface condition-extras (condition)
784 "Return a list of extra for the debugger.
785 The allowed elements are of the form:
786 (:SHOW-FRAME-SOURCE frame-number)
787 (:REFERENCES &rest refs)
788 "
789 (declare (ignore condition))
790 '())
791
792 (definterface activate-stepping (frame-number)
793 "Prepare the frame FRAME-NUMBER for stepping.")
794
795 (definterface sldb-break-on-return (frame-number)
796 "Set a breakpoint in the frame FRAME-NUMBER.")
797
798 (definterface sldb-break-at-start (symbol)
799 "Set a breakpoint on the beginning of the function for SYMBOL.")
800
801 (definterface sldb-stepper-condition-p (condition)
802 "Return true if SLDB was invoked due to a single-stepping condition,
803 false otherwise. "
804 (declare (ignore condition))
805 nil)
806
807 (definterface sldb-step-into ()
808 "Step into the current single-stepper form.")
809
810 (definterface sldb-step-next ()
811 "Step to the next form in the current function.")
812
813 (definterface sldb-step-out ()
814 "Stop single-stepping temporarily, but resume it once the current function
815 returns.")
816
817
818 ;;;; Definition finding
819
820 (defstruct (:location (:type list) :named
821 (:constructor make-location
822 (buffer position &optional hints)))
823 buffer position
824 ;; Hints is a property list optionally containing:
825 ;; :snippet SOURCE-TEXT
826 ;; This is a snippet of the actual source text at the start of
827 ;; the definition, which could be used in a text search.
828 hints)
829
830 (defstruct (:error (:type list) :named (:constructor)) message)
831
832 ;;; Valid content for BUFFER slot
833 (defstruct (:file (:type list) :named (:constructor)) name)
834 (defstruct (:buffer (:type list) :named (:constructor)) name)
835 (defstruct (:etags-file (:type list) :named (:constructor)) filename)
836
837 ;;; Valid content for POSITION slot
838 (defstruct (:position (:type list) :named (:constructor)) pos)
839 (defstruct (:tag (:type list) :named (:constructor)) tag1 tag2)
840
841 (defmacro converting-errors-to-error-location (&body body)
842 "Catches errors during BODY and converts them to an error location."
843 (let ((gblock (gensym "CONVERTING-ERRORS+")))
844 `(block ,gblock
845 (handler-bind ((error
846 #'(lambda (e)
847 (if *debug-swank-backend*
848 nil ;decline
849 (return-from ,gblock
850 (make-error-location e))))))
851 ,@body))))
852
853 (defun make-error-location (datum &rest args)
854 (cond ((typep datum 'condition)
855 `(:error ,(format nil "Error: ~A" datum)))
856 ((symbolp datum)
857 `(:error ,(format nil "Error: ~A" (apply #'make-condition datum args))))
858 (t
859 (assert (stringp datum))
860 `(:error ,(apply #'format nil datum args)))))
861
862 (definterface find-definitions (name)
863 "Return a list ((DSPEC LOCATION) ...) for NAME's definitions.
864
865 NAME is a \"definition specifier\".
866
867 DSPEC is a \"definition specifier\" describing the
868 definition, e.g., FOO or (METHOD FOO (STRING NUMBER)) or
869 \(DEFVAR FOO).
870
871 LOCATION is the source location for the definition.")
872
873 (definterface find-source-location (object)
874 "Returns the source location of OBJECT, or NIL.
875
876 That is the source location of the underlying datastructure of
877 OBJECT. E.g. on a STANDARD-OBJECT, the source location of the
878 respective DEFCLASS definition is returned, on a STRUCTURE-CLASS the
879 respective DEFSTRUCT definition, and so on."
880 ;; This returns one source location and not a list of locations. It's
881 ;; supposed to return the location of the DEFGENERIC definition on
882 ;; #'SOME-GENERIC-FUNCTION.
883 (declare (ignore object))
884 (make-error-location "FIND-DEFINITIONS is not yet implemented on ~
885 this implementation."))
886
887
888 (definterface buffer-first-change (filename)
889 "Called for effect the first time FILENAME's buffer is modified."
890 (declare (ignore filename))
891 nil)
892
893
894
895 ;;;; XREF
896
897 (definterface who-calls (function-name)
898 "Return the call sites of FUNCTION-NAME (a symbol).
899 The results is a list ((DSPEC LOCATION) ...)."
900 (declare (ignore function-name))
901 :not-implemented)
902
903 (definterface calls-who (function-name)
904 "Return the call sites of FUNCTION-NAME (a symbol).
905 The results is a list ((DSPEC LOCATION) ...)."
906 (declare (ignore function-name))
907 :not-implemented)
908
909 (definterface who-references (variable-name)
910 "Return the locations where VARIABLE-NAME (a symbol) is referenced.
911 See WHO-CALLS for a description of the return value."
912 (declare (ignore variable-name))
913 :not-implemented)
914
915 (definterface who-binds (variable-name)
916 "Return the locations where VARIABLE-NAME (a symbol) is bound.
917 See WHO-CALLS for a description of the return value."
918 (declare (ignore variable-name))
919 :not-implemented)
920
921 (definterface who-sets (variable-name)
922 "Return the locations where VARIABLE-NAME (a symbol) is set.
923 See WHO-CALLS for a description of the return value."
924 (declare (ignore variable-name))
925 :not-implemented)
926
927 (definterface who-macroexpands (macro-name)
928 "Return the locations where MACRO-NAME (a symbol) is expanded.
929 See WHO-CALLS for a description of the return value."
930 (declare (ignore macro-name))
931 :not-implemented)
932
933 (definterface who-specializes (class-name)
934 "Return the locations where CLASS-NAME (a symbol) is specialized.
935 See WHO-CALLS for a description of the return value."
936 (declare (ignore class-name))
937 :not-implemented)
938
939 ;;; Simpler variants.
940
941 (definterface list-callers (function-name)
942 "List the callers of FUNCTION-NAME.
943 This function is like WHO-CALLS except that it is expected to use
944 lower-level means. Whereas WHO-CALLS is usually implemented with
945 special compiler support, LIST-CALLERS is usually implemented by
946 groveling for constants in function objects throughout the heap.
947
948 The return value is as for WHO-CALLS.")
949
950 (definterface list-callees (function-name)
951 "List the functions called by FUNCTION-NAME.
952 See LIST-CALLERS for a description of the return value.")
953
954
955 ;;;; Profiling
956
957 ;;; The following functions define a minimal profiling interface.
958
959 (definterface profile (fname)
960 "Marks symbol FNAME for profiling.")
961
962 (definterface profiled-functions ()
963 "Returns a list of profiled functions.")
964
965 (definterface unprofile (fname)
966 "Marks symbol FNAME as not profiled.")
967
968 (definterface unprofile-all ()
969 "Marks all currently profiled functions as not profiled."
970 (dolist (f (profiled-functions))
971 (unprofile f)))
972
973 (definterface profile-report ()
974 "Prints profile report.")
975
976 (definterface profile-reset ()
977 "Resets profile counters.")
978
979 (definterface profile-package (package callers-p methods)
980 "Wrap profiling code around all functions in PACKAGE. If a function
981 is already profiled, then unprofile and reprofile (useful to notice
982 function redefinition.)
983
984 If CALLERS-P is T names have counts of the most common calling
985 functions recorded.
986
987 When called with arguments :METHODS T, profile all methods of all
988 generic functions having names in the given package. Generic functions
989 themselves, that is, their dispatch functions, are left alone.")
990
991
992 ;;;; Inspector
993
994 (defgeneric emacs-inspect (object)
995 (:documentation
996 "Explain to Emacs how to inspect OBJECT.
997
998 Returns a list specifying how to render the object for inspection.
999
1000 Every element of the list must be either a string, which will be
1001 inserted into the buffer as is, or a list of the form:
1002
1003 (:value object &optional format) - Render an inspectable
1004 object. If format is provided it must be a string and will be
1005 rendered in place of the value, otherwise use princ-to-string.
1006
1007 (:newline) - Render a \\n
1008
1009 (:action label lambda &key (refresh t)) - Render LABEL (a text
1010 string) which when clicked will call LAMBDA. If REFRESH is
1011 non-NIL the currently inspected object will be re-inspected
1012 after calling the lambda.
1013 "))
1014
1015 (defmethod emacs-inspect ((object t))
1016 "Generic method for inspecting any kind of object.
1017
1018 Since we don't know how to deal with OBJECT we simply dump the
1019 output of CL:DESCRIBE."
1020 `("Type: " (:value ,(type-of object)) (:newline)
1021 "Don't know how to inspect the object, dumping output of CL:DESCRIBE:"
1022 (:newline) (:newline)
1023 ,(with-output-to-string (desc) (describe object desc))))
1024
1025 (definterface eval-context (object)
1026 "Return a list of bindings corresponding to OBJECT's slots."
1027 (declare (ignore object))
1028 '())
1029
1030 ;;; Utilities for inspector methods.
1031 ;;;
1032
1033 (defun label-value-line (label value &key (newline t))
1034 "Create a control list which prints \"LABEL: VALUE\" in the inspector.
1035 If NEWLINE is non-NIL a `(:newline)' is added to the result."
1036
1037 (list* (princ-to-string label) ": " `(:value ,value)
1038 (if newline '((:newline)) nil)))
1039
1040 (defmacro label-value-line* (&rest label-values)
1041 ` (append ,@(loop for (label value) in label-values
1042 collect `(label-value-line ,label ,value))))
1043
1044 (definterface describe-primitive-type (object)
1045 "Return a string describing the primitive type of object."
1046 (declare (ignore object))
1047 "N/A")
1048
1049
1050 ;;;; Multithreading
1051 ;;;
1052 ;;; The default implementations are sufficient for non-multiprocessing
1053 ;;; implementations.
1054
1055 (definterface initialize-multiprocessing (continuation)
1056 "Initialize multiprocessing, if necessary and then invoke CONTINUATION.
1057
1058 Depending on the impleimentaion, this function may never return."
1059 (funcall continuation))
1060
1061 (definterface spawn (fn &key name)
1062 "Create a new thread to call FN.")
1063
1064 (definterface thread-id (thread)
1065 "Return an Emacs-parsable object to identify THREAD.
1066
1067 Ids should be comparable with equal, i.e.:
1068 (equal (thread-id <t1>) (thread-id <t2>)) <==> (eq <t1> <t2>)"
1069 thread)
1070
1071 (definterface find-thread (id)
1072 "Return the thread for ID.
1073 ID should be an id previously obtained with THREAD-ID.
1074 Can return nil if the thread no longer exists."
1075 (declare (ignore id))
1076 (current-thread))
1077
1078 (definterface thread-name (thread)
1079 "Return the name of THREAD.
1080 Thread names are short strings meaningful to the user. They do not
1081 have to be unique."
1082 (declare (ignore thread))
1083 "The One True Thread")
1084
1085 (definterface thread-status (thread)
1086 "Return a string describing THREAD's state."
1087 (declare (ignore thread))
1088 "")
1089
1090 (definterface thread-attributes (thread)
1091 "Return a plist of implementation-dependent attributes for THREAD"
1092 (declare (ignore thread))
1093 '())
1094
1095 (definterface make-lock (&key name)
1096 "Make a lock for thread synchronization.
1097 Only one thread may hold the lock (via CALL-WITH-LOCK-HELD) at a time
1098 but that thread may hold it more than once."
1099 (declare (ignore name))
1100 :null-lock)
1101
1102 (definterface call-with-lock-held (lock function)
1103 "Call FUNCTION with LOCK held, queueing if necessary."
1104 (declare (ignore lock)
1105 (type function function))
1106 (funcall function))
1107
1108 (definterface current-thread ()
1109 "Return the currently executing thread."
1110 0)
1111
1112 (definterface all-threads ()
1113 "Return a fresh list of all threads."
1114 '())
1115
1116 (definterface thread-alive-p (thread)
1117 "Test if THREAD is termintated."
1118 (member thread (all-threads)))
1119
1120 (definterface interrupt-thread (thread fn)
1121 "Cause THREAD to execute FN.")
1122
1123 (definterface kill-thread (thread)
1124 "Terminate THREAD immediately.
1125 Don't execute unwind-protected sections, don't raise conditions.
1126 (Do not pass go, do not collect $200.)"
1127 (declare (ignore thread))
1128 nil)
1129
1130 (definterface send (thread object)
1131 "Send OBJECT to thread THREAD.")
1132
1133 (definterface receive (&optional timeout)
1134 "Return the next message from current thread's mailbox."
1135 (receive-if (constantly t) timeout))
1136
1137 (definterface receive-if (predicate &optional timeout)
1138 "Return the first message satisfiying PREDICATE.")
1139
1140 (definterface set-default-initial-binding (var form)
1141 "Initialize special variable VAR by default with FORM.
1142
1143 Some implementations initialize certain variables in each newly
1144 created thread. This function sets the form which is used to produce
1145 the initial value."
1146 (set var (eval form)))
1147
1148 ;; List of delayed interrupts.
1149 ;; This should only have thread-local bindings, so no init form.
1150 (defvar *pending-slime-interrupts*)
1151
1152 (defun check-slime-interrupts ()
1153 "Execute pending interrupts if any.
1154 This should be called periodically in operations which
1155 can take a long time to complete.
1156 Return a boolean indicating whether any interrupts was processed."
1157 (when (and (boundp '*pending-slime-interrupts*)
1158 *pending-slime-interrupts*)
1159 (funcall (pop *pending-slime-interrupts*))
1160 t))
1161
1162 (defvar *interrupt-queued-handler* nil
1163 "Function to call on queued interrupts.
1164 Interrupts get queued when an interrupt occurs while interrupt
1165 handling is disabled.
1166
1167 Backends can use this function to abort slow operations.")
1168
1169 (definterface wait-for-input (streams &optional timeout)
1170 "Wait for input on a list of streams. Return those that are ready.
1171 STREAMS is a list of streams
1172 TIMEOUT nil, t, or real number. If TIMEOUT is t, return
1173 those streams which are ready immediately, without waiting.
1174 If TIMEOUT is a number and no streams is ready after TIMEOUT seconds,
1175 return nil.
1176
1177 Return :interrupt if an interrupt occurs while waiting."
1178 (assert (member timeout '(nil t)))
1179 (cond #+(or)
1180 ((null (cdr streams))
1181 (wait-for-one-stream (car streams) timeout))
1182 (t
1183 (wait-for-streams streams timeout))))
1184
1185 (defun wait-for-streams (streams timeout)
1186 (loop
1187 (when (check-slime-interrupts) (return :interrupt))
1188 (let ((ready (remove-if-not #'stream-readable-p streams)))
1189 (when ready (return ready)))
1190 (when timeout (return nil))
1191 (sleep 0.1)))
1192
1193 ;; Note: Usually we can't interrupt PEEK-CHAR cleanly.
1194 (defun wait-for-one-stream (stream timeout)
1195 (ecase timeout
1196 ((nil)
1197 (cond ((check-slime-interrupts) :interrupt)
1198 (t (peek-char nil stream nil nil)
1199 (list stream))))
1200 ((t)
1201 (let ((c (read-char-no-hang stream nil nil)))
1202 (cond (c
1203 (unread-char c stream)
1204 (list stream))
1205 (t '()))))))
1206
1207 (defun stream-readable-p (stream)
1208 (let ((c (read-char-no-hang stream nil :eof)))
1209 (cond ((not c) nil)
1210 ((eq c :eof) t)
1211 (t (unread-char c stream) t))))
1212
1213 (definterface toggle-trace (spec)
1214 "Toggle tracing of the function(s) given with SPEC.
1215 SPEC can be:
1216 (setf NAME) ; a setf function
1217 (:defmethod NAME QUALIFIER... (SPECIALIZER...)) ; a specific method
1218 (:defgeneric NAME) ; a generic function with all methods
1219 (:call CALLER CALLEE) ; trace calls from CALLER to CALLEE.
1220 (:labels TOPLEVEL LOCAL)
1221 (:flet TOPLEVEL LOCAL) ")
1222
1223
1224 ;;;; Weak datastructures
1225
1226 (definterface make-weak-key-hash-table (&rest args)
1227 "Like MAKE-HASH-TABLE, but weak w.r.t. the keys."
1228 (apply #'make-hash-table args))
1229
1230 (definterface make-weak-value-hash-table (&rest args)
1231 "Like MAKE-HASH-TABLE, but weak w.r.t. the values."
1232 (apply #'make-hash-table args))
1233
1234 (definterface hash-table-weakness (hashtable)
1235 "Return nil or one of :key :value :key-or-value :key-and-value"
1236 (declare (ignore hashtable))
1237 nil)
1238
1239
1240 ;;;; Character names
1241
1242 (definterface character-completion-set (prefix matchp)
1243 "Return a list of names of characters that match PREFIX."
1244 ;; Handle the standard and semi-standard characters.
1245 (loop for name in '("Newline" "Space" "Tab" "Page" "Rubout"
1246 "Linefeed" "Return" "Backspace")
1247 when (funcall matchp prefix name)
1248 collect name))
1249
1250
1251 (defparameter *type-specifier-arglists*
1252 '((and . (&rest type-specifiers))
1253 (array . (&optional element-type dimension-spec))
1254 (base-string . (&optional size))
1255 (bit-vector . (&optional size))
1256 (complex . (&optional type-specifier))
1257 (cons . (&optional car-typespec cdr-typespec))
1258 (double-float . (&optional lower-limit upper-limit))
1259 (eql . (object))
1260 (float . (&optional lower-limit upper-limit))
1261 (function . (&optional arg-typespec value-typespec))
1262 (integer . (&optional lower-limit upper-limit))
1263 (long-float . (&optional lower-limit upper-limit))
1264 (member . (&rest eql-objects))
1265 (mod . (n))
1266 (not . (type-specifier))
1267 (or . (&rest type-specifiers))
1268 (rational . (&optional lower-limit upper-limit))
1269 (real . (&optional lower-limit upper-limit))
1270 (satisfies . (predicate-symbol))
1271 (short-float . (&optional lower-limit upper-limit))
1272 (signed-byte . (&optional size))
1273 (simple-array . (&optional element-type dimension-spec))
1274 (simple-base-string . (&optional size))
1275 (simple-bit-vector . (&optional size))
1276 (simple-string . (&optional size))
1277 (single-float . (&optional lower-limit upper-limit))
1278 (simple-vector . (&optional size))
1279 (string . (&optional size))
1280 (unsigned-byte . (&optional size))
1281 (values . (&rest typespecs))
1282 (vector . (&optional element-type size))
1283 ))
1284
1285 ;;; Heap dumps
1286
1287 (definterface save-image (filename &optional restart-function)
1288 "Save a heap image to the file FILENAME.
1289 RESTART-FUNCTION, if non-nil, should be called when the image is loaded.")
1290
1291
1292

  ViewVC Help
Powered by ViewVC 1.1.5