/[cmucl]/src/code/pathname.lisp
ViewVC logotype

Contents of /src/code/pathname.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.75 - (show annotations)
Tue Sep 13 14:38:44 2005 UTC (8 years, 7 months ago) by rtoy
Branch: MAIN
Changes since 1.74: +8 -2 lines
Pathnames with NIL hosts now use the host from
*default-pathname-defaults* or *unix-host* to get the namestring.
Previously, an error was generated.  This change breaks print/read
consistency for pathnames with NIL hosts.
1 ;;; -*- Package: LISP -*-
2 ;;; **********************************************************************
3 ;;; This code was written as part of the CMU Common Lisp project at
4 ;;; Carnegie Mellon University, and has been placed in the public domain.
5 ;;;
6 (ext:file-comment
7 "$Header: /tiger/var/lib/cvsroots/cmucl/src/code/pathname.lisp,v 1.75 2005/09/13 14:38:44 rtoy Exp $")
8 ;;;
9 ;;; **********************************************************************
10 ;;;
11 ;;; Machine/filesystem independent pathname functions for CMU Common Lisp.
12 ;;;
13 ;;; Written by William Lott, Paul Gleichauf and Rob MacLachlan.
14 ;;; Earlier version written by Jim Large and Rob MacLachlan
15 ;;;
16 ;;; **********************************************************************
17
18 (in-package "LISP")
19
20 (export '(pathname pathnamep logical-pathname
21 parse-namestring merge-pathnames make-pathname
22 pathname-host pathname-device pathname-directory pathname-name
23 pathname-type pathname-version namestring file-namestring
24 directory-namestring host-namestring enough-namestring
25 wild-pathname-p pathname-match-p translate-pathname
26 translate-logical-pathname logical-pathname-translations
27 load-logical-pathname-translations *default-pathname-defaults*))
28
29 (in-package "EXTENSIONS")
30 (export '(search-list search-list-defined-p clear-search-list
31 enumerate-search-list *autoload-translations*))
32
33 (in-package "LISP")
34
35 (defvar *autoload-translations* nil
36 "When non-nil, attempt to load \"library:<host>.translations\" to resolve
37 an otherwise undefined logical host.")
38
39
40 ;;;; HOST structures
41
42 ;;; The host structure holds the functions that both parse the pathname
43 ;;; information into sturcture slot entries, and after translation the inverse
44 ;;; (unparse) functions.
45 ;;;
46 (defstruct (host
47 (:print-function %print-host))
48 (parse (required-argument) :type function)
49 (unparse (required-argument) :type function)
50 (unparse-host (required-argument) :type function)
51 (unparse-directory (required-argument) :type function)
52 (unparse-file (required-argument) :type function)
53 (unparse-enough (required-argument) :type function)
54 (customary-case (required-argument) :type (member :upper :lower)))
55
56 ;;; %PRINT-HOST -- Internal
57 ;;;
58 (defun %print-host (host stream depth)
59 (declare (ignore depth))
60 (print-unreadable-object (host stream :type t)))
61
62 (defstruct (logical-host
63 (:include host
64 (:parse #'parse-logical-namestring)
65 (:unparse #'unparse-logical-namestring)
66 (:unparse-host
67 #'(lambda (x) (logical-host-name (%pathname-host x))))
68 (:unparse-directory #'unparse-logical-directory)
69 (:unparse-file #'unparse-unix-file)
70 (:unparse-enough #'unparse-enough-namestring)
71 (:customary-case :upper))
72 (:make-load-form-fun make-logical-host-load-form-fun))
73 (name "" :type simple-base-string)
74 (translations nil :type list)
75 (canon-transls nil :type list))
76
77 (defun make-logical-host-load-form-fun (logical-host)
78 (values `(find-logical-host ',(logical-host-name logical-host))
79 nil))
80
81 ;;; The various magic tokens that are allowed to appear in pretty much all
82 ;;; pathname components.
83 ;;;
84 (deftype component-tokens ()
85 '(member nil :unspecific :wild))
86
87 ;;;; Pathname structures
88
89 (defstruct (pathname
90 (:conc-name %pathname-)
91 (:print-function %print-pathname)
92 (:constructor
93 %make-pathname (host device directory name type version))
94 (:predicate pathnamep)
95 (:make-load-form-fun :just-dump-it-normally))
96 ;; Slot holds the host, at present either a UNIX or logical host.
97 (host nil :type (or host null))
98 ;; Device is the name of a logical or physical device holding files.
99 (device nil :type (or simple-string component-tokens))
100 ;; A list of strings that are the component subdirectory components.
101 (directory nil :type list)
102 ;; The filename.
103 (name nil :type (or simple-string pattern component-tokens))
104 ;; The type extension of the file.
105 (type nil :type (or simple-string pattern component-tokens))
106 ;; The version number of the file, a positive integer, but not supported
107 ;; on standard UNIX filesystems.
108 (version nil :type (or integer component-tokens (member :newest))))
109
110 ;;; %PRINT-PATHNAME -- Internal
111 ;;;
112 ;;; The printed representation of the pathname structure.
113 ;;;
114 (defun %print-pathname (pathname stream depth)
115 (declare (ignore depth))
116 (let ((namestring (handler-case (namestring pathname)
117 (error nil))))
118 (cond (namestring
119 (if (or *print-escape* *print-readably*)
120 (format stream "#P~S" namestring)
121 (format stream "~A" namestring)))
122 (*print-readably*
123 (error 'print-not-readable :object pathname))
124 (t
125 (funcall (formatter "#<Unprintable pathname, Host=~S, Device=~S, ~
126 Directory=~S, Name=~S, Type=~S, Version=~S>")
127 stream
128 (%pathname-host pathname)
129 (%pathname-device pathname)
130 (%pathname-directory pathname)
131 (%pathname-name pathname)
132 (%pathname-type pathname)
133 (%pathname-version pathname))))))
134
135 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
136 ;;;
137 ;;; Logical pathnames have the following format:
138 ;;;
139 ;;; logical-namestring ::=
140 ;;; [host ":"] [";"] {directory ";"}* [name] ["." type ["." version]]
141 ;;;
142 ;;; host ::= word
143 ;;; directory ::= word | wildcard-word | **
144 ;;; name ::= word | wildcard-word
145 ;;; type ::= word | wildcard-word
146 ;;; version ::= pos-int | newest | NEWEST | *
147 ;;; word ::= {uppercase-letter | digit | -}+
148 ;;; wildcard-word ::= [word] '* {word '*}* [word]
149 ;;; pos-int ::= integer > 0
150 ;;;
151 ;;; Physical pathnames include all these slots and a device slot.
152 ;;;
153 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
154
155 ;; Logical pathnames are a subclass of pathname, their class relations are
156 ;; mimiced using structures for efficency.
157
158 (defstruct (logical-pathname
159 (:conc-name %logical-pathname-)
160 (:print-function %print-logical-pathname)
161 (:include pathname)
162 (:constructor %make-logical-pathname
163 (host device directory name type version))
164 (:make-load-form-fun :just-dump-it-normally)))
165
166 (declaim (freeze-type logical-pathname logical-host))
167
168 ;;; %PRINT-LOGICAL-PATHNAME -- Internal
169 ;;;
170 ;;; The printed representation of the logical-pathname structure.
171 ;;; The potential conflict with search-lists requires isolating the printed
172 ;;; representation to use the i/o macro #.(logical-pathname <path-designator>).
173 ;;;
174 ;;; Is there really a potential conflict? CMUCL does not allow
175 ;;; search-list hosts and logical pathname hosts have the same name.
176 ;;; Hence, if we use #P to print them out, we can always read them
177 ;;; back without confusion. (rtoy)
178 ;;;
179 (defun %print-logical-pathname (pathname stream depth)
180 (declare (ignore depth))
181 (let ((namestring (handler-case (namestring pathname)
182 (error nil))))
183 (cond (namestring
184 (if (or *print-escape* *print-readably*)
185 (format stream "#P~S" namestring)
186 (format stream "~A" namestring)))
187 (*print-readably*
188 (error 'print-not-readable :object pathname))
189 (t
190 (funcall (formatter "#<Unprintable pathname, Host=~S, ~
191 Directory=~S, File=~S, Name=~S, Version=~S>")
192 stream
193 (%pathname-host pathname)
194 (%pathname-directory pathname)
195 (%pathname-name pathname)
196 (%pathname-type pathname)
197 (%pathname-version pathname))))))
198
199 ;;; %MAKE-PATHNAME-OBJECT -- internal
200 ;;;
201 ;;; A pathname is logical if the host component is a logical-host.
202 ;;; This constructor is used to make an instance of the correct type
203 ;;; from parsed arguments.
204
205 (defun %make-pathname-object (host device directory name type version)
206 (if (typep host 'logical-host)
207 (flet ((upcasify (thing)
208 (typecase thing
209 (list
210 (mapcar #'(lambda (x)
211 (if (stringp x)
212 (string-upcase x)
213 x))
214 thing))
215 (simple-base-string
216 (string-upcase thing))
217 (t
218 thing))))
219 (%make-logical-pathname host :unspecific
220 (upcasify directory)
221 (upcasify name)
222 (upcasify type)
223 (upcasify version)))
224 (%make-pathname host device directory name type version)))
225
226 ;;; *LOGICAL-HOSTS* --internal.
227 ;;;
228 ;;; Hash table searching maps a logical-pathname's host to their physical
229 ;;; pathname translation.
230
231 (defvar *logical-hosts* (make-hash-table :test #'equal))
232
233 ;;; PATH-DESIGNATOR -- internal type
234 ;;;
235 (deftype path-designator ()
236 "A path specification, either a string, stream or pathname."
237 '(or string stream pathname))
238
239
240 ;;;; Patterns
241
242 ;;; Patterns are a list of entries and wildcards used for pattern matches
243 ;;; of translations.
244
245 (defstruct (pattern
246 (:print-function %print-pattern)
247 (:make-load-form-fun :just-dump-it-normally)
248 (:constructor make-pattern (pieces)))
249 (pieces nil :type list))
250
251 ;;; %PRINT-PATTERN -- Internal
252 ;;;
253 (defun %print-pattern (pattern stream depth)
254 (declare (ignore depth))
255 (print-unreadable-object (pattern stream :type t)
256 (if *print-pretty*
257 (let ((*print-escape* t))
258 (pprint-fill stream (pattern-pieces pattern) nil))
259 (prin1 (pattern-pieces pattern) stream))))
260
261 ;;; PATTERN= -- Internal
262 ;;;
263 (defun pattern= (pattern1 pattern2)
264 (declare (type pattern pattern1 pattern2))
265 (let ((pieces1 (pattern-pieces pattern1))
266 (pieces2 (pattern-pieces pattern2)))
267 (and (= (length pieces1) (length pieces2))
268 (every #'(lambda (piece1 piece2)
269 (typecase piece1
270 (simple-string
271 (and (simple-string-p piece2)
272 (string= piece1 piece2)))
273 (cons
274 (and (consp piece2)
275 (eq (car piece1) (car piece2))
276 (string= (cdr piece1) (cdr piece2))))
277 (t
278 (eq piece1 piece2))))
279 pieces1
280 pieces2))))
281
282 ;;; PATTERN-MATCHES -- Internal
283 ;;;
284 ;;; If the string matches the pattern returns the multiple values T and a
285 ;;; list of the matched strings.
286 ;;;
287 (defun pattern-matches (pattern string)
288 (declare (type pattern pattern)
289 (type simple-string string))
290 (let ((len (length string)))
291 (labels ((maybe-prepend (subs cur-sub chars)
292 (if cur-sub
293 (let* ((len (length chars))
294 (new (make-string len))
295 (index len))
296 (dolist (char chars)
297 (setf (schar new (decf index)) char))
298 (cons new subs))
299 subs))
300 (matches (pieces start subs cur-sub chars)
301 (if (null pieces)
302 (if (= start len)
303 (values t (maybe-prepend subs cur-sub chars))
304 (values nil nil))
305 (let ((piece (car pieces)))
306 (etypecase piece
307 (simple-string
308 (let ((end (+ start (length piece))))
309 (and (<= end len)
310 (string= piece string
311 :start2 start :end2 end)
312 (matches (cdr pieces) end
313 (maybe-prepend subs cur-sub chars)
314 nil nil))))
315 (list
316 (ecase (car piece)
317 (:character-set
318 (and (< start len)
319 (let ((char (schar string start)))
320 (if (find char (second piece) :test #'char=)
321 (matches (cdr pieces) (1+ start) subs t
322 (cons char chars))))))))
323 ((member :single-char-wild)
324 (and (< start len)
325 (matches (cdr pieces) (1+ start) subs t
326 (cons (schar string start) chars))))
327 ((member :multi-char-wild)
328 (multiple-value-bind
329 (won new-subs)
330 (matches (cdr pieces) start subs t chars)
331 (if won
332 (values t new-subs)
333 (and (< start len)
334 (matches pieces (1+ start) subs t
335 (cons (schar string start)
336 chars)))))))))))
337 (multiple-value-bind
338 (won subs)
339 (matches (pattern-pieces pattern) 0 nil nil nil)
340 (values won (reverse subs))))))
341
342
343 ;;; DIRECTORY-COMPONENTS-MATCH -- Internal
344 ;;;
345 ;;; Pathname-match-p for directory components. If thing is empty
346 ;;; then it matches :wild, (:absolute :wild-inferiors), or (:relative
347 ;;; :wild-inferiors).
348 ;;;
349 (defun directory-components-match (thing wild)
350 (or (eq thing wild)
351 (eq wild :wild)
352 (and (consp wild)
353 (let ((wild1 (first wild)))
354 (cond ((and (null thing) (member wild1 '(:absolute :relative)))
355 (equal (rest wild) '(:wild-inferiors)))
356 ((eq wild1 :wild-inferiors)
357 (let ((wild-subdirs (rest wild)))
358 (or (null wild-subdirs)
359 (loop
360 (when (directory-components-match thing
361 wild-subdirs)
362 (return t))
363 (pop thing)
364 (unless thing (return nil))))))
365 ((consp thing)
366 (and (components-match (first thing) wild1)
367 (directory-components-match (rest thing)
368 (rest wild)))))))))
369
370
371 ;;; COMPONENTS-MATCH -- Internal
372 ;;;
373 ;;; Return true if pathname component Thing is matched by Wild. Not
374 ;;; commutative.
375 ;;;
376 (defun components-match (thing wild)
377 (declare (type (or pattern symbol simple-string integer) thing wild))
378 (or (eq thing wild)
379 (eq wild :wild)
380 (typecase thing
381 (simple-base-string
382 ;; String is matched by itself, a matching pattern or :WILD.
383 (typecase wild
384 (pattern
385 (values (pattern-matches wild thing)))
386 (simple-base-string
387 (string= thing wild))))
388 (pattern
389 ;; A pattern is only matched by an identical pattern.
390 (and (pattern-p wild) (pattern= thing wild)))
391 (integer
392 ;; an integer (version number) is matched by :WILD or the same
393 ;; integer. This branch will actually always be NIL as long is the
394 ;; version is a fixnum.
395 (eql thing wild)))))
396
397
398 ;;; COMPARE-COMPONENT -- Internal
399 ;;;
400 ;;; A predicate for comparing two pathname slot component sub-entries.
401 ;;;
402 (defun compare-component (this that)
403 (or (eql this that)
404 (typecase this
405 (simple-string
406 (and (simple-string-p that)
407 (string= this that)))
408 (pattern
409 (and (pattern-p that)
410 (pattern= this that)))
411 (cons
412 (and (consp that)
413 (compare-component (car this) (car that))
414 (compare-component (cdr this) (cdr that)))))))
415
416
417 ;;;; Pathname functions.
418
419 ;;; Implementation determined defaults to pathname slots.
420
421 (defvar *default-pathname-defaults*)
422
423 ;;; PATHNAME= -- Internal
424 ;;;
425 (defun pathname= (pathname1 pathname2)
426 (declare (type pathname pathname1)
427 (type pathname pathname2))
428 (and (eq (%pathname-host pathname1)
429 (%pathname-host pathname2))
430 (compare-component (%pathname-device pathname1)
431 (%pathname-device pathname2))
432 (compare-component (%pathname-directory pathname1)
433 (%pathname-directory pathname2))
434 (compare-component (%pathname-name pathname1)
435 (%pathname-name pathname2))
436 (compare-component (%pathname-type pathname1)
437 (%pathname-type pathname2))
438 (compare-component (%pathname-version pathname1)
439 (%pathname-version pathname2))))
440
441 ;;; WITH-PATHNAME -- Internal
442 ;;; Converts the expr, a pathname designator (a pathname, or string, or
443 ;;; stream), into a pathname.
444 ;;;
445 (defmacro with-pathname ((var expr) &body body)
446 `(let ((,var (let ((,var ,expr))
447 (etypecase ,var
448 (pathname ,var)
449 (string (parse-namestring ,var))
450 (file-stream (file-name ,var))
451 (stream:file-simple-stream (file-name ,var))))))
452 ,@body))
453
454 ;;; WITH-HOST -- Internal
455 ;;;
456 ;;; Converts the var, a host or string name for a host, into a logical-host
457 ;;; structure or nil if not defined.
458 ;;;
459 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
460 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
461 ;;;
462 (defmacro with-host ((var expr) &body body)
463 `(let ((,var (let ((,var ,expr))
464 (typecase ,var
465 (logical-host ,var)
466 (string (find-logical-host ,var nil))
467 (t nil)))))
468 ,@body))
469
470 ;;; PATHNAME -- Interface
471 ;;;
472 (defun pathname (thing)
473 "Convert thing (a pathname, string or stream) into a pathname."
474 (declare (type path-designator thing))
475 (with-pathname (pathname thing)
476 pathname))
477
478 ;;; MAYBE-DIDDLE-CASE -- Internal
479 ;;;
480 ;;; Change the case of thing if diddle-p T.
481 ;;;
482 (defun maybe-diddle-case (thing diddle-p)
483 (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
484 (labels ((check-for (pred in)
485 (typecase in
486 (pattern
487 (dolist (piece (pattern-pieces in))
488 (when (typecase piece
489 (simple-string
490 (check-for pred piece))
491 (cons
492 (case (car in)
493 (:character-set
494 (check-for pred (cdr in))))))
495 (return t))))
496 (list
497 (dolist (x in)
498 (when (check-for pred x)
499 (return t))))
500 (simple-base-string
501 (dotimes (i (length in))
502 (when (funcall pred (schar in i))
503 (return t))))
504 (t nil)))
505 (diddle-with (fun thing)
506 (typecase thing
507 (pattern
508 (make-pattern
509 (mapcar #'(lambda (piece)
510 (typecase piece
511 (simple-base-string
512 (funcall fun piece))
513 (cons
514 (case (car piece)
515 (:character-set
516 (cons :character-set
517 (funcall fun (cdr piece))))
518 (t
519 piece)))
520 (t
521 piece)))
522 (pattern-pieces thing))))
523 (list
524 (mapcar fun thing))
525 (simple-base-string
526 (funcall fun thing))
527 (t
528 thing))))
529 (let ((any-uppers (check-for #'upper-case-p thing))
530 (any-lowers (check-for #'lower-case-p thing)))
531 (cond ((and any-uppers any-lowers)
532 ;; Mixed case, stays the same.
533 thing)
534 (any-uppers
535 ;; All uppercase, becomes all lower case.
536 (diddle-with #'(lambda (x) (if (stringp x)
537 (string-downcase x)
538 x)) thing))
539 (any-lowers
540 ;; All lowercase, becomes all upper case.
541 (diddle-with #'(lambda (x) (if (stringp x)
542 (string-upcase x)
543 x)) thing))
544 (t
545 ;; No letters? I guess just leave it.
546 thing))))
547 thing))
548
549
550 ;;; MERGE-DIRECTORIES -- Internal
551 ;;;
552 (defun merge-directories (dir1 dir2 diddle-case)
553 (if (or (eq (car dir1) :absolute)
554 (null dir2))
555 dir1
556 (let ((results nil))
557 (flet ((add (dir)
558 (if (and (eq dir :back)
559 results
560 (not (eq (car results) :back)))
561 (pop results)
562 (push dir results))))
563 (dolist (dir (maybe-diddle-case dir2 diddle-case))
564 (add dir))
565 (dolist (dir (cdr dir1))
566 (add dir)))
567 (reverse results))))
568
569 ;;; MERGE-PATHNAMES -- Interface
570 ;;;
571 (defun merge-pathnames (pathname
572 &optional
573 (defaults *default-pathname-defaults*)
574 (default-version :newest))
575 "Construct a filled in pathname by completing the unspecified components
576 from the defaults."
577 (declare (type path-designator pathname)
578 (type path-designator defaults)
579 (values pathname))
580 (with-pathname (defaults defaults)
581 (let ((pathname (let ((*default-pathname-defaults* defaults))
582 (pathname pathname))))
583 (let* ((default-host (%pathname-host defaults))
584 (pathname-host (%pathname-host pathname))
585 (diddle-case
586 (and default-host pathname-host
587 (not (eq (host-customary-case default-host)
588 (host-customary-case pathname-host))))))
589 (%make-pathname-object
590 (or pathname-host default-host)
591 (or (%pathname-device pathname)
592 (maybe-diddle-case (%pathname-device defaults)
593 diddle-case))
594 (merge-directories (%pathname-directory pathname)
595 (%pathname-directory defaults)
596 diddle-case)
597 (or (%pathname-name pathname)
598 (maybe-diddle-case (%pathname-name defaults)
599 diddle-case))
600 (or (%pathname-type pathname)
601 (maybe-diddle-case (%pathname-type defaults)
602 diddle-case))
603 (or (if (null (%pathname-name pathname))
604 (or (%pathname-version pathname)
605 (%pathname-version defaults))
606 (%pathname-version pathname))
607 default-version))))))
608
609 ;;; IMPORT-DIRECTORY -- Internal
610 ;;;
611 (defun import-directory (directory diddle-case)
612 (etypecase directory
613 (null nil)
614 ((member :wild) '(:absolute :wild-inferiors))
615 ((member :unspecific) '(:relative))
616 (list
617 (collect ((results))
618 (ecase (pop directory)
619 (:absolute
620 (results :absolute)
621 (when (search-list-p (car directory))
622 (results (pop directory))))
623 (:relative
624 (results :relative)))
625 (dolist (piece directory)
626 (cond ((member piece '(:wild :wild-inferiors :up :back))
627 (results piece))
628 ((or (simple-string-p piece) (pattern-p piece))
629 (results (maybe-diddle-case piece diddle-case)))
630 ((stringp piece)
631 (results (maybe-diddle-case (coerce piece 'simple-string)
632 diddle-case)))
633 (t
634 (error "~S is not allowed as a directory component." piece))))
635 (results)))
636 (simple-string
637 `(:absolute
638 ,(maybe-diddle-case directory diddle-case)))
639 (string
640 `(:absolute
641 ,(maybe-diddle-case (coerce directory 'simple-string)
642 diddle-case)))))
643
644 ;;; MAKE-PATHNAME -- Interface
645 ;;;
646 (defun make-pathname (&key (host nil hostp)
647 (device nil devp)
648 (directory nil dirp)
649 (name nil namep)
650 (type nil typep)
651 (version nil versionp)
652 defaults
653 (case :local))
654 "Makes a new pathname from the component arguments. Note that host is
655 a host-structure or string."
656 (declare (type (or null string host component-tokens) host)
657 (type (or string component-tokens) device)
658 (type (or list string pattern component-tokens) directory)
659 (type (or string pattern component-tokens) name type)
660 (type (or integer component-tokens (member :newest)) version)
661 (type (or path-designator null) defaults)
662 (type (member :common :local) case))
663 (let* ((defaults (when defaults
664 (with-pathname (defaults defaults) defaults)))
665 (default-host (if defaults
666 (%pathname-host defaults)
667 (%pathname-host *default-pathname-defaults*)))
668 ;; toy@rtp.ericsson.se: CLHS says make-pathname can take a
669 ;; string (as a logical-host) for the host part. We map that
670 ;; string into the corresponding logical host structure.
671
672 ;; pw@snoopy.mv.com:
673 ;; HyperSpec says for the arg to MAKE-PATHNAME;
674 ;; "host---a valid physical pathname host. ..."
675 ;; where it probably means -- a valid pathname host.
676 ;; "valid pathname host n. a valid physical pathname host or
677 ;; a valid logical pathname host."
678 ;; and defines
679 ;; "valid physical pathname host n. any of a string,
680 ;; a list of strings, or the symbol :unspecific,
681 ;; that is recognized by the implementation as the name of a host."
682 ;; "valid logical pathname host n. a string that has been defined
683 ;; as the name of a logical host. ..."
684 ;; HS is silent on what happens if the :host arg is NOT one of these.
685 ;; It seems an error message is appropriate.
686 (host (typecase host
687 (host host) ; A valid host, use it.
688 ((string 0) default-host) ; "" cannot be a logical host
689 (string (find-logical-host host t)) ; logical-host or lose.
690 (t
691 ;; If the user specifically set :host to be NIL, use
692 ;; it. Otherwise, we use the default host.
693 (if (and hostp (null host))
694 nil
695 default-host))))
696 (diddle-args
697 ;; What to do if no host is given? Can't figure out the
698 ;; customary case, so I (rtoy) am going to assume we don't
699 ;; need to diddle args.
700 (and host (eq (host-customary-case host) :lower)
701 (eq case :common)))
702 (diddle-defaults
703 ;; Same for diddle-defaults. Do nothing if no host was given.
704 (and host (not (eq (host-customary-case host)
705 (host-customary-case default-host)))))
706 (dev (if devp device (if defaults (%pathname-device defaults))))
707 (dir (import-directory directory diddle-args))
708 (ver (cond
709 (versionp version)
710 (defaults (%pathname-version defaults))
711 (t nil))))
712 (when (and defaults (not dirp))
713 (setf dir
714 (merge-directories dir
715 (%pathname-directory defaults)
716 diddle-defaults)))
717
718 ;; A bit of sanity checking on user arguments.
719 (flet ((check-component-validity (name name-or-type)
720 (when (stringp name)
721 (let ((unix-directory-separator #\/))
722 (when (eq host (%pathname-host *default-pathname-defaults*))
723 (when (find unix-directory-separator name)
724 (warn "Silly argument for a unix ~A: ~S"
725 name-or-type name)))))))
726 (check-component-validity name :pathname-name)
727 (check-component-validity type :pathname-type)
728 (mapc #'(lambda (d)
729 (check-component-validity d :directory))
730 (cdr dir)))
731
732 ;; More sanity checking
733 (when dir
734 ;; Try to canonicalize the directory component. :absolute
735 ;; followed by a bunch of "/" deletes the leading "/"'s.
736 ;; :relative followed by "." anywhere gets them all deleted.
737 (ecase (first dir)
738 (:absolute
739 (do ((p (cdr dir) (cdr p)))
740 ((or (null p)
741 (not (equal "/" (car p))))
742 (setf (cdr dir) p))))
743 (:relative
744 (setf (cdr dir) (delete "." (cdr dir) :test #'equal)))))
745 ;; CLHS 19.2.2.4.3 says :absolute or :wild-inferiors immediately
746 ;; followed by :up or :back signals a file-error.
747
748 (let ((d (or (member :wild-inferiors dir)
749 (member :absolute dir))))
750 (when (and d (rest d) (member (second d) '(:up :back)))
751 ;; What should we put in the for pathname part of file-error?
752 ;; I'm just going to use the directory but removing the
753 ;; offending :up or :back. Or would just (make-pathname) be
754 ;; enough?
755 ;;
756 ;; Or instead of checking here, we could check whenever we
757 ;; "use" the file system (CLHS 19.2.2.4.3). But that's a lot
758 ;; harder to do.
759 (error 'simple-file-error
760 :pathname (make-pathname :directory (remove-if #'(lambda (x)
761 (member x '(:up :back)))
762 dir))
763 :format-control "Illegal pathname: ~
764 Directory with ~S immediately followed by ~S"
765 :format-arguments (list (first d) (second d)))))
766
767 (macrolet ((pick (var varp field)
768 `(cond ((or (simple-string-p ,var)
769 (pattern-p ,var))
770 (maybe-diddle-case ,var diddle-args))
771 ((stringp ,var)
772 (maybe-diddle-case (coerce ,var 'simple-string)
773 diddle-args))
774 (,varp
775 (maybe-diddle-case ,var diddle-args))
776 (defaults
777 (maybe-diddle-case (,field defaults)
778 diddle-defaults))
779 (t
780 nil))))
781 (%make-pathname-object host
782 dev ; forced to :unspecific when logical-host
783 dir
784 (pick name namep %pathname-name)
785 (pick type typep %pathname-type)
786 ver))))
787
788 ;;; PATHNAME-HOST -- Interface
789 ;;;
790 (defun pathname-host (pathname &key (case :local))
791 "Accessor for the pathname's host."
792 (declare (type path-designator pathname)
793 (type (member :local :common) case)
794 (values (or string null))
795 (ignore case))
796 (host-namestring pathname))
797
798 ;;; PATHNAME-DEVICE -- Interface
799 ;;;
800 (defun pathname-device (pathname &key (case :local))
801 "Accessor for pathname's device."
802 (declare (type path-designator pathname)
803 (type (member :local :common) case))
804 (with-pathname (pathname pathname)
805 (maybe-diddle-case (%pathname-device pathname)
806 (and (eq case :common)
807 (eq (host-customary-case
808 (%pathname-host pathname))
809 :lower)))))
810
811 ;;; PATHNAME-DIRECTORY -- Interface
812 ;;;
813 (defun pathname-directory (pathname &key (case :local))
814 "Accessor for the pathname's directory list."
815 (declare (type path-designator pathname)
816 (type (member :local :common) case))
817 (with-pathname (pathname pathname)
818 (maybe-diddle-case (%pathname-directory pathname)
819 (and (eq case :common)
820 (eq (host-customary-case
821 (%pathname-host pathname))
822 :lower)))))
823 ;;; PATHNAME-NAME -- Interface
824 ;;;
825 (defun pathname-name (pathname &key (case :local))
826 "Accessor for the pathname's name."
827 (declare (type path-designator pathname)
828 (type (member :local :common) case))
829 (with-pathname (pathname pathname)
830 (maybe-diddle-case (%pathname-name pathname)
831 (and (eq case :common)
832 (eq (host-customary-case
833 (%pathname-host pathname))
834 :lower)))))
835
836 ;;; PATHNAME-TYPE
837 ;;;
838 (defun pathname-type (pathname &key (case :local))
839 "Accessor for the pathname's name."
840 (declare (type path-designator pathname)
841 (type (member :local :common) case))
842 (with-pathname (pathname pathname)
843 (maybe-diddle-case (%pathname-type pathname)
844 (and (eq case :common)
845 (eq (host-customary-case
846 (%pathname-host pathname))
847 :lower)))))
848
849 ;;; PATHNAME-VERSION
850 ;;;
851 (defun pathname-version (pathname)
852 "Accessor for the pathname's version."
853 (declare (type path-designator pathname))
854 (with-pathname (pathname pathname)
855 (%pathname-version pathname)))
856
857
858 ;;;; Namestrings
859
860 ;;; %PRINT-NAMESTRING-PARSE-ERROR -- Internal
861 ;;;
862 (defun %print-namestring-parse-error (condition stream)
863 (format stream "Parse error in namestring: ~?~% ~A~% ~V@T^"
864 (namestring-parse-error-complaint condition)
865 (namestring-parse-error-arguments condition)
866 (namestring-parse-error-namestring condition)
867 (namestring-parse-error-offset condition)))
868
869 (define-condition namestring-parse-error (parse-error type-error)
870 ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
871 (arguments :reader namestring-parse-error-arguments :initarg :arguments
872 :initform nil)
873 (namestring :reader namestring-parse-error-namestring :initarg :namestring)
874 (offset :reader namestring-parse-error-offset :initarg :offset))
875 (:report %print-namestring-parse-error))
876
877
878 ;;; %PARSE-NAMESTRING -- Internal
879 ;;;
880 ;;; Handle the case where parse-namestring is actually parsing a namestring.
881 ;;; We pick off the :JUNK-ALLOWED case then find a host to use for parsing,
882 ;;; call the parser, then check if the host matches.
883 ;;;
884 (defun %parse-namestring (namestr host defaults start end junk-allowed)
885 (declare (type string namestr)
886 (type (or host string null) host)
887 (type pathname defaults)
888 (type index start)
889 (type (or index null) end))
890 (if junk-allowed
891 (handler-case
892 (%parse-namestring namestr host defaults start end nil)
893 (namestring-parse-error (condition)
894 (values nil (namestring-parse-error-offset condition))))
895 (let* ((end (or end (length namestr)))
896 (host (if (and host (stringp host))
897 (find-logical-host host)
898 host))
899 (default-host (%pathname-host defaults))
900 (parse-host (or host
901 (extract-logical-host-prefix namestr start end)
902 default-host)))
903 (unless parse-host
904 (error "When Host arg is not supplied, Defaults arg must ~
905 have a non-null PATHNAME-HOST."))
906
907 (multiple-value-bind
908 (new-host device directory file type version)
909 (funcall (host-parse parse-host) namestr start end)
910 (when (and host new-host (not (eq new-host host)))
911 (error "Host in namestring: ~S~@
912 does not match explicit host argument: ~S"
913 namestr host))
914 (let ((pn-host (or new-host parse-host)))
915 (values (%make-pathname-object
916 pn-host device directory file type version)
917 end))))))
918
919
920 ;;; EXTRACT-LOGICAL-HOST-PREFIX -- Internal
921 ;;;
922 ;;; If namestr begins with a colon-terminated, defined, logical host, then
923 ;;; return that host, otherwise return NIL.
924 ;;;
925 (defun extract-logical-host-prefix (namestr start end)
926 (declare (type simple-base-string namestr)
927 (type index start end)
928 (values (or logical-host null)))
929 (let ((colon-pos (position #\: namestr :start start :end end)))
930 (if colon-pos
931 (find-logical-host (nstring-upcase (subseq namestr start colon-pos))
932 nil)
933 nil)))
934
935 ;;; PARSE-NAMESTRING -- Interface
936 ;;;
937 (defun parse-namestring (thing
938 &optional host (defaults *default-pathname-defaults*)
939 &key (start 0) end junk-allowed)
940 "Converts pathname, a pathname designator, into a pathname structure,
941 for a physical pathname, returns the printed representation. Host may be
942 a physical host structure or host namestring."
943 (declare (type path-designator thing)
944 (type (or list string host (member :unspecific)) host)
945 (type pathname defaults)
946 (type index start)
947 (type (or index null) end))
948 ;; Generally, redundant specification of information in software,
949 ;; whether in code or in comments, is bad. However, the ANSI spec
950 ;; for this is messy enough that it's hard to hold in short-term
951 ;; memory, so I've recorded these redundant notes on the
952 ;; implications of the ANSI spec.
953 ;;
954 ;; According to the ANSI spec, HOST can be a valid pathname host, or
955 ;; a logical host, or NIL.
956 ;;
957 ;; A valid pathname host can be a valid physical pathname host or a
958 ;; valid logical pathname host.
959 ;;
960 ;; A valid physical pathname host is "any of a string, a list of
961 ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
962 ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
963 ;; that means :UNSPECIFIC: though someday we might want to
964 ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
965 ;; '("RTFM" "MIT" "EDU"), that's not supported now.
966 ;;
967 ;; A valid logical pathname host is a string which has been defined as
968 ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
969 ;;
970 (let ((host (etypecase host
971 ((string 0)
972 ;; This is a special host. It's not valid as a
973 ;; logical host, so it is a sensible thing to
974 ;; designate the physical Unix host object. So
975 ;; we do that.
976 *unix-host*)
977 (string
978 ;; In general ANSI-compliant Common Lisps, a
979 ;; string might also be a physical pathname host,
980 ;; but ANSI leaves this up to the implementor,
981 ;; and in CMUCL we don't do it, so it must be a
982 ;; logical host.
983 (find-logical-host host))
984 ((or null (member :unspecific))
985 ;; CLHS says that HOST=:UNSPECIFIC has
986 ;; implementation-defined behavior. We
987 ;; just turn it into NIL.
988 nil)
989 (list
990 ;; ANSI also allows LISTs to designate hosts,
991 ;; but leaves its interpretation
992 ;; implementation-defined. Our interpretation
993 ;; is that it's unsupported.:-|
994 (error "A LIST representing a pathname host is not ~
995 supported in this implementation:~% ~S"
996 host))
997 (host
998 host))))
999 (declare (type (or null host) host))
1000 (etypecase thing
1001 (simple-string
1002 (%parse-namestring thing host defaults start end junk-allowed))
1003 (string
1004 (%parse-namestring (coerce thing 'simple-string)
1005 host defaults start end junk-allowed))
1006 (pathname
1007 (let ((host (if host host (%pathname-host defaults))))
1008 (unless (eq host (%pathname-host thing))
1009 (error "Hosts do not match: ~S and ~S."
1010 host (%pathname-host thing))))
1011 (values thing start))
1012 (stream
1013 (let ((name (file-name thing)))
1014 (unless name
1015 (error 'simple-type-error
1016 :datum thing
1017 :expected-type 'pathname
1018 :format-control "Can't figure out the file associated with stream:~% ~S"
1019 :format-arguments (list thing)))
1020 (values name nil))))))
1021
1022
1023 ;;; NAMESTRING -- Interface
1024 ;;;
1025 (defun namestring (pathname)
1026 "Construct the full (name)string form of the pathname."
1027 (declare (type path-designator pathname)
1028 (values (or null simple-base-string)))
1029 (with-pathname (pathname pathname)
1030 (when pathname
1031 (let ((host (or (%pathname-host pathname)
1032 ;; Is this what we really want? Does a NIL host
1033 ;; really mean to get it from *d-p-d* and, if
1034 ;; that's NIL, use *unix-host*?
1035 (%pathname-host *default-pathname-defaults*)
1036 *unix-host*)
1037 ))
1038 (unless host
1039 (error "Cannot determine the namestring for pathnames with no ~
1040 host:~% ~S" pathname))
1041 (funcall (host-unparse host) pathname)))))
1042
1043
1044 ;;; HOST-NAMESTRING -- Interface
1045 ;;;
1046 (defun host-namestring (pathname)
1047 "Returns a string representation of the name of the host in the pathname."
1048 (declare (type path-designator pathname)
1049 (values (or null simple-base-string)))
1050 (with-pathname (pathname pathname)
1051 (let ((host (%pathname-host pathname)))
1052 (if host
1053 (funcall (host-unparse-host host) pathname)
1054 (error
1055 "Cannot determine the namestring for pathnames with no host:~% ~S"
1056 pathname)))))
1057
1058 ;;; DIRECTORY-NAMESTRING -- Interface
1059 ;;;
1060 (defun directory-namestring (pathname)
1061 "Returns a string representation of the directories used in the pathname."
1062 (declare (type path-designator pathname)
1063 (values (or null simple-base-string)))
1064 (with-pathname (pathname pathname)
1065 (let ((host (%pathname-host pathname)))
1066 (if host
1067 (funcall (host-unparse-directory host) pathname)
1068 (error
1069 "Cannot determine the namestring for pathnames with no host:~% ~S"
1070 pathname)))))
1071
1072 ;;; FILE-NAMESTRING -- Interface
1073 ;;;
1074 (defun file-namestring (pathname)
1075 "Returns a string representation of the name used in the pathname."
1076 (declare (type path-designator pathname)
1077 (values (or null simple-base-string)))
1078 (with-pathname (pathname pathname)
1079 (let ((host (%pathname-host pathname)))
1080 (if host
1081 (funcall (host-unparse-file host) pathname)
1082 (error
1083 "Cannot determine the namestring for pathnames with no host:~% ~S"
1084 pathname)))))
1085
1086 ;;; ENOUGH-NAMESTRING -- Interface
1087 ;;;
1088 (defun enough-namestring (pathname
1089 &optional (defaults *default-pathname-defaults*))
1090 "Returns an abbreviated pathname sufficent to identify the pathname relative
1091 to the defaults."
1092 (declare (type path-designator pathname))
1093 (with-pathname (pathname pathname)
1094 (let ((host (%pathname-host pathname)))
1095 (if host
1096 (with-pathname (defaults defaults)
1097 (funcall (host-unparse-enough host) pathname defaults))
1098 (error
1099 "Cannot determine the namestring for pathnames with no host:~% ~S"
1100 pathname)))))
1101
1102
1103 ;;;; Wild pathnames.
1104
1105 ;;; WILD-PATHNAME-P -- Interface
1106 ;;;
1107 (defun wild-pathname-p (pathname &optional field-key)
1108 "Predicate for determining whether pathname contains any wildcards."
1109 (declare (type path-designator pathname)
1110 (type (member nil :host :device :directory :name :type :version)
1111 field-key))
1112 (with-pathname (pathname pathname)
1113 (flet ((frob (x)
1114 (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
1115 (ecase field-key
1116 ((nil)
1117 (or (wild-pathname-p pathname :host)
1118 (wild-pathname-p pathname :device)
1119 (wild-pathname-p pathname :directory)
1120 (wild-pathname-p pathname :name)
1121 (wild-pathname-p pathname :type)
1122 (wild-pathname-p pathname :version)))
1123 (:host (frob (%pathname-host pathname)))
1124 (:device (frob (%pathname-device pathname)))
1125 (:directory (some #'frob (%pathname-directory pathname)))
1126 (:name (frob (%pathname-name pathname)))
1127 (:type (frob (%pathname-type pathname)))
1128 (:version (frob (%pathname-version pathname)))))))
1129
1130
1131 ;;; PATHNAME-MATCH-P -- Interface
1132 ;;;
1133 (defun pathname-match-p (in-pathname in-wildname)
1134 "Pathname matches the wildname template?"
1135 (declare (type path-designator in-pathname))
1136 (with-pathname (pathname in-pathname)
1137 (with-pathname (wildname in-wildname)
1138 (macrolet ((frob (field &optional (op 'components-match ))
1139 `(or (null (,field wildname))
1140 (,op (,field pathname) (,field wildname)))))
1141 (and (or (null (%pathname-host wildname))
1142 (eq (%pathname-host wildname) (%pathname-host pathname)))
1143 (frob %pathname-device)
1144 (frob %pathname-directory directory-components-match)
1145 (frob %pathname-name)
1146 (frob %pathname-type)
1147 (frob %pathname-version))))))
1148
1149
1150 ;;; SUBSTITUTE-INTO -- Internal
1151 ;;;
1152 ;;; Place the substitutions into the pattern and return the string or pattern
1153 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
1154 ;;; in case we are translating between hosts with difference conventional case.
1155 ;;; The second value is the tail of subs with all of the values that we used up
1156 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
1157 ;;; as a single string, so we ignore subsequent contiguous wildcards.
1158 ;;;
1159 (defun substitute-into (pattern subs diddle-case)
1160 (declare (type pattern pattern)
1161 (type list subs)
1162 (values (or simple-base-string pattern) list))
1163 (let ((in-wildcard nil)
1164 (pieces nil)
1165 (strings nil))
1166 (dolist (piece (pattern-pieces pattern))
1167 (cond ((simple-string-p piece)
1168 (push piece strings)
1169 (setf in-wildcard nil))
1170 (in-wildcard)
1171 (t
1172 (setf in-wildcard t)
1173 (unless subs
1174 (error "Not enough wildcards in FROM pattern to match ~
1175 TO pattern:~% ~S"
1176 pattern))
1177 (let ((sub (pop subs)))
1178 (typecase sub
1179 (pattern
1180 (when strings
1181 (push (apply #'concatenate 'simple-string
1182 (nreverse strings))
1183 pieces))
1184 (dolist (piece (pattern-pieces sub))
1185 (push piece pieces)))
1186 (simple-string
1187 (push sub strings))
1188 (t
1189 (error "Can't substitute this into the middle of a word:~
1190 ~% ~S"
1191 sub)))))))
1192
1193 (when strings
1194 (push (apply #'concatenate 'simple-string (nreverse strings))
1195 pieces))
1196 (values
1197 (maybe-diddle-case
1198 (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
1199 (car pieces)
1200 (make-pattern (nreverse pieces)))
1201 diddle-case)
1202 subs)))
1203
1204
1205 ;;; DIDNT-MATCH-ERROR -- Internal
1206 ;;;
1207 ;;; Called when we can't see how source and from matched.
1208 ;;;
1209 (defun didnt-match-error (source from)
1210 (error "Pathname components from Source and From args to TRANSLATE-PATHNAME~@
1211 did not match:~% ~S ~S"
1212 source from))
1213
1214
1215 ;;; TRANSLATE-COMPONENT -- Internal
1216 ;;;
1217 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
1218 ;;;
1219 (defun translate-component (source from to diddle-case)
1220 (typecase to
1221 (pattern
1222 (typecase from
1223 (pattern
1224 (typecase source
1225 (pattern
1226 (if (pattern= from source)
1227 source
1228 (didnt-match-error source from)))
1229 (simple-string
1230 (multiple-value-bind
1231 (won subs)
1232 (pattern-matches from source)
1233 (if won
1234 (values (substitute-into to subs diddle-case))
1235 (didnt-match-error source from))))
1236 (t
1237 (maybe-diddle-case source diddle-case))))
1238 ((member :wild)
1239 (values (substitute-into to (list source) diddle-case)))
1240 (t
1241 (if (components-match source from)
1242 (maybe-diddle-case source diddle-case)
1243 (didnt-match-error source from)))))
1244 ((member nil :wild)
1245 (maybe-diddle-case source diddle-case))
1246 (t
1247 (if (components-match source from)
1248 to
1249 (didnt-match-error source from)))))
1250
1251
1252 ;;; COMPUTE-DIRECTORY-SUBSTITUTIONS -- Internal
1253 ;;;
1254 ;;; Return a list of all the things that we want to substitute into the TO
1255 ;;; pattern (the things matched by from on source.) When From contains
1256 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1257 ;;; subdirectories.
1258 ;;;
1259 (defun compute-directory-substitutions (orig-source orig-from)
1260 (let ((source orig-source)
1261 (from orig-from))
1262 (collect ((subs))
1263 (loop
1264 (unless source
1265 (unless (every #'(lambda (x) (eq x :wild-inferiors)) from)
1266 (didnt-match-error orig-source orig-from))
1267 (subs ())
1268 (return))
1269 (unless from (didnt-match-error orig-source orig-from))
1270 (let ((from-part (pop from))
1271 (source-part (pop source)))
1272 (typecase from-part
1273 (pattern
1274 (typecase source-part
1275 (pattern
1276 (if (pattern= from-part source-part)
1277 (subs source-part)
1278 (didnt-match-error orig-source orig-from)))
1279 (simple-string
1280 (multiple-value-bind
1281 (won new-subs)
1282 (pattern-matches from-part source-part)
1283 (if won
1284 (dolist (sub new-subs)
1285 (subs sub))
1286 (didnt-match-error orig-source orig-from))))
1287 (t
1288 (didnt-match-error orig-source orig-from))))
1289 ((member :wild)
1290 (subs source-part))
1291 ((member :wild-inferiors)
1292 (let ((remaining-source (cons source-part source)))
1293 (collect ((res))
1294 (loop
1295 (when (directory-components-match remaining-source from)
1296 (return))
1297 (unless remaining-source
1298 (didnt-match-error orig-source orig-from))
1299 (res (pop remaining-source)))
1300 (subs (res))
1301 (setq source remaining-source))))
1302 (simple-string
1303 (unless (and (simple-string-p source-part)
1304 (string= from-part source-part))
1305 (didnt-match-error orig-source orig-from)))
1306 (t
1307 (didnt-match-error orig-source orig-from)))))
1308 (subs))))
1309
1310
1311 ;;; TRANSLATE-DIRECTORIES -- Internal
1312 ;;;
1313 ;;; Called by TRANSLATE-PATHNAME on the directory components of its argument
1314 ;;; pathanames to produce the result directory component. If any leaves the
1315 ;;; directory NIL, we return the source directory. The :RELATIVE or :ABSOLUTE
1316 ;;; is taken from the source directory, except if TO is :ABSOLUTE, in which
1317 ;;; case the result will be :ABSOLUTE.
1318 ;;;
1319 (defun translate-directories (source from to diddle-case)
1320 (if (not (and source to from))
1321 (let ((source (mapcar #'(lambda (x) (maybe-diddle-case x diddle-case))
1322 source)))
1323 (if (null to)
1324 source
1325 (collect ((res))
1326 (res (cond ((null source) (first to))
1327 ((eq (first to) :absolute) :absolute)
1328 (t (first source))))
1329 (let ((match (rest source)))
1330 (dolist (to-part (rest to))
1331 (cond ((eq to-part :wild)
1332 (when match
1333 (res (first match))
1334 (setf match nil)))
1335 ((eq to-part :wild-inferiors)
1336 (when match
1337 (dolist (src-part match)
1338 (res src-part))
1339 (setf match nil)))
1340 (t
1341 (res to-part)))))
1342 (res))))
1343 (collect ((res))
1344 (res (if (eq (first to) :absolute)
1345 :absolute
1346 (first source)))
1347 (let ((subs-left (compute-directory-substitutions (rest source)
1348 (rest from))))
1349 (dolist (to-part (rest to))
1350 (typecase to-part
1351 ((member :wild)
1352 (assert subs-left)
1353 (let ((match (pop subs-left)))
1354 (when (listp match)
1355 (error ":WILD-INFERIORS not paired in from and to ~
1356 patterns:~% ~S ~S" from to))
1357 (res (maybe-diddle-case match diddle-case))))
1358 ((member :wild-inferiors)
1359 (assert subs-left)
1360 (let ((match (pop subs-left)))
1361 (unless (listp match)
1362 (error ":WILD-INFERIORS not paired in from and to ~
1363 patterns:~% ~S ~S" from to))
1364 (dolist (x match)
1365 (res (maybe-diddle-case x diddle-case)))))
1366 (pattern
1367 (multiple-value-bind
1368 (new new-subs-left)
1369 (substitute-into to-part subs-left diddle-case)
1370 (setf subs-left new-subs-left)
1371 (res new)))
1372 (t (res to-part)))))
1373 (res))))
1374
1375
1376 ;;; TRANSLATE-PATHNAME -- Interface
1377 ;;;
1378 (defun translate-pathname (source from-wildname to-wildname &key)
1379 "Use the source pathname to translate the from-wildname's wild and
1380 unspecified elements into a completed to-pathname based on the to-wildname."
1381 (declare (type path-designator source from-wildname to-wildname))
1382 (with-pathname (source source)
1383 (with-pathname (from from-wildname)
1384 (with-pathname (to to-wildname)
1385 (let* ((source-host (%pathname-host source))
1386 (to-host (%pathname-host to))
1387 (diddle-case
1388 (and source-host to-host
1389 (not (eq (host-customary-case source-host)
1390 (host-customary-case to-host))))))
1391 (macrolet ((frob (field &optional (op 'translate-component))
1392 `(let ((result (,op (,field source)
1393 (,field from)
1394 (,field to)
1395 diddle-case)))
1396 (if (eq result :error)
1397 (error "~S doesn't match ~S" source from)
1398 result))))
1399 (%make-pathname-object
1400 (or to-host source-host)
1401 (frob %pathname-device)
1402 (frob %pathname-directory translate-directories)
1403 (frob %pathname-name)
1404 (frob %pathname-type)
1405 (frob %pathname-version))))))))
1406
1407
1408 ;;;; Search lists.
1409
1410 ;;; The SEARCH-LIST structure.
1411 ;;;
1412 (defstruct (search-list
1413 (:print-function %print-search-list)
1414 (:make-load-form-fun
1415 (lambda (search-list)
1416 (values `(intern-search-list ',(search-list-name search-list))
1417 nil))))
1418 ;;
1419 ;; The name of this search-list. Always stored in lowercase.
1420 (name (required-argument) :type simple-string)
1421 ;;
1422 ;; T if this search-list has been defined. Otherwise NIL.
1423 (defined nil :type (member t nil))
1424 ;;
1425 ;; The list of expansions for this search-list. Each expansion is the list
1426 ;; of directory components to use in place of this search-list.
1427 (expansions nil :type list))
1428
1429 (defun %print-search-list (sl stream depth)
1430 (declare (ignore depth))
1431 (print-unreadable-object (sl stream :type t)
1432 (write-string (search-list-name sl) stream)))
1433
1434 ;;; *SEARCH-LISTS* -- internal.
1435 ;;;
1436 ;;; Hash table mapping search-list names to search-list structures.
1437 ;;;
1438 (defvar *search-lists* (make-hash-table :test #'equal))
1439
1440 ;;; FIND-SEARCH-LIST -- internal
1441 ;;;
1442 (defun find-search-list (name &optional (flame-not-found-p t))
1443 (let ((search-list (gethash (string-downcase name) *search-lists*)))
1444 (if search-list search-list
1445 (when flame-not-found-p
1446 (error "Search-list ~a not defined." name)))))
1447
1448 ;;; INTERN-SEARCH-LIST -- internal interface.
1449 ;;;
1450 ;;; When search-lists are encountered in namestrings, they are converted to
1451 ;;; search-list structures right then, instead of waiting until the search
1452 ;;; list used. This allows us to verify ahead of time that there are no
1453 ;;; circularities and makes expansion much quicker.
1454 ;;;
1455 (defun intern-search-list (name)
1456 (let ((name (string-downcase name)))
1457 (or (gethash name *search-lists*)
1458 (let ((new (make-search-list :name name)))
1459 (setf (gethash name *search-lists*) new)
1460 new))))
1461
1462 ;;; CLEAR-SEARCH-LIST -- public.
1463 ;;;
1464 ;;; Clear the definition. Note: we can't remove it from the hash-table
1465 ;;; because there may be pathnames still refering to it. So we just clear
1466 ;;; out the expansions and set defined to NIL.
1467 ;;;
1468 (defun clear-search-list (name)
1469 "Clear the current definition for the search-list NAME. Returns T if such
1470 a definition existed, and NIL if not."
1471 (let* ((name (string-downcase name))
1472 (search-list (gethash name *search-lists*)))
1473 (when (and search-list (search-list-defined search-list))
1474 (setf (search-list-defined search-list) nil)
1475 (setf (search-list-expansions search-list) nil)
1476 t)))
1477
1478 ;;; CLEAR-ALL-SEARCH-LISTS -- sorta public.
1479 ;;;
1480 ;;; Again, we can't actually remove the entries from the hash-table, so we
1481 ;;; just mark them as being undefined.
1482 ;;;
1483 (defun clear-all-search-lists ()
1484 "Clear the definition for all search-lists. Only use this if you know
1485 what you are doing."
1486 (maphash #'(lambda (name search-list)
1487 (declare (ignore name))
1488 (setf (search-list-defined search-list) nil)
1489 (setf (search-list-expansions search-list) nil))
1490 *search-lists*)
1491 nil)
1492
1493 ;;; EXTRACT-SEARCH-LIST -- internal.
1494 ;;;
1495 ;;; Extract the search-list from PATHNAME and return it. If PATHNAME
1496 ;;; doesn't start with a search-list, then either error (if FLAME-IF-NONE
1497 ;;; is true) or return NIL (if FLAME-IF-NONE is false).
1498 ;;;
1499 (defun extract-search-list (pathname flame-if-none)
1500 (with-pathname (pathname pathname)
1501 (let* ((directory (%pathname-directory pathname))
1502 (search-list (cadr directory)))
1503 (cond ((search-list-p search-list)
1504 search-list)
1505 (flame-if-none
1506 (error "~S doesn't start with a search-list." pathname))
1507 (t
1508 nil)))))
1509
1510 ;;; SEARCH-LIST -- public.
1511 ;;;
1512 ;;; We have to convert the internal form of the search-list back into a
1513 ;;; bunch of pathnames.
1514 ;;;
1515 (defun search-list (pathname)
1516 "Return the expansions for the search-list starting PATHNAME. If PATHNAME
1517 does not start with a search-list, then an error is signaled. If
1518 the search-list has not been defined yet, then an error is signaled.
1519 The expansion for a search-list can be set with SETF."
1520 (with-pathname (pathname pathname)
1521 (let ((search-list (extract-search-list pathname t))
1522 (host (%pathname-host pathname)))
1523 (if (search-list-defined search-list)
1524 (mapcar #'(lambda (directory)
1525 (make-pathname :host host
1526 :directory (cons :absolute directory)))
1527 (search-list-expansions search-list))
1528 (error "Search list ~S has not been defined yet." pathname)))))
1529
1530 ;;; SEARCH-LIST-DEFINED-P -- public.
1531 ;;;
1532 (defun search-list-defined-p (pathname)
1533 "Returns T if the search-list starting PATHNAME is currently defined, and
1534 NIL otherwise. An error is signaled if PATHNAME does not start with a
1535 search-list."
1536 (with-pathname (pathname pathname)
1537 (search-list-defined (extract-search-list pathname t))))
1538
1539 ;;; %SET-SEARCH-LIST -- public setf method
1540 ;;;
1541 ;;; Set the expansion for the search-list in PATHNAME. If this would result
1542 ;;; in any circularities, we flame out. If anything goes wrong, we leave the
1543 ;;; old defintion intact.
1544 ;;;
1545 (defun %set-search-list (pathname values)
1546 (let ((search-list (extract-search-list pathname t)))
1547 (labels
1548 ((check (target-list path)
1549 (when (eq search-list target-list)
1550 (error "That would result in a circularity:~% ~
1551 ~A~{ -> ~A~} -> ~A"
1552 (search-list-name search-list)
1553 (reverse path)
1554 (search-list-name target-list)))
1555 (when (search-list-p target-list)
1556 (push (search-list-name target-list) path)
1557 (dolist (expansion (search-list-expansions target-list))
1558 (check (car expansion) path))))
1559 (convert (pathname)
1560 (with-pathname (pathname pathname)
1561 (when (or (pathname-name pathname)
1562 (pathname-type pathname)
1563 (pathname-version pathname))
1564 (error "Search-lists cannot expand into pathnames that have ~
1565 a name, type, or ~%version specified:~% ~S"
1566 pathname))
1567 (let ((directory (pathname-directory pathname)))
1568 (let ((expansion
1569 (if directory
1570 (ecase (car directory)
1571 (:absolute (cdr directory))
1572 (:relative (cons (intern-search-list "default")
1573 (cdr directory))))
1574 (list (intern-search-list "default")))))
1575 (check (car expansion) nil)
1576 expansion)))))
1577 (setf (search-list-expansions search-list)
1578 (if (listp values)
1579 (mapcar #'convert values)
1580 (list (convert values)))))
1581 (setf (search-list-defined search-list) t))
1582 values)
1583
1584 ;;; ENUMERATE-SEARCH-LIST -- public.
1585 ;;;
1586 (defmacro enumerate-search-list ((var pathname &optional result) &body body)
1587 "Execute BODY with VAR bound to each successive possible expansion for
1588 PATHNAME and then return RESULT. Note: if PATHNAME does not contain a
1589 search-list, then BODY is executed exactly once. Everything is wrapped
1590 in a block named NIL, so RETURN can be used to terminate early. Note:
1591 VAR is *not* bound inside of RESULT."
1592 (let ((body-name (gensym)))
1593 `(block nil
1594 (flet ((,body-name (,var)
1595 ,@body))
1596 (%enumerate-search-list ,pathname #',body-name)
1597 ,result))))
1598
1599 (defun %enumerate-search-list (pathname function)
1600 (let* ((pathname (if (logical-pathname-p pathname)
1601 (translate-logical-pathname pathname)
1602 pathname))
1603 (search-list (extract-search-list pathname nil)))
1604 (cond
1605 ((not search-list)
1606 (funcall function pathname))
1607 ((not (search-list-defined search-list))
1608 (error "Undefined search list: ~A"
1609 (search-list-name search-list)))
1610 (t
1611 (let ((tail (cddr (pathname-directory pathname))))
1612 (dolist (expansion
1613 (search-list-expansions search-list))
1614 (%enumerate-search-list (make-pathname :defaults pathname
1615 :directory
1616 (cons :absolute
1617 (append expansion
1618 tail)))
1619 function)))))))
1620
1621
1622 ;;;; Logical pathname support. ANSI 92-102 specification.
1623 ;;;; As logical-pathname translations are loaded they are canonicalized as
1624 ;;;; patterns to enable rapid efficent translation into physical pathnames.
1625
1626 ;;;; Utilities:
1627
1628 ;;; LOGICAL-WORD-OR-LOSE -- Internal
1629 ;;;
1630 ;;; Canonicalize a logical pathanme word by uppercasing it checking that it
1631 ;;; contains only legal characters.
1632 ;;;
1633 (defun logical-word-or-lose (word)
1634 (declare (string word))
1635 (let ((word (string-upcase word)))
1636 (dotimes (i (length word))
1637 (let ((ch (schar word i)))
1638 (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1639 (error 'namestring-parse-error
1640 :complaint "Logical namestring character ~
1641 is not alphanumeric or hyphen:~% ~S"
1642 :arguments (list ch)
1643 :namestring word :offset i))))
1644 word))
1645
1646
1647 ;;; FIND-LOGICAL-HOST -- Internal
1648 ;;;
1649 ;;; Given a logical host or string, return a logical host. If Error-p is
1650 ;;; NIL, then return NIL when no such host exists.
1651 ;;;
1652 (defun find-logical-host (thing &optional (errorp t))
1653 (etypecase thing
1654 (string
1655 (let* ((valid-hostname
1656 (catch 'error-bailout
1657 (handler-bind
1658 ((namestring-parse-error
1659 (lambda(c)(declare (ignore c))
1660 (unless errorp
1661 (throw 'error-bailout nil)))))
1662 (logical-word-or-lose thing))))
1663 (found
1664 (and valid-hostname
1665 (or (gethash valid-hostname *logical-hosts*)
1666 (and *autoload-translations*
1667 (ignore-errors
1668 (load-logical-pathname-translations
1669 valid-hostname))
1670 (gethash valid-hostname *logical-hosts*))))))
1671 (if (or found (not errorp))
1672 found
1673 (error 'simple-file-error
1674 :pathname thing
1675 :format-control "Logical host not yet defined: ~S"
1676 :format-arguments (list thing)))))
1677 (logical-host thing)))
1678
1679 ;;; INTERN-LOGICAL-HOST -- Internal
1680 ;;;
1681 ;;; Given a logical host name or host, return a logical host, creating a new
1682 ;;; one if necessary.
1683 ;;;
1684 (defun intern-logical-host (thing)
1685 (declare (values logical-host))
1686 (or (find-logical-host thing nil)
1687 (let* ((name (logical-word-or-lose thing))
1688 (new (make-logical-host :name name)))
1689 (setf (gethash name *logical-hosts*) new)
1690 new)))
1691
1692
1693 ;;;; Logical pathname parsing:
1694
1695 ;;; MAYBE-MAKE-LOGICAL-PATTERN -- Internal
1696 ;;;
1697 ;;; Deal with multi-char wildcards in a logical pathname token.
1698 ;;;
1699 (defun maybe-make-logical-pattern (namestring chunks)
1700 (let ((chunk (caar chunks)))
1701 (collect ((pattern))
1702 (let ((last-pos 0)
1703 (len (length chunk)))
1704 (declare (fixnum last-pos))
1705 (loop
1706 (when (= last-pos len) (return))
1707 (let ((pos (or (position #\* chunk :start last-pos) len)))
1708 (if (= pos last-pos)
1709 (when (pattern)
1710 (error 'namestring-parse-error
1711 :complaint "Double asterisk inside of logical ~
1712 word: ~S"
1713 :arguments (list chunk)
1714 :namestring namestring
1715 :offset (+ (cdar chunks) pos)))
1716 (pattern (subseq chunk last-pos pos)))
1717 (if (= pos len)
1718 (return)
1719 (pattern :multi-char-wild))
1720 (setq last-pos (1+ pos)))))
1721 (assert (pattern))
1722 (if (cdr (pattern))
1723 (make-pattern (pattern))
1724 (let ((x (car (pattern))))
1725 (if (eq x :multi-char-wild)
1726 :wild
1727 x))))))
1728
1729
1730 ;;; LOGICAL-CHUNKIFY -- Internal
1731 ;;;
1732 ;;; Return a list of conses where the cdr is the start position and the car
1733 ;;; is a string (token) or character (punctuation.)
1734 ;;;
1735 (defun logical-chunkify (namestr start end)
1736 (collect ((chunks))
1737 (do ((i start (1+ i))
1738 (prev start))
1739 ((= i end)
1740 (when (> end prev)
1741 (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1742 (let ((ch (schar namestr i)))
1743 (unless (or (alpha-char-p ch) (digit-char-p ch)
1744 (member ch '(#\- #\*)))
1745 (when (> i prev)
1746 (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1747 (setq prev (1+ i))
1748 (unless (member ch '(#\; #\: #\.))
1749 (error 'namestring-parse-error
1750 :complaint "Illegal character for logical pathname:~% ~S"
1751 :arguments (list ch)
1752 :namestring namestr
1753 :offset i))
1754 (chunks (cons ch i)))))
1755 (chunks)))
1756
1757
1758 ;;; PARSE-LOGICAL-NAMESTRING -- Internal
1759 ;;;
1760 ;;; Break up a logical-namestring, always a string, into its constituent
1761 ;;; parts.
1762 ;;;
1763 (defun parse-logical-namestring (namestr start end)
1764 (declare (type simple-base-string namestr)
1765 (type index start end))
1766 (collect ((directory))
1767 (let ((host nil)
1768 (name nil)
1769 (type nil)
1770 (version nil))
1771 (labels ((expecting (what chunks)
1772 (unless (and chunks (simple-string-p (caar chunks)))
1773 (error 'namestring-parse-error
1774 :complaint "Expecting ~A, got ~:[nothing~;~:*~S~]."
1775 :arguments (list what (caar chunks))
1776 :namestring namestr
1777 :offset (if chunks (cdar chunks) end)))
1778 (caar chunks))
1779 (parse-host (chunks)
1780 (case (caadr chunks)
1781 (#\:
1782 (setq host
1783 (find-logical-host (expecting "a host name" chunks)))
1784 (parse-relative (cddr chunks)))
1785 (t
1786 (parse-relative chunks))))
1787 (parse-relative (chunks)
1788 (case (caar chunks)
1789 (#\;
1790 (directory :relative)
1791 (parse-directory (cdr chunks)))
1792 (t
1793 (directory :absolute) ; Assumption! Maybe revoked later.
1794 (parse-directory chunks))))
1795 (parse-directory (chunks)
1796 (case (caadr chunks)
1797 (#\;
1798 (directory
1799 (let ((res (expecting "a directory name" chunks)))
1800 (cond ((string= res "..") :up)
1801 ((string= res "**") :wild-inferiors)
1802 (t
1803 (maybe-make-logical-pattern namestr chunks)))))
1804 (parse-directory (cddr chunks)))
1805 (t
1806 (parse-name chunks))))
1807 (parse-name (chunks)
1808 (when chunks
1809 (expecting "a file name" chunks)
1810 (setq name (maybe-make-logical-pattern namestr chunks))
1811 (expecting-dot (cdr chunks))))
1812 (expecting-dot (chunks)
1813 (when chunks
1814 (unless (eql (caar chunks) #\.)
1815 (error 'namestring-parse-error
1816 :complaint "Expecting a dot, got ~S."
1817 :arguments (list (caar chunks))
1818 :namestring namestr
1819 :offset (cdar chunks)))
1820 (if type
1821 (parse-version (cdr chunks))
1822 (parse-type (cdr chunks)))))
1823 (parse-type (chunks)
1824 (expecting "a file type" chunks)
1825 (setq type (maybe-make-logical-pattern namestr chunks))
1826 (expecting-dot (cdr chunks)))
1827 (parse-version (chunks)
1828 (let ((str (expecting "a positive integer, * or NEWEST"
1829 chunks)))
1830 (cond
1831 ((string= str "*") (setq version :wild))
1832 ((string= str "NEWEST") (setq version :newest))
1833 (t
1834 (multiple-value-bind
1835 (res pos)
1836 (parse-integer str :junk-allowed t)
1837 (unless (and res (plusp res))
1838 (error 'namestring-parse-error
1839 :complaint "Expected a positive integer, ~
1840 got ~S"
1841 :arguments (list str)
1842 :namestring namestr
1843 :offset (+ pos (cdar chunks))))
1844 (setq version res)))))
1845 (when (cdr chunks)
1846 (error 'namestring-parse-error
1847 :complaint "Extra stuff after end of file name."
1848 :namestring namestr
1849 :offset (cdadr chunks)))))
1850 (parse-host (logical-chunkify namestr start end)))
1851 (values host :unspecific
1852 (directory)
1853 name type version))))
1854
1855
1856 ;;; Can't defvar here because not all host methods are loaded yet.
1857 (declaim (special *logical-pathname-defaults*))
1858
1859 ;;; LOGICAL-PATHNAME -- Public
1860 ;;;
1861 (defun logical-pathname (pathspec)
1862 "Converts the pathspec argument to a logical-pathname and returns it."
1863 (declare (type (or logical-pathname string stream) pathspec)
1864 (values logical-pathname))
1865 (if (typep pathspec 'logical-pathname)
1866 pathspec
1867 (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1868 (when (eq (%pathname-host res)
1869 (%pathname-host *logical-pathname-defaults*))
1870 (error
1871 'simple-type-error
1872 :format-control "Logical namestring does not specify a host:~% ~S"
1873 :format-arguments (list pathspec)
1874 :datum pathspec
1875 :expected-type '(satisfies logical-pathname-namestring-p)))
1876 ;; Make sure the result is a logical pathname. This can
1877 ;; happen if the pathspec is stream, and the stream was opened
1878 ;; with a pathname instead of a logical-pathname.
1879 (check-type res logical-pathname)
1880 res)))
1881
1882
1883
1884 ;;;; Logical pathname unparsing:
1885
1886 ;;; UNPARSE-LOGICAL-DIRECTORY -- Internal
1887 ;;;
1888 (defun unparse-logical-directory (pathname)
1889 (declare (type pathname pathname))
1890 (collect ((pieces))
1891 (let ((directory (%pathname-directory pathname)))
1892 (when directory
1893 (ecase (pop directory)
1894 (:absolute) ;; Nothing special.
1895 (:relative (pieces ";")))
1896 (dolist (dir directory)
1897 (cond ((or (stringp dir) (pattern-p dir))
1898 (pieces (unparse-logical-piece dir))
1899 (pieces ";"))
1900 ((eq dir :wild)
1901 (pieces "*;"))
1902 ((eq dir :wild-inferiors)
1903 (pieces "**;"))
1904 (t
1905 (error "Invalid directory component: ~S" dir))))))
1906 (apply #'concatenate 'simple-string (pieces))))
1907
1908
1909 ;;; UNPARSE-LOGICAL-PIECE -- Internal
1910 ;;;
1911 (defun unparse-logical-piece (thing)
1912 (etypecase thing
1913 (simple-string thing)
1914 (pattern
1915 (collect ((strings))
1916 (dolist (piece (pattern-pieces thing))
1917 (etypecase piece
1918 (simple-string (strings piece))
1919 (keyword
1920 (cond ((eq piece :wild-inferiors)
1921 (strings "**"))
1922 ((eq piece :multi-char-wild)
1923 (strings "*"))
1924 (t (error "Invalid keyword: ~S" piece))))))
1925 (apply #'concatenate 'simple-string (strings))))))
1926
1927 ;;; UNPARSE-ENOUGH-NAMESTRING -- Internal
1928 ;;;
1929 (defun unparse-enough-namestring (pathname defaults)
1930 (let* ((path-dir (pathname-directory pathname))
1931 (def-dir (pathname-directory defaults))
1932 (enough-dir
1933 ;; Go down the directory lists to see what matches. What's
1934 ;; left is what we want, more or less.
1935 (cond ((and (eq (first path-dir) (first def-dir))
1936 (eq (first path-dir) :absolute))
1937 ;; Both paths are :absolute, so find where the common
1938 ;; parts end and return what's left
1939 (do* ((p (rest path-dir) (rest p))
1940 (d (rest def-dir) (rest d)))
1941 ((or (endp p) (endp d)
1942 (not (equal (first p) (first d))))
1943 `(:relative ,@p))))
1944 (t
1945 ;; At least one path is :relative, so just return the
1946 ;; original path. If the original path is :relative,
1947 ;; then that's the right one. If PATH-DIR is
1948 ;; :absolute, we want to return that except when
1949 ;; DEF-DIR is :absolute, as handled above. so return
1950 ;; the original directory.
1951 path-dir))))
1952 (make-pathname :host (%pathname-host pathname)
1953 :directory enough-dir
1954 :name (pathname-name pathname)
1955 :type (pathname-type pathname)
1956 :version (pathname-version pathname))))
1957
1958 ;;; UNPARSE-LOGICAL-NAMESTRING -- Internal
1959 ;;;
1960 (defun unparse-logical-namestring (pathname)
1961 (declare (type logical-pathname pathname))
1962 (concatenate 'simple-string
1963 (logical-host-name (%pathname-host pathname)) ":"
1964 (unparse-logical-directory pathname)
1965 (unparse-unix-file pathname)))
1966
1967
1968 ;;;; Logical pathname translations:
1969
1970 ;;; CANONICALIZE-LOGICAL-PATHNAME-TRANSLATIONS -- Internal
1971 ;;;
1972 ;;; Verify that the list of translations consists of lists and prepare
1973 ;;; canonical translations (parse pathnames and expand out wildcards into
1974 ;;; patterns).
1975 ;;;
1976 (defun canonicalize-logical-pathname-translations (transl-list host)
1977 (declare (type list transl-list) (type host host)
1978 (values list))
1979 (collect ((res))
1980 (dolist (tr transl-list)
1981 (unless (and (consp tr) (= (length tr) 2))
1982 (error "Logical pathname translation is not a two-list:~% ~S"
1983 tr))
1984 (let ((from (first tr)))
1985 (res (list (if (typep from 'logical-pathname)
1986 from
1987 (parse-namestring from host))
1988 (pathname (second tr))))))
1989 (res)))
1990
1991
1992 ;;; LOGICAL-PATHNAME-TRANSLATIONS -- Public
1993 ;;;
1994 (defun logical-pathname-translations (host)
1995 "Return the (logical) host object argument's list of translations."
1996 (declare (type (or string logical-host) host)
1997 (values list))
1998 (logical-host-translations (find-logical-host host)))
1999
2000 ;;; (SETF LOGICAL-PATHNAME-TRANSLATIONS) -- Public
2001 ;;;
2002 (defun (setf logical-pathname-translations) (translations host)
2003 "Set the translations list for the logical host argument.
2004 Return translations."
2005 (declare (type (or string logical-host) host)
2006 (type list translations)
2007 (values list))
2008
2009 (let ((maybe-search-list-host (concatenate 'string host ":")))
2010 (when (and (not (logical-pathname-p (pathname maybe-search-list-host)))
2011 (search-list-defined-p maybe-search-list-host))
2012 (cerror "Clobber search-list host with logical pathname host"
2013 "~S names a CMUCL search-list"
2014 host)))
2015 (let ((host (intern-logical-host host)))
2016 (setf (logical-host-canon-transls host)
2017 (canonicalize-logical-pathname-translations translations host))
2018 (setf (logical-host-translations host) translations)))
2019
2020
2021 ;;; The search mechanism for loading pathname translations uses the CMUCL
2022 ;;; extension of search-lists. The user can add to the library: search-list
2023 ;;; using setf. The file for translations should have the name defined by
2024 ;;; the hostname (a string) and with type component "translations".
2025
2026 ;;; LOAD-LOGICAL-PATHNAME-TRANSLATIONS -- Public
2027 ;;;
2028 (defun load-logical-pathname-translations (host)
2029 "Search for a logical pathname named host, if not already defined. If already
2030 defined no attempt to find or load a definition is attempted and NIL is
2031 returned. If host is not already defined, but definition is found and loaded
2032 successfully, T is returned, else error."
2033 (declare (type string host)
2034 (values (member t nil)))
2035 (let ((*autoload-translations* nil))
2036 (unless (or (string-equal host "library")
2037 (find-logical-host host nil))
2038 (with-open-file (in-str (make-pathname :defaults "library:"
2039 :name (string-downcase host)
2040 :type "translations"))
2041 (if *load-verbose*
2042 (format *error-output*
2043 ";; Loading pathname translations from ~A~%"
2044 (namestring (truename in-str))))
2045 (setf (logical-pathname-translations host) (read in-str)))
2046 t)))
2047
2048 ;;; TRANSLATE-LOGICAL-PATHNAME -- Public
2049 ;;;
2050 (defun translate-logical-pathname (pathname &key)
2051 "Translates pathname to a physical pathname, which is returned."
2052 (declare (type path-designator pathname)
2053 (values (or null pathname)))
2054 (typecase pathname
2055 (logical-pathname
2056 (dolist (x (logical-host-canon-transls (%pathname-host pathname))
2057 (error 'simple-file-error
2058 :pathname pathname
2059 :format-control "No translation for ~S"
2060 :format-arguments (list pathname)))
2061 (destructuring-bind (from to) x
2062 (when (pathname-match-p pathname from)
2063 (return (translate-logical-pathname
2064 (translate-pathname pathname from to)))))))
2065 (pathname pathname)
2066 (stream (translate-logical-pathname (pathname pathname)))
2067 (t (translate-logical-pathname (pathname pathname)))))
2068
2069 (defvar *logical-pathname-defaults*
2070 (%make-logical-pathname (make-logical-host :name "BOGUS") :unspecific
2071 nil nil nil nil))

  ViewVC Help
Powered by ViewVC 1.1.5