/[cmucl]/src/compiler/locall.lisp
ViewVC logotype

Contents of /src/compiler/locall.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.33 - (show annotations)
Tue Jul 21 17:27:05 1992 UTC (21 years, 9 months ago) by ram
Branch: MAIN
Changes since 1.32: +12 -8 lines
We must do merge-tail-sets before potential let-conversion so that we will
correctly recognize all tail calls.
1 ;;; -*- Package: C; Log: C.Log -*-
2 ;;;
3 ;;; **********************************************************************
4 ;;; This code was written as part of the CMU Common Lisp project at
5 ;;; Carnegie Mellon University, and has been placed in the public domain.
6 ;;; If you want to use this code or any part of CMU Common Lisp, please contact
7 ;;; Scott Fahlman or slisp-group@cs.cmu.edu.
8 ;;;
9 (ext:file-comment
10 "$Header: /tiger/var/lib/cvsroots/cmucl/src/compiler/locall.lisp,v 1.33 1992/07/21 17:27:05 ram Exp $")
11 ;;;
12 ;;; **********************************************************************
13 ;;;
14 ;;; This file implements local call analysis. A local call is a function
15 ;;; call between functions being compiled at the same time. If we can tell at
16 ;;; compile time that such a call is legal, then we change the combination
17 ;;; to call the correct lambda, mark it as local, and add this link to our call
18 ;;; graph. Once a call is local, it is then eligible for let conversion, which
19 ;;; places the body of the function inline.
20 ;;;
21 ;;; We cannot always do a local call even when we do have the function being
22 ;;; called. Local call can be explicitly disabled by a NOTINLINE declaration.
23 ;;; Calls that cannot be shown to have legal arg counts are also not converted.
24 ;;;
25 ;;; Written by Rob MacLachlan
26 ;;;
27 (in-package :c)
28
29
30 ;;; Propagate-To-Args -- Interface
31 ;;;
32 ;;; This function propagates information from the variables in the function
33 ;;; Fun to the actual arguments in Call. This is also called by the VALUES IR1
34 ;;; optimizer when it sleazily converts MV-BINDs to LETs.
35 ;;;
36 ;;; We flush all arguments to Call that correspond to unreferenced variables
37 ;;; in Fun. We leave NILs in the Combination-Args so that the remaining args
38 ;;; still match up with their vars.
39 ;;;
40 ;;; We also apply the declared variable type assertion to the argument
41 ;;; continuations.
42 ;;;
43 (defun propagate-to-args (call fun)
44 (declare (type combination call) (type clambda fun))
45 (do ((args (basic-combination-args call) (cdr args))
46 (vars (lambda-vars fun) (cdr vars)))
47 ((null args))
48 (let ((arg (car args))
49 (var (car vars)))
50 (cond ((leaf-refs var)
51 (assert-continuation-type arg (leaf-type var)))
52 (t
53 (flush-dest arg)
54 (setf (car args) nil)))))
55
56 (undefined-value))
57
58
59 ;;; Merge-Tail-Sets -- Interface
60 ;;;
61 ;;; This function handles merging the tail sets if Call is potentially
62 ;;; tail-recursive, and is a call to a function with a different TAIL-SET than
63 ;;; Call's Fun. This must be called whenever we alter IR1 so as to place a
64 ;;; local call in what might be a TR context. Note that any call which returns
65 ;;; its value to a RETURN is considered potentially TR, since any implicit
66 ;;; MV-PROG1 might be optimized away.
67 ;;;
68 ;;; We destructively modify the set for the calling function to represent both,
69 ;;; and then change all the functions in callee's set to reference the first.
70 ;;; If we do merge, we reoptimize the RETURN-RESULT continuation to cause
71 ;;; IR1-OPTIMIZE-RETURN to recompute the tail set type.
72 ;;;
73 (defun merge-tail-sets (call &optional (new-fun (combination-lambda call)))
74 (declare (type basic-combination call) (type clambda new-fun))
75 (let ((return (continuation-dest (node-cont call))))
76 (when (return-p return)
77 (let ((call-set (lambda-tail-set (node-home-lambda call)))
78 (fun-set (lambda-tail-set new-fun)))
79 (unless (eq call-set fun-set)
80 (let ((funs (tail-set-functions fun-set)))
81 (dolist (fun funs)
82 (setf (lambda-tail-set fun) call-set))
83 (setf (tail-set-functions call-set)
84 (nconc (tail-set-functions call-set) funs)))
85 (reoptimize-continuation (return-result return))
86 t)))))
87
88
89 ;;; Convert-Call -- Internal
90 ;;;
91 ;;; Convert a combination into a local call. We PROPAGATE-TO-ARGS, set the
92 ;;; combination kind to :Local, add Fun to the Calls of the function that the
93 ;;; call is in, call MERGE-TAIL-SETS, then replace the function in the Ref node
94 ;;; with the new function.
95 ;;;
96 ;;; We change the Ref last, since changing the reference can trigger let
97 ;;; conversion of the new function, but will only do so if the call is local.
98 ;;; Note that the replacement may trigger let conversion or other changes in
99 ;;; IR1. We must call MERGE-TAIL-SETS with NEW-FUN before the substitution,
100 ;;; since after the substitution (and let conversion), the call may no longer
101 ;;; be recognizable as tail-recursive.
102 ;;;
103 (defun convert-call (ref call fun)
104 (declare (type ref ref) (type combination call) (type clambda fun))
105 (propagate-to-args call fun)
106 (setf (basic-combination-kind call) :local)
107 (pushnew fun (lambda-calls (node-home-lambda call)))
108 (merge-tail-sets call fun)
109 (change-ref-leaf ref fun)
110 (undefined-value))
111
112
113 ;;;; External entry point creation:
114
115 ;;; Make-XEP-Lambda -- Internal
116 ;;;
117 ;;; Return a Lambda form that can be used as the definition of the XEP for
118 ;;; Fun.
119 ;;;
120 ;;; If Fun is a lambda, then we check the number of arguments (conditional
121 ;;; on policy) and call Fun with all the arguments.
122 ;;;
123 ;;; If Fun is an Optional-Dispatch, then we dispatch off of the number of
124 ;;; supplied arguments by doing do an = test for each entry-point, calling the
125 ;;; entry with the appropriate prefix of the passed arguments.
126 ;;;
127 ;;; If there is a more arg, then there are a couple of optimizations that we
128 ;;; make (more for space than anything else):
129 ;;; -- If Min-Args is 0, then we make the more entry a T clause, since no
130 ;;; argument count error is possible.
131 ;;; -- We can omit the = clause for the last entry-point, allowing the case of
132 ;;; 0 more args to fall through to the more entry.
133 ;;;
134 ;;; We don't bother to policy conditionalize wrong arg errors in optional
135 ;;; dispatches, since the additional overhead is negligible compared to the
136 ;;; other hair going down.
137 ;;;
138 ;;; Note that if policy indicates it, argument type declarations in Fun will
139 ;;; be verified. Since nothing is known about the type of the XEP arg vars,
140 ;;; type checks will be emitted when the XEP's arg vars are passed to the
141 ;;; actual function.
142 ;;;
143 (defun make-xep-lambda (fun)
144 (declare (type functional fun))
145 (etypecase fun
146 (clambda
147 (let ((nargs (length (lambda-vars fun)))
148 (n-supplied (gensym)))
149 (collect ((temps))
150 (dotimes (i nargs)
151 (temps (gensym)))
152 `(lambda (,n-supplied ,@(temps))
153 (declare (fixnum ,n-supplied))
154 ,(if (policy (lambda-bind fun) (zerop safety))
155 `(declare (ignore ,n-supplied))
156 `(%verify-argument-count ,n-supplied ,nargs))
157 (%funcall ,fun ,@(temps))))))
158 (optional-dispatch
159 (let* ((min (optional-dispatch-min-args fun))
160 (max (optional-dispatch-max-args fun))
161 (more (optional-dispatch-more-entry fun))
162 (n-supplied (gensym)))
163 (collect ((temps)
164 (entries))
165 (dotimes (i max)
166 (temps (gensym)))
167
168 (do ((eps (optional-dispatch-entry-points fun) (rest eps))
169 (n min (1+ n)))
170 ((null eps))
171 (entries `((= ,n-supplied ,n)
172 (%funcall ,(first eps) ,@(subseq (temps) 0 n)))))
173
174 `(lambda (,n-supplied ,@(temps))
175 (declare (fixnum ,n-supplied))
176 (cond
177 ,@(if more (butlast (entries)) (entries))
178 ,@(when more
179 `((,(if (zerop min) 't `(>= ,n-supplied ,max))
180 ,(let ((n-context (gensym))
181 (n-count (gensym)))
182 `(multiple-value-bind
183 (,n-context ,n-count)
184 (%more-arg-context ,n-supplied ,max)
185 (%funcall ,more ,@(temps) ,n-context ,n-count))))))
186 (t
187 (%argument-count-error ,n-supplied)))))))))
188
189
190 ;;; Make-External-Entry-Point -- Internal
191 ;;;
192 ;;; Make an external entry point (XEP) for Fun and return it. We convert
193 ;;; the result of Make-XEP-Lambda in the correct environment, then associate
194 ;;; this lambda with Fun as its XEP. After the conversion, we iterate over the
195 ;;; function's associated lambdas, redoing local call analysis so that the XEP
196 ;;; calls will get converted. We also bind *lexical-environment* to change the
197 ;;; compilation policy over to the interface policy.
198 ;;;
199 ;;; We set Reanalyze and Reoptimize in the component, just in case we
200 ;;; discover an XEP after the initial local call analyze pass.
201 ;;;
202 (defun make-external-entry-point (fun)
203 (declare (type functional fun))
204 (assert (not (functional-entry-function fun)))
205 (with-ir1-environment (lambda-bind (main-entry fun))
206 (let* ((*lexical-environment*
207 (make-lexenv :cookie
208 (make-interface-cookie *lexical-environment*)))
209 (res (ir1-convert-lambda (make-xep-lambda fun))))
210 (setf (functional-kind res) :external)
211 (setf (leaf-ever-used res) t)
212 (setf (functional-entry-function res) fun)
213 (setf (functional-entry-function fun) res)
214 (setf (component-reanalyze *current-component*) t)
215 (setf (component-reoptimize *current-component*) t)
216 (etypecase fun
217 (clambda (local-call-analyze-1 fun))
218 (optional-dispatch
219 (dolist (ep (optional-dispatch-entry-points fun))
220 (local-call-analyze-1 ep))
221 (when (optional-dispatch-more-entry fun)
222 (local-call-analyze-1 (optional-dispatch-more-entry fun)))))
223 res)))
224
225
226 ;;; Reference-Entry-Point -- Internal
227 ;;;
228 ;;; Notice a Ref that is not in a local-call context. If the Ref is already
229 ;;; to an XEP, then do nothing, otherwise change it to the XEP, making an XEP
230 ;;; if necessary.
231 ;;;
232 ;;; If Ref is to a special :Cleanup or :Escape function, then we treat it as
233 ;;; though it was not an XEP reference (i.e. leave it alone.)
234 ;;;
235 (defun reference-entry-point (ref)
236 (declare (type ref ref))
237 (let ((fun (ref-leaf ref)))
238 (unless (or (external-entry-point-p fun)
239 (member (functional-kind fun) '(:escape :cleanup)))
240 (change-ref-leaf ref (or (functional-entry-function fun)
241 (make-external-entry-point fun))))))
242
243
244 ;;; Local-Call-Analyze-1 -- Interface
245 ;;;
246 ;;; Attempt to convert all references to Fun to local calls. The reference
247 ;;; cannot be :Notinline, and must be the function for a call. The function
248 ;;; continuation must be used only once, since otherwise we cannot be sure what
249 ;;; function is to be called. The call continuation would be multiply used if
250 ;;; there is hairy stuff such as conditionals in the expression that computes
251 ;;; the function.
252 ;;;
253 ;;; Except in the interpreter, we don't attempt to convert calls that appear
254 ;;; in a top-level lambda unless there is only one reference or the function is
255 ;;; a unwind-protect cleanup. This allows top-level components to contain only
256 ;;; load-time code: any references to run-time functions will be as closures.
257 ;;;
258 ;;; If we cannot convert a reference, then we mark the referenced function
259 ;;; as an entry-point, creating a new XEP if necessary.
260 ;;;
261 ;;; This is broken off from Local-Call-Analyze so that people can force
262 ;;; analysis of newly introduced calls. Note that we don't do let conversion
263 ;;; here.
264 ;;;
265 (defun local-call-analyze-1 (fun)
266 (declare (type functional fun))
267 (let ((refs (leaf-refs fun)))
268 (dolist (ref refs)
269 (let* ((cont (node-cont ref))
270 (dest (continuation-dest cont)))
271 (cond ((and (basic-combination-p dest)
272 (eq (basic-combination-fun dest) cont)
273 (eq (continuation-use cont) ref)
274 (or (null (rest refs))
275 *converting-for-interpreter*
276 (eq (functional-kind fun) :cleanup)
277 (not (eq (functional-kind (node-home-lambda ref))
278 :top-level))))
279 (ecase (ref-inlinep ref)
280 ((nil :inline :maybe-inline)
281 (convert-call-if-possible ref dest))
282 ((:notinline)))
283
284 (unless (eq (basic-combination-kind dest) :local)
285 (reference-entry-point ref)))
286 (t
287 (reference-entry-point ref))))))
288
289 (undefined-value))
290
291
292 ;;; Local-Call-Analyze -- Interface
293 ;;;
294 ;;; We examine all New-Functions in component, attempting to convert calls
295 ;;; into local calls when it is legal. We also attempt to convert each lambda
296 ;;; to a let. Let conversion is also triggered by deletion of a function
297 ;;; reference, but functions that start out eligible for conversion must be
298 ;;; noticed sometime.
299 ;;;
300 ;;; Note that there is a lot of action going on behind the scenes here,
301 ;;; triggered by reference deletion. In particular, the Component-Lambdas are
302 ;;; being hacked to remove newly deleted and let converted lambdas, so it is
303 ;;; important that the lambda is added to the Component-Lambdas when it is.
304 ;;;
305 (defun local-call-analyze (component)
306 (declare (type component component))
307 (loop
308 (unless (component-new-functions component) (return))
309 (let* ((fun (pop (component-new-functions component)))
310 (kind (functional-kind fun)))
311 (cond ((eq kind :deleted))
312 ((and (null (leaf-refs fun)) (eq kind nil)
313 (not (functional-entry-function fun)))
314 (delete-functional fun))
315 (t
316 (when (lambda-p fun)
317 (push fun (component-lambdas component)))
318 (local-call-analyze-1 fun)
319 (when (lambda-p fun)
320 (maybe-let-convert fun))))))
321
322 (undefined-value))
323
324
325 ;;; Convert-Call-If-Possible -- Interface
326 ;;;
327 ;;; Dispatch to the appropriate function to attempt to convert a call. This
328 ;;; is called in IR1 optimize as well as in local call analysis. If the call
329 ;;; is already :Local, we do nothing. If the call is in the top-level
330 ;;; component, also do nothing, since we don't want to join top-level code into
331 ;;; normal components.
332 ;;;
333 ;;; We bind *Compiler-Error-Context* to the node for the call so that
334 ;;; warnings will get the right context.
335 ;;;
336 (defun convert-call-if-possible (ref call)
337 (declare (type ref ref) (type basic-combination call))
338 (unless (or (eq (basic-combination-kind call) :local)
339 (let ((block (node-block call)))
340 (or (block-delete-p block)
341 (eq (functional-kind (block-home-lambda block))
342 :deleted))))
343 (let ((fun (let ((fun (ref-leaf ref)))
344 (if (external-entry-point-p fun)
345 (functional-entry-function fun)
346 fun)))
347 (*compiler-error-context* call))
348 (let ((c1 (block-component (node-block call)))
349 (c2 (block-component (node-block (lambda-bind (main-entry fun))))))
350 (assert (or (eq c1 c2)
351 (and (eq (component-kind c1) :initial)
352 (eq (component-kind c2) :initial)))))
353 (assert (member (functional-kind fun) '(nil :escape :cleanup :optional)))
354 (cond ((mv-combination-p call)
355 (convert-mv-call ref call fun))
356 ((lambda-p fun)
357 (convert-lambda-call ref call fun))
358 (t
359 (convert-hairy-call ref call fun)))))
360 (undefined-value))
361
362
363 ;;; Convert-MV-Call -- Internal
364 ;;;
365 ;;; Attempt to convert a multiple-value call. The only interesting case is
366 ;;; a call to a function that Looks-Like-An-MV-Bind, has exactly one reference
367 ;;; and no XEP, and is called with one values continuation.
368 ;;;
369 ;;; We change the call to be to the last optional entry point and change the
370 ;;; call to be local. Due to our preconditions, the call should eventually be
371 ;;; converted to a let, but we can't do that now, since there may be stray
372 ;;; references to the e-p lambda due to optional defaulting code.
373 ;;;
374 ;;; We also use variable types for the called function to construct an
375 ;;; assertion for the values continuation.
376 ;;;
377 (defun convert-mv-call (ref call fun)
378 (declare (type ref ref) (type mv-combination call) (type functional fun))
379 (when (and (looks-like-an-mv-bind fun)
380 (not (functional-entry-function fun))
381 (= (length (leaf-refs fun)) 1)
382 (= (length (basic-combination-args call)) 1))
383 (let ((ep (car (last (optional-dispatch-entry-points fun)))))
384 (setf (basic-combination-kind call) :local)
385 (pushnew ep (lambda-calls (node-home-lambda call)))
386 (change-ref-leaf ref ep)
387 (merge-tail-sets call)
388
389 (assert-continuation-type
390 (first (basic-combination-args call))
391 (make-values-type :optional (mapcar #'leaf-type (lambda-vars ep))
392 :rest *universal-type*))))
393 (undefined-value))
394
395
396 ;;; Convert-Lambda-Call -- Internal
397 ;;;
398 ;;; Attempt to convert a call to a lambda. If the number of args is wrong,
399 ;;; we give a warning and mark the Ref as :Notinline to remove it from future
400 ;;; consideration. If the argcount is O.K. then we just convert it.
401 ;;;
402 (defun convert-lambda-call (ref call fun)
403 (declare (type ref ref) (type combination call) (type clambda fun))
404 (let ((nargs (length (lambda-vars fun)))
405 (call-args (length (combination-args call))))
406 (cond ((= call-args nargs)
407 (convert-call ref call fun))
408 (t
409 (compiler-warning
410 "Function called with ~R argument~:P, but wants exactly ~R."
411 call-args nargs)
412 (setf (ref-inlinep ref) :notinline)))))
413
414
415
416 ;;;; Optional, more and keyword calls:
417
418 ;;; Convert-Hairy-Call -- Internal
419 ;;;
420 ;;; Similar to Convert-Lambda-Call, but deals with Optional-Dispatches. If
421 ;;; only fixed args are supplied, then convert a call to the correct entry
422 ;;; point. If keyword args are supplied, then dispatch to a subfunction. We
423 ;;; don't convert calls to functions that have a more (or rest) arg.
424 ;;;
425 (defun convert-hairy-call (ref call fun)
426 (declare (type ref ref) (type combination call)
427 (type optional-dispatch fun))
428 (let ((min-args (optional-dispatch-min-args fun))
429 (max-args (optional-dispatch-max-args fun))
430 (call-args (length (combination-args call))))
431 (cond ((< call-args min-args)
432 (compiler-warning "Function called with ~R argument~:P, but wants at least ~R."
433 call-args min-args)
434 (setf (ref-inlinep ref) :notinline))
435 ((<= call-args max-args)
436 (convert-call ref call
437 (elt (optional-dispatch-entry-points fun)
438 (- call-args min-args))))
439 ((optional-dispatch-more-entry fun)
440 (convert-more-call ref call fun))
441 (t
442 (compiler-warning "Function called with ~R argument~:P, but wants at most ~R."
443 call-args max-args)
444 (setf (ref-inlinep ref) :notinline))))
445
446 (undefined-value))
447
448
449 ;;; Convert-Hairy-Fun-Entry -- Internal
450 ;;;
451 ;;; This function is used to convert a call to an entry point when complex
452 ;;; transformations need to be done on the original arguments. Entry is the
453 ;;; entry point function that we are calling. Vars is a list of variable names
454 ;;; which are bound to the oringinal call arguments. Ignores is the subset of
455 ;;; Vars which are ignored. Args is the list of arguments to the entry point
456 ;;; function.
457 ;;;
458 ;;; In order to avoid gruesome graph grovelling, we introduce a new function
459 ;;; that rearranges the arguments and calls the entry point. We analyze the
460 ;;; new function and the entry point immediately so that everything gets
461 ;;; converted during the single pass.
462 ;;;
463 (defun convert-hairy-fun-entry (ref call entry vars ignores args)
464 (declare (list vars ignores args) (type ref ref) (type combination call)
465 (type clambda entry))
466 (let ((new-fun
467 (with-ir1-environment call
468 (ir1-convert-lambda
469 `(lambda ,vars
470 (declare (ignorable . ,ignores))
471 (%funcall ,entry . ,args))))))
472 (convert-call ref call new-fun)
473 (dolist (ref (leaf-refs entry))
474 (convert-call-if-possible ref (continuation-dest (node-cont ref))))))
475
476
477 ;;; Convert-More-Call -- Internal
478 ;;;
479 ;;; Use Convert-Hairy-Fun-Entry to convert a more-arg call to a known
480 ;;; function into a local call to the Main-Entry.
481 ;;;
482 ;;; First we verify that all keywords are constant and legal. If there
483 ;;; aren't, then we warn the user and don't attempt to convert the call.
484 ;;;
485 ;;; We massage the supplied keyword arguments into the order expected by the
486 ;;; main entry. This is done by binding all the arguments to the keyword call
487 ;;; to variables in the introduced lambda, then passing these values variables
488 ;;; in the correct order when calling the main entry. Unused arguments
489 ;;; (such as the keywords themselves) are discarded simply by not passing them
490 ;;; along.
491 ;;;
492 ;;; If there is a rest arg, then we bundle up the args and pass them to
493 ;;; LIST.
494 ;;;
495 (defun convert-more-call (ref call fun)
496 (declare (type ref ref) (type combination call) (type optional-dispatch fun))
497 (let* ((max (optional-dispatch-max-args fun))
498 (arglist (optional-dispatch-arglist fun))
499 (args (combination-args call))
500 (more (nthcdr max args))
501 (flame (policy call (or (> speed brevity) (> space brevity))))
502 (loser nil))
503 (collect ((temps)
504 (more-temps)
505 (ignores)
506 (supplied)
507 (key-vars))
508
509 (dolist (var arglist)
510 (let ((info (lambda-var-arg-info var)))
511 (when info
512 (ecase (arg-info-kind info)
513 (:keyword
514 (key-vars var))
515 ((:rest :optional))))))
516
517 (dotimes (i max)
518 (temps (gensym "FIXED-ARG-TEMP-")))
519
520 (dotimes (i (length more))
521 (more-temps (gensym "MORE-ARG-TEMP-")))
522
523 (when (optional-dispatch-keyp fun)
524 (when (oddp (length more))
525 (compiler-warning "Function called with odd number of ~
526 arguments in keyword portion.")
527 (setf (ref-inlinep ref) :notinline)
528 (return-from convert-more-call))
529
530 (do ((key more (cddr key))
531 (temp (more-temps) (cddr temp)))
532 ((null key))
533 (let ((cont (first key)))
534 (unless (constant-continuation-p cont)
535 (when flame
536 (compiler-note "Non-constant keyword in keyword call."))
537 (setf (ref-inlinep ref) :notinline)
538 (return-from convert-more-call))
539
540 (let ((name (continuation-value cont))
541 (dummy (first temp))
542 (val (second temp)))
543 (dolist (var (key-vars)
544 (progn
545 (ignores dummy val)
546 (setq loser name)))
547 (let ((info (lambda-var-arg-info var)))
548 (when (eq (arg-info-keyword info) name)
549 (ignores dummy)
550 (supplied (cons var val))
551 (return)))))))
552
553 (when (and loser (not (optional-dispatch-allowp fun)))
554 (compiler-warning "Function called with unknown argument keyword ~S."
555 loser)
556 (setf (ref-inlinep ref) :notinline)
557 (return-from convert-more-call)))
558
559 (collect ((call-args))
560 (do ((var arglist (cdr var))
561 (temp (temps) (cdr temp)))
562 (())
563 (let ((info (lambda-var-arg-info (car var))))
564 (if info
565 (ecase (arg-info-kind info)
566 (:optional
567 (call-args (car temp))
568 (when (arg-info-supplied-p info)
569 (call-args t)))
570 (:rest
571 (call-args `(list ,@(more-temps)))
572 (return))
573 (:keyword
574 (return)))
575 (call-args (car temp)))))
576
577 (dolist (var (key-vars))
578 (let ((info (lambda-var-arg-info var))
579 (temp (cdr (assoc var (supplied)))))
580 (if temp
581 (call-args temp)
582 (call-args (arg-info-default info)))
583 (when (arg-info-supplied-p info)
584 (call-args (not (null temp))))))
585
586 (convert-hairy-fun-entry ref call (optional-dispatch-main-entry fun)
587 (append (temps) (more-temps))
588 (ignores) (call-args)))))
589
590 (undefined-value))
591
592
593 ;;;; Let conversion:
594 ;;;
595 ;;; Converting to a let has differing significance to various parts of the
596 ;;; compiler:
597 ;;; -- The body of a Let is spliced in immediately after the the corresponding
598 ;;; combination node, making the control transfer explicit and allowing lets
599 ;;; to mashed together into a single block. The value of the let is
600 ;;; delivered directly to the original continuation for the call,
601 ;;; eliminating the need to propagate information from the dummy result
602 ;;; continuation.
603 ;;; -- As far as IR1 optimization is concerned, it is interesting in that there
604 ;;; is only one expression that the variable can be bound to, and this is
605 ;;; easily substitited for.
606 ;;; -- Lets are interesting to environment analysis and the back end because in
607 ;;; most ways a let can be considered to be "the same function" as its home
608 ;;; function.
609 ;;; -- Let conversion has dynamic scope implications, since control transfers
610 ;;; within the same environment are local. In a local control transfer,
611 ;;; cleanup code must be emitted to remove dynamic bindings that are no
612 ;;; longer in effect.
613
614
615 ;;; Insert-Let-Body -- Internal
616 ;;;
617 ;;; Set up the control transfer to the called lambda. We split the call
618 ;;; block immediately after the call, and link the head of Fun to the call
619 ;;; block. The successor block after splitting (where we return to) is
620 ;;; returned.
621 ;;;
622 ;;; If the lambda is is a different component than the call, then we call
623 ;;; JOIN-COMPONENTS. This only happens in block compilation before
624 ;;; FIND-INITIAL-DFO.
625 ;;;
626 (defun insert-let-body (fun call)
627 (declare (type clambda fun) (type basic-combination call))
628 (let* ((call-block (node-block call))
629 (bind-block (node-block (lambda-bind fun)))
630 (component (block-component call-block)))
631 (let ((fun-component (block-component bind-block)))
632 (unless (eq fun-component component)
633 (assert (eq (component-kind component) :initial))
634 (join-components component fun-component)))
635
636 (let ((*current-component* component))
637 (node-ends-block call))
638 (assert (= (length (block-succ call-block)) 1))
639 (let ((next-block (first (block-succ call-block))))
640 (unlink-blocks call-block next-block)
641 (link-blocks call-block bind-block)
642 next-block)))
643
644
645 ;;; Merge-Lets -- Internal
646 ;;;
647 ;;; Handle the environment semantics of let conversion. We add the lambda
648 ;;; and its lets to lets for the Call's home function. We merge the calls for
649 ;;; Fun with the calls for the home function, removing Fun in the process. We
650 ;;; also merge the Entries.
651 ;;;
652 ;;; We also unlink the function head from the component head and set
653 ;;; Component-Reanalyze to true to indicate that the DFO should be recomputed.
654 ;;;
655 (defun merge-lets (fun call)
656 (declare (type clambda fun) (type basic-combination call))
657 (let ((component (block-component (node-block call))))
658 (unlink-blocks (component-head component) (node-block (lambda-bind fun)))
659 (setf (component-lambdas component)
660 (delete fun (component-lambdas component)))
661 (setf (component-reanalyze component) t))
662 (setf (lambda-call-lexenv fun) (node-lexenv call))
663 (let ((tails (lambda-tail-set fun)))
664 (setf (tail-set-functions tails)
665 (delete fun (tail-set-functions tails))))
666 (setf (lambda-tail-set fun) nil)
667 (let* ((home (node-home-lambda call))
668 (home-env (lambda-environment home)))
669 (push fun (lambda-lets home))
670 (setf (lambda-home fun) home)
671 (setf (lambda-environment fun) home-env)
672
673 (let ((lets (lambda-lets fun)))
674 (dolist (let lets)
675 (setf (lambda-home let) home)
676 (setf (lambda-environment let) home-env))
677
678 (setf (lambda-lets home) (nconc lets (lambda-lets home)))
679 (setf (lambda-lets fun) ()))
680
681 (setf (lambda-calls home)
682 (nunion (lambda-calls fun)
683 (delete fun (lambda-calls home))))
684 (setf (lambda-calls fun) ())
685
686 (setf (lambda-entries home)
687 (nconc (lambda-entries fun) (lambda-entries home)))
688 (setf (lambda-entries fun) ()))
689 (undefined-value))
690
691
692 ;;; Move-Return-Uses -- Internal
693 ;;;
694 ;;; Handle the value semantics of let conversion. Delete Fun's return node,
695 ;;; and change the control flow to transfer to Next-Block instead. Move all
696 ;;; the uses of the result continuation to Call's Cont.
697 ;;;
698 ;;; If the actual continuation is only used by the let call, then we
699 ;;; intersect the type assertion on the dummy continuation with the assertion
700 ;;; for the actual continuation; in all other cases assertions on the dummy
701 ;;; continuation are lost.
702 ;;;
703 ;;; We also intersect the derived type of the call with the derived type of
704 ;;; all the dummy continuation's uses. This serves mainly to propagate
705 ;;; TRULY-THE through lets.
706 ;;;
707 (defun move-return-uses (fun call next-block)
708 (declare (type clambda fun) (type basic-combination call)
709 (type cblock next-block))
710 (let* ((return (lambda-return fun))
711 (return-block (node-block return)))
712 (unlink-blocks return-block
713 (component-tail (block-component return-block)))
714 (link-blocks return-block next-block)
715 (unlink-node return)
716 (delete-return return)
717 (let ((result (return-result return))
718 (cont (node-cont call))
719 (call-type (node-derived-type call)))
720 (when (eq (continuation-use cont) call)
721 (assert-continuation-type cont (continuation-asserted-type result)))
722 (unless (eq call-type *wild-type*)
723 (do-uses (use result)
724 (derive-node-type use call-type)))
725 (substitute-continuation-uses cont result)))
726 (undefined-value))
727
728
729
730 ;;; MOVE-LET-CALL-CONT -- Internal
731 ;;;
732 ;;; Change all Cont for all the calls to Fun to be the start continuation
733 ;;; for the bind node. This allows the blocks to be joined if the caller count
734 ;;; ever goes to one.
735 ;;;
736 (defun move-let-call-cont (fun)
737 (declare (type clambda fun))
738 (let ((new-cont (node-prev (lambda-bind fun))))
739 (dolist (ref (leaf-refs fun))
740 (let ((dest (continuation-dest (node-cont ref))))
741 (delete-continuation-use dest)
742 (add-continuation-use dest new-cont))))
743 (undefined-value))
744
745
746 ;;; Unconvert-Tail-Calls -- Internal
747 ;;;
748 ;;; We are converting Fun to be a let when the call is in a non-tail
749 ;;; position. Any previously tail calls in Fun are no longer tail calls, and
750 ;;; must be restored to normal calls which transfer to Next-Block (Fun's
751 ;;; return point.) We can't do this by DO-USES on the RETURN-RESULT, because
752 ;;; the return might have been deleted (if all calls were TR.)
753 ;;;
754 ;;; The called function might be an assignment in the case where we are
755 ;;; currently converting that function. In steady-state, assignments never
756 ;;; appear in the lambda-calls.
757 ;;;
758 (defun unconvert-tail-calls (fun call next-block)
759 (dolist (called (lambda-calls fun))
760 (dolist (ref (leaf-refs called))
761 (let ((this-call (continuation-dest (node-cont ref))))
762 (when (and (node-tail-p this-call)
763 (eq (node-home-lambda this-call) fun))
764 (setf (node-tail-p this-call) nil)
765 (ecase (functional-kind called)
766 ((nil :cleanup :optional)
767 (let ((block (node-block this-call)))
768 (unlink-blocks block (first (block-succ block)))
769 (link-blocks block next-block)
770 (delete-continuation-use this-call)
771 (add-continuation-use this-call (node-cont call))))
772 (:assignment
773 (assert (eq called fun))))))))
774 (undefined-value))
775
776
777 ;;; MOVE-RETURN-STUFF -- Internal
778 ;;;
779 ;;; Deal with returning from a let or assignment that we are converting.
780 ;;; FUN is the function we are calling, CALL is a call to FUN, and NEXT-BLOCK
781 ;;; is the return point for a non-tail call, or NULL if call is a tail call.
782 ;;;
783 ;;; If the call is not a tail call, then we must do UNCONVERT-TAIL-CALLS, since
784 ;;; a tail call is a call which returns its value out of the enclosing non-let
785 ;;; function. When call is non-TR, we must convert it back to an ordinary
786 ;;; local call, since the value must be delivered to the receiver of CALL's
787 ;;; value.
788 ;;;
789 ;;; We do different things depending on whether the caller and callee have
790 ;;; returns left:
791 ;;; -- If the callee has no return we just do MOVE-LET-CALL-CONT. Either the
792 ;;; function doesn't return, or all returns are via tail-recursive local
793 ;;; calls.
794 ;;; -- If CALL is a non-tail call, or if both have returns, then we
795 ;;; delete the callee's return, move its uses to the call's result
796 ;;; continuation, and transfer control to the appropriate return point.
797 ;;; -- If the callee has a return, but the caller doesn't, then we move the
798 ;;; return to the caller.
799 ;;;
800 (defun move-return-stuff (fun call next-block)
801 (declare (type clambda fun) (type basic-combination call)
802 (type (or cblock null) next-block))
803 (when next-block
804 (unconvert-tail-calls fun call next-block))
805 (let* ((return (lambda-return fun))
806 (call-fun (node-home-lambda call))
807 (call-return (lambda-return call-fun)))
808 (cond ((not return))
809 ((or next-block call-return)
810 (unless (block-delete-p (node-block return))
811 (move-return-uses fun call
812 (or next-block (node-block call-return)))))
813 (t
814 (assert (node-tail-p call))
815 (setf (lambda-return call-fun) return)
816 (setf (return-lambda return) call-fun))))
817 (move-let-call-cont fun)
818 (undefined-value))
819
820
821 ;;; Let-Convert -- Internal
822 ;;;
823 ;;; Actually do let conversion. We call subfunctions to do most of the
824 ;;; work. We change the Call's cont to be the continuation heading the bind
825 ;;; block, and also do Reoptimize-Continuation on the args and Cont so that
826 ;;; let-specific IR1 optimizations get a chance. We blow away any entry for
827 ;;; the function in *free-functions* so that nobody will create new reference
828 ;;; to it.
829 ;;;
830 (defun let-convert (fun call)
831 (declare (type clambda fun) (type basic-combination call))
832 (let ((next-block (if (node-tail-p call)
833 nil
834 (insert-let-body fun call))))
835 (move-return-stuff fun call next-block)
836 (merge-lets fun call))
837
838 (maybe-remove-free-function fun)
839 (dolist (arg (basic-combination-args call))
840 (when arg
841 (reoptimize-continuation arg)))
842 (reoptimize-continuation (node-cont call))
843 (undefined-value))
844
845
846 ;;; Maybe-Let-Convert -- Interface
847 ;;;
848 ;;; This function is called when there is some reason to believe that
849 ;;; the lambda Fun might be converted into a let. This is done after local
850 ;;; call analysis, and also when a reference is deleted. We only convert to a
851 ;;; let when the function is a normal local function, has no XEP, and is
852 ;;; referenced in exactly one local call. Conversion is also inhibited if the
853 ;;; only reference is in a block about to be deleted. We return true if we
854 ;;; converted.
855 ;;;
856 ;;; These rules may seem unnecessarily restrictive, since there are some
857 ;;; cases where we could do the return with a jump that don't satisfy these
858 ;;; requirements. The reason for doing things this way is that it makes the
859 ;;; concept of a let much more useful at the level of IR1 semantics. The
860 ;;; :ASSIGNMENT function kind provides another way to optimize calls to
861 ;;; single-return/multiple call functions.
862 ;;;
863 ;;; We don't attempt to convert calls to functions that have an XEP, since
864 ;;; we might be embarrassed later when we want to convert a newly discovered
865 ;;; local call.
866 ;;;
867 (defun maybe-let-convert (fun)
868 (declare (type clambda fun))
869 (let ((refs (leaf-refs fun)))
870 (when (and refs (null (rest refs))
871 (member (functional-kind fun) '(nil :assignment))
872 (not (functional-entry-function fun)))
873 (let* ((ref-cont (node-cont (first refs)))
874 (dest (continuation-dest ref-cont)))
875 (when (and (basic-combination-p dest)
876 (eq (basic-combination-fun dest) ref-cont)
877 (eq (basic-combination-kind dest) :local)
878 (not (block-delete-p (node-block dest))))
879 (let-convert fun dest)
880 (setf (functional-kind fun)
881 (if (mv-combination-p dest) :mv-let :let))))
882 t)))
883
884
885 ;;;; Tail local calls and assignments:
886
887 ;;; ONLY-HARMLESS-CLEANUPS -- Internal
888 ;;;
889 ;;; Return T if there are no cleanups between Block1 and Block2, or if they
890 ;;; definitely won't generate any cleanup code. Currently we recognize lexical
891 ;;; entry points that are only used locally (if at all).
892 ;;;
893 (defun only-harmless-cleanups (block1 block2)
894 (declare (type cblock block1 block2))
895 (or (eq block1 block2)
896 (let ((cleanup2 (block-start-cleanup block2)))
897 (do ((cleanup (block-end-cleanup block1)
898 (node-enclosing-cleanup (cleanup-mess-up cleanup))))
899 ((eq cleanup cleanup2) t)
900 (case (cleanup-kind cleanup)
901 ((:block :tagbody)
902 (unless (null (entry-exits (cleanup-mess-up cleanup)))
903 (return nil)))
904 (t (return nil)))))))
905
906
907 ;;; MAYBE-CONVERT-TAIL-LOCAL-CALL -- Interface
908 ;;;
909 ;;; If a potentially TR local call really is TR, then convert it to jump
910 ;;; directly to the called function. We also call MAYBE-CONVERT-TO-ASSIGNMENT.
911 ;;; We can switch the succesor (potentially deleting the RETURN node) unless:
912 ;;; -- The call has already been converted.
913 ;;; -- The call isn't TR (random implicit MV PROG1.)
914 ;;; -- The call is in an XEP (thus we might decide to make it non-tail so that
915 ;;; we can use known return inside the component.)
916 ;;; -- There is a change in the cleanup between the call in the return, so we
917 ;;; might need to introduce cleanup code.
918 ;;;
919 (defun maybe-convert-tail-local-call (call)
920 (declare (type combination call))
921 (let ((return (continuation-dest (node-cont call))))
922 (assert (return-p return))
923 (when (and (not (node-tail-p call))
924 (immediately-used-p (return-result return) call)
925 (not (eq (functional-kind (node-home-lambda call))
926 :external))
927 (only-harmless-cleanups (node-block call)
928 (node-block return)))
929 (node-ends-block call)
930 (let ((block (node-block call))
931 (fun (combination-lambda call)))
932 (setf (node-tail-p call) t)
933 (unlink-blocks block (first (block-succ block)))
934 (link-blocks block (node-block (lambda-bind fun)))
935 (values t (maybe-convert-to-assignment fun))))))
936
937
938 ;;; MAYBE-CONVERT-TO-ASSIGNMENT -- Interface
939 ;;;
940 ;;; Called when we believe it might make sense to convert Fun to an
941 ;;; assignment. All this function really does is determine when a function
942 ;;; with more than one call can still be combined with the calling function's
943 ;;; environment. We can convert when:
944 ;;; -- The function is a normal, non-entry function, and
945 ;;; -- Except for one call, all calls must be tail recursive calls in the
946 ;;; called function (i.e. are self-recursive tail calls)
947 ;;;
948 ;;; There may be one outside call, and it need not be tail-recursive. Since
949 ;;; all tail local calls have already been converted to direct transfers, the
950 ;;; only control semantics needed are to splice in the body at the non-tail
951 ;;; call. If there is no non-tail call, then we need only merge the
952 ;;; environments. Both cases are handled by LET-CONVERT.
953 ;;;
954 ;;; ### It would actually be possible to allow any number of outside calls as
955 ;;; long as they all return to the same place (i.e. have the same conceptual
956 ;;; continuation.) A special case of this would be when all of the outside
957 ;;; calls are tail recursive.
958 ;;;
959 (defun maybe-convert-to-assignment (fun)
960 (declare (type clambda fun))
961 (when (and (not (functional-kind fun))
962 (not (functional-entry-function fun)))
963 (let ((non-tail nil)
964 (call-fun nil))
965 (when (dolist (ref (leaf-refs fun) t)
966 (let ((dest (continuation-dest (node-cont ref))))
967 (when (block-delete-p (node-block dest)) (return nil))
968 (let ((home (node-home-lambda ref)))
969 (unless (eq home fun)
970 (when call-fun (return nil))
971 (setq call-fun home))
972 (unless (node-tail-p dest)
973 (when (or non-tail (eq home fun)) (return nil))
974 (setq non-tail dest)))))
975 (setf (functional-kind fun) :assignment)
976 (let-convert fun (or non-tail
977 (continuation-dest
978 (node-cont (first (leaf-refs fun))))))
979 t))))

  ViewVC Help
Powered by ViewVC 1.1.5