/[cmucl]/src/pcl/std-class.lisp
ViewVC logotype

Contents of /src/pcl/std-class.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.8 - (show annotations)
Mon Feb 8 17:39:23 1993 UTC (21 years, 2 months ago) by phg
Branch: MAIN
Branch point for: cmu
Changes since 1.7: +1 -2 lines
Changed the definition of force-cache-flushes by removing unnecessary
call to update-constructors, as suggested by Richard Harris.
1 ;;;-*-Mode:LISP; Package:PCL; Base:10; Syntax:Common-lisp -*-
2 ;;;
3 ;;; *************************************************************************
4 ;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
5 ;;; All rights reserved.
6 ;;;
7 ;;; Use and copying of this software and preparation of derivative works
8 ;;; based upon this software are permitted. Any distribution of this
9 ;;; software or derivative works must comply with all applicable United
10 ;;; States export control laws.
11 ;;;
12 ;;; This software is made available AS IS, and Xerox Corporation makes no
13 ;;; warranty about the software, its performance or its conformity to any
14 ;;; specification.
15 ;;;
16 ;;; Any person obtaining a copy of this software is requested to send their
17 ;;; name and post office or electronic mail address to:
18 ;;; CommonLoops Coordinator
19 ;;; Xerox PARC
20 ;;; 3333 Coyote Hill Rd.
21 ;;; Palo Alto, CA 94304
22 ;;; (or send Arpanet mail to CommonLoops-Coordinator.pa@Xerox.arpa)
23 ;;;
24 ;;; Suggestions, comments and requests for improvements are also welcome.
25 ;;; *************************************************************************
26 ;;;
27
28 (in-package :pcl)
29
30 (defmethod slot-accessor-function ((slotd effective-slot-definition) type)
31 (ecase type
32 (reader (slot-definition-reader-function slotd))
33 (writer (slot-definition-writer-function slotd))
34 (boundp (slot-definition-boundp-function slotd))))
35
36 (defmethod (setf slot-accessor-function) (function
37 (slotd effective-slot-definition) type)
38 (ecase type
39 (reader (setf (slot-definition-reader-function slotd) function))
40 (writer (setf (slot-definition-writer-function slotd) function))
41 (boundp (setf (slot-definition-boundp-function slotd) function))))
42
43 (defconstant *slotd-reader-function-std-p* 1)
44 (defconstant *slotd-writer-function-std-p* 2)
45 (defconstant *slotd-boundp-function-std-p* 4)
46 (defconstant *slotd-all-function-std-p* 7)
47
48 (defmethod slot-accessor-std-p ((slotd effective-slot-definition) type)
49 (let ((flags (slot-value slotd 'accessor-flags)))
50 (declare (type fixnum flags))
51 (if (eq type 'all)
52 (eql *slotd-all-function-std-p* flags)
53 (let ((mask (ecase type
54 (reader *slotd-reader-function-std-p*)
55 (writer *slotd-writer-function-std-p*)
56 (boundp *slotd-boundp-function-std-p*))))
57 (declare (type fixnum mask))
58 (not (zerop (the fixnum (logand mask flags))))))))
59
60 (defmethod (setf slot-accessor-std-p) (value (slotd effective-slot-definition) type)
61 (let ((mask (ecase type
62 (reader *slotd-reader-function-std-p*)
63 (writer *slotd-writer-function-std-p*)
64 (boundp *slotd-boundp-function-std-p*)))
65 (flags (slot-value slotd 'accessor-flags)))
66 (declare (type fixnum mask flags))
67 (setf (slot-value slotd 'accessor-flags)
68 (if value
69 (the fixnum (logior mask flags))
70 (the fixnum (logand (the fixnum (lognot mask)) flags)))))
71 value)
72
73 (defmethod initialize-internal-slot-functions ((slotd effective-slot-definition))
74 (let* ((name (slot-value slotd 'name))
75 (class (slot-value slotd 'class)))
76 (let ((table (or (gethash name *name->class->slotd-table*)
77 (setf (gethash name *name->class->slotd-table*)
78 (make-hash-table :test 'eq :size 5)))))
79 (setf (gethash class table) slotd))
80 (dolist (type '(reader writer boundp))
81 (let* ((gf-name (ecase type
82 (reader 'slot-value-using-class)
83 (writer '(setf slot-value-using-class))
84 (boundp 'slot-boundp-using-class)))
85 (gf (gdefinition gf-name)))
86 (compute-slot-accessor-info slotd type gf)))
87 (initialize-internal-slot-gfs name)))
88
89 (defmethod compute-slot-accessor-info ((slotd effective-slot-definition) type gf)
90 (let* ((name (slot-value slotd 'name))
91 (class (slot-value slotd 'class))
92 (old-slotd (find-slot-definition class name))
93 (old-std-p (and old-slotd (slot-accessor-std-p old-slotd 'all))))
94 (multiple-value-bind (function std-p)
95 (if (eq *boot-state* 'complete)
96 (get-accessor-method-function gf type class slotd)
97 (get-optimized-std-accessor-method-function class slotd type))
98 #+kcl (si:turbo-closure function)
99 (setf (slot-accessor-std-p slotd type) std-p)
100 (setf (slot-accessor-function slotd type) function))
101 (when (and old-slotd (not (eq old-std-p (slot-accessor-std-p slotd 'all))))
102 (push (cons class name) *pv-table-cache-update-info*))))
103
104 (defmethod slot-definition-allocation ((slotd structure-slot-definition))
105 :instance)
106
107
108
109 (defmethod shared-initialize :after ((object documentation-mixin)
110 slot-names
111 &key (documentation nil documentation-p))
112 (declare (ignore slot-names))
113 (when documentation-p
114 (setf (plist-value object 'documentation) documentation)))
115
116 (defmethod documentation (object &optional doc-type)
117 (lisp:documentation object doc-type))
118
119 (defmethod (setf documentation) (new-value object &optional doc-type)
120 (declare (ignore new-value doc-type))
121 (error "Can't change the documentation of ~S." object))
122
123
124 (defmethod documentation ((object documentation-mixin) &optional doc-type)
125 (declare (ignore doc-type))
126 (plist-value object 'documentation))
127
128 (defmethod (setf documentation) (new-value (object documentation-mixin) &optional doc-type)
129 (declare (ignore doc-type))
130 (setf (plist-value object 'documentation) new-value))
131
132
133 (defmethod documentation ((slotd standard-slot-definition) &optional doc-type)
134 (declare (ignore doc-type))
135 (slot-value slotd 'documentation))
136
137 (defmethod (setf documentation) (new-value (slotd standard-slot-definition) &optional doc-type)
138 (declare (ignore doc-type))
139 (setf (slot-value slotd 'documentation) new-value))
140
141
142 ;;;
143 ;;; Various class accessors that are a little more complicated than can be
144 ;;; done with automatically generated reader methods.
145 ;;;
146 (defmethod class-finalized-p ((class pcl-class))
147 (with-slots (wrapper) class
148 (not (null wrapper))))
149
150 (defmethod class-prototype ((class std-class))
151 (with-slots (prototype) class
152 (or prototype (setq prototype (allocate-instance class)))))
153
154 (defmethod class-prototype ((class structure-class))
155 (with-slots (prototype wrapper defstruct-constructor) class
156 (or prototype
157 (setq prototype
158 (if #-new-kcl-wrapper defstruct-constructor #+new-kcl-wrapper nil
159 (allocate-instance class)
160 (allocate-standard-instance wrapper))))))
161
162 (defmethod class-direct-default-initargs ((class slot-class))
163 (plist-value class 'direct-default-initargs))
164
165 (defmethod class-default-initargs ((class slot-class))
166 (plist-value class 'default-initargs))
167
168 (defmethod class-constructors ((class slot-class))
169 (plist-value class 'constructors))
170
171 (defmethod class-slot-cells ((class std-class))
172 (plist-value class 'class-slot-cells))
173
174
175 ;;;
176 ;;; Class accessors that are even a little bit more complicated than those
177 ;;; above. These have a protocol for updating them, we must implement that
178 ;;; protocol.
179 ;;;
180
181 ;;;
182 ;;; Maintaining the direct subclasses backpointers. The update methods are
183 ;;; here, the values are read by an automatically generated reader method.
184 ;;;
185 (defmethod add-direct-subclass ((class class) (subclass class))
186 (with-slots (direct-subclasses) class
187 (pushnew subclass direct-subclasses)
188 subclass))
189
190 (defmethod remove-direct-subclass ((class class) (subclass class))
191 (with-slots (direct-subclasses) class
192 (setq direct-subclasses (remove subclass direct-subclasses))
193 subclass))
194
195 ;;;
196 ;;; Maintaining the direct-methods and direct-generic-functions backpointers.
197 ;;;
198 ;;; There are four generic functions involved, each has one method for the
199 ;;; class case and another method for the damned EQL specializers. All of
200 ;;; these are specified methods and appear in their specified place in the
201 ;;; class graph.
202 ;;;
203 ;;; ADD-DIRECT-METHOD
204 ;;; REMOVE-DIRECT-METHOD
205 ;;; SPECIALIZER-DIRECT-METHODS
206 ;;; SPECIALIZER-DIRECT-GENERIC-FUNCTIONS
207 ;;;
208 ;;; In each case, we maintain one value which is a cons. The car is the list
209 ;;; methods. The cdr is a list of the generic functions. The cdr is always
210 ;;; computed lazily.
211 ;;;
212
213 (defmethod add-direct-method ((specializer class) (method method))
214 (with-slots (direct-methods) specializer
215 (setf (car direct-methods) (adjoin method (car direct-methods)) ;PUSH
216 (cdr direct-methods) ()))
217 method)
218
219 (defmethod remove-direct-method ((specializer class) (method method))
220 (with-slots (direct-methods) specializer
221 (setf (car direct-methods) (remove method (car direct-methods))
222 (cdr direct-methods) ()))
223 method)
224
225 (defmethod specializer-direct-methods ((specializer class))
226 (with-slots (direct-methods) specializer
227 (car direct-methods)))
228
229 (defmethod specializer-direct-generic-functions ((specializer class))
230 (with-slots (direct-methods) specializer
231 (or (cdr direct-methods)
232 (setf (cdr direct-methods)
233 (gathering1 (collecting-once)
234 (dolist (m (car direct-methods))
235 (gather1 (method-generic-function m))))))))
236
237
238
239 ;;;
240 ;;; This hash table is used to store the direct methods and direct generic
241 ;;; functions of EQL specializers. Each value in the table is the cons.
242 ;;;
243 (defvar *eql-specializer-methods* (make-hash-table :test #'eql))
244 (defvar *class-eq-specializer-methods* (make-hash-table :test #'eq))
245
246 (defmethod specializer-method-table ((specializer eql-specializer))
247 *eql-specializer-methods*)
248
249 (defmethod specializer-method-table ((specializer class-eq-specializer))
250 *class-eq-specializer-methods*)
251
252 (defmethod add-direct-method ((specializer specializer-with-object) (method method))
253 (let* ((object (specializer-object specializer))
254 (table (specializer-method-table specializer))
255 (entry (gethash object table)))
256 (unless entry
257 (setq entry
258 (setf (gethash object table)
259 (cons nil nil))))
260 (setf (car entry) (adjoin method (car entry))
261 (cdr entry) ())
262 method))
263
264 (defmethod remove-direct-method ((specializer specializer-with-object) (method method))
265 (let* ((object (specializer-object specializer))
266 (entry (gethash object (specializer-method-table specializer))))
267 (when entry
268 (setf (car entry) (remove method (car entry))
269 (cdr entry) ()))
270 method))
271
272 (defmethod specializer-direct-methods ((specializer specializer-with-object))
273 (car (gethash (specializer-object specializer)
274 (specializer-method-table specializer))))
275
276 (defmethod specializer-direct-generic-functions ((specializer specializer-with-object))
277 (let* ((object (specializer-object specializer))
278 (entry (gethash object (specializer-method-table specializer))))
279 (when entry
280 (or (cdr entry)
281 (setf (cdr entry)
282 (gathering1 (collecting-once)
283 (dolist (m (car entry))
284 (gather1 (method-generic-function m)))))))))
285
286 (defun map-specializers (function)
287 (map-all-classes #'(lambda (class)
288 (funcall function (class-eq-specializer class))
289 (funcall function class)))
290 (maphash #'(lambda (object methods)
291 (declare (ignore methods))
292 (intern-eql-specializer object))
293 *eql-specializer-methods*)
294 (maphash #'(lambda (object specl)
295 (declare (ignore object))
296 (funcall function specl))
297 *eql-specializer-table*)
298 nil)
299
300 (defun map-all-generic-functions (function)
301 (let ((all-generic-functions (make-hash-table :test 'eq)))
302 (map-specializers #'(lambda (specl)
303 (dolist (gf (specializer-direct-generic-functions specl))
304 (unless (gethash gf all-generic-functions)
305 (setf (gethash gf all-generic-functions) t)
306 (funcall function gf))))))
307 nil)
308
309 (defmethod shared-initialize :after ((specl class-eq-specializer) slot-names &key)
310 (declare (ignore slot-names))
311 (setf (slot-value specl 'type) `(class-eq ,(specializer-class specl))))
312
313 (defmethod shared-initialize :after ((specl eql-specializer) slot-names &key)
314 (declare (ignore slot-names))
315 (setf (slot-value specl 'type) `(eql ,(specializer-object specl))))
316
317
318
319 (defun real-load-defclass (name metaclass-name supers slots other accessors)
320 (do-standard-defsetfs-for-defclass accessors) ;***
321 (apply #'ensure-class name :metaclass metaclass-name
322 :direct-superclasses supers
323 :direct-slots slots
324 :definition-source `((defclass ,name)
325 ,(load-truename))
326 other))
327
328 (setf (gdefinition 'load-defclass) #'real-load-defclass)
329
330 (defun ensure-class (name &rest all)
331 (apply #'ensure-class-using-class name (find-class name nil) all))
332
333 (defmethod ensure-class-using-class (name (class null) &rest args &key)
334 (multiple-value-bind (meta initargs)
335 (ensure-class-values class args)
336 (inform-type-system-about-class (class-prototype meta) name);***
337 (setf class (apply #'make-instance meta :name name initargs)
338 (find-class name) class)
339 (inform-type-system-about-class class name) ;***
340 class))
341
342 (defmethod ensure-class-using-class (name (class pcl-class) &rest args &key)
343 (multiple-value-bind (meta initargs)
344 (ensure-class-values class args)
345 (unless (eq (class-of class) meta) (change-class class meta))
346 (apply #'reinitialize-instance class initargs)
347 (setf (find-class name) class)
348 (inform-type-system-about-class class name) ;***
349 class))
350
351 (defmethod class-predicate-name ((class t))
352 'function-returning-nil)
353
354 (defun ensure-class-values (class args)
355 (let* ((initargs (copy-list args))
356 (unsupplied (list 1))
357 (supplied-meta (getf initargs :metaclass unsupplied))
358 (supplied-supers (getf initargs :direct-superclasses unsupplied))
359 (supplied-slots (getf initargs :direct-slots unsupplied))
360 (meta
361 (cond ((neq supplied-meta unsupplied)
362 (find-class supplied-meta))
363 ((or (null class)
364 (forward-referenced-class-p class))
365 *the-class-standard-class*)
366 (t
367 (class-of class)))))
368 (flet ((fix-super (s)
369 (cond ((classp s) s)
370 ((not (legal-class-name-p s))
371 (error "~S is not a class or a legal class name." s))
372 (t
373 (or (find-class s nil)
374 (setf (find-class s)
375 (make-instance 'forward-referenced-class
376 :name s)))))))
377 (loop (unless (remf initargs :metaclass) (return)))
378 (loop (unless (remf initargs :direct-superclasses) (return)))
379 (loop (unless (remf initargs :direct-slots) (return)))
380 (values meta
381 (list* :direct-superclasses
382 (and (neq supplied-supers unsupplied)
383 (mapcar #'fix-super supplied-supers))
384 :direct-slots
385 (and (neq supplied-slots unsupplied) supplied-slots)
386 initargs)))))
387
388
389 ;;;
390 ;;;
391 ;;;
392 #|| ; since it doesn't do anything
393 (defmethod shared-initialize :before ((class std-class)
394 slot-names
395 &key direct-superclasses)
396 (declare (ignore slot-names))
397 ;; *** error checking
398 )
399 ||#
400
401 (defmethod shared-initialize :after
402 ((class std-class)
403 slot-names
404 &key (direct-superclasses nil direct-superclasses-p)
405 (direct-slots nil direct-slots-p)
406 (direct-default-initargs nil direct-default-initargs-p)
407 (predicate-name nil predicate-name-p))
408 (declare (ignore slot-names))
409 (if direct-superclasses-p
410 (progn
411 (setq direct-superclasses (or direct-superclasses
412 (list *the-class-standard-object*)))
413 (dolist (superclass direct-superclasses)
414 (unless (validate-superclass class superclass)
415 (error "The class ~S was specified as a~%super-class of the class ~S;~%~
416 but the meta-classes ~S and~%~S are incompatible."
417 superclass class (class-of superclass) (class-of class))))
418 (setf (slot-value class 'direct-superclasses) direct-superclasses))
419 (setq direct-superclasses (slot-value class 'direct-superclasses)))
420 (setq direct-slots
421 (if direct-slots-p
422 (setf (slot-value class 'direct-slots)
423 (mapcar #'(lambda (pl) (make-direct-slotd class pl)) direct-slots))
424 (slot-value class 'direct-slots)))
425 (if direct-default-initargs-p
426 (setf (plist-value class 'direct-default-initargs) direct-default-initargs)
427 (setq direct-default-initargs (plist-value class 'direct-default-initargs)))
428 (setf (plist-value class 'class-slot-cells)
429 (gathering1 (collecting)
430 (dolist (dslotd direct-slots)
431 (when (eq (slot-definition-allocation dslotd) class)
432 (let ((initfunction (slot-definition-initfunction dslotd)))
433 (gather1 (cons (slot-definition-name dslotd)
434 (if initfunction
435 (funcall initfunction)
436 *slot-unbound*))))))))
437 (setq predicate-name (if predicate-name-p
438 (setf (slot-value class 'predicate-name)
439 (car predicate-name))
440 (or (slot-value class 'predicate-name)
441 (setf (slot-value class 'predicate-name)
442 (make-class-predicate-name (class-name class))))))
443 (add-direct-subclasses class direct-superclasses)
444 (update-class class nil)
445 (make-class-predicate class predicate-name)
446 (add-slot-accessors class direct-slots))
447
448 (defmethod shared-initialize :before ((class class) slot-names &key name)
449 (declare (ignore slot-names name))
450 (setf (slot-value class 'type) `(class ,class))
451 (setf (slot-value class 'class-eq-specializer)
452 (make-instance 'class-eq-specializer :class class)))
453
454 (defmethod reinitialize-instance :before ((class slot-class) &key)
455 (remove-direct-subclasses class (class-direct-superclasses class))
456 (remove-slot-accessors class (class-direct-slots class)))
457
458 (defmethod reinitialize-instance :after ((class slot-class)
459 &rest initargs
460 &key)
461 (map-dependents class
462 #'(lambda (dependent)
463 (apply #'update-dependent class dependent initargs))))
464
465 (defmethod shared-initialize :after
466 ((class structure-class)
467 slot-names
468 &key (direct-superclasses nil direct-superclasses-p)
469 (direct-slots nil direct-slots-p)
470 direct-default-initargs
471 (predicate-name nil predicate-name-p))
472 (declare (ignore slot-names direct-default-initargs))
473 (if direct-superclasses-p
474 (setf (slot-value class 'direct-superclasses)
475 (or direct-superclasses
476 (setq direct-superclasses
477 (and (not (eq (class-name class) 'structure-object))
478 (list *the-class-structure-object*)))))
479 (setq direct-superclasses (slot-value class 'direct-superclasses)))
480 (let* ((name (class-name class))
481 (from-defclass-p (slot-value class 'from-defclass-p))
482 (defstruct-p (or from-defclass-p (not (structure-type-p name)))))
483 (if direct-slots-p
484 (setf (slot-value class 'direct-slots)
485 (setq direct-slots
486 (mapcar #'(lambda (pl)
487 (when defstruct-p
488 (let* ((slot-name (getf pl :name))
489 (acc-name (format nil "~s structure class ~a"
490 name slot-name))
491 (accessor (intern acc-name)))
492 (setq pl (list* :defstruct-accessor-symbol accessor
493 pl))))
494 (make-direct-slotd class pl))
495 direct-slots)))
496 (setq direct-slots (slot-value class 'direct-slots)))
497 (when defstruct-p
498 (let* ((include (car (slot-value class 'direct-superclasses)))
499 (conc-name (intern (format nil "~s structure class " name)))
500 (constructor (intern (format nil "~a constructor" conc-name)))
501 (defstruct `(defstruct (,name
502 ,@(when include
503 `((:include ,(class-name include))))
504 (:print-function print-std-instance)
505 (:predicate nil)
506 (:conc-name ,conc-name)
507 (:constructor ,constructor ()))
508 ,@(mapcar #'(lambda (slot)
509 `(,(slot-definition-name slot)
510 *slot-unbound*))
511 direct-slots)))
512 (reader-names (mapcar #'(lambda (slotd)
513 (intern (format nil "~A~A reader" conc-name
514 (slot-definition-name slotd))))
515 direct-slots))
516 (writer-names (mapcar #'(lambda (slotd)
517 (intern (format nil "~A~A writer" conc-name
518 (slot-definition-name slotd))))
519 direct-slots))
520 (readers-init
521 (mapcar #'(lambda (slotd reader-name)
522 (let ((accessor
523 (slot-definition-defstruct-accessor-symbol slotd)))
524 `(defun ,reader-name (obj)
525 (declare (type ,name obj))
526 (,accessor obj))))
527 direct-slots reader-names))
528 (writers-init
529 (mapcar #'(lambda (slotd writer-name)
530 (let ((accessor
531 (slot-definition-defstruct-accessor-symbol slotd)))
532 `(defun ,writer-name (nv obj)
533 (declare (type ,name obj))
534 (setf (,accessor obj) nv))))
535 direct-slots writer-names))
536 (defstruct-form
537 `(progn
538 ,defstruct
539 ,@readers-init ,@writers-init
540 (declare-structure ',name nil nil))))
541 (unless (structure-type-p name) (eval defstruct-form))
542 (mapc #'(lambda (dslotd reader-name writer-name)
543 (let* ((reader (gdefinition reader-name))
544 (writer (when (gboundp writer-name)
545 (gdefinition writer-name))))
546 (setf (slot-value dslotd 'internal-reader-function) reader)
547 (setf (slot-value dslotd 'internal-writer-function) writer)))
548 direct-slots reader-names writer-names)
549 (setf (slot-value class 'defstruct-form) defstruct-form)
550 (setf (slot-value class 'defstruct-constructor) constructor))))
551 (add-direct-subclasses class direct-superclasses)
552 (setf (slot-value class 'class-precedence-list)
553 (compute-class-precedence-list class))
554 (setf (slot-value class 'slots) (compute-slots class))
555 #-new-kcl-wrapper
556 (unless (slot-value class 'wrapper)
557 (setf (slot-value class 'wrapper) (make-wrapper 0 class)))
558 #+new-kcl-wrapper
559 (let ((wrapper (get (class-name class) 'si::s-data)))
560 (setf (slot-value class 'wrapper) wrapper)
561 (setf (wrapper-class wrapper) class))
562 (update-pv-table-cache-info class)
563 (setq predicate-name (if predicate-name-p
564 (setf (slot-value class 'predicate-name)
565 (car predicate-name))
566 (or (slot-value class 'predicate-name)
567 (setf (slot-value class 'predicate-name)
568 (make-class-predicate-name (class-name class))))))
569 (make-class-predicate class predicate-name)
570 (add-slot-accessors class direct-slots))
571
572 (defmethod direct-slot-definition-class ((class structure-class) initargs)
573 (declare (ignore initargs))
574 (find-class 'structure-direct-slot-definition))
575
576 (defmethod finalize-inheritance ((class structure-class))
577 nil) ; always finalized
578
579 (defun add-slot-accessors (class dslotds)
580 (fix-slot-accessors class dslotds 'add))
581
582 (defun remove-slot-accessors (class dslotds)
583 (fix-slot-accessors class dslotds 'remove))
584
585 (defun fix-slot-accessors (class dslotds add/remove)
586 (flet ((fix (gfspec name r/w)
587 (let ((gf (ensure-generic-function gfspec)))
588 (case r/w
589 (r (if (eq add/remove 'add)
590 (add-reader-method class gf name)
591 (remove-reader-method class gf)))
592 (w (if (eq add/remove 'add)
593 (add-writer-method class gf name)
594 (remove-writer-method class gf)))))))
595 (dolist (dslotd dslotds)
596 (let ((slot-name (slot-definition-name dslotd)))
597 (dolist (r (slot-definition-readers dslotd)) (fix r slot-name 'r))
598 (dolist (w (slot-definition-writers dslotd)) (fix w slot-name 'w))))))
599
600
601 (defun add-direct-subclasses (class new)
602 (dolist (n new)
603 (unless (memq class (class-direct-subclasses class))
604 (add-direct-subclass n class))))
605
606 (defun remove-direct-subclasses (class new)
607 (let ((old (class-direct-superclasses class)))
608 (dolist (o (set-difference old new))
609 (remove-direct-subclass o class))))
610
611
612 ;;;
613 ;;;
614 ;;;
615 (defmethod finalize-inheritance ((class std-class))
616 (update-class class t))
617
618
619 (defun class-has-a-forward-referenced-superclass-p (class)
620 (or (forward-referenced-class-p class)
621 (some #'class-has-a-forward-referenced-superclass-p
622 (class-direct-superclasses class))))
623
624 ;;;
625 ;;; Called by :after shared-initialize whenever a class is initialized or
626 ;;; reinitialized. The class may or may not be finalized.
627 ;;;
628 (defun update-class (class finalizep)
629 (when (or finalizep (class-finalized-p class)
630 (not (class-has-a-forward-referenced-superclass-p class)))
631 (update-cpl class (compute-class-precedence-list class))
632 (update-slots class (compute-slots class))
633 (update-gfs-of-class class)
634 (update-inits class (compute-default-initargs class))
635 (update-make-instance-function-table class))
636 (unless finalizep
637 (dolist (sub (class-direct-subclasses class)) (update-class sub nil))))
638
639 (defun update-cpl (class cpl)
640 (when (class-finalized-p class)
641 (unless (equal (class-precedence-list class) cpl)
642 (force-cache-flushes class)))
643 (setf (slot-value class 'class-precedence-list) cpl)
644 (update-class-can-precede-p cpl))
645
646 (defun update-class-can-precede-p (cpl)
647 (when cpl
648 (let ((first (car cpl)))
649 (dolist (c (cdr cpl))
650 (pushnew c (slot-value first 'can-precede-list))))
651 (update-class-can-precede-p (cdr cpl))))
652
653 (defun class-can-precede-p (class1 class2)
654 (member class2 (class-can-precede-list class1)))
655
656 (defun update-slots (class eslotds)
657 (let ((instance-slots ())
658 (class-slots ()))
659 (dolist (eslotd eslotds)
660 (let ((alloc (slot-definition-allocation eslotd)))
661 (cond ((eq alloc :instance) (push eslotd instance-slots))
662 ((classp alloc) (push eslotd class-slots)))))
663 ;;
664 ;; If there is a change in the shape of the instances then the
665 ;; old class is now obsolete.
666 ;;
667 (let* ((nlayout (mapcar #'slot-definition-name
668 (sort instance-slots #'< :key #'slot-definition-location)))
669 (nslots (length nlayout))
670 (nwrapper-class-slots (compute-class-slots class-slots))
671 (owrapper (class-wrapper class))
672 (olayout (and owrapper (wrapper-instance-slots-layout owrapper)))
673 (owrapper-class-slots (and owrapper (wrapper-class-slots owrapper)))
674 (nwrapper
675 (cond ((null owrapper)
676 (make-wrapper nslots class))
677 ((and (equal nlayout olayout)
678 (not
679 (iterate ((o (list-elements owrapper-class-slots))
680 (n (list-elements nwrapper-class-slots)))
681 (unless (eq (car o) (car n)) (return t)))))
682 owrapper)
683 (t
684 ;;
685 ;; This will initialize the new wrapper to have the same
686 ;; state as the old wrapper. We will then have to change
687 ;; that. This may seem like wasted work (it is), but the
688 ;; spec requires that we call make-instances-obsolete.
689 ;;
690 (make-instances-obsolete class)
691 (class-wrapper class)))))
692 (with-slots (wrapper slots) class
693 #+new-kcl-wrapper
694 (setf (si::s-data-name nwrapper) (class-name class))
695 (setf slots eslotds
696 (wrapper-instance-slots-layout nwrapper) nlayout
697 (wrapper-class-slots nwrapper) nwrapper-class-slots
698 (wrapper-no-of-instance-slots nwrapper) nslots
699 wrapper nwrapper))
700 (unless (eq owrapper nwrapper)
701 (update-pv-table-cache-info class)))))
702
703 (defun compute-class-slots (eslotds)
704 (gathering1 (collecting)
705 (dolist (eslotd eslotds)
706 (gather1
707 (assoc (slot-definition-name eslotd)
708 (class-slot-cells (slot-definition-allocation eslotd)))))))
709
710 (defun compute-layout (cpl instance-eslotds)
711 (let* ((names
712 (gathering1 (collecting)
713 (dolist (eslotd instance-eslotds)
714 (when (eq (slot-definition-allocation eslotd) :instance)
715 (gather1 (slot-definition-name eslotd))))))
716 (order ()))
717 (labels ((rwalk (tail)
718 (when tail
719 (rwalk (cdr tail))
720 (dolist (ss (class-slots (car tail)))
721 (let ((n (slot-definition-name ss)))
722 (when (member n names)
723 (setq order (cons n order)
724 names (remove n names))))))))
725 (rwalk (if (slot-boundp (car cpl) 'slots)
726 cpl
727 (cdr cpl)))
728 (reverse (append names order)))))
729
730 (defun update-gfs-of-class (class)
731 (when (and (class-finalized-p class)
732 (let ((cpl (class-precedence-list class)))
733 (or (member *the-class-slot-class* cpl)
734 (member *the-class-standard-effective-slot-definition* cpl))))
735 (let ((gf-table (make-hash-table :test 'eq)))
736 (labels ((collect-gfs (class)
737 (dolist (gf (specializer-direct-generic-functions class))
738 (setf (gethash gf gf-table) t))
739 (mapc #'collect-gfs (class-direct-superclasses class))))
740 (collect-gfs class)
741 (maphash #'(lambda (gf ignore)
742 (declare (ignore ignore))
743 (update-gf-dfun class gf))
744 gf-table)))))
745
746 (defun update-inits (class inits)
747 (setf (plist-value class 'default-initargs) inits))
748
749
750 ;;;
751 ;;;
752 ;;;
753 (defmethod compute-default-initargs ((class slot-class))
754 (let ((cpl (class-precedence-list class))
755 (direct (class-direct-default-initargs class)))
756 (labels ((walk (tail)
757 (if (null tail)
758 nil
759 (let ((c (pop tail)))
760 (append (if (eq c class)
761 direct
762 (class-direct-default-initargs c))
763 (walk tail))))))
764 (let ((initargs (walk cpl)))
765 (delete-duplicates initargs :test #'eq :key #'car :from-end t)))))
766
767
768 ;;;
769 ;;; Protocols for constructing direct and effective slot definitions.
770 ;;;
771 ;;;
772 ;;;
773 ;;;
774 (defmethod direct-slot-definition-class ((class std-class) initargs)
775 (declare (ignore initargs))
776 (find-class 'standard-direct-slot-definition))
777
778 (defun make-direct-slotd (class initargs)
779 (let ((initargs (list* :class class initargs)))
780 (apply #'make-instance (direct-slot-definition-class class initargs) initargs)))
781
782 ;;;
783 ;;;
784 ;;;
785 (defmethod compute-slots ((class std-class))
786 ;;
787 ;; As specified, we must call COMPUTE-EFFECTIVE-SLOT-DEFINITION once
788 ;; for each different slot name we find in our superclasses. Each
789 ;; call receives the class and a list of the dslotds with that name.
790 ;; The list is in most-specific-first order.
791 ;;
792 (let ((name-dslotds-alist ()))
793 (dolist (c (class-precedence-list class))
794 (let ((dslotds (class-direct-slots c)))
795 (dolist (d dslotds)
796 (let* ((name (slot-definition-name d))
797 (entry (assq name name-dslotds-alist)))
798 (if entry
799 (push d (cdr entry))
800 (push (list name d) name-dslotds-alist))))))
801 (mapcar #'(lambda (direct)
802 (compute-effective-slot-definition class
803 (nreverse (cdr direct))))
804 name-dslotds-alist)))
805
806 (defmethod compute-slots :around ((class std-class))
807 (let ((eslotds (call-next-method))
808 (cpl (class-precedence-list class))
809 (instance-slots ())
810 (class-slots ()))
811 (dolist (eslotd eslotds)
812 (let ((alloc (slot-definition-allocation eslotd)))
813 (cond ((eq alloc :instance) (push eslotd instance-slots))
814 ((classp alloc) (push eslotd class-slots)))))
815 (let ((nlayout (compute-layout cpl instance-slots)))
816 (dolist (eslotd instance-slots)
817 (setf (slot-definition-location eslotd)
818 (position (slot-definition-name eslotd) nlayout))))
819 (dolist (eslotd class-slots)
820 (setf (slot-definition-location eslotd)
821 (assoc (slot-definition-name eslotd)
822 (class-slot-cells (slot-definition-allocation eslotd)))))
823 (mapc #'initialize-internal-slot-functions eslotds)
824 eslotds))
825
826 (defmethod compute-slots ((class structure-class))
827 (mapcan #'(lambda (superclass)
828 (mapcar #'(lambda (dslotd)
829 (compute-effective-slot-definition class
830 (list dslotd)))
831 (class-direct-slots superclass)))
832 (reverse (slot-value class 'class-precedence-list))))
833
834 (defmethod compute-slots :around ((class structure-class))
835 (let ((eslotds (call-next-method)))
836 (mapc #'initialize-internal-slot-functions eslotds)
837 eslotds))
838
839 (defmethod compute-effective-slot-definition ((class slot-class) dslotds)
840 (let* ((initargs (compute-effective-slot-definition-initargs class dslotds))
841 (class (effective-slot-definition-class class initargs)))
842 (apply #'make-instance class initargs)))
843
844 (defmethod effective-slot-definition-class ((class std-class) initargs)
845 (declare (ignore initargs))
846 (find-class 'standard-effective-slot-definition))
847
848 (defmethod effective-slot-definition-class ((class structure-class) initargs)
849 (declare (ignore initargs))
850 (find-class 'structure-effective-slot-definition))
851
852 (defmethod compute-effective-slot-definition-initargs
853 ((class slot-class) direct-slotds)
854 (let* ((name nil)
855 (initfunction nil)
856 (initform nil)
857 (initargs nil)
858 (allocation nil)
859 (type t)
860 (namep nil)
861 (initp nil)
862 (allocp nil))
863
864 (dolist (slotd direct-slotds)
865 (when slotd
866 (unless namep
867 (setq name (slot-definition-name slotd)
868 namep t))
869 (unless initp
870 (when (slot-definition-initfunction slotd)
871 (setq initform (slot-definition-initform slotd)
872 initfunction (slot-definition-initfunction slotd)
873 initp t)))
874 (unless allocp
875 (setq allocation (slot-definition-allocation slotd)
876 allocp t))
877 (setq initargs (append (slot-definition-initargs slotd) initargs))
878 (let ((slotd-type (slot-definition-type slotd)))
879 (setq type (cond ((eq type 't) slotd-type)
880 ((*subtypep type slotd-type) type)
881 (t `(and ,type ,slotd-type)))))))
882 (list :name name
883 :initform initform
884 :initfunction initfunction
885 :initargs initargs
886 :allocation allocation
887 :type type
888 :class class)))
889
890 (defmethod compute-effective-slot-definition-initargs :around
891 ((class structure-class) direct-slotds)
892 (let ((slotd (car direct-slotds)))
893 (list* :defstruct-accessor-symbol (slot-definition-defstruct-accessor-symbol slotd)
894 :internal-reader-function (slot-definition-internal-reader-function slotd)
895 :internal-writer-function (slot-definition-internal-writer-function slotd)
896 (call-next-method))))
897
898 ;;;
899 ;;; NOTE: For bootstrapping considerations, these can't use make-instance
900 ;;; to make the method object. They have to use make-a-method which
901 ;;; is a specially bootstrapped mechanism for making standard methods.
902 ;;;
903 (defmethod reader-method-class ((class slot-class) direct-slot &rest initargs)
904 (declare (ignore direct-slot initargs))
905 (find-class 'standard-reader-method))
906
907 (defmethod add-reader-method ((class slot-class) generic-function slot-name)
908 (add-method generic-function
909 (make-a-method 'standard-reader-method
910 ()
911 (list (or (class-name class) 'object))
912 (list class)
913 (make-reader-method-function class slot-name)
914 "automatically generated reader method"
915 slot-name)))
916
917 (defmethod writer-method-class ((class slot-class) direct-slot &rest initargs)
918 (declare (ignore direct-slot initargs))
919 (find-class 'standard-writer-method))
920
921 (defmethod add-writer-method ((class slot-class) generic-function slot-name)
922 (add-method generic-function
923 (make-a-method 'standard-writer-method
924 ()
925 (list 'new-value (or (class-name class) 'object))
926 (list *the-class-t* class)
927 (make-writer-method-function class slot-name)
928 "automatically generated writer method"
929 slot-name)))
930
931 (defmethod add-boundp-method ((class slot-class) generic-function slot-name)
932 (add-method generic-function
933 (make-a-method 'standard-boundp-method
934 ()
935 (list (or (class-name class) 'object))
936 (list class)
937 (make-boundp-method-function class slot-name)
938 "automatically generated boundp method"
939 slot-name)))
940
941 (defmethod remove-reader-method ((class slot-class) generic-function)
942 (let ((method (get-method generic-function () (list class) nil)))
943 (when method (remove-method generic-function method))))
944
945 (defmethod remove-writer-method ((class slot-class) generic-function)
946 (let ((method
947 (get-method generic-function () (list *the-class-t* class) nil)))
948 (when method (remove-method generic-function method))))
949
950 (defmethod remove-boundp-method ((class slot-class) generic-function)
951 (let ((method (get-method generic-function () (list class) nil)))
952 (when method (remove-method generic-function method))))
953
954
955 ;;;
956 ;;; make-reader-method-function and make-write-method function are NOT part of
957 ;;; the standard protocol. They are however useful, PCL makes uses makes use
958 ;;; of them internally and documents them for PCL users.
959 ;;;
960 ;;; *** This needs work to make type testing by the writer functions which
961 ;;; *** do type testing faster. The idea would be to have one constructor
962 ;;; *** for each possible type test. In order to do this it would be nice
963 ;;; *** to have help from inform-type-system-about-class and friends.
964 ;;;
965 ;;; *** There is a subtle bug here which is going to have to be fixed.
966 ;;; *** Namely, the simplistic use of the template has to be fixed. We
967 ;;; *** have to give the optimize-slot-value method the user might have
968 ;;; *** defined for this metclass a chance to run.
969 ;;;
970 (defmethod make-reader-method-function ((class slot-class) slot-name)
971 (make-std-reader-method-function (class-name class) slot-name))
972
973 (defmethod make-writer-method-function ((class slot-class) slot-name)
974 (make-std-writer-method-function (class-name class) slot-name))
975
976 (defmethod make-boundp-method-function ((class slot-class) slot-name)
977 (make-std-boundp-method-function (class-name class) slot-name))
978
979
980 ;;;; inform-type-system-about-class
981 ;;;; make-type-predicate
982 ;;;
983 ;;; These are NOT part of the standard protocol. They are internal mechanism
984 ;;; which PCL uses to *try* and tell the type system about class definitions.
985 ;;; In a more fully integrated implementation of CLOS, the type system would
986 ;;; know about class objects and class names in a more fundamental way and
987 ;;; the mechanism used to inform the type system about new classes would be
988 ;;; different.
989 ;;;
990 (defmethod inform-type-system-about-class ((class std-class) name)
991 (inform-type-system-about-std-class name))
992
993
994 (defmethod compatible-meta-class-change-p (class proto-new-class)
995 (eq (class-of class) (class-of proto-new-class)))
996
997 (defmethod validate-superclass ((class class) (new-super class))
998 (or (eq new-super *the-class-t*)
999 (eq (class-of class) (class-of new-super))))
1000
1001
1002
1003 ;;;
1004 ;;;
1005 ;;;
1006 (defun force-cache-flushes (class)
1007 (let* ((owrapper (class-wrapper class))
1008 (state (wrapper-state owrapper)))
1009 ;;
1010 ;; We only need to do something if the state is still T. If the
1011 ;; state isn't T, it will be FLUSH or OBSOLETE, and both of those
1012 ;; will already be doing what we want. In particular, we must be
1013 ;; sure we never change an OBSOLETE into a FLUSH since OBSOLETE
1014 ;; means do what FLUSH does and then some.
1015 ;;
1016 (when (eq state 't)
1017 (let ((nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1018 class)))
1019 (setf (wrapper-instance-slots-layout nwrapper)
1020 (wrapper-instance-slots-layout owrapper))
1021 (setf (wrapper-class-slots nwrapper)
1022 (wrapper-class-slots owrapper))
1023 (without-interrupts
1024 (setf (slot-value class 'wrapper) nwrapper)
1025 (invalidate-wrapper owrapper ':flush nwrapper))))))
1026
1027 (defun flush-cache-trap (owrapper nwrapper instance)
1028 (declare (ignore owrapper))
1029 (set-wrapper instance nwrapper))
1030
1031
1032
1033 ;;;
1034 ;;; make-instances-obsolete can be called by user code. It will cause the
1035 ;;; next access to the instance (as defined in 88-002R) to trap through the
1036 ;;; update-instance-for-redefined-class mechanism.
1037 ;;;
1038 (defmethod make-instances-obsolete ((class std-class))
1039 (let* ((owrapper (class-wrapper class))
1040 (nwrapper (make-wrapper (wrapper-no-of-instance-slots owrapper)
1041 class)))
1042 (setf (wrapper-instance-slots-layout nwrapper)
1043 (wrapper-instance-slots-layout owrapper))
1044 (setf (wrapper-class-slots nwrapper)
1045 (wrapper-class-slots owrapper))
1046 (without-interrupts
1047 (setf (slot-value class 'wrapper) nwrapper)
1048 (invalidate-wrapper owrapper ':obsolete nwrapper)
1049 class)))
1050
1051 (defmethod make-instances-obsolete ((class symbol))
1052 (make-instances-obsolete (find-class class)))
1053
1054
1055 ;;;
1056 ;;; obsolete-instance-trap is the internal trap that is called when we see
1057 ;;; an obsolete instance. The times when it is called are:
1058 ;;; - when the instance is involved in method lookup
1059 ;;; - when attempting to access a slot of an instance
1060 ;;;
1061 ;;; It is not called by class-of, wrapper-of, or any of the low-level instance
1062 ;;; access macros.
1063 ;;;
1064 ;;; Of course these times when it is called are an internal implementation
1065 ;;; detail of PCL and are not part of the documented description of when the
1066 ;;; obsolete instance update happens. The documented description is as it
1067 ;;; appears in 88-002R.
1068 ;;;
1069 ;;; This has to return the new wrapper, so it counts on all the methods on
1070 ;;; obsolete-instance-trap-internal to return the new wrapper. It also does
1071 ;;; a little internal error checking to make sure that the traps are only
1072 ;;; happening when they should, and that the trap methods are computing
1073 ;;; apropriate new wrappers.
1074 ;;;
1075 (defun obsolete-instance-trap (owrapper nwrapper instance)
1076 ;;
1077 ;; local --> local transfer
1078 ;; local --> shared discard
1079 ;; local --> -- discard
1080 ;; shared --> local transfer
1081 ;; shared --> shared discard
1082 ;; shared --> -- discard
1083 ;; -- --> local add
1084 ;; -- --> shared --
1085 ;;
1086 (let* ((class (wrapper-class* nwrapper))
1087 (guts (allocate-instance class)) ;??? allocate-instance ???
1088 (olayout (wrapper-instance-slots-layout owrapper))
1089 (nlayout (wrapper-instance-slots-layout nwrapper))
1090 (oslots (get-slots instance))
1091 (nslots (get-slots guts))
1092 (oclass-slots (wrapper-class-slots owrapper))
1093 (added ())
1094 (discarded ())
1095 (plist ()))
1096 ;;
1097 ;; Go through all the old local slots.
1098 ;;
1099 (iterate ((name (list-elements olayout))
1100 (opos (interval :from 0)))
1101 (let ((npos (posq name nlayout)))
1102 (if npos
1103 (setf (instance-ref nslots npos) (instance-ref oslots opos))
1104 (progn (push name discarded)
1105 (unless (eq (instance-ref oslots opos) *slot-unbound*)
1106 (setf (getf plist name) (instance-ref oslots opos)))))))
1107 ;;
1108 ;; Go through all the old shared slots.
1109 ;;
1110 (iterate ((oclass-slot-and-val (list-elements oclass-slots)))
1111 (let ((name (car oclass-slot-and-val))
1112 (val (cdr oclass-slot-and-val)))
1113 (let ((npos (posq name nlayout)))
1114 (if npos
1115 (setf (instance-ref nslots npos) (cdr oclass-slot-and-val))
1116 (progn (push name discarded)
1117 (unless (eq val *slot-unbound*)
1118 (setf (getf plist name) val)))))))
1119 ;;
1120 ;; Go through all the new local slots to compute the added slots.
1121 ;;
1122 (dolist (nlocal nlayout)
1123 (unless (or (memq nlocal olayout)
1124 (assq nlocal oclass-slots))
1125 (push nlocal added)))
1126
1127 (swap-wrappers-and-slots instance guts)
1128
1129 (update-instance-for-redefined-class instance
1130 added
1131 discarded
1132 plist)
1133 nwrapper))
1134
1135
1136
1137 ;;;
1138 ;;;
1139 ;;;
1140 (defmacro copy-instance-internal (instance)
1141 `(#+new-kcl-wrapper if #-new-kcl-wrapper progn
1142 #+new-kcl-wrapper (not (std-instance-p ,instance))
1143 (let* ((class (class-of instance))
1144 (copy (allocate-instance class)))
1145 (if (std-instance-p ,instance)
1146 (setf (std-instance-slots ,instance) (std-instance-slots ,instance))
1147 (setf (fsc-instance-slots ,instance) (fsc-instance-slots ,instance)))
1148 copy)
1149 #+new-kcl-wrapper
1150 (copy-structure-header ,instance)))
1151
1152 (defun change-class-internal (instance new-class)
1153 (let* ((old-class (class-of instance))
1154 (copy (copy-instance-internal instance))
1155 (guts (allocate-instance new-class))
1156 (new-wrapper (get-wrapper guts))
1157 (old-wrapper (class-wrapper old-class))
1158 (old-layout (wrapper-instance-slots-layout old-wrapper))
1159 (new-layout (wrapper-instance-slots-layout new-wrapper))
1160 (old-slots (get-slots instance))
1161 (new-slots (get-slots guts))
1162 (old-class-slots (wrapper-class-slots old-wrapper)))
1163
1164 ;;
1165 ;; "The values of local slots specified by both the class Cto and
1166 ;; Cfrom are retained. If such a local slot was unbound, it remains
1167 ;; unbound."
1168 ;;
1169 (iterate ((new-slot (list-elements new-layout))
1170 (new-position (interval :from 0)))
1171 (let ((old-position (posq new-slot old-layout)))
1172 (when old-position
1173 (setf (instance-ref new-slots new-position)
1174 (instance-ref old-slots old-position)))))
1175
1176 ;;
1177 ;; "The values of slots specified as shared in the class Cfrom and
1178 ;; as local in the class Cto are retained."
1179 ;;
1180 (iterate ((slot-and-val (list-elements old-class-slots)))
1181 (let ((position (posq (car slot-and-val) new-layout)))
1182 (when position
1183 (setf (instance-ref new-slots position) (cdr slot-and-val)))))
1184
1185 ;; Make the copy point to the old instance's storage, and make the
1186 ;; old instance point to the new storage.
1187 (swap-wrappers-and-slots instance guts)
1188
1189 (update-instance-for-different-class copy instance)
1190 instance))
1191
1192 (defmethod change-class ((instance standard-object)
1193 (new-class standard-class))
1194 (unless (std-instance-p instance)
1195 (error "Can't change the class of ~S to ~S~@
1196 because it isn't already an instance with metaclass~%~S."
1197 instance
1198 new-class
1199 'standard-class))
1200 (change-class-internal instance new-class))
1201
1202 (defmethod change-class ((instance standard-object)
1203 (new-class funcallable-standard-class))
1204 (unless (fsc-instance-p instance)
1205 (error "Can't change the class of ~S to ~S~@
1206 because it isn't already an instance with metaclass~%~S."
1207 instance
1208 new-class
1209 'funcallable-standard-class))
1210 (change-class-internal instance new-class))
1211
1212 (defmethod change-class ((instance t) (new-class-name symbol))
1213 (change-class instance (find-class new-class-name)))
1214
1215
1216
1217 ;;;
1218 ;;; The metaclass BUILT-IN-CLASS
1219 ;;;
1220 ;;; This metaclass is something of a weird creature. By this point, all
1221 ;;; instances of it which will exist have been created, and no instance
1222 ;;; is ever created by calling MAKE-INSTANCE.
1223 ;;;
1224 ;;; But, there are other parts of the protcol we must follow and those
1225 ;;; definitions appear here.
1226 ;;;
1227 (defmethod shared-initialize :before
1228 ((class built-in-class) slot-names &rest initargs)
1229 (declare (ignore slot-names initargs))
1230 (error "Attempt to initialize or reinitialize a built in class."))
1231
1232 (defmethod class-direct-slots ((class built-in-class)) ())
1233 (defmethod class-slots ((class built-in-class)) ())
1234 (defmethod class-direct-default-initargs ((class built-in-class)) ())
1235 (defmethod class-default-initargs ((class built-in-class)) ())
1236
1237 (defmethod validate-superclass ((c class) (s built-in-class))
1238 (eq s *the-class-t*))
1239
1240
1241
1242 ;;;
1243 ;;;
1244 ;;;
1245
1246 (defmethod validate-superclass ((c slot-class)
1247 (f forward-referenced-class))
1248 't)
1249
1250
1251 ;;;
1252 ;;;
1253 ;;;
1254
1255 (defmethod add-dependent ((metaobject dependent-update-mixin) dependent)
1256 (pushnew dependent (plist-value metaobject 'dependents)))
1257
1258 (defmethod remove-dependent ((metaobject dependent-update-mixin) dependent)
1259 (setf (plist-value metaobject 'dependents)
1260 (delete dependent (plist-value metaobject 'dependents))))
1261
1262 (defmethod map-dependents ((metaobject dependent-update-mixin) function)
1263 (dolist (dependent (plist-value metaobject 'dependents))
1264 (funcall function dependent)))
1265

  ViewVC Help
Powered by ViewVC 1.1.5