/[cmucl]/src/compiler/ir1opt.lisp
ViewVC logotype

Contents of /src/compiler/ir1opt.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.41 - (show annotations)
Wed Feb 19 16:15:21 1992 UTC (22 years, 2 months ago) by wlott
Branch: MAIN
Changes since 1.40: +5 -2 lines
Flame out when speed>=brevity if the transform is important.
1 ;;; -*- Package: C; Log: C.Log -*-
2 ;;;
3 ;;; **********************************************************************
4 ;;; This code was written as part of the CMU Common Lisp project at
5 ;;; Carnegie Mellon University, and has been placed in the public domain.
6 ;;; If you want to use this code or any part of CMU Common Lisp, please contact
7 ;;; Scott Fahlman or slisp-group@cs.cmu.edu.
8 ;;;
9 (ext:file-comment
10 "$Header: /tiger/var/lib/cvsroots/cmucl/src/compiler/ir1opt.lisp,v 1.41 1992/02/19 16:15:21 wlott Exp $")
11 ;;;
12 ;;; **********************************************************************
13 ;;;
14 ;;; This file implements the IR1 optimization phase of the compiler. IR1
15 ;;; optimization is a grab-bag of optimizations that don't make major changes
16 ;;; to the block-level control flow and don't use flow analysis. These
17 ;;; optimizations can mostly be classified as "meta-evaluation", but there is a
18 ;;; sizable top-down component as well.
19 ;;;
20 ;;; Written by Rob MacLachlan
21 ;;;
22 (in-package 'c)
23
24
25 ;;;; Interface for obtaining results of constant folding:
26
27 ;;; Constant-Continuation-P -- Interface
28 ;;;
29 ;;; Return true if the sole use of Cont is a reference to a constant leaf.
30 ;;;
31 (proclaim '(function constant-continuation-p (continuation) boolean))
32 (defun constant-continuation-p (cont)
33 (let ((use (continuation-use cont)))
34 (and (ref-p use)
35 (constant-p (ref-leaf use)))))
36
37
38 ;;; Continuation-Value -- Interface
39 ;;;
40 ;;; Return the constant value for a continuation whose only use is a
41 ;;; constant node.
42 ;;;
43 (proclaim '(function continuation-value (continuation) t))
44 (defun continuation-value (cont)
45 (assert (constant-continuation-p cont))
46 (constant-value (ref-leaf (continuation-use cont))))
47
48
49 ;;;; Interface for obtaining results of type inference:
50
51 ;;; CONTINUATION-PROVEN-TYPE -- Interface
52 ;;;
53 ;;; Return a (possibly values) type that describes what we have proven about
54 ;;; the type of Cont without taking any type assertions into consideration.
55 ;;; This is just the union of the NODE-DERIVED-TYPE of all the uses. Most
56 ;;; often people use CONTINUATION-DERIVED-TYPE or CONTINUATION-TYPE instead of
57 ;;; using this function directly.
58 ;;;
59 (defun continuation-proven-type (cont)
60 (declare (type continuation cont))
61 (ecase (continuation-kind cont)
62 ((:block-start :deleted-block-start)
63 (let ((uses (block-start-uses (continuation-block cont))))
64 (if uses
65 (do ((res (node-derived-type (first uses))
66 (values-type-union (node-derived-type (first current))
67 res))
68 (current (rest uses) (rest current)))
69 ((null current) res))
70 *empty-type*)))
71 (:inside-block
72 (node-derived-type (continuation-use cont)))))
73
74
75 ;;; Continuation-Derived-Type -- Interface
76 ;;;
77 ;;; Our best guess for the type of this continuation's value. Note that
78 ;;; this may be Values or Function type, which cannot be passed as an argument
79 ;;; to the normal type operations. See Continuation-Type. This may be called
80 ;;; on deleted continuations, always returning *.
81 ;;;
82 ;;; What we do is call CONTINUATION-PROVEN-TYPE and check whether the result
83 ;;; is a subtype of the assertion. If so, return the proven type and set
84 ;;; TYPE-CHECK to nil. Otherwise, return the intersection of the asserted and
85 ;;; proven types, and set TYPE-CHECK T. If TYPE-CHECK already has a non-null
86 ;;; value, then preserve it. Only in the somewhat unusual circumstance of
87 ;;; a newly discovered assertion will we change TYPE-CHECK from NIL to T.
88 ;;;
89 ;;; The result value is cached in the Continuation-%Derived-Type. If the
90 ;;; slot is true, just return that value, otherwise recompute and stash the
91 ;;; value there.
92 ;;;
93 (proclaim '(inline continuation-derived-type))
94 (defun continuation-derived-type (cont)
95 (declare (type continuation cont))
96 (or (continuation-%derived-type cont)
97 (%continuation-derived-type cont)))
98 ;;;
99 (defun %continuation-derived-type (cont)
100 (declare (type continuation cont))
101 (let ((proven (continuation-proven-type cont))
102 (asserted (continuation-asserted-type cont)))
103 (cond ((values-subtypep proven asserted)
104 (setf (continuation-%type-check cont) nil)
105 (setf (continuation-%derived-type cont) proven))
106 (t
107 (unless (or (continuation-%type-check cont)
108 (not (continuation-dest cont))
109 (eq asserted *universal-type*))
110 (setf (continuation-%type-check cont) t))
111
112 (setf (continuation-%derived-type cont)
113 (values-type-intersection asserted proven))))))
114
115
116 ;;; CONTINUATION-TYPE-CHECK -- Interface
117 ;;;
118 ;;; Call CONTINUATION-DERIVED-TYPE to make sure the slot is up to date, then
119 ;;; return it.
120 ;;;
121 (proclaim '(inline continuation-type-check))
122 (defun continuation-type-check (cont)
123 (declare (type continuation cont))
124 (continuation-derived-type cont)
125 (continuation-%type-check cont))
126
127
128 ;;; Continuation-Type -- Interface
129 ;;;
130 ;;; Return the derived type for Cont's first value. This is guaranteed not
131 ;;; to be a Values or Function type.
132 ;;;
133 (proclaim '(function continuation-type (continuation) ctype))
134 (defun continuation-type (cont)
135 (single-value-type (continuation-derived-type cont)))
136
137
138 ;;;; Interface routines used by optimizers:
139
140 ;;; Reoptimize-Continuation -- Interface
141 ;;;
142 ;;; This function is called by optimizers to indicate that something
143 ;;; interesting has happened to the value of Cont. Optimizers must make sure
144 ;;; that they don't call for reoptimization when nothing has happened, since
145 ;;; optimization will fail to terminate.
146 ;;;
147 ;;; We clear any cached type for the continuation and set the reoptimize
148 ;;; flags on everything in sight, unless the continuation is deleted (in which
149 ;;; case we do nothing.)
150 ;;;
151 ;;; Since this can get called curing IR1 conversion, we have to be careful
152 ;;; not to fly into space when the Dest's Prev is missing.
153 ;;;
154 (defun reoptimize-continuation (cont)
155 (declare (type continuation cont))
156 (unless (member (continuation-kind cont) '(:deleted :unused))
157 (setf (continuation-%derived-type cont) nil)
158 (let ((dest (continuation-dest cont)))
159 (when dest
160 (setf (continuation-reoptimize cont) t)
161 (setf (node-reoptimize dest) t)
162 (let ((prev (node-prev dest)))
163 (when prev
164 (let* ((block (continuation-block prev))
165 (component (block-component block)))
166 (when (typep dest 'cif)
167 (setf (block-test-modified block) t))
168 (setf (block-reoptimize block) t)
169 (setf (component-reoptimize component) t))))))
170 (do-uses (node cont)
171 (setf (block-type-check (node-block node)) t)))
172 (undefined-value))
173
174
175 ;;; Derive-Node-Type -- Interface
176 ;;;
177 ;;; Annotate Node to indicate that its result has been proven to be typep to
178 ;;; RType. After IR1 conversion has happened, this is the only correct way to
179 ;;; supply information discovered about a node's type. If you fuck with the
180 ;;; Node-Derived-Type directly, then information may be lost and reoptimization
181 ;;; may not happen.
182 ;;;
183 ;;; What we do is intersect Rtype with Node's Derived-Type. If the
184 ;;; intersection is different from the old type, then we do a
185 ;;; Reoptimize-Continuation on the Node-Cont.
186 ;;;
187 (defun derive-node-type (node rtype)
188 (declare (type node node) (type ctype rtype))
189 (let ((node-type (node-derived-type node)))
190 (unless (eq node-type rtype)
191 (let ((int (values-type-intersection node-type rtype)))
192 (when (type/= node-type int)
193 (when (and *check-consistency*
194 (eq int *empty-type*)
195 (not (eq rtype *empty-type*)))
196 (let ((*compiler-error-context* node))
197 (compiler-warning
198 "New inferred type ~S conflicts with old type:~
199 ~% ~S~%*** Bug?"
200 (type-specifier rtype) (type-specifier node-type))))
201 (setf (node-derived-type node) int)
202 (reoptimize-continuation (node-cont node))))))
203 (undefined-value))
204
205
206 ;;; Assert-Continuation-Type -- Interface
207 ;;;
208 ;;; Similar to Derive-Node-Type, but asserts that it is an error for Cont's
209 ;;; value not to be typep to Type. If we improve the assertion, we set
210 ;;; TYPE-CHECK and TYPE-ASSERTED to guarantee that the new assertion will be
211 ;;; checked.
212 ;;;
213 (defun assert-continuation-type (cont type)
214 (declare (type continuation cont) (type ctype type))
215 (let ((cont-type (continuation-asserted-type cont)))
216 (unless (eq cont-type type)
217 (let ((int (values-type-intersection cont-type type)))
218 (when (type/= cont-type int)
219 (setf (continuation-asserted-type cont) int)
220 (do-uses (node cont)
221 (setf (block-attributep (block-flags (node-block node))
222 type-check type-asserted)
223 t))
224 (reoptimize-continuation cont)))))
225 (undefined-value))
226
227
228 ;;; Assert-Call-Type -- Interface
229 ;;;
230 ;;; Assert that Call is to a function of the specified Type. It is assumed
231 ;;; that the call is legal and has only constants in the keyword positions.
232 ;;;
233 (defun assert-call-type (call type)
234 (declare (type combination call) (type function-type type))
235 (derive-node-type call (function-type-returns type))
236 (let ((args (combination-args call)))
237 (dolist (req (function-type-required type))
238 (when (null args) (return-from assert-call-type))
239 (let ((arg (pop args)))
240 (assert-continuation-type arg req)))
241 (dolist (opt (function-type-optional type))
242 (when (null args) (return-from assert-call-type))
243 (let ((arg (pop args)))
244 (assert-continuation-type arg opt)))
245
246 (let ((rest (function-type-rest type)))
247 (when rest
248 (dolist (arg args)
249 (assert-continuation-type arg rest))))
250
251 (dolist (key (function-type-keywords type))
252 (let ((name (key-info-name key)))
253 (do ((arg args (cddr arg)))
254 ((null arg))
255 (when (eq (continuation-value (first arg)) name)
256 (assert-continuation-type
257 (second arg) (key-info-type key)))))))
258 (undefined-value))
259
260
261 ;;; IR1-Optimize -- Interface
262 ;;;
263 ;;; Do one forward pass over Component, deleting unreachable blocks and
264 ;;; doing IR1 optimizations. We can ignore all blocks that don't have the
265 ;;; Reoptimize flag set. If Component-Reoptimize is true when we are done,
266 ;;; then another iteration would be beneficial.
267 ;;;
268 ;;; We delete blocks when there is either no predecessor or the block is in
269 ;;; a lambda that has been deleted. These blocks would eventually be deleted
270 ;;; by DFO recomputation, but doing it here immediately makes the effect
271 ;;; avaliable to IR1 optimization.
272 ;;;
273 (defun ir1-optimize (component)
274 (declare (type component component))
275 (setf (component-reoptimize component) nil)
276 (do-blocks (block component)
277 (cond
278 ((or (block-delete-p block)
279 (null (block-pred block))
280 (eq (functional-kind (block-home-lambda block)) :deleted))
281 (delete-block block))
282 (t
283 (loop
284 (let ((succ (block-succ block)))
285 (unless (and succ (null (rest succ)))
286 (return)))
287
288 (let ((last (block-last block)))
289 (typecase last
290 (cif
291 (flush-dest (if-test last))
292 (when (unlink-node last) (return)))
293 (exit
294 (when (maybe-delete-exit last) (return)))))
295
296 (unless (join-successor-if-possible block)
297 (return)))
298
299 (when (and (block-reoptimize block) (block-component block))
300 (assert (not (block-delete-p block)))
301 (ir1-optimize-block block))
302
303 (when (and (block-flush-p block) (block-component block))
304 (assert (not (block-delete-p block)))
305 (flush-dead-code block)))))
306
307 (undefined-value))
308
309
310 ;;; IR1-Optimize-Block -- Internal
311 ;;;
312 ;;; Loop over the nodes in Block, looking for stuff that needs to be
313 ;;; optimized. We dispatch off of the type of each node with its reoptimize
314 ;;; flag set:
315 ;;; -- With a combination, we call Propagate-Function-Change whenever the
316 ;;; function changes, and call IR1-Optimize-Combination if any argument
317 ;;; changes.
318 ;;; -- With an Exit, we derive the node's type from the Value's type. We don't
319 ;;; propagate Cont's assertion to the Value, since if we did, this would
320 ;;; move the checking of Cont's assertion to the exit. This wouldn't work
321 ;;; with Catch and UWP, where the Exit node is just a placeholder for the
322 ;;; actual unknown exit.
323 ;;;
324 ;;; Note that we clear the node & block reoptimize flags *before* doing the
325 ;;; optimization. This ensures that the node or block will be reoptimized if
326 ;;; necessary. We leave the NODE-OPTIMIZE flag set going into
327 ;;; IR1-OPTIMIZE-RETURN, since it wants to clear the flag itself.
328 ;;;
329 (defun ir1-optimize-block (block)
330 (declare (type cblock block))
331 (setf (block-reoptimize block) nil)
332 (do-nodes (node cont block :restart-p t)
333 (when (node-reoptimize node)
334 (setf (node-reoptimize node) nil)
335 (typecase node
336 (ref)
337 (combination
338 (when (continuation-reoptimize (basic-combination-fun node))
339 (propagate-function-change node))
340 (ir1-optimize-combination node)
341 (unless (node-deleted node)
342 (maybe-terminate-block node nil)))
343 (cif
344 (ir1-optimize-if node))
345 (creturn
346 (setf (node-reoptimize node) t)
347 (ir1-optimize-return node))
348 (mv-combination
349 (ir1-optimize-mv-combination node))
350 (exit
351 (let ((value (exit-value node)))
352 (when value
353 (derive-node-type node (continuation-derived-type value)))))
354 (cset
355 (ir1-optimize-set node)))))
356 (undefined-value))
357
358
359 ;;; Join-Successor-If-Possible -- Internal
360 ;;;
361 ;;; We cannot combine with a successor block if:
362 ;;; 1] The successor has more than one predecessor.
363 ;;; 2] The last node's Cont is also used somewhere else.
364 ;;; 3] The successor is the current block (infinite loop).
365 ;;; 4] The next block has a different cleanup, and thus we may want to insert
366 ;;; cleanup code between the two blocks at some point.
367 ;;; 5] The next block has a different home lambda, and thus the control
368 ;;; transfer is a non-local exit.
369 ;;;
370 ;;; If we succeed, we return true, otherwise false.
371 ;;;
372 ;;; Joining is easy when the successor's Start continuation is the same from
373 ;;; our Last's Cont. If they differ, then we can still join when the last
374 ;;; continuation has no next and the next continuation has no uses. In this
375 ;;; case, we replace the next continuation with the last before joining the
376 ;;; blocks.
377 ;;;
378 (defun join-successor-if-possible (block)
379 (declare (type cblock block))
380 (let ((next (first (block-succ block))))
381 (when (block-start next)
382 (let* ((last (block-last block))
383 (last-cont (node-cont last))
384 (next-cont (block-start next)))
385 (cond ((or (rest (block-pred next))
386 (not (eq (continuation-use last-cont) last))
387 (eq next block)
388 (not (eq (block-end-cleanup block)
389 (block-start-cleanup next)))
390 (not (eq (block-home-lambda block)
391 (block-home-lambda next))))
392 nil)
393 ((eq last-cont next-cont)
394 (join-blocks block next)
395 t)
396 ((and (null (block-start-uses next))
397 (eq (continuation-kind last-cont) :inside-block))
398 (let ((next-node (continuation-next next-cont)))
399 ;;
400 ;; If next-cont does have a dest, it must be unreachable,
401 ;; since there are no uses. DELETE-CONTINUATION will mark the
402 ;; dest block as delete-p [and also this block, unless it is
403 ;; no longer backward reachable from the dest block.]
404 (delete-continuation next-cont)
405 (setf (node-prev next-node) last-cont)
406 (setf (continuation-next last-cont) next-node)
407 (setf (block-start next) last-cont)
408 (join-blocks block next))
409 t)
410 (t
411 nil))))))
412
413
414 ;;; Join-Blocks -- Internal
415 ;;;
416 ;;; Join together two blocks which have the same ending/starting
417 ;;; continuation. The code in Block2 is moved into Block1 and Block2 is
418 ;;; deleted from the DFO. We combine the optimize flags for the two blocks so
419 ;;; that any indicated optimization gets done.
420 ;;;
421 (defun join-blocks (block1 block2)
422 (declare (type cblock block1 block2))
423 (let* ((last (block-last block2))
424 (last-cont (node-cont last))
425 (succ (block-succ block2))
426 (start2 (block-start block2)))
427 (do ((cont start2 (node-cont (continuation-next cont))))
428 ((eq cont last-cont)
429 (when (eq (continuation-kind last-cont) :inside-block)
430 (setf (continuation-block last-cont) block1)))
431 (setf (continuation-block cont) block1))
432
433 (unlink-blocks block1 block2)
434 (dolist (block succ)
435 (unlink-blocks block2 block)
436 (link-blocks block1 block))
437
438 (setf (block-last block1) last)
439 (setf (continuation-kind start2) :inside-block))
440
441 (setf (block-flags block1)
442 (attributes-union (block-flags block1)
443 (block-flags block2)
444 (block-attributes type-asserted test-modified)))
445
446 (let ((next (block-next block2))
447 (prev (block-prev block2)))
448 (setf (block-next prev) next)
449 (setf (block-prev next) prev))
450
451 (undefined-value))
452
453
454 ;;;; Local call return type propagation:
455
456 ;;; Find-Result-Type -- Internal
457 ;;;
458 ;;; This function is called on RETURN nodes that have their REOPTIMIZE flag
459 ;;; set. It iterates over the uses of the RESULT, looking for interesting
460 ;;; stuff to update the TAIL-SET:
461 ;;; -- If a use is a tail local call, then we check that the called function
462 ;;; has the tail set Tails. If we encounter any different tail set, we
463 ;;; return true. If NODE-TAIL-P is not set, we also call
464 ;;; CONVERT-TAIL-LOCAL-CALL, which changes the succesor of the call to be
465 ;;; the called function and checks if the call can become an assignment.
466 ;;; -- If a use isn't a local call, then we union its type together with the
467 ;;; types of other such uses. We assign to the RETURN-RESULT-TYPE the
468 ;;; intersection of this type with the RESULT's asserted type. We can make
469 ;;; this intersection now (potentially before type checking) because this
470 ;;; assertion on the result will eventually be checked (if appropriate.)
471 ;;;
472 (defun find-result-type (node tails)
473 (declare (type creturn node))
474 (let ((result (return-result node))
475 (retry nil))
476 (collect ((use-union *empty-type* values-type-union))
477 (do-uses (use result)
478 (cond ((and (basic-combination-p use)
479 (eq (basic-combination-kind use) :local)
480 (immediately-used-p result use))
481 (when (merge-tail-sets use tails)
482 (setq retry t))
483 (when (combination-p use)
484 (maybe-convert-tail-local-call use)))
485 (t
486 (use-union (node-derived-type use)))))
487 (let ((int (values-type-intersection
488 (continuation-asserted-type result)
489 (use-union))))
490 (setf (return-result-type node) int)))
491 retry))
492
493
494 ;;; Merge-Tail-Sets -- Internal
495 ;;;
496 ;;; This function handles merging the tail sets if Call is a call to a
497 ;;; function with a different TAIL-SET than Ret-Set. We return true if we do
498 ;;; anything.
499 ;;;
500 ;;; It is assumed that Call sends its value to a RETURN node. We
501 ;;; destructively modify the set for the returning function to represent both,
502 ;;; and then change all the functions in callee's set to reference the first.
503 ;;;
504 (defun merge-tail-sets (call ret-set)
505 (declare (type basic-combination call) (type tail-set ret-set))
506 (let ((fun-set (lambda-tail-set (combination-lambda call))))
507 (unless (eq ret-set fun-set)
508 (let ((funs (tail-set-functions fun-set)))
509 (dolist (fun funs)
510 (setf (lambda-tail-set fun) ret-set))
511 (setf (tail-set-functions ret-set)
512 (nconc (tail-set-functions ret-set) funs)))
513 t)))
514
515
516 ;;; IR1-Optimize-Return -- Internal
517 ;;;
518 ;;; Do stuff to realize that something has changed about the value delivered
519 ;;; to a return node. Since we consider the return values of all functions in
520 ;;; the tail set to be equivalent, this amounts to bringing the entire tail set
521 ;;; up to date. We iterate over the returns for all the functions in the tail
522 ;;; set, reanalyzing them all (not treating Node specially.)
523 ;;;
524 ;;; During this iteration, we may discover new functions that should be
525 ;;; added to the tail set. If this happens, we restart the iteration over the
526 ;;; TAIL-SET-FUNCTIONS. Note that this really doesn't duplicate much work, as
527 ;;; we clear the NODE-REOPTIMIZE flags in the return nodes as we go, thus we
528 ;;; don't call FIND-RESULT-TYPE on any given return more than once.
529 ;;;
530 ;;; Restarting the iteration doesn't disturb the computation of the result
531 ;;; type RES, since we will just be adding more types to the union. (or when
532 ;;; we iterate over a return multiple times, unioning in the same type more
533 ;;; than once.)
534 ;;;
535 ;;; When we are done, we check if the new type is different from the old
536 ;;; TAIL-SET-TYPE. If so, we set the type and also reoptimize all the
537 ;;; continuations for references to functions in the tail set. This will
538 ;;; cause IR1-OPTIMIZE-COMBINATION to derive the new type as the results of the
539 ;;; calls.
540 ;;;
541 (defun ir1-optimize-return (node)
542 (declare (type creturn node))
543 (let ((tails (lambda-tail-set (return-lambda node))))
544 (collect ((res *empty-type* values-type-union))
545 (loop
546 (block RETRY
547 (let ((funs (tail-set-functions tails)))
548 (dolist (fun funs)
549 (let ((return (lambda-return fun)))
550 (when return
551 (when (node-reoptimize return)
552 (setf (node-reoptimize node) nil)
553 (when (find-result-type return tails) (return-from RETRY)))
554 (res (return-result-type return))))))
555 (return)))
556
557 (when (type/= (res) (tail-set-type tails))
558 (setf (tail-set-type tails) (res))
559 (dolist (fun (tail-set-functions tails))
560 (dolist (ref (leaf-refs fun))
561 (reoptimize-continuation (node-cont ref)))))))
562
563 (undefined-value))
564
565
566 ;;; IR1-Optimize-If -- Internal
567 ;;;
568 ;;; If the test has multiple uses, replicate the node when possible. Also
569 ;;; check if the predicate is known to be true or false, deleting the IF node
570 ;;; in favor of the appropriate branch when this is the case.
571 ;;;
572 (defun ir1-optimize-if (node)
573 (declare (type cif node))
574 (let ((test (if-test node))
575 (block (node-block node)))
576
577 (when (and (eq (block-start block) test)
578 (eq (continuation-next test) node)
579 (rest (block-start-uses block)))
580 (do-uses (use test)
581 (when (immediately-used-p test use)
582 (convert-if-if use node)
583 (when (continuation-use test) (return)))))
584
585 (let* ((type (continuation-type test))
586 (victim
587 (cond ((constant-continuation-p test)
588 (if (continuation-value test)
589 (if-alternative node)
590 (if-consequent node)))
591 ((not (types-intersect type *null-type*))
592 (if-alternative node))
593 ((type= type *null-type*)
594 (if-consequent node)))))
595 (when victim
596 (flush-dest test)
597 (when (rest (block-succ block))
598 (unlink-blocks block victim))
599 (setf (component-reanalyze (block-component (node-block node))) t)
600 (unlink-node node))))
601 (undefined-value))
602
603
604 ;;; Convert-If-If -- Internal
605 ;;;
606 ;;; Create a new copy of an IF Node that tests the value of the node Use.
607 ;;; The test must have >1 use, and must be immediately used by Use. Node must
608 ;;; be the only node in its block (implying that block-start = if-test).
609 ;;;
610 ;;; This optimization has an effect semantically similar to the
611 ;;; source-to-source transformation:
612 ;;; (IF (IF A B C) D E) ==>
613 ;;; (IF A (IF B D E) (IF C D E))
614 ;;;
615 (defun convert-if-if (use node)
616 (declare (type node use) (type cif node))
617 (with-ir1-environment node
618 (let* ((block (node-block node))
619 (test (if-test node))
620 (cblock (if-consequent node))
621 (ablock (if-alternative node))
622 (use-block (node-block use))
623 (dummy-cont (make-continuation))
624 (new-cont (make-continuation))
625 (new-node (make-if :test new-cont
626 :consequent cblock :alternative ablock))
627 (new-block (continuation-starts-block new-cont)))
628 (prev-link new-node new-cont)
629 (setf (continuation-dest new-cont) new-node)
630 (add-continuation-use new-node dummy-cont)
631 (setf (block-last new-block) new-node)
632
633 (unlink-blocks use-block block)
634 (delete-continuation-use use)
635 (add-continuation-use use new-cont)
636 (link-blocks use-block new-block)
637
638 (link-blocks new-block cblock)
639 (link-blocks new-block ablock)
640
641 (reoptimize-continuation test)
642 (reoptimize-continuation new-cont)
643 (setf (component-reanalyze *current-component*) t)))
644 (undefined-value))
645
646
647 ;;;; Exit IR1 optimization:
648
649 ;;; Maybe-Delete-Exit -- Interface
650 ;;;
651 ;;; This function attempts to delete an exit node, returning true if it
652 ;;; deletes the block as a consequence:
653 ;;; -- If the exit is degenerate (has no Entry), then we don't do anything,
654 ;;; since there is nothing to be done.
655 ;;; -- If the exit node and its Entry have the same home lambda then we know
656 ;;; the exit is local, and can delete the exit. We change uses of the
657 ;;; Exit-Value to be uses of the original continuation, then unlink the
658 ;;; node.
659 ;;; -- If there is no value (as in a GO), then we skip the value semantics.
660 ;;;
661 ;;; This function is also called by environment analysis, since it wants all
662 ;;; exits to be optimized even if normal optimization was omitted.
663 ;;;
664 (defun maybe-delete-exit (node)
665 (declare (type exit node))
666 (let ((value (exit-value node))
667 (entry (exit-entry node))
668 (cont (node-cont node)))
669 (when (and entry
670 (eq (node-home-lambda node) (node-home-lambda entry)))
671 (setf (entry-exits entry) (delete node (entry-exits entry)))
672 (prog1
673 (unlink-node node)
674 (when value
675 (substitute-continuation-uses cont value))))))
676
677
678 ;;;; Combination IR1 optimization:
679
680 ;;; Ir1-Optimize-Combination -- Internal
681 ;;;
682 ;;; Do IR1 optimizations on a Combination node.
683 ;;;
684 (proclaim '(function ir1-optimize-combination (combination) void))
685 (defun ir1-optimize-combination (node)
686 (let ((args (basic-combination-args node))
687 (kind (basic-combination-kind node)))
688 (case kind
689 (:local
690 (let ((fun (combination-lambda node)))
691 (if (eq (functional-kind fun) :let)
692 (propagate-let-args node fun)
693 (propagate-local-call-args node fun))))
694 (:full
695 (dolist (arg args)
696 (when arg
697 (setf (continuation-reoptimize arg) nil))))
698 (t
699 (dolist (arg args)
700 (when arg
701 (setf (continuation-reoptimize arg) nil)))
702
703 (let ((attr (function-info-attributes kind)))
704 (when (and (ir1-attributep attr foldable)
705 (not (ir1-attributep attr call))
706 (every #'constant-continuation-p args)
707 (continuation-dest (node-cont node)))
708 (constant-fold-call node)
709 (return-from ir1-optimize-combination)))
710
711 (let ((fun (function-info-derive-type kind)))
712 (when fun
713 (let ((res (funcall fun node)))
714 (when res
715 (derive-node-type node res)))))
716
717 (let ((fun (function-info-optimizer kind)))
718 (unless (and fun (funcall fun node))
719 (dolist (x (function-info-transforms kind))
720 (unless (ir1-transform node x)
721 (return))))))))
722
723 (undefined-value))
724
725
726 ;;; MAYBE-TERMINATE-BLOCK -- Interface
727 ;;;
728 ;;; If Call is to a function that doesn't return (type NIL), then terminate
729 ;;; the block there, and link it to the component tail. We also change the
730 ;;; call's CONT to be a dummy continuation to prevent the use from confusing
731 ;;; things.
732 ;;;
733 ;;; Except when called during IR1, we delete the continuation if it has no
734 ;;; other uses. (If it does have other uses, we reoptimize.)
735 ;;;
736 ;;; Termination on the basis of a continuation type assertion is inhibited
737 ;;; when:
738 ;;; -- The continuation is deleted (hence the assertion is spurious), or
739 ;;; -- We are in IR1 conversion (where THE assertions are subject to
740 ;;; weakening.)
741 ;;;
742 (defun maybe-terminate-block (call ir1-p)
743 (declare (type basic-combination call))
744 (let* ((block (node-block call))
745 (cont (node-cont call))
746 (tail (component-tail (block-component block)))
747 (succ (first (block-succ block))))
748 (unless (or (and (eq call (block-last block)) (eq succ tail))
749 (block-delete-p block))
750 (when (or (and (eq (continuation-asserted-type cont) *empty-type*)
751 (not (or ir1-p (eq (continuation-kind cont) :deleted))))
752 (eq (node-derived-type call) *empty-type*))
753 (cond (ir1-p
754 (delete-continuation-use call)
755 (cond
756 ((block-last block)
757 (assert (and (eq (block-last block) call)
758 (eq (continuation-kind cont) :block-start))))
759 (t
760 (setf (block-last block) call)
761 (link-blocks block (continuation-starts-block cont)))))
762 (t
763 (node-ends-block call)
764 (delete-continuation-use call)
765 (if (eq (continuation-kind cont) :unused)
766 (delete-continuation cont)
767 (reoptimize-continuation cont))))
768
769 (unlink-blocks block (first (block-succ block)))
770 (assert (not (block-succ block)))
771 (link-blocks block tail)
772 (add-continuation-use call (make-continuation))
773 t))))
774
775
776 ;;; Recognize-Known-Call -- Interface
777 ;;;
778 ;;; If Call is a call to a known function, mark it as such by setting the
779 ;;; Kind. In addition to a direct check for the function name in the table, we
780 ;;; also must check for slot accessors. If the function is a slot accessor,
781 ;;; then we set the combination kind to the function info of %Slot-Setter or
782 ;;; %Slot-Accessor, as appropriate.
783 ;;;
784 ;;; If convert-again is true, and the function has a source-transform or
785 ;;; inline-expansion, or if the function is conditional, and the destination of
786 ;;; the value is not an IF, then instead of making the existing call known, we
787 ;;; change it to be a call to a lambda that just re-calls the function. This
788 ;;; gives IR1 transformation another go at the call, in the case where the call
789 ;;; wasn't obviously known during the initial IR1 conversion.
790 ;;;
791 (defun recognize-known-call (call &optional convert-again)
792 (declare (type combination call))
793 (let* ((fun (basic-combination-fun call))
794 (name (continuation-function-name fun)))
795 (when name
796 (let ((info (info function info name)))
797 (cond
798 ((and info convert-again
799 (or (info function source-transform name)
800 (info function inline-expansion name)
801 (and (ir1-attributep (function-info-attributes info)
802 predicate)
803 (let ((dest (continuation-dest (node-cont call))))
804 (and dest (not (if-p dest)))))))
805 (let ((dums (loop repeat (length (combination-args call))
806 collect (gensym))))
807 (transform-call call
808 `(lambda ,dums
809 (,name ,@dums)))))
810 (info
811 (setf (basic-combination-kind call) info))
812 ((slot-accessor-p (ref-leaf (continuation-use fun)))
813 (setf (basic-combination-kind call)
814 (info function info
815 (if (consp name)
816 '%slot-setter
817 '%slot-accessor))))))))
818 (undefined-value))
819
820
821 ;;; Propagate-Function-Change -- Internal
822 ;;;
823 ;;; Called by Ir1-Optimize when the function for a call has changed.
824 ;;; If the call is to a functional, then we attempt to convert it to a local
825 ;;; call, otherwise we check the call for legality with respect to the new
826 ;;; type; if it is illegal, we mark the Ref as :Notline and punt.
827 ;;;
828 ;;; If we do have a good type for the call, we propagate type information from
829 ;;; the type to the arg and result continuations. If we discover that the call
830 ;;; is to a known global function, then we mark the combination as known.
831 ;;;
832 (defun propagate-function-change (call)
833 (declare (type combination call))
834 (let* ((fun (combination-fun call))
835 (use (continuation-use fun))
836 (type (continuation-derived-type fun))
837 (*compiler-error-context* call))
838 (setf (continuation-reoptimize fun) nil)
839 (cond ((or (not (ref-p use))
840 (eq (ref-inlinep use) :notinline)))
841 ((functional-p (ref-leaf use))
842 (let ((leaf (ref-leaf use)))
843 (cond ((eq (combination-kind call) :local)
844 (unless (member (functional-kind leaf)
845 '(:let :assignment :deleted))
846 (derive-node-type
847 call (tail-set-type (lambda-tail-set leaf)))))
848 ((not (eq (ref-inlinep use) :notinline))
849 (convert-call-if-possible use call)
850 (maybe-let-convert leaf)))))
851 ((not (function-type-p type)))
852 ((valid-function-use call type
853 :argument-test #'always-subtypep
854 :result-test #'always-subtypep
855 :error-function #'compiler-warning
856 :warning-function #'compiler-note)
857 (assert-call-type call type)
858 (recognize-known-call call t))
859 (t
860 (setf (ref-inlinep use) :notinline))))
861
862 (undefined-value))
863
864
865 ;;;; Known function optimization:
866
867 ;;;
868 ;;; A hashtable from combination nodes to things describing how an
869 ;;; optimization of the node failed. The value is an alist (Transform . Args),
870 ;;; where Transform is the structure describing the transform that failed, and
871 ;;; Args is either a list of format arguments for the note, or the
872 ;;; FUNCTION-TYPE that would have enabled the transformation but failed to
873 ;;; match.
874 ;;;
875 (defvar *failed-optimizations* (make-hash-table :test #'eq))
876
877
878 ;;; RECORD-OPTIMIZATION-FAILURE -- Internal
879 ;;;
880 ;;; Add a failed optimization note to *FAILED-OPTIMZATIONS* for Node, Fun
881 ;;; and Args. If there is already a note for Node and Transform, replace it,
882 ;;; otherwise add a new one.
883 ;;;
884 (defun record-optimization-failure (node transform args)
885 (declare (type combination node) (type transform transform)
886 (type (or function-type list) args))
887 (let ((found (assoc transform (gethash node *failed-optimizations*))))
888 (if found
889 (setf (cdr found) args)
890 (push (cons transform args)
891 (gethash node *failed-optimizations*))))
892 (undefined-value))
893
894
895 ;;; IR1-Transform -- Internal
896 ;;;
897 ;;; Attempt to transform Node using Function, subject to the call type
898 ;;; constraint Type. If we are inhibited from doing the transform for some
899 ;;; reason and Flame is true, then we make a note of the message in
900 ;;; *failed-optimizations* for IR1 finalize to pick up. We return true if
901 ;;; the transform failed, and thus further transformation should be
902 ;;; attempted. We return false if either the transform suceeded or was
903 ;;; aborted.
904 ;;;
905 (defun ir1-transform (node transform)
906 (declare (type combination node) (type transform transform))
907 (let* ((type (transform-type transform))
908 (fun (transform-function transform))
909 (constrained (function-type-p type))
910 (flame
911 (if (transform-important transform)
912 (policy node (>= speed brevity))
913 (policy node (> speed brevity))))
914 (*compiler-error-context* node))
915 (cond ((or (not constrained)
916 (valid-function-use node type :strict-result t))
917 (multiple-value-bind
918 (severity args)
919 (catch 'give-up
920 (transform-call node (funcall fun node))
921 (values :none nil))
922 (ecase severity
923 (:none
924 (remhash node *failed-optimizations*)
925 nil)
926 (:aborted
927 (setf (combination-kind node) :full)
928 (setf (ref-inlinep (continuation-use (combination-fun node)))
929 :notinline)
930 (when args
931 (apply #'compiler-warning args))
932 (remhash node *failed-optimizations*)
933 nil)
934 (:failure
935 (if args
936 (when flame
937 (record-optimization-failure node transform args))
938 (setf (gethash node *failed-optimizations*)
939 (remove transform
940 (gethash node *failed-optimizations*)
941 :key #'car)))
942 t))))
943 ((and flame
944 (valid-function-use node type
945 :argument-test #'types-intersect
946 :result-test #'values-types-intersect))
947 (record-optimization-failure node transform type)
948 t)
949 (t
950 t))))
951
952
953 ;;; GIVE-UP, ABORT-TRANSFORM -- Interface
954 ;;;
955 ;;; Just throw the severity and args...
956 ;;;
957 (proclaim '(function give-up (&rest t) nil))
958 (defun give-up (&rest args)
959 "This function is used to throw out of an IR1 transform, aborting this
960 attempt to transform the call, but admitting the possibility that this or
961 some other transform will later suceed. If arguments are supplied, they are
962 format arguments for an efficiency note."
963 (throw 'give-up (values :failure args)))
964 ;;;
965 (defun abort-transform (&rest args)
966 "This function is used to throw out of an IR1 transform and force a normal
967 call to the function at run time. No further optimizations will be
968 attempted."
969 (throw 'give-up (values :aborted args)))
970
971
972 ;;; Transform-Call -- Internal
973 ;;;
974 ;;; Take the lambda-expression Res, IR1 convert it in the proper
975 ;;; environment, and then install it as the function for the call Node. We do
976 ;;; local call analysis so that the new function is integrated into the control
977 ;;; flow. We set the Reanalyze flag in the component to cause the DFO to be
978 ;;; recomputed at soonest convenience.
979 ;;;
980 (defun transform-call (node res)
981 (declare (type combination node) (list res))
982 (with-ir1-environment node
983 (let ((new-fun (ir1-convert-global-lambda res))
984 (ref (continuation-use (combination-fun node))))
985 (change-ref-leaf ref new-fun)
986 (setf (combination-kind node) :full)
987 (local-call-analyze *current-component*)))
988 (undefined-value))
989
990
991 ;;; Constant-Fold-Call -- Internal
992 ;;;
993 ;;; Replace a call to a foldable function of constant arguments with the
994 ;;; result of evaluating the form. We insert the resulting constant node after
995 ;;; the call, stealing the call's continuation. We give the call a
996 ;;; continuation with no Dest, which should cause it and its arguments to go
997 ;;; away. If there is an error during the evaluation, we give a warning and
998 ;;; leave the call alone, making the call a full call and marking it as
999 ;;; :notinline to make sure that it stays that way.
1000 ;;;
1001 ;;; For now, if the result is other than one value, we don't fold it.
1002 ;;;
1003 (defun constant-fold-call (call)
1004 (declare (type combination call))
1005 (let* ((args (mapcar #'continuation-value (combination-args call)))
1006 (ref (continuation-use (combination-fun call)))
1007 (fun (leaf-name (ref-leaf ref))))
1008
1009 (multiple-value-bind (values win)
1010 (careful-call fun args call "constant folding")
1011 (cond
1012 ((not win)
1013 (setf (ref-inlinep ref) :notinline)
1014 (setf (combination-kind call) :full))
1015 ((= (length values) 1)
1016 (with-ir1-environment call
1017 (when (producing-fasl-file)
1018 (maybe-emit-make-load-forms (first values)))
1019 (let* ((leaf (find-constant (first values)))
1020 (node (make-ref (leaf-type leaf)
1021 leaf
1022 nil))
1023 (dummy (make-continuation))
1024 (cont (node-cont call))
1025 (block (node-block call))
1026 (next (continuation-next cont)))
1027 (push node (leaf-refs leaf))
1028 (setf (leaf-ever-used leaf) t)
1029
1030 (delete-continuation-use call)
1031 (add-continuation-use call dummy)
1032 (prev-link node dummy)
1033 (add-continuation-use node cont)
1034 (setf (continuation-next cont) next)
1035 (when (eq call (block-last block))
1036 (setf (block-last block) node))
1037 (reoptimize-continuation cont))))
1038 (t
1039 (let ((dummies (loop repeat (length args)
1040 collect (gensym))))
1041 (transform-call
1042 call
1043 `(lambda ,dummies
1044 (declare (ignore ,@dummies))
1045 (values ,@(mapcar #'(lambda (x) `',x) values)))))))))
1046
1047 (undefined-value))
1048
1049
1050 ;;;; Local call optimization:
1051
1052 ;;; Propagate-To-Refs -- Internal
1053 ;;;
1054 ;;; Propagate Type to Leaf and its Refs, marking things changed. If the
1055 ;;; leaf type is a function type, then just leave it alone, since TYPE is never
1056 ;;; going to be more specific than that (and TYPE-INTERSECTION would choke.)
1057 ;;;
1058 (defun propagate-to-refs (leaf type)
1059 (declare (type leaf leaf) (type ctype type))
1060 (let ((var-type (leaf-type leaf)))
1061 (unless (function-type-p var-type)
1062 (let ((int (type-intersection var-type type)))
1063 (when (type/= int var-type)
1064 (setf (leaf-type leaf) int)
1065 (dolist (ref (leaf-refs leaf))
1066 (derive-node-type ref int))))
1067 (undefined-value))))
1068
1069
1070 ;;; PROPAGATE-FROM-SETS -- Internal
1071 ;;;
1072 ;;; Figure out the type of a LET variable that has sets. We compute the
1073 ;;; union of the initial value Type and the types of all the set values and to
1074 ;;; a PROPAGATE-TO-REFS with this type.
1075 ;;;
1076 (defun propagate-from-sets (var type)
1077 (collect ((res type type-union))
1078 (dolist (set (basic-var-sets var))
1079 (res (continuation-type (set-value set)))
1080 (setf (node-reoptimize set) nil))
1081 (propagate-to-refs var (res)))
1082 (undefined-value))
1083
1084
1085 ;;; IR1-OPTIMIZE-SET -- Internal
1086 ;;;
1087 ;;; If a let variable, find the initial value's type and do
1088 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's type.
1089 ;;;
1090 (defun ir1-optimize-set (node)
1091 (declare (type cset node))
1092 (let ((var (set-var node)))
1093 (when (and (lambda-var-p var) (leaf-refs var))
1094 (let ((home (lambda-var-home var)))
1095 (when (eq (functional-kind home) :let)
1096 (let ((iv (let-var-initial-value var)))
1097 (setf (continuation-reoptimize iv) nil)
1098 (propagate-from-sets var (continuation-type iv)))))))
1099
1100 (derive-node-type node (continuation-type (set-value node)))
1101 (undefined-value))
1102
1103
1104 ;;; CONSTANT-REFERENCE-P -- Interface
1105 ;;;
1106 ;;; Return true if the value of Ref will always be the same (and is thus
1107 ;;; legal to substitute.)
1108 ;;;
1109 (defun constant-reference-p (ref)
1110 (declare (type ref ref))
1111 (let ((leaf (ref-leaf ref)))
1112 (typecase leaf
1113 (constant t)
1114 (functional t)
1115 (lambda-var
1116 (null (lambda-var-sets leaf)))
1117 (global-var
1118 (case (global-var-kind leaf)
1119 (:global-function
1120 (not (eq (ref-inlinep ref) :notinline)))
1121 (:constant t))))))
1122
1123
1124 ;;; SUBSTITUTE-SINGLE-USE-CONTINUATION -- Internal
1125 ;;;
1126 ;;; If we have a non-set let var with a single use, then (if possible)
1127 ;;; replace the variable reference's CONT with the arg continuation. This is
1128 ;;; inhibited when:
1129 ;;; -- CONT has other uses, or
1130 ;;; -- CONT receives multiple values, or
1131 ;;; -- the reference is in a different environment from the variable, or
1132 ;;; -- either continuation has a funky TYPE-CHECK annotation.
1133 ;;; -- the var's DEST has a different policy than the ARG's (think safety).
1134 ;;;
1135 ;;; We change the Ref to be a reference to NIL with unused value, and let it
1136 ;;; be flushed as dead code. A side-effect of this substitution is to delete
1137 ;;; the variable.
1138 ;;;
1139 (defun substitute-single-use-continuation (arg var)
1140 (declare (type continuation arg) (type lambda-var var))
1141 (let* ((ref (first (leaf-refs var)))
1142 (cont (node-cont ref))
1143 (dest (continuation-dest cont)))
1144 (when (and (eq (continuation-use cont) ref)
1145 dest
1146 (not (typep dest '(or creturn exit mv-combination)))
1147 (eq (node-home-lambda ref)
1148 (lambda-home (lambda-var-home var)))
1149 (member (continuation-type-check arg) '(t nil))
1150 (member (continuation-type-check cont) '(t nil))
1151 (eq (lexenv-cookie (node-lexenv dest))
1152 (lexenv-cookie (node-lexenv (continuation-dest arg)))))
1153 (assert (member (continuation-kind arg)
1154 '(:block-start :deleted-block-start :inside-block)))
1155 (assert-continuation-type arg (continuation-asserted-type cont))
1156 (setf (node-derived-type ref) *wild-type*)
1157 (change-ref-leaf ref (find-constant nil))
1158 (substitute-continuation arg cont)
1159 (reoptimize-continuation arg)
1160 t)))
1161
1162
1163 ;;; DELETE-LET -- Interface
1164 ;;;
1165 ;;; Delete a Let, removing the call and bind nodes, and warning about any
1166 ;;; unreferenced variables. Note that FLUSH-DEAD-CODE will come along right
1167 ;;; away and delete the REF and then the lambda, since we flush the FUN
1168 ;;; continuation.
1169 ;;;
1170 (defun delete-let (fun)
1171 (declare (type clambda fun))
1172 (assert (eq (functional-kind fun) :let))
1173 (note-unreferenced-vars fun)
1174 (let ((call (let-combination fun)))
1175 (flush-dest (combination-fun call))
1176 (unlink-node call)
1177 (unlink-node (lambda-bind fun))
1178 (setf (lambda-bind fun) nil))
1179 (undefined-value))
1180
1181
1182 ;;; Propagate-Let-Args -- Internal
1183 ;;;
1184 ;;; This function is called when one of the arguments to a LET changes. We
1185 ;;; look at each changed argument. If the corresponding variable is set, then
1186 ;;; we call PROPAGATE-FROM-SETS. Otherwise, we consider substituting for the
1187 ;;; variable, and also propagate derived-type information for the arg to all
1188 ;;; the Var's refs.
1189 ;;;
1190 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1191 ;;; subtype of the argument's asserted type. This prevents type checking from
1192 ;;; being defeated, and also ensures that the best representation for the
1193 ;;; variable can be used.
1194 ;;;
1195 ;;; Substitution of individual references is inhibited if the reference is
1196 ;;; in a different component from the home. This can only happen with closures
1197 ;;; over top-level lambda vars. In such cases, the references may have already
1198 ;;; been compiled, and thus can't be retroactively modified.
1199 ;;;
1200 ;;; If all of the variables are deleted (have no references) when we are
1201 ;;; done, then we delete the let.
1202 ;;;
1203 ;;; Note that we are responsible for clearing the Continuation-Reoptimize
1204 ;;; flags.
1205 ;;;
1206 (defun propagate-let-args (call fun)
1207 (declare (type combination call) (type clambda fun))
1208 (loop for arg in (combination-args call)
1209 and var in (lambda-vars fun) do
1210 (when (and arg (continuation-reoptimize arg))
1211 (setf (continuation-reoptimize arg) nil)
1212 (cond
1213 ((lambda-var-sets var)
1214 (propagate-from-sets var (continuation-type arg)))
1215 ((let ((use (continuation-use arg)))
1216 (when (ref-p use)
1217 (let ((leaf (ref-leaf use)))
1218 (when (and (constant-reference-p use)
1219 (values-subtypep (leaf-type leaf)
1220 (continuation-asserted-type arg)))
1221 (propagate-to-refs var (continuation-type arg))
1222 (let ((this-comp (block-component (node-block use))))
1223 (substitute-leaf-if
1224 #'(lambda (ref)
1225 (cond ((eq (block-component (node-block ref))
1226 this-comp)
1227 t)
1228 (t
1229 (assert (eq (functional-kind (lambda-home fun))
1230 :top-level))
1231 nil)))
1232 leaf var))
1233 t)))))
1234 ((and (null (rest (leaf-refs var)))
1235 (substitute-single-use-continuation arg var)))
1236 (t
1237 (propagate-to-refs var (continuation-type arg))))))
1238
1239 (when (every #'null (combination-args call))
1240 (delete-let fun))
1241
1242 (undefined-value))
1243
1244
1245 ;;; Propagate-Local-Call-Args -- Internal
1246 ;;;
1247 ;;; This function is called when one of the args to a non-let local call
1248 ;;; changes. For each changed argument corresponding to an unset variable, we
1249 ;;; compute the union of the types across all calls and propagate this type
1250 ;;; information to the var's refs.
1251 ;;;
1252 ;;; If the function has an XEP, then we don't do anything, since we won't
1253 ;;; discover anything.
1254 ;;;
1255 ;;; We can clear the Continuation-Reoptimize flags for arguments in all calls
1256 ;;; corresponding to changed arguments in Call, since the only use in IR1
1257 ;;; optimization of the Reoptimize flag for local call args is right here.
1258 ;;;
1259 (defun propagate-local-call-args (call fun)
1260 (declare (type combination call) (type clambda fun))
1261
1262 (unless (functional-entry-function fun)
1263 (let* ((vars (lambda-vars fun))
1264 (union (mapcar #'(lambda (arg var)
1265 (when (and arg
1266 (continuation-reoptimize arg)
1267 (null (basic-var-sets var)))
1268 (continuation-type arg)))
1269 (basic-combination-args call)
1270 vars))
1271 (this-ref (continuation-use (basic-combination-fun call))))
1272
1273 (dolist (arg (basic-combination-args call))
1274 (when arg
1275 (setf (continuation-reoptimize arg) nil)))
1276
1277 (dolist (ref (leaf-refs fun))
1278 (unless (eq ref this-ref)
1279 (setq union
1280 (mapcar #'(lambda (this-arg old)
1281 (when old
1282 (setf (continuation-reoptimize this-arg) nil)
1283 (type-union (continuation-type this-arg) old)))
1284 (basic-combination-args
1285 (continuation-dest (node-cont ref)))
1286 union))))
1287
1288 (mapc #'(lambda (var type)
1289 (when type
1290 (propagate-to-refs var type)))
1291 vars union)))
1292
1293 (undefined-value))
1294
1295
1296 ;;;; Multiple values optimization:
1297
1298 ;;; IR1-OPTIMIZE-MV-COMBINATION -- Internal
1299 ;;;
1300 ;;; Do stuff to notice a change to a MV combination node. There are two
1301 ;;; main branches here:
1302 ;;; -- If the call is local, then it is already a MV let, or should become one.
1303 ;;; Note that although all :LOCAL MV calls must eventually be converted to
1304 ;;; :MV-LETs, there can be a window when the call is local, but has not
1305 ;;; been let converted yet. This is because the entry-point lambdas may
1306 ;;; have stray references (in other entry points) that have not been
1307 ;;; deleted yet.
1308 ;;; -- The call is full. This case is somewhat similar to the non-MV
1309 ;;; combination optimization: we propagate return type information and
1310 ;;; notice non-returning calls. We also have an optimization
1311 ;;; which tries to convert MV-CALLs into MV-binds.
1312 ;;;
1313 (defun ir1-optimize-mv-combination (node)
1314 (cond
1315 ((eq (basic-combination-kind node) :local)
1316 (let ((fun (basic-combination-fun node)))
1317 (when (continuation-reoptimize fun)
1318 (setf (continuation-reoptimize fun) nil)
1319 (maybe-let-convert (combination-lambda node))))
1320 (setf (continuation-reoptimize (first (basic-combination-args node))) nil)
1321 (when (eq (functional-kind (combination-lambda node)) :mv-let)
1322 (unless (convert-mv-bind-to-let node)
1323 (ir1-optimize-mv-bind node))))
1324 (t
1325 (let* ((fun (basic-combination-fun node))
1326 (fun-changed (continuation-reoptimize fun))
1327 (args (basic-combination-args node)))
1328 (when fun-changed
1329 (setf (continuation-reoptimize fun) nil)
1330 (let ((type (continuation-type fun)))
1331 (when (function-type-p type)
1332 (derive-node-type node (function-type-returns type))))
1333 (maybe-terminate-block node nil)
1334 (let ((use (continuation-use fun)))
1335 (when (and (ref-p use) (functional-p (ref-leaf use))
1336 (not (eq (ref-inlinep use) :notinline)))
1337 (convert-call-if-possible use node)
1338 (maybe-let-convert (ref-leaf use)))))
1339 (unless (or (eq (basic-combination-kind node) :local)
1340 (eq (continuation-function-name fun) '%throw))
1341 (ir1-optimize-mv-call node))
1342 (dolist (arg args)
1343 (setf (continuation-reoptimize arg) nil)))))
1344 (undefined-value))
1345
1346
1347 ;;; IR1-OPTIMIZE-MV-BIND -- Internal
1348 ;;;
1349 ;;; Propagate derived type info from the values continuation to the vars.
1350 ;;;
1351 (defun ir1-optimize-mv-bind (node)
1352 (declare (type mv-combination node))
1353 (let ((arg (first (basic-combination-args node)))
1354 (vars (lambda-vars (combination-lambda node))))
1355 (multiple-value-bind (types nvals)
1356 (values-types (continuation-derived-type arg))
1357 (unless (eq nvals :unknown)
1358 (mapc #'(lambda (var type)
1359 (if (basic-var-sets var)
1360 (propagate-from-sets var type)
1361 (propagate-to-refs var type)))
1362 vars
1363 (append types
1364 (make-list (max (- (length vars) nvals) 0)
1365 :initial-element *null-type*)))))
1366
1367 (setf (continuation-reoptimize arg) nil))
1368 (undefined-value))
1369
1370
1371 ;;; IR1-OPTIMIZE-MV-CALL -- Internal
1372 ;;;
1373 ;;; If possible, convert a general MV call to an MV-BIND. We can do this
1374 ;;; if:
1375 ;;; -- The call has only one argument, and
1376 ;;; -- The function has a known fixed number of arguments, or
1377 ;;; -- The argument yields a known fixed number of values.
1378 ;;;
1379 ;;; What we do is change the function in the MV-CALL to be a lambda that "looks
1380 ;;; like an MV bind", which allows IR1-OPTIMIZE-MV-COMBINATION to notice that
1381 ;;; this call can be converted (the next time around.) This new lambda just
1382 ;;; calls the actual function with the MV-BIND variables as arguments. Note
1383 ;;; that this new MV bind is not let-converted immediately, as there are going
1384 ;;; to be stray references from the entry-point functions until they get
1385 ;;; deleted.
1386 ;;;
1387 ;;; In order to avoid loss of argument count checking, we only do the
1388 ;;; transformation according to a known number of expected argument if safety
1389 ;;; is unimportant. We can always convert if we know the number of actual
1390 ;;; values, since the normal call that we build will still do any appropriate
1391 ;;; argument count checking.
1392 ;;;
1393 ;;; We only attempt the transformation if the called function is a constant
1394 ;;; reference. This allows us to just splice the leaf into the new function,
1395 ;;; instead of trying to somehow bind the function expression. The leaf must
1396 ;;; be constant because we are evaluating it again in a different place. This
1397 ;;; also has the effect of squelching multiple warnings when there is an
1398 ;;; argument count error.
1399 ;;;
1400 (defun ir1-optimize-mv-call (node)
1401 (let ((fun (basic-combination-fun node))
1402 (*compiler-error-context* node)
1403 (ref (continuation-use (basic-combination-fun node)))
1404 (args (basic-combination-args node)))
1405
1406 (unless (and (ref-p ref) (constant-reference-p ref)
1407 args (null (rest args)))
1408 (return-from ir1-optimize-mv-call))
1409
1410 (multiple-value-bind (min max)
1411 (function-type-nargs (continuation-type fun))
1412 (let ((total-nvals
1413 (multiple-value-bind
1414 (types nvals)
1415 (values-types (continuation-derived-type (first args)))
1416 (declare (ignore types))
1417 (if (eq nvals :unknown) nil nvals))))
1418
1419 (when total-nvals
1420 (when (and min (< total-nvals min))
1421 (compiler-warning
1422 "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1423 at least ~R."
1424 total-nvals min)
1425 (setf (ref-inlinep ref) :notinline)
1426 (return-from ir1-optimize-mv-call))
1427 (when (and max (> total-nvals max))
1428 (compiler-warning
1429 "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1430 at most ~R."
1431 total-nvals max)
1432 (setf (ref-inlinep ref) :notinline)
1433 (return-from ir1-optimize-mv-call)))
1434
1435 (let ((count (cond (total-nvals)
1436 ((and (policy node (zerop safety)) (eql min max))
1437 min)
1438 (t nil))))
1439 (when count
1440 (with-ir1-environment node
1441 (let* ((dums (loop repeat count collect (gensym)))
1442 (ignore (gensym))
1443 (fun (ir1-convert-lambda
1444 `(lambda (&optional ,@dums &rest ,ignore)
1445 (declare (ignore ,ignore))
1446 (funcall ,(ref-leaf ref) ,@dums)))))
1447 (change-ref-leaf ref fun)
1448 (assert (eq (basic-combination-kind node) :full))
1449 (local-call-analyze *current-component*)
1450 (assert (eq (basic-combination-kind node) :local)))))))))
1451 (undefined-value))
1452
1453
1454 ;;; CONVERT-MV-BIND-TO-LET -- Internal
1455 ;;;
1456 ;;; If we see:
1457 ;;; (multiple-value-bind (x y)
1458 ;;; (values xx yy)
1459 ;;; ...)
1460 ;;; Convert to:
1461 ;;; (let ((x xx)
1462 ;;; (y yy))
1463 ;;; ...)
1464 ;;;
1465 ;;; What we actually do is convert the VALUES combination into a normal let
1466 ;;; combination calling the original :MV-LET lambda. If there are extra args to
1467 ;;; VALUES, discard the corresponding continuations. If there are insufficient
1468 ;;; args, insert references to NIL.
1469 ;;;
1470 (defun convert-mv-bind-to-let (call)
1471 (declare (type mv-combination call))
1472 (let* ((arg (first (basic-combination-args call)))
1473 (use (continuation-use arg)))
1474 (when (and (combination-p use)
1475 (eq (continuation-function-name (combination-fun use))
1476 'values))
1477 (let* ((fun (combination-lambda call))
1478 (vars (lambda-vars fun))
1479 (vals (combination-args use))
1480 (nvars (length vars))
1481 (nvals (length vals)))
1482 (cond ((> nvals nvars)
1483 (mapc #'flush-dest (subseq vals nvars))
1484 (setq vals (subseq vals 0 nvars)))
1485 ((< nvals nvars)
1486 (with-ir1-environment use
1487 (let ((node-prev (node-prev use)))
1488 (setf (node-prev use) nil)
1489 (setf (continuation-next node-prev) nil)
1490 (collect ((res vals))
1491 (loop as cont = (make-continuation use)
1492 and prev = node-prev then cont
1493 repeat (- nvars nvals)
1494 do (reference-constant prev cont nil)
1495 (res cont))
1496 (setq vals (res)))
1497 (prev-link use (car (last vals)))))))
1498 (setf (combination-args use) vals)
1499 (flush-dest (combination-fun use))
1500 (let ((fun-cont (basic-combination-fun call)))
1501 (setf (continuation-dest fun-cont) use)
1502 (setf (combination-fun use) fun-cont))
1503 (setf (combination-kind use) :local)
1504 (setf (functional-kind fun) :let)
1505 (flush-dest (first (basic-combination-args call)))
1506 (unlink-node call)
1507 (when vals
1508 (reoptimize-continuation (first vals)))
1509 (propagate-to-args use fun))
1510 t)))
1511
1512
1513 ;;; VALUES-LIST IR1 optimizer -- Internal
1514 ;;;
1515 ;;; If we see:
1516 ;;; (values-list (list x y z))
1517 ;;;
1518 ;;; Convert to:
1519 ;;; (values x y z)
1520 ;;;
1521 ;;; In implementation, this is somewhat similar to CONVERT-MV-BIND-TO-LET. We
1522 ;;; grab the args of LIST and make them args of the VALUES-LIST call, flushing
1523 ;;; the old argument continuation (allowing the LIST to be flushed.)
1524 ;;;
1525 (defoptimizer (values-list optimizer) ((list) node)
1526 (let ((use (continuation-use list)))
1527 (when (and (combination-p use)
1528 (eq (continuation-function-name (combination-fun use))
1529 'list))
1530 (change-ref-leaf (continuation-use (combination-fun node))
1531 (find-free-function 'values "in a strange place"))
1532 (setf (combination-kind node) :full)
1533 (let ((args (combination-args use)))
1534 (dolist (arg args)
1535 (setf (continuation-dest arg) node))
1536 (setf (combination-args use) nil)
1537 (flush-dest list)
1538 (setf (combination-args node) args))
1539 t)))
1540
1541
1542 ;;; VALUES IR1 transform -- Internal
1543 ;;;
1544 ;;; If VALUES appears in a non-MV context, then effectively convert it to a
1545 ;;; PROG1. This allows the computation of the additional values to become dead
1546 ;;; code.
1547 ;;;
1548 (deftransform values ((&rest vals) * * :node node)
1549 (when (typep (continuation-dest (node-cont node))
1550 '(or creturn exit mv-combination))
1551 (give-up))
1552 (setf (node-derived-type node) *wild-type*)
1553 (if vals
1554 (let ((dummies (loop repeat (1- (length vals))
1555 collect (gensym))))
1556 `(lambda (val ,@dummies)
1557 (declare (ignore ,@dummies))
1558 val))
1559 'nil))
1560
1561
1562 ;;; Flush-Dead-Code -- Internal
1563 ;;;
1564 ;;; Delete any nodes in Block whose value is unused and have no
1565 ;;; side-effects. We can delete sets of lexical variables when the set
1566 ;;; variable has no references.
1567 ;;;
1568 ;;; [### For now, don't delete potentially flushable calls when they have the
1569 ;;; Call attribute. Someday we should look at the funcitonal args to determine
1570 ;;; if they have any side-effects.]
1571 ;;;
1572 (defun flush-dead-code (block)
1573 (declare (type cblock block))
1574 (do-nodes-backwards (node cont block)
1575 (unless (continuation-dest cont)
1576 (typecase node
1577 (ref
1578 (delete-ref node)
1579 (unlink-node node))
1580 (combination
1581 (let ((info (combination-kind node)))
1582 (when (function-info-p info)
1583 (let ((attr (function-info-attributes info)))
1584 (when (and (ir1-attributep attr flushable)
1585 (not (ir1-attributep attr call)))
1586 (flush-dest (combination-fun node))
1587 (dolist (arg (combination-args node))
1588 (flush-dest arg))
1589 (unlink-node node))))))
1590 (exit
1591 (let ((value (exit-value node)))
1592 (when value
1593 (flush-dest value)
1594 (setf (exit-value node) nil))))
1595 (cset
1596 (let ((var (set-var node)))
1597 (when (and (lambda-var-p var)
1598 (null (leaf-refs var)))
1599 (flush-dest (set-value node))
1600 (setf (basic-var-sets var)
1601 (delete node (basic-var-sets var)))
1602 (unlink-node node)))))))
1603
1604 (setf (block-flush-p block) nil)
1605 (undefined-value))

  ViewVC Help
Powered by ViewVC 1.1.5