/[cmucl]/src/code/pathname.lisp
ViewVC logotype

Contents of /src/code/pathname.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.68 - (show annotations)
Tue Sep 7 15:13:51 2004 UTC (9 years, 7 months ago) by rtoy
Branch: MAIN
Changes since 1.67: +7 -2 lines
Print out logical pathnames using #P"..." instead of
#.(logical-pathname "...").
1 ;;; -*- Package: LISP -*-
2 ;;; **********************************************************************
3 ;;; This code was written as part of the CMU Common Lisp project at
4 ;;; Carnegie Mellon University, and has been placed in the public domain.
5 ;;;
6 (ext:file-comment
7 "$Header: /tiger/var/lib/cvsroots/cmucl/src/code/pathname.lisp,v 1.68 2004/09/07 15:13:51 rtoy Exp $")
8 ;;;
9 ;;; **********************************************************************
10 ;;;
11 ;;; Machine/filesystem independent pathname functions for CMU Common Lisp.
12 ;;;
13 ;;; Written by William Lott, Paul Gleichauf and Rob MacLachlan.
14 ;;; Earlier version written by Jim Large and Rob MacLachlan
15 ;;;
16 ;;; **********************************************************************
17
18 (in-package "LISP")
19
20 (export '(pathname pathnamep logical-pathname
21 parse-namestring merge-pathnames make-pathname
22 pathname-host pathname-device pathname-directory pathname-name
23 pathname-type pathname-version namestring file-namestring
24 directory-namestring host-namestring enough-namestring
25 wild-pathname-p pathname-match-p translate-pathname
26 translate-logical-pathname logical-pathname-translations
27 load-logical-pathname-translations *default-pathname-defaults*))
28
29 (in-package "EXTENSIONS")
30 (export '(search-list search-list-defined-p clear-search-list
31 enumerate-search-list *autoload-translations*))
32
33 (in-package "LISP")
34
35 (defvar *autoload-translations* nil
36 "When non-nil, attempt to load \"library:<host>.translations\" to resolve
37 an otherwise undefined logical host.")
38
39
40 ;;;; HOST structures
41
42 ;;; The host structure holds the functions that both parse the pathname
43 ;;; information into sturcture slot entries, and after translation the inverse
44 ;;; (unparse) functions.
45 ;;;
46 (defstruct (host
47 (:print-function %print-host))
48 (parse (required-argument) :type function)
49 (unparse (required-argument) :type function)
50 (unparse-host (required-argument) :type function)
51 (unparse-directory (required-argument) :type function)
52 (unparse-file (required-argument) :type function)
53 (unparse-enough (required-argument) :type function)
54 (customary-case (required-argument) :type (member :upper :lower)))
55
56 ;;; %PRINT-HOST -- Internal
57 ;;;
58 (defun %print-host (host stream depth)
59 (declare (ignore depth))
60 (print-unreadable-object (host stream :type t)))
61
62 (defstruct (logical-host
63 (:include host
64 (:parse #'parse-logical-namestring)
65 (:unparse #'unparse-logical-namestring)
66 (:unparse-host
67 #'(lambda (x) (logical-host-name (%pathname-host x))))
68 (:unparse-directory #'unparse-logical-directory)
69 (:unparse-file #'unparse-unix-file)
70 (:unparse-enough #'unparse-enough-namestring)
71 (:customary-case :upper))
72 (:make-load-form-fun make-logical-host-load-form-fun))
73 (name "" :type simple-base-string)
74 (translations nil :type list)
75 (canon-transls nil :type list))
76
77 (defun make-logical-host-load-form-fun (logical-host)
78 (values `(find-logical-host ',(logical-host-name logical-host))
79 nil))
80
81 ;;; The various magic tokens that are allowed to appear in pretty much all
82 ;;; pathname components.
83 ;;;
84 (deftype component-tokens ()
85 '(member nil :unspecific :wild))
86
87 ;;;; Pathname structures
88
89 (defstruct (pathname
90 (:conc-name %pathname-)
91 (:print-function %print-pathname)
92 (:constructor
93 %make-pathname (host device directory name type version))
94 (:predicate pathnamep)
95 (:make-load-form-fun :just-dump-it-normally))
96 ;; Slot holds the host, at present either a UNIX or logical host.
97 (host nil :type (or host null))
98 ;; Device is the name of a logical or physical device holding files.
99 (device nil :type (or simple-string component-tokens))
100 ;; A list of strings that are the component subdirectory components.
101 (directory nil :type list)
102 ;; The filename.
103 (name nil :type (or simple-string pattern component-tokens))
104 ;; The type extension of the file.
105 (type nil :type (or simple-string pattern component-tokens))
106 ;; The version number of the file, a positive integer, but not supported
107 ;; on standard UNIX filesystems.
108 (version nil :type (or integer component-tokens (member :newest))))
109
110 ;;; %PRINT-PATHNAME -- Internal
111 ;;;
112 ;;; The printed representation of the pathname structure.
113 ;;;
114 (defun %print-pathname (pathname stream depth)
115 (declare (ignore depth))
116 (let ((namestring (handler-case (namestring pathname)
117 (error nil))))
118 (cond (namestring
119 (if (or *print-escape* *print-readably*)
120 (format stream "#P~S" namestring)
121 (format stream "~A" namestring)))
122 (*print-readably*
123 (error "~S Cannot be printed readably." pathname))
124 (t
125 (funcall (formatter "#<Unprintable pathname, Host=~S, Device=~S, ~
126 Directory=~S, Name=~S, Type=~S, Version=~S>")
127 stream
128 (%pathname-host pathname)
129 (%pathname-device pathname)
130 (%pathname-directory pathname)
131 (%pathname-name pathname)
132 (%pathname-type pathname)
133 (%pathname-version pathname))))))
134
135 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
136 ;;;
137 ;;; Logical pathnames have the following format:
138 ;;;
139 ;;; logical-namestring ::=
140 ;;; [host ":"] [";"] {directory ";"}* [name] ["." type ["." version]]
141 ;;;
142 ;;; host ::= word
143 ;;; directory ::= word | wildcard-word | **
144 ;;; name ::= word | wildcard-word
145 ;;; type ::= word | wildcard-word
146 ;;; version ::= pos-int | newest | NEWEST | *
147 ;;; word ::= {uppercase-letter | digit | -}+
148 ;;; wildcard-word ::= [word] '* {word '*}* [word]
149 ;;; pos-int ::= integer > 0
150 ;;;
151 ;;; Physical pathnames include all these slots and a device slot.
152 ;;;
153 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
154
155 ;; Logical pathnames are a subclass of pathname, their class relations are
156 ;; mimiced using structures for efficency.
157
158 (defstruct (logical-pathname
159 (:conc-name %logical-pathname-)
160 (:print-function %print-logical-pathname)
161 (:include pathname)
162 (:constructor %make-logical-pathname
163 (host device directory name type version))
164 (:make-load-form-fun :just-dump-it-normally)))
165
166 (declaim (freeze-type logical-pathname logical-host))
167
168 ;;; %PRINT-LOGICAL-PATHNAME -- Internal
169 ;;;
170 ;;; The printed representation of the logical-pathname structure.
171 ;;; The potential conflict with search-lists requires isolating the printed
172 ;;; representation to use the i/o macro #.(logical-pathname <path-designator>).
173 ;;;
174 ;;; Is there really a potential conflict? CMUCL does not allow
175 ;;; search-list hosts and logical pathname hosts have the same name.
176 ;;; Hence, if we use #P to print them out, we can always read them
177 ;;; back without confusion. (rtoy)
178 ;;;
179 (defun %print-logical-pathname (pathname stream depth)
180 (declare (ignore depth))
181 (let ((namestring (handler-case (namestring pathname)
182 (error nil))))
183 (cond (namestring
184 (if (or *print-escape* *print-readably*)
185 (format stream "#P~S" namestring)
186 (format stream "~A" namestring)))
187 (*print-readably*
188 (error "~S Cannot be printed readably." pathname))
189 (t
190 (funcall (formatter "#<Unprintable pathname, Host=~S, ~
191 Directory=~S, File=~S, Name=~S, Version=~S>")
192 stream
193 (%pathname-host pathname)
194 (%pathname-directory pathname)
195 (%pathname-name pathname)
196 (%pathname-type pathname)
197 (%pathname-version pathname))))))
198
199 ;;; %MAKE-PATHNAME-OBJECT -- internal
200 ;;;
201 ;;; A pathname is logical if the host component is a logical-host.
202 ;;; This constructor is used to make an instance of the correct type
203 ;;; from parsed arguments.
204
205 (defun %make-pathname-object (host device directory name type version)
206 (if (typep host 'logical-host)
207 (flet ((upcasify (thing)
208 (typecase thing
209 (list
210 (mapcar #'(lambda (x)
211 (if (stringp x)
212 (string-upcase x)
213 x))
214 thing))
215 (simple-base-string
216 (string-upcase thing))
217 (t
218 thing))))
219 (%make-logical-pathname host :unspecific
220 (upcasify directory)
221 (upcasify name)
222 (upcasify type)
223 (upcasify version)))
224 (%make-pathname host device directory name type version)))
225
226 ;;; *LOGICAL-HOSTS* --internal.
227 ;;;
228 ;;; Hash table searching maps a logical-pathname's host to their physical
229 ;;; pathname translation.
230
231 (defvar *logical-hosts* (make-hash-table :test #'equal))
232
233 ;;; PATH-DESIGNATOR -- internal type
234 ;;;
235 (deftype path-designator ()
236 "A path specification, either a string, stream or pathname."
237 '(or string stream pathname))
238
239
240 ;;;; Patterns
241
242 ;;; Patterns are a list of entries and wildcards used for pattern matches
243 ;;; of translations.
244
245 (defstruct (pattern
246 (:print-function %print-pattern)
247 (:make-load-form-fun :just-dump-it-normally)
248 (:constructor make-pattern (pieces)))
249 (pieces nil :type list))
250
251 ;;; %PRINT-PATTERN -- Internal
252 ;;;
253 (defun %print-pattern (pattern stream depth)
254 (declare (ignore depth))
255 (print-unreadable-object (pattern stream :type t)
256 (if *print-pretty*
257 (let ((*print-escape* t))
258 (pprint-fill stream (pattern-pieces pattern) nil))
259 (prin1 (pattern-pieces pattern) stream))))
260
261 ;;; PATTERN= -- Internal
262 ;;;
263 (defun pattern= (pattern1 pattern2)
264 (declare (type pattern pattern1 pattern2))
265 (let ((pieces1 (pattern-pieces pattern1))
266 (pieces2 (pattern-pieces pattern2)))
267 (and (= (length pieces1) (length pieces2))
268 (every #'(lambda (piece1 piece2)
269 (typecase piece1
270 (simple-string
271 (and (simple-string-p piece2)
272 (string= piece1 piece2)))
273 (cons
274 (and (consp piece2)
275 (eq (car piece1) (car piece2))
276 (string= (cdr piece1) (cdr piece2))))
277 (t
278 (eq piece1 piece2))))
279 pieces1
280 pieces2))))
281
282 ;;; PATTERN-MATCHES -- Internal
283 ;;;
284 ;;; If the string matches the pattern returns the multiple values T and a
285 ;;; list of the matched strings.
286 ;;;
287 (defun pattern-matches (pattern string)
288 (declare (type pattern pattern)
289 (type simple-string string))
290 (let ((len (length string)))
291 (labels ((maybe-prepend (subs cur-sub chars)
292 (if cur-sub
293 (let* ((len (length chars))
294 (new (make-string len))
295 (index len))
296 (dolist (char chars)
297 (setf (schar new (decf index)) char))
298 (cons new subs))
299 subs))
300 (matches (pieces start subs cur-sub chars)
301 (if (null pieces)
302 (if (= start len)
303 (values t (maybe-prepend subs cur-sub chars))
304 (values nil nil))
305 (let ((piece (car pieces)))
306 (etypecase piece
307 (simple-string
308 (let ((end (+ start (length piece))))
309 (and (<= end len)
310 (string= piece string
311 :start2 start :end2 end)
312 (matches (cdr pieces) end
313 (maybe-prepend subs cur-sub chars)
314 nil nil))))
315 (list
316 (ecase (car piece)
317 (:character-set
318 (and (< start len)
319 (let ((char (schar string start)))
320 (if (find char (second piece) :test #'char=)
321 (matches (cdr pieces) (1+ start) subs t
322 (cons char chars))))))))
323 ((member :single-char-wild)
324 (and (< start len)
325 (matches (cdr pieces) (1+ start) subs t
326 (cons (schar string start) chars))))
327 ((member :multi-char-wild)
328 (multiple-value-bind
329 (won new-subs)
330 (matches (cdr pieces) start subs t chars)
331 (if won
332 (values t new-subs)
333 (and (< start len)
334 (matches pieces (1+ start) subs t
335 (cons (schar string start)
336 chars)))))))))))
337 (multiple-value-bind
338 (won subs)
339 (matches (pattern-pieces pattern) 0 nil nil nil)
340 (values won (reverse subs))))))
341
342
343 ;;; DIRECTORY-COMPONENTS-MATCH -- Internal
344 ;;;
345 ;;; Pathname-match-p for directory components. If thing is empty
346 ;;; then it matches :wild, (:absolute :wild-inferiors), or (:relative
347 ;;; :wild-inferiors).
348 ;;;
349 (defun directory-components-match (thing wild)
350 (or (eq thing wild)
351 (eq wild :wild)
352 (and (consp wild)
353 (let ((wild1 (first wild)))
354 (cond ((and (null thing) (member wild1 '(:absolute :relative)))
355 (equal (rest wild) '(:wild-inferiors)))
356 ((eq wild1 :wild-inferiors)
357 (let ((wild-subdirs (rest wild)))
358 (or (null wild-subdirs)
359 (loop
360 (when (directory-components-match thing
361 wild-subdirs)
362 (return t))
363 (pop thing)
364 (unless thing (return nil))))))
365 ((consp thing)
366 (and (components-match (first thing) wild1)
367 (directory-components-match (rest thing)
368 (rest wild)))))))))
369
370
371 ;;; COMPONENTS-MATCH -- Internal
372 ;;;
373 ;;; Return true if pathname component Thing is matched by Wild. Not
374 ;;; commutative.
375 ;;;
376 (defun components-match (thing wild)
377 (declare (type (or pattern symbol simple-string integer) thing wild))
378 (or (eq thing wild)
379 (eq wild :wild)
380 (typecase thing
381 (simple-base-string
382 ;; String is matched by itself, a matching pattern or :WILD.
383 (typecase wild
384 (pattern
385 (values (pattern-matches wild thing)))
386 (simple-base-string
387 (string= thing wild))))
388 (pattern
389 ;; A pattern is only matched by an identical pattern.
390 (and (pattern-p wild) (pattern= thing wild)))
391 (integer
392 ;; an integer (version number) is matched by :WILD or the same
393 ;; integer. This branch will actually always be NIL as long is the
394 ;; version is a fixnum.
395 (eql thing wild)))))
396
397
398 ;;; COMPARE-COMPONENT -- Internal
399 ;;;
400 ;;; A predicate for comparing two pathname slot component sub-entries.
401 ;;;
402 (defun compare-component (this that)
403 (or (eql this that)
404 (typecase this
405 (simple-string
406 (and (simple-string-p that)
407 (string= this that)))
408 (pattern
409 (and (pattern-p that)
410 (pattern= this that)))
411 (cons
412 (and (consp that)
413 (compare-component (car this) (car that))
414 (compare-component (cdr this) (cdr that)))))))
415
416
417 ;;;; Pathname functions.
418
419 ;;; Implementation determined defaults to pathname slots.
420
421 (defvar *default-pathname-defaults*)
422
423 ;;; PATHNAME= -- Internal
424 ;;;
425 (defun pathname= (pathname1 pathname2)
426 (declare (type pathname pathname1)
427 (type pathname pathname2))
428 (and (eq (%pathname-host pathname1)
429 (%pathname-host pathname2))
430 (compare-component (%pathname-device pathname1)
431 (%pathname-device pathname2))
432 (compare-component (%pathname-directory pathname1)
433 (%pathname-directory pathname2))
434 (compare-component (%pathname-name pathname1)
435 (%pathname-name pathname2))
436 (compare-component (%pathname-type pathname1)
437 (%pathname-type pathname2))
438 (compare-component (%pathname-version pathname1)
439 (%pathname-version pathname2))))
440
441 ;;; WITH-PATHNAME -- Internal
442 ;;; Converts the expr, a pathname designator (a pathname, or string, or
443 ;;; stream), into a pathname.
444 ;;;
445 (defmacro with-pathname ((var expr) &body body)
446 `(let ((,var (let ((,var ,expr))
447 (etypecase ,var
448 (pathname ,var)
449 (string (parse-namestring ,var))
450 (file-stream (file-name ,var))
451 (stream:file-simple-stream (file-name ,var))))))
452 ,@body))
453
454 ;;; WITH-HOST -- Internal
455 ;;;
456 ;;; Converts the var, a host or string name for a host, into a logical-host
457 ;;; structure or nil if not defined.
458 ;;;
459 ;;; pw notes 1/12/97 this potentially useful macro is not used anywhere
460 ;;; and 'find-host' is not defined. 'find-logical-host' seems to be needed.
461 ;;;
462 (defmacro with-host ((var expr) &body body)
463 `(let ((,var (let ((,var ,expr))
464 (typecase ,var
465 (logical-host ,var)
466 (string (find-logical-host ,var nil))
467 (t nil)))))
468 ,@body))
469
470 ;;; PATHNAME -- Interface
471 ;;;
472 (defun pathname (thing)
473 "Convert thing (a pathname, string or stream) into a pathname."
474 (declare (type path-designator thing))
475 (with-pathname (pathname thing)
476 pathname))
477
478 ;;; MAYBE-DIDDLE-CASE -- Internal
479 ;;;
480 ;;; Change the case of thing if diddle-p T.
481 ;;;
482 (defun maybe-diddle-case (thing diddle-p)
483 (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
484 (labels ((check-for (pred in)
485 (typecase in
486 (pattern
487 (dolist (piece (pattern-pieces in))
488 (when (typecase piece
489 (simple-string
490 (check-for pred piece))
491 (cons
492 (case (car in)
493 (:character-set
494 (check-for pred (cdr in))))))
495 (return t))))
496 (list
497 (dolist (x in)
498 (when (check-for pred x)
499 (return t))))
500 (simple-base-string
501 (dotimes (i (length in))
502 (when (funcall pred (schar in i))
503 (return t))))
504 (t nil)))
505 (diddle-with (fun thing)
506 (typecase thing
507 (pattern
508 (make-pattern
509 (mapcar #'(lambda (piece)
510 (typecase piece
511 (simple-base-string
512 (funcall fun piece))
513 (cons
514 (case (car piece)
515 (:character-set
516 (cons :character-set
517 (funcall fun (cdr piece))))
518 (t
519 piece)))
520 (t
521 piece)))
522 (pattern-pieces thing))))
523 (list
524 (mapcar fun thing))
525 (simple-base-string
526 (funcall fun thing))
527 (t
528 thing))))
529 (let ((any-uppers (check-for #'upper-case-p thing))
530 (any-lowers (check-for #'lower-case-p thing)))
531 (cond ((and any-uppers any-lowers)
532 ;; Mixed case, stays the same.
533 thing)
534 (any-uppers
535 ;; All uppercase, becomes all lower case.
536 (diddle-with #'(lambda (x) (if (stringp x)
537 (string-downcase x)
538 x)) thing))
539 (any-lowers
540 ;; All lowercase, becomes all upper case.
541 (diddle-with #'(lambda (x) (if (stringp x)
542 (string-upcase x)
543 x)) thing))
544 (t
545 ;; No letters? I guess just leave it.
546 thing))))
547 thing))
548
549
550 ;;; MERGE-DIRECTORIES -- Internal
551 ;;;
552 (defun merge-directories (dir1 dir2 diddle-case)
553 (if (or (eq (car dir1) :absolute)
554 (null dir2))
555 dir1
556 (let ((results nil))
557 (flet ((add (dir)
558 (if (and (eq dir :back)
559 results
560 (not (eq (car results) :back)))
561 (pop results)
562 (push dir results))))
563 (dolist (dir (maybe-diddle-case dir2 diddle-case))
564 (add dir))
565 (dolist (dir (cdr dir1))
566 (add dir)))
567 (reverse results))))
568
569 ;;; MERGE-PATHNAMES -- Interface
570 ;;;
571 (defun merge-pathnames (pathname
572 &optional
573 (defaults *default-pathname-defaults*)
574 (default-version :newest))
575 "Construct a filled in pathname by completing the unspecified components
576 from the defaults."
577 (declare (type path-designator pathname)
578 (type path-designator defaults)
579 (values pathname))
580 (with-pathname (defaults defaults)
581 (let ((pathname (let ((*default-pathname-defaults* defaults))
582 (pathname pathname))))
583 (let* ((default-host (%pathname-host defaults))
584 (pathname-host (%pathname-host pathname))
585 (diddle-case
586 (and default-host pathname-host
587 (not (eq (host-customary-case default-host)
588 (host-customary-case pathname-host))))))
589 (%make-pathname-object
590 (or pathname-host default-host)
591 (or (%pathname-device pathname)
592 (maybe-diddle-case (%pathname-device defaults)
593 diddle-case))
594 (merge-directories (%pathname-directory pathname)
595 (%pathname-directory defaults)
596 diddle-case)
597 (or (%pathname-name pathname)
598 (maybe-diddle-case (%pathname-name defaults)
599 diddle-case))
600 (or (%pathname-type pathname)
601 (maybe-diddle-case (%pathname-type defaults)
602 diddle-case))
603 (or (if (null (%pathname-name pathname))
604 (or (%pathname-version pathname)
605 (%pathname-version defaults))
606 (%pathname-version pathname))
607 default-version))))))
608
609 ;;; IMPORT-DIRECTORY -- Internal
610 ;;;
611 (defun import-directory (directory diddle-case)
612 (etypecase directory
613 (null nil)
614 ((member :wild) '(:absolute :wild-inferiors))
615 ((member :unspecific) '(:relative))
616 (list
617 (collect ((results))
618 (ecase (pop directory)
619 (:absolute
620 (results :absolute)
621 (when (search-list-p (car directory))
622 (results (pop directory))))
623 (:relative
624 (results :relative)))
625 (dolist (piece directory)
626 (cond ((member piece '(:wild :wild-inferiors :up :back))
627 (results piece))
628 ((or (simple-string-p piece) (pattern-p piece))
629 (results (maybe-diddle-case piece diddle-case)))
630 ((stringp piece)
631 (results (maybe-diddle-case (coerce piece 'simple-string)
632 diddle-case)))
633 (t
634 (error "~S is not allowed as a directory component." piece))))
635 (results)))
636 (simple-string
637 `(:absolute
638 ,(maybe-diddle-case directory diddle-case)))
639 (string
640 `(:absolute
641 ,(maybe-diddle-case (coerce directory 'simple-string)
642 diddle-case)))))
643
644 ;;; MAKE-PATHNAME -- Interface
645 ;;;
646 (defun make-pathname (&key host
647 (device nil devp)
648 (directory nil dirp)
649 (name nil namep)
650 (type nil typep)
651 (version nil versionp)
652 defaults
653 (case :local))
654 "Makes a new pathname from the component arguments. Note that host is
655 a host-structure or string."
656 (declare (type (or string host component-tokens) host)
657 (type (or string component-tokens) device)
658 (type (or list string pattern component-tokens) directory)
659 (type (or string pattern component-tokens) name type)
660 (type (or integer component-tokens (member :newest)) version)
661 (type (or path-designator null) defaults)
662 (type (member :common :local) case))
663 (let* ((defaults (when defaults
664 (with-pathname (defaults defaults) defaults)))
665 (default-host (if defaults
666 (%pathname-host defaults)
667 (%pathname-host *default-pathname-defaults*)))
668 ;; toy@rtp.ericsson.se: CLHS says make-pathname can take a
669 ;; string (as a logical-host) for the host part. We map that
670 ;; string into the corresponding logical host structure.
671
672 ;; pw@snoopy.mv.com:
673 ;; HyperSpec says for the arg to MAKE-PATHNAME;
674 ;; "host---a valid physical pathname host. ..."
675 ;; where it probably means -- a valid pathname host.
676 ;; "valid pathname host n. a valid physical pathname host or
677 ;; a valid logical pathname host."
678 ;; and defines
679 ;; "valid physical pathname host n. any of a string,
680 ;; a list of strings, or the symbol :unspecific,
681 ;; that is recognized by the implementation as the name of a host."
682 ;; "valid logical pathname host n. a string that has been defined
683 ;; as the name of a logical host. ..."
684 ;; HS is silent on what happens if the :host arg is NOT one of these.
685 ;; It seems an error message is appropriate.
686 (host (typecase host
687 (host host) ; A valid host, use it.
688 ((string 0) default-host) ; "" cannot be a logical host
689 (string (find-logical-host host t)) ; logical-host or lose.
690 (t default-host))) ; unix-host
691 (diddle-args (and (eq (host-customary-case host) :lower)
692 (eq case :common)))
693 (diddle-defaults
694 (not (eq (host-customary-case host)
695 (host-customary-case default-host))))
696 (dev (if devp device (if defaults (%pathname-device defaults))))
697 (dir (import-directory directory diddle-args))
698 (ver (cond
699 (versionp version)
700 (defaults (%pathname-version defaults))
701 (t nil))))
702 (when (and defaults (not dirp))
703 (setf dir
704 (merge-directories dir
705 (%pathname-directory defaults)
706 diddle-defaults)))
707
708 ;; A bit of sanity checking on user arguments.
709 (flet ((check-component-validity (name name-or-type)
710 (when (stringp name)
711 (let ((unix-directory-separator #\/))
712 (when (eq host (%pathname-host *default-pathname-defaults*))
713 (when (find unix-directory-separator name)
714 (warn "Silly argument for a unix ~A: ~S"
715 name-or-type name)))))))
716 (check-component-validity name :pathname-name)
717 (check-component-validity type :pathname-type))
718
719 ;; CLHS 19.2.2.4.3 says :absolute or :wild-inferiors immediately
720 ;; followed by :up or :back signals a file-error.
721
722 (let ((d (or (member :wild-inferiors dir)
723 (member :absolute dir))))
724 (when (and d (rest d) (member (second d) '(:up :back)))
725 (error 'file-error)))
726
727 (macrolet ((pick (var varp field)
728 `(cond ((or (simple-string-p ,var)
729 (pattern-p ,var))
730 (maybe-diddle-case ,var diddle-args))
731 ((stringp ,var)
732 (maybe-diddle-case (coerce ,var 'simple-string)
733 diddle-args))
734 (,varp
735 (maybe-diddle-case ,var diddle-args))
736 (defaults
737 (maybe-diddle-case (,field defaults)
738 diddle-defaults))
739 (t
740 nil))))
741 (%make-pathname-object host
742 dev ; forced to :unspecific when logical-host
743 dir
744 (pick name namep %pathname-name)
745 (pick type typep %pathname-type)
746 ver))))
747
748 ;;; PATHNAME-HOST -- Interface
749 ;;;
750 (defun pathname-host (pathname &key (case :local))
751 "Accessor for the pathname's host."
752 (declare (type path-designator pathname)
753 (type (member :local :common) case)
754 (values (or string null))
755 (ignore case))
756 (host-namestring pathname))
757
758 ;;; PATHNAME-DEVICE -- Interface
759 ;;;
760 (defun pathname-device (pathname &key (case :local))
761 "Accessor for pathname's device."
762 (declare (type path-designator pathname)
763 (type (member :local :common) case))
764 (with-pathname (pathname pathname)
765 (maybe-diddle-case (%pathname-device pathname)
766 (and (eq case :common)
767 (eq (host-customary-case
768 (%pathname-host pathname))
769 :lower)))))
770
771 ;;; PATHNAME-DIRECTORY -- Interface
772 ;;;
773 (defun pathname-directory (pathname &key (case :local))
774 "Accessor for the pathname's directory list."
775 (declare (type path-designator pathname)
776 (type (member :local :common) case))
777 (with-pathname (pathname pathname)
778 (maybe-diddle-case (%pathname-directory pathname)
779 (and (eq case :common)
780 (eq (host-customary-case
781 (%pathname-host pathname))
782 :lower)))))
783 ;;; PATHNAME-NAME -- Interface
784 ;;;
785 (defun pathname-name (pathname &key (case :local))
786 "Accessor for the pathname's name."
787 (declare (type path-designator pathname)
788 (type (member :local :common) case))
789 (with-pathname (pathname pathname)
790 (maybe-diddle-case (%pathname-name pathname)
791 (and (eq case :common)
792 (eq (host-customary-case
793 (%pathname-host pathname))
794 :lower)))))
795
796 ;;; PATHNAME-TYPE
797 ;;;
798 (defun pathname-type (pathname &key (case :local))
799 "Accessor for the pathname's name."
800 (declare (type path-designator pathname)
801 (type (member :local :common) case))
802 (with-pathname (pathname pathname)
803 (maybe-diddle-case (%pathname-type pathname)
804 (and (eq case :common)
805 (eq (host-customary-case
806 (%pathname-host pathname))
807 :lower)))))
808
809 ;;; PATHNAME-VERSION
810 ;;;
811 (defun pathname-version (pathname)
812 "Accessor for the pathname's version."
813 (declare (type path-designator pathname))
814 (with-pathname (pathname pathname)
815 (%pathname-version pathname)))
816
817
818 ;;;; Namestrings
819
820 ;;; %PRINT-NAMESTRING-PARSE-ERROR -- Internal
821 ;;;
822 (defun %print-namestring-parse-error (condition stream)
823 (format stream "Parse error in namestring: ~?~% ~A~% ~V@T^"
824 (namestring-parse-error-complaint condition)
825 (namestring-parse-error-arguments condition)
826 (namestring-parse-error-namestring condition)
827 (namestring-parse-error-offset condition)))
828
829 (define-condition namestring-parse-error (parse-error)
830 ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
831 (arguments :reader namestring-parse-error-arguments :initarg :arguments
832 :initform nil)
833 (namestring :reader namestring-parse-error-namestring :initarg :namestring)
834 (offset :reader namestring-parse-error-offset :initarg :offset))
835 (:report %print-namestring-parse-error))
836
837
838 ;;; %PARSE-NAMESTRING -- Internal
839 ;;;
840 ;;; Handle the case where parse-namestring is actually parsing a namestring.
841 ;;; We pick off the :JUNK-ALLOWED case then find a host to use for parsing,
842 ;;; call the parser, then check if the host matches.
843 ;;;
844 (defun %parse-namestring (namestr host defaults start end junk-allowed)
845 (declare (type string namestr)
846 (type (or host string null) host)
847 (type pathname defaults)
848 (type index start)
849 (type (or index null) end))
850 (if junk-allowed
851 (handler-case
852 (%parse-namestring namestr host defaults start end nil)
853 (namestring-parse-error (condition)
854 (values nil (namestring-parse-error-offset condition))))
855 (let* ((end (or end (length namestr)))
856 (host (if (and host (stringp host))
857 (find-logical-host host)
858 host))
859 (default-host (%pathname-host defaults))
860 (parse-host (or host
861 (extract-logical-host-prefix namestr start end)
862 default-host)))
863 (unless parse-host
864 (error "When Host arg is not supplied, Defaults arg must ~
865 have a non-null PATHNAME-HOST."))
866
867 (multiple-value-bind
868 (new-host device directory file type version)
869 (funcall (host-parse parse-host) namestr start end)
870 (when (and host new-host (not (eq new-host host)))
871 (error "Host in namestring: ~S~@
872 does not match explicit host argument: ~S"
873 namestr host))
874 (let ((pn-host (or new-host parse-host)))
875 (values (%make-pathname-object
876 pn-host device directory file type version)
877 end))))))
878
879
880 ;;; EXTRACT-LOGICAL-HOST-PREFIX -- Internal
881 ;;;
882 ;;; If namestr begins with a colon-terminated, defined, logical host, then
883 ;;; return that host, otherwise return NIL.
884 ;;;
885 (defun extract-logical-host-prefix (namestr start end)
886 (declare (type simple-base-string namestr)
887 (type index start end)
888 (values (or logical-host null)))
889 (let ((colon-pos (position #\: namestr :start start :end end)))
890 (if colon-pos
891 (find-logical-host (nstring-upcase (subseq namestr start colon-pos))
892 nil)
893 nil)))
894
895 ;;; PARSE-NAMESTRING -- Interface
896 ;;;
897 (defun parse-namestring (thing
898 &optional host (defaults *default-pathname-defaults*)
899 &key (start 0) end junk-allowed)
900 "Converts pathname, a pathname designator, into a pathname structure,
901 for a physical pathname, returns the printed representation. Host may be
902 a physical host structure or host namestring."
903 (declare (type path-designator thing)
904 (type (or list string host (member :unspecific)) host)
905 (type pathname defaults)
906 (type index start)
907 (type (or index null) end))
908 ;; Generally, redundant specification of information in software,
909 ;; whether in code or in comments, is bad. However, the ANSI spec
910 ;; for this is messy enough that it's hard to hold in short-term
911 ;; memory, so I've recorded these redundant notes on the
912 ;; implications of the ANSI spec.
913 ;;
914 ;; According to the ANSI spec, HOST can be a valid pathname host, or
915 ;; a logical host, or NIL.
916 ;;
917 ;; A valid pathname host can be a valid physical pathname host or a
918 ;; valid logical pathname host.
919 ;;
920 ;; A valid physical pathname host is "any of a string, a list of
921 ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
922 ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
923 ;; that means :UNSPECIFIC: though someday we might want to
924 ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
925 ;; '("RTFM" "MIT" "EDU"), that's not supported now.
926 ;;
927 ;; A valid logical pathname host is a string which has been defined as
928 ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
929 ;;
930 (let ((host (etypecase host
931 ((string 0)
932 ;; This is a special host. It's not valid as a
933 ;; logical host, so it is a sensible thing to
934 ;; designate the physical Unix host object. So
935 ;; we do that.
936 *unix-host*)
937 (string
938 ;; In general ANSI-compliant Common Lisps, a
939 ;; string might also be a physical pathname host,
940 ;; but ANSI leaves this up to the implementor,
941 ;; and in CMUCL we don't do it, so it must be a
942 ;; logical host.
943 (find-logical-host host))
944 ((or null (member :unspecific))
945 ;; CLHS says that HOST=:UNSPECIFIC has
946 ;; implementation-defined behavior. We
947 ;; just turn it into NIL.
948 nil)
949 (list
950 ;; ANSI also allows LISTs to designate hosts,
951 ;; but leaves its interpretation
952 ;; implementation-defined. Our interpretation
953 ;; is that it's unsupported.:-|
954 (error "A LIST representing a pathname host is not ~
955 supported in this implementation:~% ~S"
956 host))
957 (host
958 host))))
959 (declare (type (or null host) host))
960 (etypecase thing
961 (simple-string
962 (%parse-namestring thing host defaults start end junk-allowed))
963 (string
964 (%parse-namestring (coerce thing 'simple-string)
965 host defaults start end junk-allowed))
966 (pathname
967 (let ((host (if host host (%pathname-host defaults))))
968 (unless (eq host (%pathname-host thing))
969 (error "Hosts do not match: ~S and ~S."
970 host (%pathname-host thing))))
971 (values thing start))
972 (stream
973 (let ((name (file-name thing)))
974 (unless name
975 (error "Can't figure out the file associated with stream:~% ~S"
976 thing))
977 (values name nil))))))
978
979
980 ;;; NAMESTRING -- Interface
981 ;;;
982 (defun namestring (pathname)
983 "Construct the full (name)string form of the pathname."
984 (declare (type path-designator pathname)
985 (values (or null simple-base-string)))
986 (with-pathname (pathname pathname)
987 (when pathname
988 (let ((host (%pathname-host pathname)))
989 (unless host
990 (error "Cannot determine the namestring for pathnames with no ~
991 host:~% ~S" pathname))
992 (funcall (host-unparse host) pathname)))))
993
994
995 ;;; HOST-NAMESTRING -- Interface
996 ;;;
997 (defun host-namestring (pathname)
998 "Returns a string representation of the name of the host in the pathname."
999 (declare (type path-designator pathname)
1000 (values (or null simple-base-string)))
1001 (with-pathname (pathname pathname)
1002 (let ((host (%pathname-host pathname)))
1003 (if host
1004 (funcall (host-unparse-host host) pathname)
1005 (error
1006 "Cannot determine the namestring for pathnames with no host:~% ~S"
1007 pathname)))))
1008
1009 ;;; DIRECTORY-NAMESTRING -- Interface
1010 ;;;
1011 (defun directory-namestring (pathname)
1012 "Returns a string representation of the directories used in the pathname."
1013 (declare (type path-designator pathname)
1014 (values (or null simple-base-string)))
1015 (with-pathname (pathname pathname)
1016 (let ((host (%pathname-host pathname)))
1017 (if host
1018 (funcall (host-unparse-directory host) pathname)
1019 (error
1020 "Cannot determine the namestring for pathnames with no host:~% ~S"
1021 pathname)))))
1022
1023 ;;; FILE-NAMESTRING -- Interface
1024 ;;;
1025 (defun file-namestring (pathname)
1026 "Returns a string representation of the name used in the pathname."
1027 (declare (type path-designator pathname)
1028 (values (or null simple-base-string)))
1029 (with-pathname (pathname pathname)
1030 (let ((host (%pathname-host pathname)))
1031 (if host
1032 (funcall (host-unparse-file host) pathname)
1033 (error
1034 "Cannot determine the namestring for pathnames with no host:~% ~S"
1035 pathname)))))
1036
1037 ;;; ENOUGH-NAMESTRING -- Interface
1038 ;;;
1039 (defun enough-namestring (pathname
1040 &optional (defaults *default-pathname-defaults*))
1041 "Returns an abbreviated pathname sufficent to identify the pathname relative
1042 to the defaults."
1043 (declare (type path-designator pathname))
1044 (with-pathname (pathname pathname)
1045 (let ((host (%pathname-host pathname)))
1046 (if host
1047 (with-pathname (defaults defaults)
1048 (funcall (host-unparse-enough host) pathname defaults))
1049 (error
1050 "Cannot determine the namestring for pathnames with no host:~% ~S"
1051 pathname)))))
1052
1053
1054 ;;;; Wild pathnames.
1055
1056 ;;; WILD-PATHNAME-P -- Interface
1057 ;;;
1058 (defun wild-pathname-p (pathname &optional field-key)
1059 "Predicate for determining whether pathname contains any wildcards."
1060 (declare (type path-designator pathname)
1061 (type (member nil :host :device :directory :name :type :version)
1062 field-key))
1063 (with-pathname (pathname pathname)
1064 (flet ((frob (x)
1065 (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
1066 (ecase field-key
1067 ((nil)
1068 (or (wild-pathname-p pathname :host)
1069 (wild-pathname-p pathname :device)
1070 (wild-pathname-p pathname :directory)
1071 (wild-pathname-p pathname :name)
1072 (wild-pathname-p pathname :type)
1073 (wild-pathname-p pathname :version)))
1074 (:host (frob (%pathname-host pathname)))
1075 (:device (frob (%pathname-device pathname)))
1076 (:directory (some #'frob (%pathname-directory pathname)))
1077 (:name (frob (%pathname-name pathname)))
1078 (:type (frob (%pathname-type pathname)))
1079 (:version (frob (%pathname-version pathname)))))))
1080
1081
1082 ;;; PATHNAME-MATCH-P -- Interface
1083 ;;;
1084 (defun pathname-match-p (in-pathname in-wildname)
1085 "Pathname matches the wildname template?"
1086 (declare (type path-designator in-pathname))
1087 (with-pathname (pathname in-pathname)
1088 (with-pathname (wildname in-wildname)
1089 (macrolet ((frob (field &optional (op 'components-match ))
1090 `(or (null (,field wildname))
1091 (,op (,field pathname) (,field wildname)))))
1092 (and (or (null (%pathname-host wildname))
1093 (eq (%pathname-host wildname) (%pathname-host pathname)))
1094 (frob %pathname-device)
1095 (frob %pathname-directory directory-components-match)
1096 (frob %pathname-name)
1097 (frob %pathname-type)
1098 (frob %pathname-version))))))
1099
1100
1101 ;;; SUBSTITUTE-INTO -- Internal
1102 ;;;
1103 ;;; Place the substitutions into the pattern and return the string or pattern
1104 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
1105 ;;; in case we are translating between hosts with difference conventional case.
1106 ;;; The second value is the tail of subs with all of the values that we used up
1107 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
1108 ;;; as a single string, so we ignore subsequent contiguous wildcards.
1109 ;;;
1110 (defun substitute-into (pattern subs diddle-case)
1111 (declare (type pattern pattern)
1112 (type list subs)
1113 (values (or simple-base-string pattern) list))
1114 (let ((in-wildcard nil)
1115 (pieces nil)
1116 (strings nil))
1117 (dolist (piece (pattern-pieces pattern))
1118 (cond ((simple-string-p piece)
1119 (push piece strings)
1120 (setf in-wildcard nil))
1121 (in-wildcard)
1122 (t
1123 (setf in-wildcard t)
1124 (unless subs
1125 (error "Not enough wildcards in FROM pattern to match ~
1126 TO pattern:~% ~S"
1127 pattern))
1128 (let ((sub (pop subs)))
1129 (typecase sub
1130 (pattern
1131 (when strings
1132 (push (apply #'concatenate 'simple-string
1133 (nreverse strings))
1134 pieces))
1135 (dolist (piece (pattern-pieces sub))
1136 (push piece pieces)))
1137 (simple-string
1138 (push sub strings))
1139 (t
1140 (error "Can't substitute this into the middle of a word:~
1141 ~% ~S"
1142 sub)))))))
1143
1144 (when strings
1145 (push (apply #'concatenate 'simple-string (nreverse strings))
1146 pieces))
1147 (values
1148 (maybe-diddle-case
1149 (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
1150 (car pieces)
1151 (make-pattern (nreverse pieces)))
1152 diddle-case)
1153 subs)))
1154
1155
1156 ;;; DIDNT-MATCH-ERROR -- Internal
1157 ;;;
1158 ;;; Called when we can't see how source and from matched.
1159 ;;;
1160 (defun didnt-match-error (source from)
1161 (error "Pathname components from Source and From args to TRANSLATE-PATHNAME~@
1162 did not match:~% ~S ~S"
1163 source from))
1164
1165
1166 ;;; TRANSLATE-COMPONENT -- Internal
1167 ;;;
1168 ;;; Do TRANSLATE-COMPONENT for all components except host and directory.
1169 ;;;
1170 (defun translate-component (source from to diddle-case)
1171 (typecase to
1172 (pattern
1173 (typecase from
1174 (pattern
1175 (typecase source
1176 (pattern
1177 (if (pattern= from source)
1178 source
1179 (didnt-match-error source from)))
1180 (simple-string
1181 (multiple-value-bind
1182 (won subs)
1183 (pattern-matches from source)
1184 (if won
1185 (values (substitute-into to subs diddle-case))
1186 (didnt-match-error source from))))
1187 (t
1188 (maybe-diddle-case source diddle-case))))
1189 ((member :wild)
1190 (values (substitute-into to (list source) diddle-case)))
1191 (t
1192 (if (components-match source from)
1193 (maybe-diddle-case source diddle-case)
1194 (didnt-match-error source from)))))
1195 ((member nil :wild)
1196 (maybe-diddle-case source diddle-case))
1197 (t
1198 (if (components-match source from)
1199 to
1200 (didnt-match-error source from)))))
1201
1202
1203 ;;; COMPUTE-DIRECTORY-SUBSTITUTIONS -- Internal
1204 ;;;
1205 ;;; Return a list of all the things that we want to substitute into the TO
1206 ;;; pattern (the things matched by from on source.) When From contains
1207 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1208 ;;; subdirectories.
1209 ;;;
1210 (defun compute-directory-substitutions (orig-source orig-from)
1211 (let ((source orig-source)
1212 (from orig-from))
1213 (collect ((subs))
1214 (loop
1215 (unless source
1216 (unless (every #'(lambda (x) (eq x :wild-inferiors)) from)
1217 (didnt-match-error orig-source orig-from))
1218 (subs ())
1219 (return))
1220 (unless from (didnt-match-error orig-source orig-from))
1221 (let ((from-part (pop from))
1222 (source-part (pop source)))
1223 (typecase from-part
1224 (pattern
1225 (typecase source-part
1226 (pattern
1227 (if (pattern= from-part source-part)
1228 (subs source-part)
1229 (didnt-match-error orig-source orig-from)))
1230 (simple-string
1231 (multiple-value-bind
1232 (won new-subs)
1233 (pattern-matches from-part source-part)
1234 (if won
1235 (dolist (sub new-subs)
1236 (subs sub))
1237 (didnt-match-error orig-source orig-from))))
1238 (t
1239 (didnt-match-error orig-source orig-from))))
1240 ((member :wild)
1241 (subs source-part))
1242 ((member :wild-inferiors)
1243 (let ((remaining-source (cons source-part source)))
1244 (collect ((res))
1245 (loop
1246 (when (directory-components-match remaining-source from)
1247 (return))
1248 (unless remaining-source
1249 (didnt-match-error orig-source orig-from))
1250 (res (pop remaining-source)))
1251 (subs (res))
1252 (setq source remaining-source))))
1253 (simple-string
1254 (unless (and (simple-string-p source-part)
1255 (string= from-part source-part))
1256 (didnt-match-error orig-source orig-from)))
1257 (t
1258 (didnt-match-error orig-source orig-from)))))
1259 (subs))))
1260
1261
1262 ;;; TRANSLATE-DIRECTORIES -- Internal
1263 ;;;
1264 ;;; Called by TRANSLATE-PATHNAME on the directory components of its argument
1265 ;;; pathanames to produce the result directory component. If any leaves the
1266 ;;; directory NIL, we return the source directory. The :RELATIVE or :ABSOLUTE
1267 ;;; is taken from the source directory, except if TO is :ABSOLUTE, in which
1268 ;;; case the result will be :ABSOLUTE.
1269 ;;;
1270 (defun translate-directories (source from to diddle-case)
1271 (if (not (and source to from))
1272 (let ((source (mapcar #'(lambda (x) (maybe-diddle-case x diddle-case))
1273 source)))
1274 (if (null to)
1275 source
1276 (collect ((res))
1277 (res (cond ((null source) (first to))
1278 ((eq (first to) :absolute) :absolute)
1279 (t (first source))))
1280 (let ((match (rest source)))
1281 (dolist (to-part (rest to))
1282 (cond ((eq to-part :wild)
1283 (when match
1284 (res (first match))
1285 (setf match nil)))
1286 ((eq to-part :wild-inferiors)
1287 (when match
1288 (dolist (src-part match)
1289 (res src-part))
1290 (setf match nil)))
1291 (t
1292 (res to-part)))))
1293 (res))))
1294 (collect ((res))
1295 (res (if (eq (first to) :absolute)
1296 :absolute
1297 (first source)))
1298 (let ((subs-left (compute-directory-substitutions (rest source)
1299 (rest from))))
1300 (dolist (to-part (rest to))
1301 (typecase to-part
1302 ((member :wild)
1303 (assert subs-left)
1304 (let ((match (pop subs-left)))
1305 (when (listp match)
1306 (error ":WILD-INFERIORS not paired in from and to ~
1307 patterns:~% ~S ~S" from to))
1308 (res (maybe-diddle-case match diddle-case))))
1309 ((member :wild-inferiors)
1310 (assert subs-left)
1311 (let ((match (pop subs-left)))
1312 (unless (listp match)
1313 (error ":WILD-INFERIORS not paired in from and to ~
1314 patterns:~% ~S ~S" from to))
1315 (dolist (x match)
1316 (res (maybe-diddle-case x diddle-case)))))
1317 (pattern
1318 (multiple-value-bind
1319 (new new-subs-left)
1320 (substitute-into to-part subs-left diddle-case)
1321 (setf subs-left new-subs-left)
1322 (res new)))
1323 (t (res to-part)))))
1324 (res))))
1325
1326
1327 ;;; TRANSLATE-PATHNAME -- Interface
1328 ;;;
1329 (defun translate-pathname (source from-wildname to-wildname &key)
1330 "Use the source pathname to translate the from-wildname's wild and
1331 unspecified elements into a completed to-pathname based on the to-wildname."
1332 (declare (type path-designator source from-wildname to-wildname))
1333 (with-pathname (source source)
1334 (with-pathname (from from-wildname)
1335 (with-pathname (to to-wildname)
1336 (let* ((source-host (%pathname-host source))
1337 (to-host (%pathname-host to))
1338 (diddle-case
1339 (and source-host to-host
1340 (not (eq (host-customary-case source-host)
1341 (host-customary-case to-host))))))
1342 (macrolet ((frob (field &optional (op 'translate-component))
1343 `(let ((result (,op (,field source)
1344 (,field from)
1345 (,field to)
1346 diddle-case)))
1347 (if (eq result :error)
1348 (error "~S doesn't match ~S" source from)
1349 result))))
1350 (%make-pathname-object
1351 (or to-host source-host)
1352 (frob %pathname-device)
1353 (frob %pathname-directory translate-directories)
1354 (frob %pathname-name)
1355 (frob %pathname-type)
1356 (frob %pathname-version))))))))
1357
1358
1359 ;;;; Search lists.
1360
1361 ;;; The SEARCH-LIST structure.
1362 ;;;
1363 (defstruct (search-list
1364 (:print-function %print-search-list)
1365 (:make-load-form-fun
1366 (lambda (search-list)
1367 (values `(intern-search-list ',(search-list-name search-list))
1368 nil))))
1369 ;;
1370 ;; The name of this search-list. Always stored in lowercase.
1371 (name (required-argument) :type simple-string)
1372 ;;
1373 ;; T if this search-list has been defined. Otherwise NIL.
1374 (defined nil :type (member t nil))
1375 ;;
1376 ;; The list of expansions for this search-list. Each expansion is the list
1377 ;; of directory components to use in place of this search-list.
1378 (expansions nil :type list))
1379
1380 (defun %print-search-list (sl stream depth)
1381 (declare (ignore depth))
1382 (print-unreadable-object (sl stream :type t)
1383 (write-string (search-list-name sl) stream)))
1384
1385 ;;; *SEARCH-LISTS* -- internal.
1386 ;;;
1387 ;;; Hash table mapping search-list names to search-list structures.
1388 ;;;
1389 (defvar *search-lists* (make-hash-table :test #'equal))
1390
1391 ;;; FIND-SEARCH-LIST -- internal
1392 ;;;
1393 (defun find-search-list (name &optional (flame-not-found-p t))
1394 (let ((search-list (gethash (string-downcase name) *search-lists*)))
1395 (if search-list search-list
1396 (when flame-not-found-p
1397 (error "Search-list ~a not defined." name)))))
1398
1399 ;;; INTERN-SEARCH-LIST -- internal interface.
1400 ;;;
1401 ;;; When search-lists are encountered in namestrings, they are converted to
1402 ;;; search-list structures right then, instead of waiting until the search
1403 ;;; list used. This allows us to verify ahead of time that there are no
1404 ;;; circularities and makes expansion much quicker.
1405 ;;;
1406 (defun intern-search-list (name)
1407 (let ((name (string-downcase name)))
1408 (or (gethash name *search-lists*)
1409 (let ((new (make-search-list :name name)))
1410 (setf (gethash name *search-lists*) new)
1411 new))))
1412
1413 ;;; CLEAR-SEARCH-LIST -- public.
1414 ;;;
1415 ;;; Clear the definition. Note: we can't remove it from the hash-table
1416 ;;; because there may be pathnames still refering to it. So we just clear
1417 ;;; out the expansions and set defined to NIL.
1418 ;;;
1419 (defun clear-search-list (name)
1420 "Clear the current definition for the search-list NAME. Returns T if such
1421 a definition existed, and NIL if not."
1422 (let* ((name (string-downcase name))
1423 (search-list (gethash name *search-lists*)))
1424 (when (and search-list (search-list-defined search-list))
1425 (setf (search-list-defined search-list) nil)
1426 (setf (search-list-expansions search-list) nil)
1427 t)))
1428
1429 ;;; CLEAR-ALL-SEARCH-LISTS -- sorta public.
1430 ;;;
1431 ;;; Again, we can't actually remove the entries from the hash-table, so we
1432 ;;; just mark them as being undefined.
1433 ;;;
1434 (defun clear-all-search-lists ()
1435 "Clear the definition for all search-lists. Only use this if you know
1436 what you are doing."
1437 (maphash #'(lambda (name search-list)
1438 (declare (ignore name))
1439 (setf (search-list-defined search-list) nil)
1440 (setf (search-list-expansions search-list) nil))
1441 *search-lists*)
1442 nil)
1443
1444 ;;; EXTRACT-SEARCH-LIST -- internal.
1445 ;;;
1446 ;;; Extract the search-list from PATHNAME and return it. If PATHNAME
1447 ;;; doesn't start with a search-list, then either error (if FLAME-IF-NONE
1448 ;;; is true) or return NIL (if FLAME-IF-NONE is false).
1449 ;;;
1450 (defun extract-search-list (pathname flame-if-none)
1451 (with-pathname (pathname pathname)
1452 (let* ((directory (%pathname-directory pathname))
1453 (search-list (cadr directory)))
1454 (cond ((search-list-p search-list)
1455 search-list)
1456 (flame-if-none
1457 (error "~S doesn't start with a search-list." pathname))
1458 (t
1459 nil)))))
1460
1461 ;;; SEARCH-LIST -- public.
1462 ;;;
1463 ;;; We have to convert the internal form of the search-list back into a
1464 ;;; bunch of pathnames.
1465 ;;;
1466 (defun search-list (pathname)
1467 "Return the expansions for the search-list starting PATHNAME. If PATHNAME
1468 does not start with a search-list, then an error is signaled. If
1469 the search-list has not been defined yet, then an error is signaled.
1470 The expansion for a search-list can be set with SETF."
1471 (with-pathname (pathname pathname)
1472 (let ((search-list (extract-search-list pathname t))
1473 (host (%pathname-host pathname)))
1474 (if (search-list-defined search-list)
1475 (mapcar #'(lambda (directory)
1476 (make-pathname :host host
1477 :directory (cons :absolute directory)))
1478 (search-list-expansions search-list))
1479 (error "Search list ~S has not been defined yet." pathname)))))
1480
1481 ;;; SEARCH-LIST-DEFINED-P -- public.
1482 ;;;
1483 (defun search-list-defined-p (pathname)
1484 "Returns T if the search-list starting PATHNAME is currently defined, and
1485 NIL otherwise. An error is signaled if PATHNAME does not start with a
1486 search-list."
1487 (with-pathname (pathname pathname)
1488 (search-list-defined (extract-search-list pathname t))))
1489
1490 ;;; %SET-SEARCH-LIST -- public setf method
1491 ;;;
1492 ;;; Set the expansion for the search-list in PATHNAME. If this would result
1493 ;;; in any circularities, we flame out. If anything goes wrong, we leave the
1494 ;;; old defintion intact.
1495 ;;;
1496 (defun %set-search-list (pathname values)
1497 (let ((search-list (extract-search-list pathname t)))
1498 (labels
1499 ((check (target-list path)
1500 (when (eq search-list target-list)
1501 (error "That would result in a circularity:~% ~
1502 ~A~{ -> ~A~} -> ~A"
1503 (search-list-name search-list)
1504 (reverse path)
1505 (search-list-name target-list)))
1506 (when (search-list-p target-list)
1507 (push (search-list-name target-list) path)
1508 (dolist (expansion (search-list-expansions target-list))
1509 (check (car expansion) path))))
1510 (convert (pathname)
1511 (with-pathname (pathname pathname)
1512 (when (or (pathname-name pathname)
1513 (pathname-type pathname)
1514 (pathname-version pathname))
1515 (error "Search-lists cannot expand into pathnames that have ~
1516 a name, type, or ~%version specified:~% ~S"
1517 pathname))
1518 (let ((directory (pathname-directory pathname)))
1519 (let ((expansion
1520 (if directory
1521 (ecase (car directory)
1522 (:absolute (cdr directory))
1523 (:relative (cons (intern-search-list "default")
1524 (cdr directory))))
1525 (list (intern-search-list "default")))))
1526 (check (car expansion) nil)
1527 expansion)))))
1528 (setf (search-list-expansions search-list)
1529 (if (listp values)
1530 (mapcar #'convert values)
1531 (list (convert values)))))
1532 (setf (search-list-defined search-list) t))
1533 values)
1534
1535 ;;; ENUMERATE-SEARCH-LIST -- public.
1536 ;;;
1537 (defmacro enumerate-search-list ((var pathname &optional result) &body body)
1538 "Execute BODY with VAR bound to each successive possible expansion for
1539 PATHNAME and then return RESULT. Note: if PATHNAME does not contain a
1540 search-list, then BODY is executed exactly once. Everything is wrapped
1541 in a block named NIL, so RETURN can be used to terminate early. Note:
1542 VAR is *not* bound inside of RESULT."
1543 (let ((body-name (gensym)))
1544 `(block nil
1545 (flet ((,body-name (,var)
1546 ,@body))
1547 (%enumerate-search-list ,pathname #',body-name)
1548 ,result))))
1549
1550 (defun %enumerate-search-list (pathname function)
1551 (let* ((pathname (if (logical-pathname-p pathname)
1552 (translate-logical-pathname pathname)
1553 pathname))
1554 (search-list (extract-search-list pathname nil)))
1555 (cond
1556 ((not search-list)
1557 (funcall function pathname))
1558 ((not (search-list-defined search-list))
1559 (error "Undefined search list: ~A"
1560 (search-list-name search-list)))
1561 (t
1562 (let ((tail (cddr (pathname-directory pathname))))
1563 (dolist (expansion
1564 (search-list-expansions search-list))
1565 (%enumerate-search-list (make-pathname :defaults pathname
1566 :directory
1567 (cons :absolute
1568 (append expansion
1569 tail)))
1570 function)))))))
1571
1572
1573 ;;;; Logical pathname support. ANSI 92-102 specification.
1574 ;;;; As logical-pathname translations are loaded they are canonicalized as
1575 ;;;; patterns to enable rapid efficent translation into physical pathnames.
1576
1577 ;;;; Utilities:
1578
1579 ;;; LOGICAL-WORD-OR-LOSE -- Internal
1580 ;;;
1581 ;;; Canonicalize a logical pathanme word by uppercasing it checking that it
1582 ;;; contains only legal characters.
1583 ;;;
1584 (defun logical-word-or-lose (word)
1585 (declare (string word))
1586 (let ((word (string-upcase word)))
1587 (dotimes (i (length word))
1588 (let ((ch (schar word i)))
1589 (unless (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-))
1590 (error 'namestring-parse-error
1591 :complaint "Logical namestring character ~
1592 is not alphanumeric or hyphen:~% ~S"
1593 :arguments (list ch)
1594 :namestring word :offset i))))
1595 word))
1596
1597
1598 ;;; FIND-LOGICAL-HOST -- Internal
1599 ;;;
1600 ;;; Given a logical host or string, return a logical host. If Error-p is
1601 ;;; NIL, then return NIL when no such host exists.
1602 ;;;
1603 (defun find-logical-host (thing &optional (errorp t))
1604 (etypecase thing
1605 (string
1606 (let* ((valid-hostname
1607 (catch 'error-bailout
1608 (handler-bind
1609 ((namestring-parse-error
1610 (lambda(c)(declare (ignore c))
1611 (unless errorp
1612 (throw 'error-bailout nil)))))
1613 (logical-word-or-lose thing))))
1614 (found
1615 (and valid-hostname
1616 (or (gethash valid-hostname *logical-hosts*)
1617 (and *autoload-translations*
1618 (ignore-errors
1619 (load-logical-pathname-translations
1620 valid-hostname))
1621 (gethash valid-hostname *logical-hosts*))))))
1622 (if (or found (not errorp))
1623 found
1624 (error 'simple-file-error
1625 :pathname thing
1626 :format-control "Logical host not yet defined: ~S"
1627 :format-arguments (list thing)))))
1628 (logical-host thing)))
1629
1630 ;;; INTERN-LOGICAL-HOST -- Internal
1631 ;;;
1632 ;;; Given a logical host name or host, return a logical host, creating a new
1633 ;;; one if necessary.
1634 ;;;
1635 (defun intern-logical-host (thing)
1636 (declare (values logical-host))
1637 (or (find-logical-host thing nil)
1638 (let* ((name (logical-word-or-lose thing))
1639 (new (make-logical-host :name name)))
1640 (setf (gethash name *logical-hosts*) new)
1641 new)))
1642
1643
1644 ;;;; Logical pathname parsing:
1645
1646 ;;; MAYBE-MAKE-LOGICAL-PATTERN -- Internal
1647 ;;;
1648 ;;; Deal with multi-char wildcards in a logical pathname token.
1649 ;;;
1650 (defun maybe-make-logical-pattern (namestring chunks)
1651 (let ((chunk (caar chunks)))
1652 (collect ((pattern))
1653 (let ((last-pos 0)
1654 (len (length chunk)))
1655 (declare (fixnum last-pos))
1656 (loop
1657 (when (= last-pos len) (return))
1658 (let ((pos (or (position #\* chunk :start last-pos) len)))
1659 (if (= pos last-pos)
1660 (when (pattern)
1661 (error 'namestring-parse-error
1662 :complaint "Double asterisk inside of logical ~
1663 word: ~S"
1664 :arguments (list chunk)
1665 :namestring namestring
1666 :offset (+ (cdar chunks) pos)))
1667 (pattern (subseq chunk last-pos pos)))
1668 (if (= pos len)
1669 (return)
1670 (pattern :multi-char-wild))
1671 (setq last-pos (1+ pos)))))
1672 (assert (pattern))
1673 (if (cdr (pattern))
1674 (make-pattern (pattern))
1675 (let ((x (car (pattern))))
1676 (if (eq x :multi-char-wild)
1677 :wild
1678 x))))))
1679
1680
1681 ;;; LOGICAL-CHUNKIFY -- Internal
1682 ;;;
1683 ;;; Return a list of conses where the cdr is the start position and the car
1684 ;;; is a string (token) or character (punctuation.)
1685 ;;;
1686 (defun logical-chunkify (namestr start end)
1687 (collect ((chunks))
1688 (do ((i start (1+ i))
1689 (prev start))
1690 ((= i end)
1691 (when (> end prev)
1692 (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1693 (let ((ch (schar namestr i)))
1694 (unless (or (alpha-char-p ch) (digit-char-p ch)
1695 (member ch '(#\- #\*)))
1696 (when (> i prev)
1697 (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1698 (setq prev (1+ i))
1699 (unless (member ch '(#\; #\: #\.))
1700 (error 'namestring-parse-error
1701 :complaint "Illegal character for logical pathname:~% ~S"
1702 :arguments (list ch)
1703 :namestring namestr
1704 :offset i))
1705 (chunks (cons ch i)))))
1706 (chunks)))
1707
1708
1709 ;;; PARSE-LOGICAL-NAMESTRING -- Internal
1710 ;;;
1711 ;;; Break up a logical-namestring, always a string, into its constituent
1712 ;;; parts.
1713 ;;;
1714 (defun parse-logical-namestring (namestr start end)
1715 (declare (type simple-base-string namestr)
1716 (type index start end))
1717 (collect ((directory))
1718 (let ((host nil)
1719 (name nil)
1720 (type nil)
1721 (version nil))
1722 (labels ((expecting (what chunks)
1723 (unless (and chunks (simple-string-p (caar chunks)))
1724 (error 'namestring-parse-error
1725 :complaint "Expecting ~A, got ~:[nothing~;~:*~S~]."
1726 :arguments (list what (caar chunks))
1727 :namestring namestr
1728 :offset (if chunks (cdar chunks) end)))
1729 (caar chunks))
1730 (parse-host (chunks)
1731 (case (caadr chunks)
1732 (#\:
1733 (setq host
1734 (find-logical-host (expecting "a host name" chunks)))
1735 (parse-relative (cddr chunks)))
1736 (t
1737 (parse-relative chunks))))
1738 (parse-relative (chunks)
1739 (case (caar chunks)
1740 (#\;
1741 (directory :relative)
1742 (parse-directory (cdr chunks)))
1743 (t
1744 (directory :absolute) ; Assumption! Maybe revoked later.
1745 (parse-directory chunks))))
1746 (parse-directory (chunks)
1747 (case (caadr chunks)
1748 (#\;
1749 (directory
1750 (let ((res (expecting "a directory name" chunks)))
1751 (cond ((string= res "..") :up)
1752 ((string= res "**") :wild-inferiors)
1753 (t
1754 (maybe-make-logical-pattern namestr chunks)))))
1755 (parse-directory (cddr chunks)))
1756 (t
1757 (parse-name chunks))))
1758 (parse-name (chunks)
1759 (when chunks
1760 (expecting "a file name" chunks)
1761 (setq name (maybe-make-logical-pattern namestr chunks))
1762 (expecting-dot (cdr chunks))))
1763 (expecting-dot (chunks)
1764 (when chunks
1765 (unless (eql (caar chunks) #\.)
1766 (error 'namestring-parse-error
1767 :complaint "Expecting a dot, got ~S."
1768 :arguments (list (caar chunks))
1769 :namestring namestr
1770 :offset (cdar chunks)))
1771 (if type
1772 (parse-version (cdr chunks))
1773 (parse-type (cdr chunks)))))
1774 (parse-type (chunks)
1775 (expecting "a file type" chunks)
1776 (setq type (maybe-make-logical-pattern namestr chunks))
1777 (expecting-dot (cdr chunks)))
1778 (parse-version (chunks)
1779 (let ((str (expecting "a positive integer, * or NEWEST"
1780 chunks)))
1781 (cond
1782 ((string= str "*") (setq version :wild))
1783 ((string= str "NEWEST") (setq version :newest))
1784 (t
1785 (multiple-value-bind
1786 (res pos)
1787 (parse-integer str :junk-allowed t)
1788 (unless (and res (plusp res))
1789 (error 'namestring-parse-error
1790 :complaint "Expected a positive integer, ~
1791 got ~S"
1792 :arguments (list str)
1793 :namestring namestr
1794 :offset (+ pos (cdar chunks))))
1795 (setq version res)))))
1796 (when (cdr chunks)
1797 (error 'namestring-parse-error
1798 :complaint "Extra stuff after end of file name."
1799 :namestring namestr
1800 :offset (cdadr chunks)))))
1801 (parse-host (logical-chunkify namestr start end)))
1802 (values host :unspecific
1803 (directory)
1804 name type version))))
1805
1806
1807 ;;; Can't defvar here because not all host methods are loaded yet.
1808 (declaim (special *logical-pathname-defaults*))
1809
1810 ;;; LOGICAL-PATHNAME -- Public
1811 ;;;
1812 (defun logical-pathname (pathspec)
1813 "Converts the pathspec argument to a logical-pathname and returns it."
1814 (declare (type (or logical-pathname string stream) pathspec)
1815 (values logical-pathname))
1816 (if (typep pathspec 'logical-pathname)
1817 pathspec
1818 (let ((res (parse-namestring pathspec nil *logical-pathname-defaults*)))
1819 (when (eq (%pathname-host res)
1820 (%pathname-host *logical-pathname-defaults*))
1821 (error
1822 'simple-type-error
1823 :format-control "Logical namestring does not specify a host:~% ~S"
1824 :format-arguments (list pathspec)
1825 :datum pathspec
1826 :expected-type '(satisfies logical-pathname-namestring-p)))
1827 res)))
1828
1829
1830
1831 ;;;; Logical pathname unparsing:
1832
1833 ;;; UNPARSE-LOGICAL-DIRECTORY -- Internal
1834 ;;;
1835 (defun unparse-logical-directory (pathname)
1836 (declare (type pathname pathname))
1837 (collect ((pieces))
1838 (let ((directory (%pathname-directory pathname)))
1839 (when directory
1840 (ecase (pop directory)
1841 (:absolute) ;; Nothing special.
1842 (:relative (pieces ";")))
1843 (dolist (dir directory)
1844 (cond ((or (stringp dir) (pattern-p dir))
1845 (pieces (unparse-logical-piece dir))
1846 (pieces ";"))
1847 ((eq dir :wild)
1848 (pieces "*;"))
1849 ((eq dir :wild-inferiors)
1850 (pieces "**;"))
1851 (t
1852 (error "Invalid directory component: ~S" dir))))))
1853 (apply #'concatenate 'simple-string (pieces))))
1854
1855
1856 ;;; UNPARSE-LOGICAL-PIECE -- Internal
1857 ;;;
1858 (defun unparse-logical-piece (thing)
1859 (etypecase thing
1860 (simple-string thing)
1861 (pattern
1862 (collect ((strings))
1863 (dolist (piece (pattern-pieces thing))
1864 (etypecase piece
1865 (simple-string (strings piece))
1866 (keyword
1867 (cond ((eq piece :wild-inferiors)
1868 (strings "**"))
1869 ((eq piece :multi-char-wild)
1870 (strings "*"))
1871 (t (error "Invalid keyword: ~S" piece))))))
1872 (apply #'concatenate 'simple-string (strings))))))
1873
1874 ;;; UNPARSE-ENOUGH-NAMESTRING -- Internal
1875 ;;;
1876 (defun unparse-enough-namestring (pathname defaults)
1877 (let* ((path-dir (pathname-directory pathname))
1878 (def-dir (pathname-directory defaults))
1879 (enough-dir
1880 ;; Go down the directory lists to see what matches. What's
1881 ;; left is what we want, more or less.
1882 (cond ((and (eq (first path-dir) (first def-dir))
1883 (eq (first path-dir) :absolute))
1884 ;; Both paths are :absolute, so find where the common
1885 ;; parts end and return what's left
1886 (do* ((p (rest path-dir) (rest p))
1887 (d (rest def-dir) (rest d)))
1888 ((or (endp p) (endp d)
1889 (not (equal (first p) (first d))))
1890 `(:relative ,@p))))
1891 (t
1892 ;; At least one path is :relative, so just return the
1893 ;; original path. If the original path is :relative,
1894 ;; then that's the right one. If PATH-DIR is
1895 ;; :absolute, we want to return that except when
1896 ;; DEF-DIR is :absolute, as handled above. so return
1897 ;; the original directory.
1898 path-dir))))
1899 (make-pathname :host (%pathname-host pathname)
1900 :directory enough-dir
1901 :name (pathname-name pathname)
1902 :type (pathname-type pathname)
1903 :version (pathname-version pathname))))
1904
1905 ;;; UNPARSE-LOGICAL-NAMESTRING -- Internal
1906 ;;;
1907 (defun unparse-logical-namestring (pathname)
1908 (declare (type logical-pathname pathname))
1909 (concatenate 'simple-string
1910 (logical-host-name (%pathname-host pathname)) ":"
1911 (unparse-logical-directory pathname)
1912 (unparse-unix-file pathname)))
1913
1914
1915 ;;;; Logical pathname translations:
1916
1917 ;;; CANONICALIZE-LOGICAL-PATHNAME-TRANSLATIONS -- Internal
1918 ;;;
1919 ;;; Verify that the list of translations consists of lists and prepare
1920 ;;; canonical translations (parse pathnames and expand out wildcards into
1921 ;;; patterns).
1922 ;;;
1923 (defun canonicalize-logical-pathname-translations (transl-list host)
1924 (declare (type list transl-list) (type host host)
1925 (values list))
1926 (collect ((res))
1927 (dolist (tr transl-list)
1928 (unless (and (consp tr) (= (length tr) 2))
1929 (error "Logical pathname translation is not a two-list:~% ~S"
1930 tr))
1931 (let ((from (first tr)))
1932 (res (list (if (typep from 'logical-pathname)
1933 from
1934 (parse-namestring from host))
1935 (pathname (second tr))))))
1936 (res)))
1937
1938
1939 ;;; LOGICAL-PATHNAME-TRANSLATIONS -- Public
1940 ;;;
1941 (defun logical-pathname-translations (host)
1942 "Return the (logical) host object argument's list of translations."
1943 (declare (type (or string logical-host) host)
1944 (values list))
1945 (logical-host-translations (find-logical-host host)))
1946
1947 ;;; (SETF LOGICAL-PATHNAME-TRANSLATIONS) -- Public
1948 ;;;
1949 (defun (setf logical-pathname-translations) (translations host)
1950 "Set the translations list for the logical host argument.
1951 Return translations."
1952 (declare (type (or string logical-host) host)
1953 (type list translations)
1954 (values list))
1955
1956 (let ((maybe-search-list-host (concatenate 'string host ":")))
1957 (when (and (not (logical-pathname-p (pathname maybe-search-list-host)))
1958 (search-list-defined-p maybe-search-list-host))
1959 (cerror "Clobber search-list host with logical pathname host"
1960 "~S names a CMUCL search-list"
1961 host)))
1962 (let ((host (intern-logical-host host)))
1963 (setf (logical-host-canon-transls host)
1964 (canonicalize-logical-pathname-translations translations host))
1965 (setf (logical-host-translations host) translations)))
1966
1967
1968 ;;; The search mechanism for loading pathname translations uses the CMUCL
1969 ;;; extension of search-lists. The user can add to the library: search-list
1970 ;;; using setf. The file for translations should have the name defined by
1971 ;;; the hostname (a string) and with type component "translations".
1972
1973 ;;; LOAD-LOGICAL-PATHNAME-TRANSLATIONS -- Public
1974 ;;;
1975 (defun load-logical-pathname-translations (host)
1976 "Search for a logical pathname named host, if not already defined. If already
1977 defined no attempt to find or load a definition is attempted and NIL is
1978 returned. If host is not already defined, but definition is found and loaded
1979 successfully, T is returned, else error."
1980 (declare (type string host)
1981 (values (member t nil)))
1982 (let ((*autoload-translations* nil))
1983 (unless (or (string-equal host "library")
1984 (find-logical-host host nil))
1985 (with-open-file (in-str (make-pathname :defaults "library:"
1986 :name (string-downcase host)
1987 :type "translations"))
1988 (if *load-verbose*
1989 (format *error-output*
1990 ";; Loading pathname translations from ~A~%"
1991 (namestring (truename in-str))))
1992 (setf (logical-pathname-translations host) (read in-str)))
1993 t)))
1994
1995 ;;; TRANSLATE-LOGICAL-PATHNAME -- Public
1996 ;;;
1997 (defun translate-logical-pathname (pathname &key)
1998 "Translates pathname to a physical pathname, which is returned."
1999 (declare (type path-designator pathname)
2000 (values (or null pathname)))
2001 (typecase pathname
2002 (logical-pathname
2003 (dolist (x (logical-host-canon-transls (%pathname-host pathname))
2004 (error 'simple-file-error
2005 :pathname pathname
2006 :format-control "No translation for ~S"
2007 :format-arguments (list pathname)))
2008 (destructuring-bind (from to) x
2009 (when (pathname-match-p pathname from)
2010 (return (translate-logical-pathname
2011 (translate-pathname pathname from to)))))))
2012 (pathname pathname)
2013 (stream (translate-logical-pathname (pathname pathname)))
2014 (t (translate-logical-pathname (pathname pathname)))))
2015
2016 (defvar *logical-pathname-defaults*
2017 (%make-logical-pathname (make-logical-host :name "BOGUS") :unspecific
2018 nil nil nil nil))

  ViewVC Help
Powered by ViewVC 1.1.5