/[cmucl]/src/code/macros.lisp
ViewVC logotype

Contents of /src/code/macros.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.79 - (show annotations)
Fri Nov 1 17:41:53 2002 UTC (11 years, 5 months ago) by toy
Branch: MAIN
Changes since 1.78: +45 -19 lines
The previous checkin adding multiple-values support to push and
pushnew screwed up the evaluation order.  Fix that, and get the
evaluation order correct for multiple-values too.
1 ;;; -*- Log: code.log; Package: Lisp -*-
2 ;;;
3 ;;; **********************************************************************
4 ;;; This code was written as part of the CMU Common Lisp project at
5 ;;; Carnegie Mellon University, and has been placed in the public domain.
6 ;;;
7 (ext:file-comment
8 "$Header: /tiger/var/lib/cvsroots/cmucl/src/code/macros.lisp,v 1.79 2002/11/01 17:41:53 toy Exp $")
9 ;;;
10 ;;; **********************************************************************
11 ;;;
12 ;;; This file contains the macros that are part of the standard
13 ;;; Spice Lisp environment.
14 ;;;
15 ;;; Written by Scott Fahlman and Rob MacLachlan.
16 ;;; Modified by Bill Chiles to adhere to the wall.
17 ;;;
18 (in-package "LISP")
19 (export '(defvar defparameter defconstant when unless setf
20 defsetf psetf shiftf rotatef push pushnew pop
21 incf decf remf case typecase with-open-file
22 with-open-stream with-input-from-string with-output-to-string
23 locally etypecase ctypecase ecase ccase
24 get-setf-expansion define-setf-expander
25 define-modify-macro destructuring-bind nth-value
26 otherwise ; Sacred to CASE and related macros.
27 define-compiler-macro))
28
29 (in-package "EXTENSIONS")
30 (export '(do-anonymous collect iterate))
31
32 (in-package "LISP")
33
34
35 ;;; Parse-Body -- Public
36 ;;;
37 ;;; Parse out declarations and doc strings, *not* expanding macros.
38 ;;; Eventually the environment arg should be flushed, since macros can't expand
39 ;;; into declarations anymore.
40 ;;;
41 (defun parse-body (body environment &optional (doc-string-allowed t))
42 "This function is to parse the declarations and doc-string out of the body of
43 a defun-like form. Body is the list of stuff which is to be parsed.
44 Environment is ignored. If Doc-String-Allowed is true, then a doc string
45 will be parsed out of the body and returned. If it is false then a string
46 will terminate the search for declarations. Three values are returned: the
47 tail of Body after the declarations and doc strings, a list of declare forms,
48 and the doc-string, or NIL if none."
49 (declare (ignore environment))
50 (let ((decls ())
51 (doc nil))
52 (do ((tail body (cdr tail)))
53 ((endp tail)
54 (values tail (nreverse decls) doc))
55 (let ((form (car tail)))
56 (cond ((and (stringp form) (cdr tail))
57 (if doc-string-allowed
58 (setq doc form
59 ;; Only one doc string is allowed.
60 doc-string-allowed nil)
61 (return (values tail (nreverse decls) doc))))
62 ((not (and (consp form) (symbolp (car form))))
63 (return (values tail (nreverse decls) doc)))
64 ((eq (car form) 'declare)
65 (push form decls))
66 (t
67 (return (values tail (nreverse decls) doc))))))))
68
69
70 ;;;; DEFMACRO:
71
72 ;;; Defmacro -- Public
73 ;;;
74 ;;; Parse the definition and make an expander function. The actual
75 ;;; definition is done by %defmacro which we expand into.
76 ;;;
77 (defmacro defmacro (name lambda-list &body body)
78 (let ((whole (gensym "WHOLE-"))
79 (environment (gensym "ENV-")))
80 (multiple-value-bind
81 (body local-decs doc)
82 (parse-defmacro lambda-list whole body name 'defmacro
83 :environment environment)
84 (let ((def `(lambda (,whole ,environment)
85 ,@local-decs
86 (block ,name
87 ,body))))
88 `(progn
89 (eval-when (:compile-toplevel)
90 (c::do-macro-compile-time ',name #',def))
91 (eval-when (:load-toplevel :execute)
92 (c::%defmacro ',name #',def ',lambda-list ,doc)))))))
93
94
95 ;;; %Defmacro, %%Defmacro -- Internal
96 ;;;
97 ;;; Defmacro expands into %Defmacro which is a function that is treated
98 ;;; magically the compiler. After the compiler has gotten the information it
99 ;;; wants out of macro definition, it compiles a call to %%Defmacro which
100 ;;; happens at load time. We have a %Defmacro function which just calls
101 ;;; %%Defmacro in order to keep the interpreter happy.
102 ;;;
103 ;;; Eventually %%Defmacro should deal with clearing old compiler information
104 ;;; for the functional value.
105 ;;;
106 (defun c::%defmacro (name definition lambda-list doc)
107 (assert (eval:interpreted-function-p definition))
108 (setf (eval:interpreted-function-name definition)
109 (format nil "DEFMACRO ~S" name))
110 (setf (eval:interpreted-function-arglist definition) lambda-list)
111 (c::%%defmacro name definition doc))
112 ;;;
113 (defun c::%%defmacro (name definition doc)
114 (clear-info function where-from name)
115 (setf (macro-function name) definition)
116 (setf (documentation name 'function) doc)
117 name)
118
119
120
121 ;;;; DEFINE-COMPILER-MACRO
122
123 (defmacro define-compiler-macro (name lambda-list &body body)
124 "Define a compiler-macro for NAME."
125 (let ((whole (gensym "WHOLE-"))
126 (environment (gensym "ENV-")))
127 (multiple-value-bind
128 (body local-decs doc)
129 (parse-defmacro lambda-list whole body name 'define-compiler-macro
130 :environment environment)
131 (let ((def `(lambda (,whole ,environment)
132 ,@local-decs
133 (block ,name
134 ,body))))
135 `(progn
136 (eval-when (:compile-toplevel)
137 (c::do-compiler-macro-compile-time ',name #',def))
138 (eval-when (:load-toplevel :execute)
139 (c::%define-compiler-macro ',name #',def ',lambda-list ,doc)))))))
140
141
142 (defun c::%define-compiler-macro (name definition lambda-list doc)
143 (assert (eval:interpreted-function-p definition))
144 (setf (eval:interpreted-function-name definition)
145 (let ((*print-case* :upcase))
146 (format nil "DEFINE-COMPILER-MACRO ~S" name)))
147 (setf (eval:interpreted-function-arglist definition) lambda-list)
148 (c::%%define-compiler-macro name definition doc))
149 ;;;
150 (defun c::%%define-compiler-macro (name definition doc)
151 (setf (compiler-macro-function name) definition)
152 (setf (documentation name 'compiler-macro) doc)
153 name)
154
155
156
157 ;;;; DEFINE-SYMBOL-MACRO
158
159 ;;; define-symbol-macro -- Public
160 ;;;
161 (defmacro define-symbol-macro (name expansion)
162 `(eval-when (compile load eval)
163 (%define-symbol-macro ',name ',expansion)))
164 ;;;
165 (defun %define-symbol-macro (name expansion)
166 (unless (symbolp name)
167 (error 'simple-type-error :datum name :expected-type 'symbol
168 :format-control "Symbol macro name is not a symbol: ~S."
169 :format-arguments (list name)))
170 (ecase (info variable kind name)
171 ((:macro :global nil)
172 (setf (info variable kind name) :macro)
173 (setf (info variable macro-expansion name) expansion))
174 (:special
175 (error 'simple-program-error
176 :format-control "Symbol macro name already declared special: ~S."
177 :format-arguments (list name)))
178 (:constant
179 (error 'simple-program-error
180 :format-control "Symbol macro name already declared constant: ~S."
181 :format-arguments (list name))))
182 name)
183
184
185 ;;; DEFTYPE is a lot like DEFMACRO.
186
187 (defmacro deftype (name arglist &body body)
188 "Syntax like DEFMACRO, but defines a new type."
189 (unless (symbolp name)
190 (error "~S -- Type name not a symbol." name))
191
192 (let ((whole (gensym "WHOLE-")))
193 (multiple-value-bind (body local-decs doc)
194 (parse-defmacro arglist whole body name 'deftype
195 :default-default ''*)
196 `(eval-when (compile load eval)
197 (%deftype ',name
198 #'(lambda (,whole)
199 ,@local-decs
200 (block ,name ,body))
201 ,@(when doc `(,doc)))))))
202 ;;;
203 (defun %deftype (name expander &optional doc)
204 (ecase (info type kind name)
205 (:primitive
206 (when *type-system-initialized*
207 (error "Illegal to redefine standard type: ~S." name)))
208 (:instance
209 (warn "Redefining class ~S to be a DEFTYPE." name)
210 (undefine-structure (layout-info (class-layout (find-class name))))
211 (setf (class-cell-class (find-class-cell name)) nil)
212 (setf (info type compiler-layout name) nil)
213 (setf (info type kind name) :defined))
214 (:defined)
215 ((nil)
216 (setf (info type kind name) :defined)))
217
218 (setf (info type expander name) expander)
219 (when doc
220 (setf (documentation name 'type) doc))
221 ;; ### Bootstrap hack -- we need to define types before %note-type-defined
222 ;; is defined.
223 (when (fboundp 'c::%note-type-defined)
224 (c::%note-type-defined name))
225 name)
226
227
228 ;;; And so is DEFINE-SETF-EXPANDER.
229
230 (defparameter defsetf-error-string "Setf expander for ~S cannot be called with ~S args.")
231
232 (defmacro define-setf-expander (access-fn lambda-list &body body)
233 "Syntax like DEFMACRO, but creates a Setf-Expansion generator. The body
234 must be a form that returns the five magical values."
235 (unless (symbolp access-fn)
236 (error "~S -- Access-function name not a symbol in DEFINE-SETF-EXPANDER."
237 access-fn))
238
239 (let ((whole (gensym "WHOLE-"))
240 (environment (gensym "ENV-")))
241 (multiple-value-bind (body local-decs doc)
242 (parse-defmacro lambda-list whole body access-fn
243 'define-setf-expander
244 :environment environment)
245 `(eval-when (load compile eval)
246 (%define-setf-macro
247 ',access-fn
248 #'(lambda (,whole ,environment)
249 ,@local-decs
250 (block ,access-fn ,body))
251 nil
252 ',doc)))))
253
254 (defmacro define-setf-method (&rest stuff)
255 "Obsolete, use define-setf-expander."
256 `(define-setf-expander ,@stuff))
257
258
259 ;;; %DEFINE-SETF-MACRO -- Internal
260 ;;;
261 ;;; Do stuff for defining a setf macro.
262 ;;;
263 (defun %define-setf-macro (name expander inverse doc)
264 (cond ((not (fboundp `(setf ,name))))
265 ((info function accessor-for name)
266 (warn "Defining setf macro for destruct slot accessor; redefining as ~
267 a normal function:~% ~S"
268 name)
269 (c::define-function-name name))
270 ((not (eq (symbol-package name) (symbol-package 'aref)))
271 (warn "Defining setf macro for ~S, but ~S is fbound."
272 name `(setf ,name))))
273 (when (or inverse (info setf inverse name))
274 (setf (info setf inverse name) inverse))
275 (when (or expander (info setf expander name))
276 (setf (info setf expander name) expander))
277 (when doc
278 (setf (documentation name 'setf) doc))
279 name)
280
281
282 ;;;; Destructuring-bind
283
284 (defmacro destructuring-bind (lambda-list arg-list &rest body)
285 "Bind the variables in LAMBDA-LIST to the contents of ARG-LIST."
286 (let* ((arg-list-name (gensym "ARG-LIST-")))
287 (multiple-value-bind
288 (body local-decls)
289 (parse-defmacro lambda-list arg-list-name body nil 'destructuring-bind
290 :annonymousp t :doc-string-allowed nil)
291 `(let ((,arg-list-name ,arg-list))
292 ,@local-decls
293 ,body))))
294
295
296 ;;;; Defun, Defvar, Defparameter, Defconstant:
297
298 ;;; Defun -- Public
299 ;;;
300 ;;; Very similar to Defmacro, but simpler. We don't have to parse the
301 ;;; lambda-list.
302 ;;;
303 (defmacro defun (&whole source name lambda-list &body (body decls doc))
304 (let ((def `(lambda ,lambda-list
305 ,@decls
306 (block ,(if (and (consp name) (eq (car name) 'setf))
307 (cadr name)
308 name)
309 ,@body))))
310 `(c::%defun ',name #',def ,doc ',source)))
311
312
313 ;;; %Defun, %%Defun -- Internal
314 ;;;
315 ;;; Similar to %Defmacro, ...
316 ;;;
317 (defun c::%%defun (name def doc &optional inline-expansion)
318 (setf (fdefinition name) def)
319 (when doc
320 (if (and (consp name) (eq (first name) 'setf))
321 (setf (documentation (second name) 'setf) doc)
322 (setf (documentation name 'function) doc)))
323 (c::define-function-name name)
324 (when (eq (info function where-from name) :assumed)
325 (setf (info function where-from name) :defined)
326 (when (info function assumed-type name)
327 (setf (info function assumed-type name) nil)))
328 (when (or inline-expansion
329 (info function inline-expansion name))
330 (setf (info function inline-expansion name) inline-expansion))
331 name)
332 ;;;
333 (defun c::%defun (name def doc source)
334 (declare (ignore source))
335 (assert (eval:interpreted-function-p def))
336 (setf (eval:interpreted-function-name def) name)
337 (c::%%defun name def doc))
338
339
340 ;;; DEFCONSTANT -- Public
341 ;;;
342 (defmacro defconstant (var val &optional doc)
343 "For defining global constants at top level. The DEFCONSTANT says that the
344 value is constant and may be compiled into code. If the variable already has
345 a value, and this is not equal to the init, an error is signalled. The third
346 argument is an optional documentation string for the variable."
347 `(progn
348 (eval-when (:compile-toplevel)
349 (c::do-defconstant-compile-time ',var ,val ',doc))
350 (eval-when (:load-toplevel :execute)
351 (c::%%defconstant ',var ,val ',doc))))
352
353 ;;; %Defconstant, %%Defconstant -- Internal
354 ;;;
355 ;;; Like the other %mumbles except that we currently actually do something
356 ;;; interesting at load time, namely checking if the constant is being
357 ;;; redefined.
358 ;;;
359 (defun c::%defconstant (name value doc)
360 (c::%%defconstant name value doc))
361 ;;;
362 (defun c::%%defconstant (name value doc)
363 (when doc
364 (setf (documentation name 'variable) doc))
365 (when (boundp name)
366 (unless (equalp (symbol-value name) value)
367 (cerror "Go ahead and change the value."
368 "Constant ~S being redefined." name)))
369 (setf (symbol-value name) value)
370 (setf (info variable kind name) :constant)
371 (clear-info variable constant-value name)
372 name)
373
374
375 (defmacro defvar (var &optional (val nil valp) (doc nil docp))
376 "For defining global variables at top level. Declares the variable
377 SPECIAL and, optionally, initializes it. If the variable already has a
378 value, the old value is not clobbered. The third argument is an optional
379 documentation string for the variable."
380 `(progn
381 (declaim (special ,var))
382 ,@(when valp
383 `((unless (boundp ',var)
384 (setq ,var ,val))))
385 ,@(when docp
386 `((setf (documentation ',var 'variable) ',doc)))
387 ',var))
388
389 (defmacro defparameter (var val &optional (doc nil docp))
390 "Defines a parameter that is not normally changed by the program,
391 but that may be changed without causing an error. Declares the
392 variable special and sets its value to VAL. The third argument is
393 an optional documentation string for the parameter."
394 `(progn
395 (declaim (special ,var))
396 (setq ,var ,val)
397 ,@(when docp
398 `((setf (documentation ',var 'variable) ',doc)))
399 ',var))
400
401
402 ;;;; ASSORTED CONTROL STRUCTURES
403
404
405 (defmacro when (test &body forms)
406 "First arg is a predicate. If it is non-null, the rest of the forms are
407 evaluated as a PROGN."
408 `(cond (,test nil ,@forms)))
409
410 (defmacro unless (test &rest forms)
411 "First arg is a predicate. If it is null, the rest of the forms are
412 evaluated as a PROGN."
413 `(cond ((not ,test) nil ,@forms)))
414
415
416 (defmacro return (&optional (value nil))
417 `(return-from nil ,value))
418
419 (defmacro prog (varlist &body (body decls))
420 `(block nil
421 (let ,varlist
422 ,@decls
423 (tagbody ,@body))))
424
425 (defmacro prog* (varlist &body (body decls))
426 `(block nil
427 (let* ,varlist
428 ,@decls
429 (tagbody ,@body))))
430
431
432 ;;; Prog1, Prog2 -- Public
433 ;;;
434 ;;; These just turn into a Let.
435 ;;;
436 (defmacro prog1 (result &rest body)
437 (let ((n-result (gensym)))
438 `(let ((,n-result ,result))
439 ,@body
440 ,n-result)))
441 ;;;
442 (defmacro prog2 (form1 result &rest body)
443 `(prog1 (progn ,form1 ,result) ,@body))
444
445
446 ;;; And, Or -- Public
447 ;;;
448 ;;; AND and OR are defined in terms of IF.
449 ;;;
450 (defmacro and (&rest forms)
451 (cond ((endp forms) t)
452 ((endp (rest forms)) (first forms))
453 (t
454 `(if ,(first forms)
455 (and ,@(rest forms))
456 nil))))
457 ;;;
458 (defmacro or (&rest forms)
459 (cond ((endp forms) nil)
460 ((endp (rest forms)) (first forms))
461 (t
462 (let ((n-result (gensym)))
463 `(let ((,n-result ,(first forms)))
464 (if ,n-result
465 ,n-result
466 (or ,@(rest forms))))))))
467
468
469 ;;; Cond -- Public
470 ;;;
471 ;;; COND also turns into IF.
472 ;;;
473 (defmacro cond (&rest clauses)
474 (if (endp clauses)
475 nil
476 (let ((clause (first clauses)))
477 (when (atom clause)
478 (error "Cond clause is not a list: ~S." clause))
479 (let ((test (first clause))
480 (forms (rest clause)))
481 (if (endp forms)
482 (let ((n-result (gensym)))
483 `(let ((,n-result ,test))
484 (if ,n-result
485 ,n-result
486 (cond ,@(rest clauses)))))
487 `(if ,test
488 (progn ,@forms)
489 (cond ,@(rest clauses))))))))
490
491
492 ;;;; Multiple value macros:
493
494 ;;; Multiple-Value-XXX -- Public
495 ;;;
496 ;;; All the multiple-value receiving forms are defined in terms of
497 ;;; Multiple-Value-Call.
498 ;;;
499 (defmacro multiple-value-setq (varlist value-form)
500 (unless (and (listp varlist) (every #'symbolp varlist))
501 (error "Varlist is not a list of symbols: ~S." varlist))
502 (let ((temps (mapcar #'(lambda (x) (declare (ignore x)) (gensym)) varlist)))
503 `(multiple-value-bind ,temps ,value-form
504 ,@(mapcar #'(lambda (var temp)
505 `(setq ,var ,temp))
506 varlist temps)
507 ,(car temps))))
508 ;;;
509 (defmacro multiple-value-bind (varlist value-form &body body)
510 (unless (and (listp varlist) (every #'symbolp varlist))
511 (error "Varlist is not a list of symbols: ~S." varlist))
512 (if (= (length varlist) 1)
513 `(let ((,(car varlist) ,value-form))
514 ,@body)
515 (let ((ignore (gensym)))
516 `(multiple-value-call #'(lambda (&optional ,@varlist &rest ,ignore)
517 (declare (ignore ,ignore))
518 ,@body)
519 ,value-form))))
520 ;;;
521 (defmacro multiple-value-list (value-form)
522 `(multiple-value-call #'list ,value-form))
523
524
525 (defmacro nth-value (n form)
526 "Evaluates FORM and returns the Nth value (zero based). This involves no
527 consing when N is a trivial constant integer."
528 (if (integerp n)
529 (let ((dummy-list nil)
530 (keeper (gensym "KEEPER-")))
531 ;; We build DUMMY-LIST, a list of variables to bind to useless
532 ;; values, then we explicitly IGNORE those bindings and return
533 ;; KEEPER, the only thing we're really interested in right now.
534 (dotimes (i n)
535 (push (gensym "IGNORE-") dummy-list))
536 `(multiple-value-bind (,@dummy-list ,keeper)
537 ,form
538 (declare (ignore ,@dummy-list))
539 ,keeper))
540 (once-only ((n n))
541 `(case (the (values fixnum &rest t) ,n)
542 (0 (nth-value 0 ,form))
543 (1 (nth-value 1 ,form))
544 (2 (nth-value 2 ,form))
545 (T (nth (the (values fixnum &rest t) ,n)
546 (multiple-value-list ,form)))))))
547
548
549 ;;;; SETF and friends.
550
551 ;;; Note: The expansions for SETF and friends sometimes create needless
552 ;;; LET-bindings of argument values. The compiler will remove most of
553 ;;; these spurious bindings, so SETF doesn't worry too much about creating
554 ;;; them.
555
556 ;;; The inverse for a generalized-variable reference function is stored in
557 ;;; one of two ways:
558 ;;;
559 ;;; A SETF inverse property corresponds to the short form of DEFSETF. It is
560 ;;; the name of a function takes the same args as the reference form, plus a
561 ;;; new-value arg at the end.
562 ;;;
563 ;;; A SETF method expander is created by the long form of DEFSETF or
564 ;;; by DEFINE-SETF-EXPANDER. It is a function that is called on the reference
565 ;;; form and that produces five values: a list of temporary variables, a list
566 ;;; of value forms, a list of the single store-value form, a storing function,
567 ;;; and an accessing function.
568
569 (defun get-setf-expansion (form &optional environment)
570 "Returns five values needed by the SETF machinery: a list of temporary
571 variables, a list of values with which to fill them, a list of temporaries
572 for the new values, the setting function, and the accessing function."
573 (let (temp)
574 (cond ((symbolp form)
575 (multiple-value-bind
576 (expansion expanded)
577 (macroexpand-1 form environment)
578 (if expanded
579 (get-setf-expansion expansion environment)
580 (let ((new-var (gensym)))
581 (values nil nil (list new-var)
582 `(setq ,form ,new-var) form)))))
583 ;;
584 ;; Local functions inhibit global setf methods...
585 ((and environment
586 (let ((name (car form)))
587 (dolist (x (c::lexenv-functions environment) nil)
588 (when (and (eq (car x) name)
589 (not (c::defined-function-p (cdr x))))
590 (return t)))))
591 (expand-or-get-setf-inverse form environment))
592 ((setq temp (info setf inverse (car form)))
593 (get-setf-method-inverse form `(,temp) nil))
594 ((setq temp (info setf expander (car form)))
595 (funcall temp form environment))
596 (t
597 (expand-or-get-setf-inverse form environment)))))
598
599 (defun get-setf-method-multiple-value (form &optional env)
600 "Obsolete: use GET-SETF-EXPANSION."
601 (get-setf-expansion form env))
602
603 ;;;
604 ;;; If a macro, expand one level and try again. If not, go for the
605 ;;; SETF function.
606 (defun expand-or-get-setf-inverse (form environment)
607 (multiple-value-bind
608 (expansion expanded)
609 (macroexpand-1 form environment)
610 (if expanded
611 (get-setf-expansion expansion environment)
612 (get-setf-method-inverse form `(funcall #'(setf ,(car form)))
613 t))))
614
615
616 (defun get-setf-method-inverse (form inverse setf-function)
617 (let ((new-var (gensym))
618 (vars nil)
619 (vals nil))
620 (dolist (x (cdr form))
621 (push (gensym) vars)
622 (push x vals))
623 (setq vals (nreverse vals))
624 (values vars vals (list new-var)
625 (if setf-function
626 `(,@inverse ,new-var ,@vars)
627 `(,@inverse ,@vars ,new-var))
628 `(,(car form) ,@vars))))
629
630
631 (defun get-setf-method (form &optional environment)
632 "Obsolete: use GET-SETF-EXPANSION and handle multiple store values."
633 (multiple-value-bind
634 (temps value-forms store-vars store-form access-form)
635 (get-setf-expansion form environment)
636 (when (cdr store-vars)
637 (error "GET-SETF-METHOD used for a form with multiple store ~
638 variables:~% ~S" form))
639 (values temps value-forms store-vars store-form access-form)))
640
641
642 (defun defsetter (fn rest)
643 (let ((arglist (car rest))
644 (arglist-var (gensym "ARGS-"))
645 (new-var (car (cadr rest))))
646 (multiple-value-bind
647 (body local-decs doc)
648 (parse-defmacro arglist arglist-var (cddr rest) fn 'defsetf)
649 (values
650 `(lambda (,arglist-var ,new-var)
651 ,@local-decs
652 ,body)
653 doc))))
654
655
656 (defmacro defsetf (access-fn &rest rest)
657 "Associates a SETF update function or macro with the specified access
658 function or macro. The format is complex. See the manual for
659 details."
660 (cond ((not (listp (car rest)))
661 `(eval-when (load compile eval)
662 (%define-setf-macro ',access-fn nil ',(car rest)
663 ,(when (and (car rest) (stringp (cadr rest)))
664 `',(cadr rest)))))
665 ((and (cdr rest) (listp (cadr rest)))
666 (destructuring-bind
667 (lambda-list (&rest store-variables) &body body)
668 rest
669 (let ((arglist-var (gensym "ARGS-"))
670 (access-form-var (gensym "ACCESS-FORM-"))
671 (env-var (gensym "ENVIRONMENT-")))
672 (multiple-value-bind
673 (body local-decs doc)
674 (parse-defmacro `(,lambda-list ,@store-variables)
675 arglist-var body access-fn 'defsetf
676 :annonymousp t)
677 `(eval-when (load compile eval)
678 (%define-setf-macro
679 ',access-fn
680 #'(lambda (,access-form-var ,env-var)
681 (declare (ignore ,env-var))
682 (%defsetf ,access-form-var ,(length store-variables)
683 #'(lambda (,arglist-var)
684 ,@local-decs
685 (block ,access-fn
686 ,body))))
687 nil
688 ',doc))))))
689 (t
690 (error "Ill-formed DEFSETF for ~S." access-fn))))
691
692 (defun %defsetf (orig-access-form num-store-vars expander)
693 (collect ((subforms) (subform-vars) (subform-exprs) (store-vars))
694 (dolist (subform (cdr orig-access-form))
695 (if (constantp subform)
696 (subforms subform)
697 (let ((var (gensym)))
698 (subforms var)
699 (subform-vars var)
700 (subform-exprs subform))))
701 (dotimes (i num-store-vars)
702 (store-vars (gensym)))
703 (values (subform-vars)
704 (subform-exprs)
705 (store-vars)
706 (funcall expander (cons (subforms) (store-vars)))
707 `(,(car orig-access-form) ,@(subforms)))))
708
709
710 ;;; SETF -- Public
711 ;;;
712 ;;; Except for atoms, we always call GET-SETF-METHOD, since it has some
713 ;;; non-trivial semantics. But when there is a setf inverse, and G-S-M uses
714 ;;; it, then we return a call to the inverse, rather than returning a hairy let
715 ;;; form. This is probably important mainly as a convenince in allowing the
716 ;;; use of setf inverses without the full interpreter.
717 ;;;
718 (defmacro setf (&rest args &environment env)
719 "Takes pairs of arguments like SETQ. The first is a place and the second
720 is the value that is supposed to go into that place. Returns the last
721 value. The place argument may be any of the access forms for which SETF
722 knows a corresponding setting form."
723 (let ((nargs (length args)))
724 (cond
725 ((= nargs 2)
726 (let ((place (first args))
727 (value-form (second args)))
728 (if (atom place)
729 `(setq ,place ,value-form)
730 (multiple-value-bind (dummies vals newval setter getter)
731 (get-setf-expansion place env)
732 (declare (ignore getter))
733 (let ((inverse (info setf inverse (car place))))
734 (if (and inverse (eq inverse (car setter)))
735 `(,inverse ,@(cdr place) ,value-form)
736 `(let* (,@(mapcar #'list dummies vals))
737 (multiple-value-bind ,newval ,value-form
738 ,setter))))))))
739 ((oddp nargs)
740 (error "Odd number of args to SETF."))
741 (t
742 (do ((a args (cddr a)) (l nil))
743 ((null a) `(progn ,@(nreverse l)))
744 (setq l (cons (list 'setf (car a) (cadr a)) l)))))))
745
746 (defmacro psetf (&rest args &environment env)
747 "This is to SETF as PSETQ is to SETQ. Args are alternating place
748 expressions and values to go into those places. All of the subforms and
749 values are determined, left to right, and only then are the locations
750 updated. Returns NIL."
751 (collect ((let*-bindings) (mv-bindings) (setters))
752 (do ((a args (cddr a)))
753 ((endp a))
754 (if (endp (cdr a))
755 (error "Odd number of args to PSETF."))
756 (multiple-value-bind
757 (dummies vals newval setter getter)
758 (get-setf-expansion (car a) env)
759 (declare (ignore getter))
760 (let*-bindings (mapcar #'list dummies vals))
761 (mv-bindings (list newval (cadr a)))
762 (setters setter)))
763 (labels ((thunk (let*-bindings mv-bindings)
764 (if let*-bindings
765 `(let* ,(car let*-bindings)
766 (multiple-value-bind ,@(car mv-bindings)
767 ,(thunk (cdr let*-bindings) (cdr mv-bindings))))
768 `(progn ,@(setters) nil))))
769 (thunk (let*-bindings) (mv-bindings)))))
770
771 (defmacro shiftf (&rest args &environment env)
772 "One or more SETF-style place expressions, followed by a single
773 value expression. Evaluates all of the expressions in turn, then
774 assigns the value of each expression to the place on its left,
775 returning the value of the leftmost."
776 (when args
777 (collect ((let*-bindings) (mv-bindings) (setters) (getters))
778 ;; The last arg isn't necessarily a place, so we have to handle
779 ;; that separately.
780 (dolist (arg (butlast args))
781 (multiple-value-bind
782 (temps subforms store-vars setter getter)
783 (get-setf-expansion arg env)
784 (loop
785 for temp in temps
786 for subform in subforms
787 do (let*-bindings `(,temp ,subform)))
788 (mv-bindings store-vars)
789 (setters setter)
790 (getters getter)))
791 ;; Handle the last arg specially here. Just put something to
792 ;; force the setter so the setter for the previous var gets set,
793 ;; and the getter is just the last arg itself.
794 (setters nil)
795 (getters (car (last args)))
796
797 (labels ((thunk (mv-bindings getters)
798 (if mv-bindings
799 `((multiple-value-bind
800 ,(car mv-bindings)
801 ,(car getters)
802 ,@(thunk (cdr mv-bindings) (cdr getters))))
803 `(,@(butlast (setters))))))
804 `(let* ,(let*-bindings)
805 (multiple-value-bind ,(car (mv-bindings))
806 ,(car (getters))
807 ,@(thunk (mv-bindings) (cdr (getters)))
808 (values ,@(car (mv-bindings)))))))))
809
810 (defmacro rotatef (&rest args &environment env)
811 "Takes any number of SETF-style place expressions. Evaluates all of the
812 expressions in turn, then assigns to each place the value of the form to
813 its right. The rightmost form gets the value of the leftmost.
814 Returns NIL."
815 (when args
816 (collect ((let*-bindings) (mv-bindings) (setters) (getters))
817 (dolist (arg args)
818 (multiple-value-bind
819 (temps subforms store-vars setter getter)
820 (get-setf-expansion arg env)
821 (loop
822 for temp in temps
823 for subform in subforms
824 do (let*-bindings `(,temp ,subform)))
825 (mv-bindings store-vars)
826 (setters setter)
827 (getters getter)))
828 (setters nil)
829 (getters (car (getters)))
830 (labels ((thunk (mv-bindings getters)
831 (if mv-bindings
832 `((multiple-value-bind
833 ,(car mv-bindings)
834 ,(car getters)
835 ,@(thunk (cdr mv-bindings) (cdr getters))))
836 (setters))))
837 `(let* ,(let*-bindings)
838 ,@(thunk (mv-bindings) (cdr (getters))))))))
839
840
841 (defmacro define-modify-macro (name lambda-list function &optional doc-string)
842 "Creates a new read-modify-write macro like PUSH or INCF."
843 (let ((other-args nil)
844 (rest-arg nil)
845 (env (gensym))
846 (reference (gensym)))
847
848 ;; Parse out the variable names and rest arg from the lambda list.
849 (do ((ll lambda-list (cdr ll))
850 (arg nil))
851 ((null ll))
852 (setq arg (car ll))
853 (cond ((eq arg '&optional))
854 ((eq arg '&rest)
855 (if (symbolp (cadr ll))
856 (setq rest-arg (cadr ll))
857 (error "Non-symbol &rest arg in definition of ~S." name))
858 (if (null (cddr ll))
859 (return nil)
860 (error "Illegal stuff after &rest arg in Define-Modify-Macro.")))
861 ((memq arg '(&key &allow-other-keys &aux))
862 (error "~S not allowed in Define-Modify-Macro lambda list." arg))
863 ((symbolp arg)
864 (push arg other-args))
865 ((and (listp arg) (symbolp (car arg)))
866 (push (car arg) other-args))
867 (t (error "Illegal stuff in lambda list of Define-Modify-Macro."))))
868 (setq other-args (nreverse other-args))
869 `(defmacro ,name (,reference ,@lambda-list &environment ,env)
870 ,doc-string
871 (multiple-value-bind (dummies vals newval setter getter)
872 (get-setf-method ,reference ,env)
873 (do ((d dummies (cdr d))
874 (v vals (cdr v))
875 (let-list nil (cons (list (car d) (car v)) let-list)))
876 ((null d)
877 (push
878 (list (car newval)
879 ,(if rest-arg
880 `(list* ',function getter ,@other-args ,rest-arg)
881 `(list ',function getter ,@other-args)))
882 let-list)
883 `(let* ,(nreverse let-list)
884 ,setter)))))))
885
886 (defmacro push (obj place &environment env)
887 "Takes an object and a location holding a list. Conses the object onto
888 the list, returning the modified list. OBJ is evaluated before PLACE."
889
890 ;; This special case for place being a symbol isn't strictly needed.
891 ;; It's so we can do push (and pushnew) with a kernel.core.
892 (if (and (symbolp place)
893 (eq place (macroexpand place env)))
894 `(setq ,place (cons ,obj ,place))
895 (multiple-value-bind (dummies vals newval setter getter)
896 (get-setf-expansion place env)
897 (cond
898 ((cdr newval)
899 ;; Handle multiple values
900 (let ((g (mapcar #'(lambda (x)
901 (declare (ignore x))
902 (gensym))
903 (rest obj))))
904 `(multiple-value-bind ,g
905 ,obj
906 (let* (,@(mapcar #'list dummies vals))
907 (multiple-value-bind ,newval
908 (values ,@(mapcar #'(lambda (a b)
909 (list 'cons a b))
910 g (rest getter)))
911 ,setter)))))
912 (t
913 ;; A single value
914 (let ((g (gensym)))
915 `(let* ((,g ,obj)
916 ,@(mapcar #'list dummies vals)
917 (,@newval (cons ,g ,getter)))
918 ,setter)))))))
919
920 (defmacro pushnew (obj place &rest keys &environment env)
921 "Takes an object and a location holding a list. If the object is already
922 in the list, does nothing. Else, conses the object onto the list. Returns
923 NIL. If there is a :TEST keyword, this is used for the comparison."
924 (if (and (symbolp place)
925 (eq place (macroexpand place env)))
926 `(setq ,place (adjoin ,obj ,place ,@keys))
927 (multiple-value-bind (vars vals stores setter getter)
928 (get-setf-expansion place env)
929 (cond
930 ((cdr stores)
931 ;; Multiple values
932 (let ((g (mapcar #'(lambda (x)
933 (declare (ignore x))
934 (gensym))
935 (rest obj))))
936 `(multiple-value-bind ,g
937 ,obj
938 (let* (,@(mapcar #'list vars vals))
939 (multiple-value-bind ,stores
940 (values ,@(mapcar #'(lambda (a b)
941 `(adjoin ,a ,b ,@keys))
942 g (rest getter)))
943 ,setter)))))
944 (t
945 ;; Single value
946 (let ((g (gensym)))
947 `(let* ((,g ,obj)
948 ,@(mapcar #'list vars vals)
949 (,@stores (adjoin ,g ,getter ,@keys)))
950 ,setter)))))))
951
952 (defmacro pop (place &environment env)
953 "The argument is a location holding a list. Pops one item off the front
954 of the list and returns it."
955 (if (and (symbolp place)
956 (eq place (macroexpand place env)))
957 `(prog1 (car ,place)
958 (setq ,place (cdr ,place)))
959 (multiple-value-bind (dummies vals newval setter getter)
960 (get-setf-method place env)
961 (do* ((d dummies (cdr d))
962 (v vals (cdr v))
963 (let-list nil))
964 ((null d)
965 (push (list (car newval) getter) let-list)
966 `(let* ,(nreverse let-list)
967 (prog1 (car ,(car newval))
968 (setq ,(car newval) (cdr ,(car newval)))
969 ,setter)))
970 (push (list (car d) (car v)) let-list)))))
971
972
973 (define-modify-macro incf (&optional (delta 1)) +
974 "The first argument is some location holding a number. This number is
975 incremented by the second argument, DELTA, which defaults to 1.")
976
977
978 (define-modify-macro decf (&optional (delta 1)) -
979 "The first argument is some location holding a number. This number is
980 decremented by the second argument, DELTA, which defaults to 1.")
981
982
983 (defmacro remf (place indicator &environment env)
984 "Place may be any place expression acceptable to SETF, and is expected
985 to hold a property list or (). This list is destructively altered to
986 remove the property specified by the indicator. Returns T if such a
987 property was present, NIL if not."
988 (multiple-value-bind (dummies vals newval setter getter)
989 (get-setf-method place env)
990 (do* ((d dummies (cdr d))
991 (v vals (cdr v))
992 (let-list nil)
993 (ind-temp (gensym))
994 (local1 (gensym))
995 (local2 (gensym)))
996 ((null d)
997 (push (list (car newval) getter) let-list)
998 (push (list ind-temp indicator) let-list)
999 `(let* ,(nreverse let-list)
1000 (do ((,local1 ,(car newval) (cddr ,local1))
1001 (,local2 nil ,local1))
1002 ((atom ,local1) nil)
1003 (cond ((atom (cdr ,local1))
1004 (error "Odd-length property list in REMF."))
1005 ((eq (car ,local1) ,ind-temp)
1006 (cond (,local2
1007 (rplacd (cdr ,local2) (cddr ,local1))
1008 (return t))
1009 (t (setq ,(car newval) (cddr ,(car newval)))
1010 ,setter
1011 (return t))))))))
1012 (push (list (car d) (car v)) let-list))))
1013
1014
1015 ;;; The built-in DEFSETFs.
1016
1017 (defsetf car %rplaca)
1018 (defsetf cdr %rplacd)
1019 (defsetf caar (x) (v) `(%rplaca (car ,x) ,v))
1020 (defsetf cadr (x) (v) `(%rplaca (cdr ,x) ,v))
1021 (defsetf cdar (x) (v) `(%rplacd (car ,x) ,v))
1022 (defsetf cddr (x) (v) `(%rplacd (cdr ,x) ,v))
1023 (defsetf caaar (x) (v) `(%rplaca (caar ,x) ,v))
1024 (defsetf cadar (x) (v) `(%rplaca (cdar ,x) ,v))
1025 (defsetf cdaar (x) (v) `(%rplacd (caar ,x) ,v))
1026 (defsetf cddar (x) (v) `(%rplacd (cdar ,x) ,v))
1027 (defsetf caadr (x) (v) `(%rplaca (cadr ,x) ,v))
1028 (defsetf caddr (x) (v) `(%rplaca (cddr ,x) ,v))
1029 (defsetf cdadr (x) (v) `(%rplacd (cadr ,x) ,v))
1030 (defsetf cdddr (x) (v) `(%rplacd (cddr ,x) ,v))
1031 (defsetf caaaar (x) (v) `(%rplaca (caaar ,x) ,v))
1032 (defsetf cadaar (x) (v) `(%rplaca (cdaar ,x) ,v))
1033 (defsetf cdaaar (x) (v) `(%rplacd (caaar ,x) ,v))
1034 (defsetf cddaar (x) (v) `(%rplacd (cdaar ,x) ,v))
1035 (defsetf caadar (x) (v) `(%rplaca (cadar ,x) ,v))
1036 (defsetf caddar (x) (v) `(%rplaca (cddar ,x) ,v))
1037 (defsetf cdadar (x) (v) `(%rplacd (cadar ,x) ,v))
1038 (defsetf cdddar (x) (v) `(%rplacd (cddar ,x) ,v))
1039 (defsetf caaadr (x) (v) `(%rplaca (caadr ,x) ,v))
1040 (defsetf cadadr (x) (v) `(%rplaca (cdadr ,x) ,v))
1041 (defsetf cdaadr (x) (v) `(%rplacd (caadr ,x) ,v))
1042 (defsetf cddadr (x) (v) `(%rplacd (cdadr ,x) ,v))
1043 (defsetf caaddr (x) (v) `(%rplaca (caddr ,x) ,v))
1044 (defsetf cadddr (x) (v) `(%rplaca (cdddr ,x) ,v))
1045 (defsetf cdaddr (x) (v) `(%rplacd (caddr ,x) ,v))
1046 (defsetf cddddr (x) (v) `(%rplacd (cdddr ,x) ,v))
1047
1048 (defsetf first %rplaca)
1049 (defsetf second (x) (v) `(%rplaca (cdr ,x) ,v))
1050 (defsetf third (x) (v) `(%rplaca (cddr ,x) ,v))
1051 (defsetf fourth (x) (v) `(%rplaca (cdddr ,x) ,v))
1052 (defsetf fifth (x) (v) `(%rplaca (cddddr ,x) ,v))
1053 (defsetf sixth (x) (v) `(%rplaca (cdr (cddddr ,x)) ,v))
1054 (defsetf seventh (x) (v) `(%rplaca (cddr (cddddr ,x)) ,v))
1055 (defsetf eighth (x) (v) `(%rplaca (cdddr (cddddr ,x)) ,v))
1056 (defsetf ninth (x) (v) `(%rplaca (cddddr (cddddr ,x)) ,v))
1057 (defsetf tenth (x) (v) `(%rplaca (cdr (cddddr (cddddr ,x))) ,v))
1058 (defsetf rest %rplacd)
1059
1060 (defsetf elt %setelt)
1061 (defsetf aref %aset)
1062 (defsetf row-major-aref %set-row-major-aref)
1063 (defsetf svref %svset)
1064 (defsetf char %charset)
1065 (defsetf bit %bitset)
1066 (defsetf schar %scharset)
1067 (defsetf sbit %sbitset)
1068 (defsetf %array-dimension %set-array-dimension)
1069 (defsetf %raw-bits %set-raw-bits)
1070 (defsetf symbol-value set)
1071 (defsetf symbol-function fset)
1072 (defsetf symbol-plist %set-symbol-plist)
1073 (defsetf nth %setnth)
1074 (defsetf fill-pointer %set-fill-pointer)
1075 (defsetf search-list %set-search-list)
1076
1077 (defsetf sap-ref-8 %set-sap-ref-8)
1078 (defsetf signed-sap-ref-8 %set-signed-sap-ref-8)
1079 (defsetf sap-ref-16 %set-sap-ref-16)
1080 (defsetf signed-sap-ref-16 %set-signed-sap-ref-16)
1081 (defsetf sap-ref-32 %set-sap-ref-32)
1082 (defsetf signed-sap-ref-32 %set-signed-sap-ref-32)
1083 (defsetf sap-ref-64 %set-sap-ref-64)
1084 (defsetf signed-sap-ref-64 %set-signed-sap-ref-64)
1085 (defsetf sap-ref-sap %set-sap-ref-sap)
1086 (defsetf sap-ref-single %set-sap-ref-single)
1087 (defsetf sap-ref-double %set-sap-ref-double)
1088 #+long-float
1089 (defsetf sap-ref-long %set-sap-ref-long)
1090
1091 (define-setf-expander getf (place prop &optional default &environment env)
1092 (multiple-value-bind (temps values stores set get)
1093 (get-setf-method place env)
1094 (let ((newval (gensym))
1095 (ptemp (gensym))
1096 (def-temp (if default (gensym))))
1097 (values `(,@temps ,ptemp ,@(if default `(,def-temp)))
1098 `(,@values ,prop ,@(if default `(,default)))
1099 `(,newval)
1100 `(let ((,(car stores) (%putf ,get ,ptemp ,newval)))
1101 ,set
1102 ,newval)
1103 `(getf ,get ,ptemp ,@(if default `(,def-temp)))))))
1104
1105 (define-setf-expander get (symbol prop &optional default)
1106 (let ((symbol-temp (gensym))
1107 (prop-temp (gensym))
1108 (def-temp (gensym))
1109 (newval (gensym)))
1110 (values `(,symbol-temp ,prop-temp ,@(if default `(,def-temp)))
1111 `(,symbol ,prop ,@(if default `(,default)))
1112 (list newval)
1113 `(%put ,symbol-temp ,prop-temp ,newval)
1114 `(get ,symbol-temp ,prop-temp ,@(if default `(,def-temp))))))
1115
1116 (define-setf-expander gethash (key hashtable &optional default)
1117 (let ((key-temp (gensym))
1118 (hashtable-temp (gensym))
1119 (default-temp (gensym))
1120 (new-value-temp (gensym)))
1121 (values
1122 `(,key-temp ,hashtable-temp ,@(if default `(,default-temp)))
1123 `(,key ,hashtable ,@(if default `(,default)))
1124 `(,new-value-temp)
1125 `(%puthash ,key-temp ,hashtable-temp ,new-value-temp)
1126 `(gethash ,key-temp ,hashtable-temp ,@(if default `(,default-temp))))))
1127
1128 (defsetf subseq (sequence start &optional (end nil)) (v)
1129 `(progn (replace ,sequence ,v :start1 ,start :end1 ,end)
1130 ,v))
1131
1132
1133 ;;; Evil hack invented by the gnomes of Vassar Street (though not as evil as
1134 ;;; it used to be.) The function arg must be constant, and is converted to an
1135 ;;; APPLY of ther SETF function, which ought to exist.
1136 ;;;
1137 (define-setf-expander apply (function &rest args)
1138 (unless (and (listp function)
1139 (= (list-length function) 2)
1140 (eq (first function) 'function)
1141 (symbolp (second function)))
1142 (error "Setf of Apply is only defined for function args like #'symbol."))
1143 (let ((function (second function))
1144 (new-var (gensym))
1145 (vars nil))
1146 (dolist (x args)
1147 (declare (ignore x))
1148 (push (gensym) vars))
1149 (values vars args (list new-var)
1150 `(apply #'(setf ,function) ,new-var ,@vars)
1151 `(apply #',function ,@vars))))
1152
1153
1154 ;;; Special-case a BYTE bytespec so that the compiler can recognize it.
1155 ;;;
1156 (define-setf-expander ldb (bytespec place &environment env)
1157 "The first argument is a byte specifier. The second is any place form
1158 acceptable to SETF. Replaces the specified byte of the number in this
1159 place with bits from the low-order end of the new value."
1160 (multiple-value-bind (dummies vals newval setter getter)
1161 (get-setf-method place env)
1162 (if (and (consp bytespec) (eq (car bytespec) 'byte))
1163 (let ((n-size (gensym))
1164 (n-pos (gensym))
1165 (n-new (gensym)))
1166 (values (list* n-size n-pos dummies)
1167 (list* (second bytespec) (third bytespec) vals)
1168 (list n-new)
1169 `(let ((,(car newval) (dpb ,n-new (byte ,n-size ,n-pos)
1170 ,getter)))
1171 ,setter
1172 ,n-new)
1173 `(ldb (byte ,n-size ,n-pos) ,getter)))
1174 (let ((btemp (gensym))
1175 (gnuval (gensym)))
1176 (values (cons btemp dummies)
1177 (cons bytespec vals)
1178 (list gnuval)
1179 `(let ((,(car newval) (dpb ,gnuval ,btemp ,getter)))
1180 ,setter
1181 ,gnuval)
1182 `(ldb ,btemp ,getter))))))
1183
1184
1185 (define-setf-expander mask-field (bytespec place &environment env)
1186 "The first argument is a byte specifier. The second is any place form
1187 acceptable to SETF. Replaces the specified byte of the number in this place
1188 with bits from the corresponding position in the new value."
1189 (multiple-value-bind (dummies vals newval setter getter)
1190 (get-setf-method place env)
1191 (let ((btemp (gensym))
1192 (gnuval (gensym)))
1193 (values (cons btemp dummies)
1194 (cons bytespec vals)
1195 (list gnuval)
1196 `(let ((,(car newval) (deposit-field ,gnuval ,btemp ,getter)))
1197 ,setter
1198 ,gnuval)
1199 `(mask-field ,btemp ,getter)))))
1200
1201
1202 (define-setf-expander the (type place &environment env)
1203 (multiple-value-bind (dummies vals newval setter getter)
1204 (get-setf-method place env)
1205 (values dummies
1206 vals
1207 newval
1208 (subst `(the ,type ,(car newval)) (car newval) setter)
1209 `(the ,type ,getter))))
1210
1211 (define-setf-expander values (&rest places &environment env)
1212 (collect ((setters) (getters))
1213 (let ((all-dummies '())
1214 (all-vals '())
1215 (newvals '()))
1216 (dolist (place places)
1217 (multiple-value-bind (dummies vals newval setter getter)
1218 (get-setf-expansion place env)
1219 (setf all-dummies (append all-dummies dummies))
1220 (setf all-vals (append all-vals vals))
1221 (setf newvals (append newvals newval))
1222 (setters setter)
1223 (getters getter)))
1224 (values all-dummies all-vals newvals
1225 `(values ,@(setters)) `(values ,@(getters))))))
1226
1227
1228 ;;;; CASE, TYPECASE, & Friends.
1229
1230 (eval-when (compile load eval)
1231
1232 ;;; CASE-BODY returns code for all the standard "case" macros. Name is the
1233 ;;; macro name, and keyform is the thing to case on. Multi-p indicates whether
1234 ;;; a branch may fire off a list of keys; otherwise, a key that is a list is
1235 ;;; interpreted in some way as a single key. When multi-p, test is applied to
1236 ;;; the value of keyform and each key for a given branch; otherwise, test is
1237 ;;; applied to the value of keyform and the entire first element, instead of
1238 ;;; each part, of the case branch. When errorp, no t or otherwise branch is
1239 ;;; permitted, and an ERROR form is generated. When proceedp, it is an error
1240 ;;; to omit errorp, and the ERROR form generated is executed within a
1241 ;;; RESTART-CASE allowing keyform to be set and retested.
1242 ;;;
1243 ;;; If ALLOW-OTHERWISE, then we allow T and OTHERWISE clauses and also
1244 ;;; generate an ERROR form. (This is for CCASE and ECASE which allow
1245 ;;; using T and OTHERWISE as regular keys.)
1246 ;;;
1247 (defun case-body (name keyform cases multi-p test errorp proceedp &optional allow-otherwise)
1248 (let ((keyform-value (gensym))
1249 (clauses ())
1250 (keys ()))
1251 (dolist (case cases)
1252 (cond ((atom case)
1253 (error "~S -- Bad clause in ~S." case name))
1254 ((and (not allow-otherwise)
1255 (memq (car case) '(t otherwise)))
1256 (if errorp
1257 (error "No default clause allowed in ~S: ~S" name case)
1258 (push `(t nil ,@(rest case)) clauses)))
1259 ((and multi-p (listp (first case)))
1260 (setf keys (append (first case) keys))
1261 (push `((or ,@(mapcar #'(lambda (key)
1262 `(,test ,keyform-value ',key))
1263 (first case)))
1264 nil ,@(rest case))
1265 clauses))
1266 (t
1267 (when (and allow-otherwise
1268 (memq (car case) '(t otherwise)))
1269 (warn "Bad style to use T or OTHERWISE in ECASE or CCASE"))
1270 (push (first case) keys)
1271 (push `((,test ,keyform-value
1272 ',(first case)) nil ,@(rest case)) clauses))))
1273 (case-body-aux name keyform keyform-value clauses keys errorp proceedp
1274 allow-otherwise
1275 `(,(if multi-p 'member 'or) ,@keys))))
1276
1277 ;;; CASE-BODY-AUX provides the expansion once CASE-BODY has groveled all the
1278 ;;; cases. Note: it is not necessary that the resulting code signal
1279 ;;; case-failure conditions, but that's what KMP's prototype code did. We call
1280 ;;; CASE-BODY-ERROR, because of how closures are compiled. RESTART-CASE has
1281 ;;; forms with closures that the compiler causes to be generated at the top of
1282 ;;; any function using the case macros, regardless of whether they are needed.
1283 ;;;
1284 (defun case-body-aux (name keyform keyform-value clauses keys
1285 errorp proceedp allow-otherwise expected-type)
1286 (if proceedp
1287 (let ((block (gensym))
1288 (again (gensym)))
1289 `(let ((,keyform-value ,keyform))
1290 (block ,block
1291 (tagbody
1292 ,again
1293 (return-from
1294 ,block
1295 (cond ,@(nreverse clauses)
1296 (t
1297 (setf ,keyform-value
1298 (setf ,keyform
1299 (case-body-error
1300 ',name ',keyform ,keyform-value
1301 ',expected-type ',keys)))
1302 (go ,again))))))))
1303 `(let ((,keyform-value ,keyform))
1304 ,keyform-value ; prevent warnings when key not used eg (case key (t))
1305 (cond
1306 ,@(nreverse clauses)
1307 ,@(if (or errorp allow-otherwise)
1308 `((t (error 'conditions::case-failure
1309 :name ',name
1310 :datum ,keyform-value
1311 :expected-type ',expected-type
1312 :possibilities ',keys))))))))
1313
1314 ); eval-when
1315
1316 (defun case-body-error (name keyform keyform-value expected-type keys)
1317 (restart-case
1318 (error 'conditions::case-failure
1319 :name name
1320 :datum keyform-value
1321 :expected-type expected-type
1322 :possibilities keys)
1323 (store-value (value)
1324 :report (lambda (stream)
1325 (format stream "Supply a new value for ~S." keyform))
1326 :interactive read-evaluated-form
1327 value)))
1328
1329
1330 (defmacro case (keyform &body cases)
1331 "CASE Keyform {({(Key*) | Key} Form*)}*
1332 Evaluates the Forms in the first clause with a Key EQL to the value of
1333 Keyform. If a singleton key is T then the clause is a default clause."
1334 (case-body 'case keyform cases t 'eql nil nil))
1335
1336 (defmacro ccase (keyform &body cases)
1337 "CCASE Keyform {({(Key*) | Key} Form*)}*
1338 Evaluates the Forms in the first clause with a Key EQL to the value of
1339 Keyform. If none of the keys matches then a correctable error is
1340 signalled."
1341 (case-body 'ccase keyform cases t 'eql nil t t))
1342
1343 (defmacro ecase (keyform &body cases)
1344 "ECASE Keyform {({(Key*) | Key} Form*)}*
1345 Evaluates the Forms in the first clause with a Key EQL to the value of
1346 Keyform. If none of the keys matches then an error is signalled."
1347 (case-body 'ecase keyform cases t 'eql nil nil t))
1348
1349 (defmacro typecase (keyform &body cases)
1350 "TYPECASE Keyform {(Type Form*)}*
1351 Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
1352 is true."
1353 (case-body 'typecase keyform cases nil 'typep nil nil))
1354
1355 (defmacro ctypecase (keyform &body cases)
1356 "CTYPECASE Keyform {(Type Form*)}*
1357 Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
1358 is true. If no form is satisfied then a correctable error is signalled."
1359 (case-body 'ctypecase keyform cases nil 'typep nil t t))
1360
1361 (defmacro etypecase (keyform &body cases)
1362 "ETYPECASE Keyform {(Type Form*)}*
1363 Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
1364 is true. If no form is satisfied then an error is signalled."
1365 (case-body 'etypecase keyform cases nil 'typep nil nil t))
1366
1367
1368 ;;;; ASSERT and CHECK-TYPE.
1369
1370 ;;; ASSERT is written this way, to call ASSERT-ERROR, because of how closures
1371 ;;; are compiled. RESTART-CASE has forms with closures that the compiler
1372 ;;; causes to be generated at the top of any function using ASSERT, regardless
1373 ;;; of whether they are needed.
1374 ;;;
1375 (defmacro assert (test-form &optional places datum &rest arguments)
1376 "Signals an error if the value of test-form is nil. Continuing from this
1377 error using the CONTINUE restart will allow the user to alter the value of
1378 some locations known to SETF, starting over with test-form. Returns nil."
1379 `(loop
1380 (when ,test-form (return nil))
1381 (assert-error ',test-form ',places ,datum ,@arguments)
1382 ,@(mapcar #'(lambda (place)
1383 `(setf ,place (assert-prompt ',place ,place)))
1384 places)))
1385
1386 (defun assert-error (assertion places datum &rest arguments)
1387 (let ((cond (if datum
1388 (conditions::coerce-to-condition
1389 datum arguments
1390 'simple-error 'error)
1391 (make-condition 'simple-error
1392 :format-control "The assertion ~S failed."
1393 :format-arguments (list assertion)))))
1394 (restart-case (error cond)
1395 (continue ()
1396 :report (lambda (stream) (assert-report places stream))
1397 nil))))
1398
1399
1400 (defun assert-report (names stream)
1401 (format stream "Retry assertion")
1402 (if names
1403 (format stream " with new value~P for ~{~S~^, ~}."
1404 (length names) names)
1405 (format stream ".")))
1406
1407 (defun assert-prompt (name value)
1408 (cond ((y-or-n-p "The old value of ~S is ~S.~
1409 ~%Do you want to supply a new value? "
1410 name value)
1411 (format *query-io* "~&Type a form to be evaluated:~%")
1412 (flet ((read-it () (eval (read *query-io*))))
1413 (if (symbolp name) ;help user debug lexical variables
1414 (progv (list name) (list value) (read-it))
1415 (read-it))))
1416 (t value)))
1417
1418
1419 ;;; CHECK-TYPE is written this way, to call CHECK-TYPE-ERROR, because of how
1420 ;;; closures are compiled. RESTART-CASE has forms with closures that the
1421 ;;; compiler causes to be generated at the top of any function using
1422 ;;; CHECK-TYPE, regardless of whether they are needed. Because it would be
1423 ;;; nice if this were cheap to use, and some things can't afford this excessive
1424 ;;; consing (e.g., READ-CHAR), we bend backwards a little.
1425 ;;;
1426
1427 (defmacro check-type (place type &optional type-string)
1428 "Signals an error of type type-error if the contents of place are not of the
1429 specified type. If an error is signaled, this can only return if
1430 STORE-VALUE is invoked. It will store into place and start over."
1431 (let ((place-value (gensym)))
1432 `(loop
1433 (let ((,place-value ,place))
1434 (when (typep ,place-value ',type) (return nil))
1435 (setf ,place
1436 (check-type-error ',place ,place-value ',type ,type-string))))))
1437
1438 (defun check-type-error (place place-value type type-string)
1439 (let ((cond (if type-string
1440 (make-condition 'simple-type-error
1441 :datum place :expected-type type
1442 :format-control
1443 "The value of ~S is ~S, which is not ~A."
1444 :format-arguments
1445 (list place place-value type-string))
1446 (make-condition 'simple-type-error
1447 :datum place :expected-type type
1448 :format-control
1449 "The value of ~S is ~S, which is not of type ~S."
1450 :format-arguments
1451 (list place place-value type)))))
1452 (restart-case (error cond)
1453 (store-value (value)
1454 :report (lambda (stream)
1455 (format stream "Supply a new value of ~S."
1456 place))
1457 :interactive read-evaluated-form
1458 value))))
1459
1460 ;;; READ-EVALUATED-FORM is used as the interactive method for restart cases
1461 ;;; setup by the Common Lisp "casing" (e.g., CCASE and CTYPECASE) macros
1462 ;;; and by CHECK-TYPE.
1463 ;;;
1464 (defun read-evaluated-form ()
1465 (format *query-io* "~&Type a form to be evaluated:~%")
1466 (list (eval (read *query-io*))))
1467
1468
1469 ;;;; With-XXX
1470 (defmacro with-open-file ((var &rest open-args) &body (forms decls))
1471 "Bindspec is of the form (Stream File-Name . Options). The file whose
1472 name is File-Name is opened using the Options and bound to the variable
1473 Stream. If the call to open is unsuccessful, the forms are not
1474 evaluated. The Forms are executed, and when they
1475 terminate, normally or otherwise, the file is closed."
1476 (let ((abortp (gensym)))
1477 `(let ((,var (open ,@open-args))
1478 (,abortp t))
1479 ,@decls
1480 (unwind-protect
1481 (multiple-value-prog1
1482 (progn ,@forms)
1483 (setq ,abortp nil))
1484 (when ,var
1485 (close ,var :abort ,abortp))))))
1486
1487
1488 (defmacro with-open-stream ((var stream) &body (forms decls))
1489 "The form stream should evaluate to a stream. VAR is bound
1490 to the stream and the forms are evaluated as an implicit
1491 progn. The stream is closed upon exit."
1492 (let ((abortp (gensym)))
1493 `(let ((,var ,stream)
1494 (,abortp t))
1495 ,@decls
1496 (unwind-protect
1497 (multiple-value-prog1
1498 (progn ,@forms)
1499 (setq ,abortp nil))
1500 (when ,var
1501 (close ,var :abort ,abortp))))))
1502
1503
1504 (defmacro with-input-from-string ((var string &key index start end) &body (forms decls))
1505 "Binds the Var to an input stream that returns characters from String and
1506 executes the body. See manual for details."
1507 ;; The once-only inhibits compiler note for unreachable code when 'end' is true.
1508 (once-only ((string string))
1509 `(let ((,var
1510 ,(cond ((null end)
1511 `(make-string-input-stream ,string ,(or start 0)))
1512 ((symbolp end)
1513 `(if ,end
1514 (make-string-input-stream ,string ,(or start 0) ,end)
1515 (make-string-input-stream ,string ,(or start 0))))
1516 (t
1517 `(make-string-input-stream ,string ,(or start 0) ,end)))))
1518 ,@decls
1519 (unwind-protect
1520 (progn ,@forms)
1521 (close ,var)
1522 ,@(if index `((setf ,index (string-input-stream-current ,var))))))))
1523
1524
1525 (defmacro with-output-to-string ((var &optional string) &body (forms decls))
1526 "If *string* is specified, it must be a string with a fill pointer;
1527 the output is incrementally appended to the string (as if by use of
1528 VECTOR-PUSH-EXTEND)."
1529 (if string
1530 `(let ((,var (make-fill-pointer-output-stream ,string)))
1531 ,@decls
1532 (unwind-protect
1533 (progn ,@forms)
1534 (close ,var)))
1535 `(let ((,var (make-string-output-stream)))
1536 ,@decls
1537 (unwind-protect
1538 (progn ,@forms)
1539 (close ,var))
1540 (get-output-stream-string ,var))))
1541
1542
1543 ;;;; Iteration macros:
1544
1545 (defmacro dotimes ((var count &optional (result nil)) &body body)
1546 (cond ((numberp count)
1547 `(do ((,var 0 (1+ ,var)))
1548 ((>= ,var ,count) ,result)
1549 (declare (type (integer 0 ,count) ,var))
1550 ,@body))
1551 (t (let ((v1 (gensym)))
1552 `(do ((,var 0 (1+ ,var)) (,v1 ,count))
1553 ((>= ,var ,v1) ,result)
1554 (declare (type unsigned-byte ,var))
1555 ,@body)))))
1556
1557
1558 ;;; We repeatedly bind the var instead of setting it so that we never give the
1559 ;;; var a random value such as NIL (which might conflict with a declaration).
1560 ;;; If there is a result form, we introduce a gratitous binding of the variable
1561 ;;; to NIL w/o the declarations, then evaluate the result form in that
1562 ;;; environment. We spuriously reference the gratuitous variable, since we
1563 ;;; don't want to use IGNORABLE on what might be a special var.
1564 ;;;
1565 (defmacro dolist ((var list &optional (result nil)) &body body)
1566 (let ((n-list (gensym)))
1567 `(do ((,n-list ,list (cdr ,n-list)))
1568 ((endp ,n-list)
1569 ,@(if result
1570 `((let ((,var nil))
1571 ,var
1572 ,result))
1573 '(nil)))
1574 (let ((,var (car ,n-list)))
1575 ,@body))))
1576
1577
1578 (defmacro do (varlist endlist &body (body decls))
1579 "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1580 Iteration construct. Each Var is initialized in parallel to the value of the
1581 specified Init form. On subsequent iterations, the Vars are assigned the
1582 value of the Step form (if any) in paralell. The Test is evaluated before
1583 each evaluation of the body Forms. When the Test is true, the Exit-Forms
1584 are evaluated as a PROGN, with the result being the value of the DO. A block
1585 named NIL is established around the entire expansion, allowing RETURN to be
1586 used as an laternate exit mechanism."
1587
1588 (do-do-body varlist endlist body decls 'let 'psetq 'do nil))
1589
1590
1591 (defmacro do* (varlist endlist &body (body decls))
1592 "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1593 Iteration construct. Each Var is initialized sequentially (like LET*) to the
1594 value of the specified Init form. On subsequent iterations, the Vars are
1595 sequentially assigned the value of the Step form (if any). The Test is
1596 evaluated before each evaluation of the body Forms. When the Test is true,
1597 the Exit-Forms are evaluated as a PROGN, with the result being the value
1598 of the DO. A block named NIL is established around the entire expansion,
1599 allowing RETURN to be used as an laternate exit mechanism."
1600 (do-do-body varlist endlist body decls 'let* 'setq 'do* nil))
1601
1602
1603 ;;;; Miscellaneous macros:
1604
1605 (defmacro psetq (&rest pairs)
1606 (do ((lets nil)
1607 (setqs nil)
1608 (pairs pairs (cddr pairs)))
1609 ((atom (cdr pairs))
1610 `(let ,(nreverse lets) (setq ,@(nreverse setqs)) nil))
1611 (let ((gen (gensym)))
1612 (push `(,gen ,(cadr pairs)) lets)
1613 (push (car pairs) setqs)
1614 (push gen setqs))))
1615
1616 ;;; LAMBDA -- from the ANSI spec.
1617 ;;;
1618 (defmacro lambda (&whole form &rest bvl-decls-and-body)
1619 (declare (ignore bvl-decls-and-body))
1620 `#',form)
1621
1622
1623
1624 ;;;; With-Compilation-Unit:
1625
1626 ;;; True if we are within a With-Compilation-Unit form, which normally causes
1627 ;;; nested uses to be NOOPS.
1628 ;;;
1629 (defvar *in-compilation-unit* nil)
1630
1631 ;;; Count of the number of compilation units dynamically enclosed by the
1632 ;;; current active WITH-COMPILATION-UNIT that were unwound out of.
1633 ;;;
1634 (defvar *aborted-compilation-units*)
1635
1636 (declaim (special c::*context-declarations*))
1637
1638
1639 ;;; EVALUATE-DECLARATION-CONTEXT -- Internal
1640 ;;;
1641 ;;; Recursively descend the context form, returning true if this subpart
1642 ;;; matches the specified context.
1643 ;;;
1644 (defun evaluate-declaration-context (context name parent)
1645 (let* ((base (if (and (consp name) (consp (cdr name)))
1646 (cadr name)
1647 name))
1648 (package (and (symbolp base) (symbol-package base))))
1649 (if (atom context)
1650 (multiple-value-bind (ignore how)
1651 (if package
1652 (find-symbol (symbol-name base) package)
1653 (values nil nil))
1654 (declare (ignore ignore))
1655 (case context
1656 (:internal (eq how :internal))
1657 (:external (eq how :external))
1658 (:uninterned (and (symbolp base) (not package)))
1659 (:anonymous (not name))
1660 (:macro (eq parent 'defmacro))
1661 (:function (member parent '(defun labels flet function)))
1662 (:global (member parent '(defun defmacro function)))
1663 (:local (member parent '(labels flet)))
1664 (t
1665 (error "Unknown declaration context: ~S." context))))
1666 (case (first context)
1667 (:or
1668 (loop for x in (rest context)
1669 thereis (evaluate-declaration-context x name parent)))
1670 (:and
1671 (loop for x in (rest context)
1672 always (evaluate-declaration-context x name parent)))
1673 (:not
1674 (evaluate-declaration-context (second context) name parent))
1675 (:member
1676 (member name (rest context) :test #'equal))
1677 (:match
1678 (let ((name (concatenate 'string "$" (string base) "$")))
1679 (loop for x in (rest context)
1680 thereis (search (string x) name))))
1681 (:package
1682 (and package
1683 (loop for x in (rest context)
1684 thereis (eq (find-package (string x)) package))))
1685 (t
1686 (error "Unknown declaration context: ~S." context))))))
1687
1688
1689 ;;; PROCESS-CONTEXT-DECLARATIONS -- Internal
1690 ;;;
1691 ;;; Given a list of context declaration specs, return a new value for
1692 ;;; C::*CONTEXT-DECLARATIONS*.
1693 ;;;
1694 (defun process-context-declarations (decls)
1695 (append
1696 (mapcar
1697 #'(lambda (decl)
1698 (unless (>= (length decl) 2)
1699 (error "Context declaration spec should have context and at ~
1700 least one DECLARE form:~% ~S" decl))
1701 #'(lambda (name parent)
1702 (when (evaluate-declaration-context (first decl) name parent)
1703 (rest decl))))
1704 decls)
1705 c::*context-declarations*))
1706
1707
1708 ;;; With-Compilation-Unit -- Public
1709 ;;;
1710 (defmacro with-compilation-unit (options &body body)
1711 "WITH-COMPILATION-UNIT ({Key Value}*) Form*
1712 This form affects compilations that take place within its dynamic extent. It
1713 is intended to be wrapped around the compilation of all files in the same
1714 system. These keywords are defined:
1715 :OVERRIDE Boolean-Form
1716 One of the effects of this form is to delay undefined warnings
1717 until the end of the form, instead of giving them at the end of each
1718 compilation. If OVERRIDE is NIL (the default), then the outermost
1719 WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
1720 OVERRIDE true causes that form to grab any enclosed warnings, even if
1721 it is enclosed by another WITH-COMPILATION-UNIT.
1722 :OPTIMIZE Decl-Form
1723 Decl-Form should evaluate to an OPTIMIZE declaration specifier. This
1724 declaration changes the `global' policy for compilations within the
1725 body.
1726 :OPTIMIZE-INTERFACE Decl-Form
1727 Like OPTIMIZE, except that it specifies the value of the CMU extension
1728 OPTIMIZE-INTERFACE policy (which controls argument type and syntax
1729 checking.)
1730 :CONTEXT-DECLARATIONS List-of-Context-Decls-Form
1731 This is a CMU extension which allows compilation to be controlled
1732 by pattern matching on the context in which a definition appears. The
1733 argument should evaluate to a list of lists of the form:
1734 (Context-Spec Declare-Form+)
1735 In the indicated context, the specified declare forms are inserted at
1736 the head of each definition. The declare forms for all contexts that
1737 match are appended together, with earlier declarations getting
1738 predecence over later ones. A simple example:
1739 :context-declarations
1740 '((:external (declare (optimize (safety 2)))))
1741 This will cause all functions that are named by external symbols to be
1742 compiled with SAFETY 2. The full syntax of context specs is:
1743 :INTERNAL, :EXTERNAL
1744 True if the symbols is internal (external) in its home package.
1745 :UNINTERNED
1746 True if the symbol has no home package.
1747 :ANONYMOUS
1748 True if the function doesn't have any interesting name (not
1749 DEFMACRO, DEFUN, LABELS or FLET).
1750 :MACRO, :FUNCTION
1751 :MACRO is a global (DEFMACRO) macro. :FUNCTION is anything else.
1752 :LOCAL, :GLOBAL
1753 :LOCAL is a LABELS or FLET. :GLOBAL is anything else.
1754 (:OR Context-Spec*)
1755 True in any specified context.
1756 (:AND Context-Spec*)
1757 True only when all specs are true.
1758 (:NOT Context-Spec)
1759 True when the spec is false.
1760 (:MEMBER Name*)
1761 True when the name is one of these names (EQUAL test.)
1762 (:MATCH Pattern*)
1763 True when any of the patterns is a substring of the name. The name
1764 is wrapped with $'s, so $FOO matches names beginning with FOO,
1765 etc."
1766 (let ((override nil)
1767 (optimize nil)
1768 (optimize-interface nil)
1769 (context-declarations nil)
1770 (n-fun (gensym))
1771 (n-abort-p (gensym)))
1772 (when (oddp (length options))
1773 (error "Odd number of key/value pairs: ~S." options))
1774 (do ((opt options (cddr opt)))
1775 ((null opt))
1776 (case (first opt)
1777 (:override
1778 (setq override (second opt)))
1779 (:optimize
1780 (setq optimize (second opt)))
1781 (:optimize-interface
1782 (setq optimize-interface (second opt)))
1783 (:context-declarations
1784 (setq context-declarations (second opt)))
1785 (t
1786 (warn "Ignoring unknown option: ~S." (first opt)))))
1787
1788 `(flet ((,n-fun ()
1789 (let (,@(when optimize
1790 `((c::*default-cookie*
1791 (c::process-optimize-declaration
1792 ,optimize c::*default-cookie*))))
1793 ,@(when optimize-interface
1794 `((c::*default-interface-cookie*
1795 (c::process-optimize-declaration
1796 ,optimize-interface
1797 c::*default-interface-cookie*))))
1798 ,@(when context-declarations
1799 `((c::*context-declarations*
1800 (process-context-declarations
1801 ,context-declarations)))))
1802 ,@body)))
1803 (if (or ,override (not *in-compilation-unit*))
1804 (let ((c::*undefined-warnings* nil)
1805 (c::*compiler-error-count* 0)
1806 (c::*compiler-warning-count* 0)
1807 (c::*compiler-note-count* 0)
1808 (*in-compilation-unit* t)
1809 (*aborted-compilation-units* 0)
1810 (,n-abort-p t))
1811 (handler-bind ((c::parse-unknown-type
1812 #'(lambda (c)
1813 (c::note-undefined-reference
1814 (c::parse-unknown-type-specifier c)
1815 :type))))
1816 (unwind-protect
1817 (multiple-value-prog1
1818 (,n-fun)
1819 (setq ,n-abort-p nil))
1820 (c::print-summary ,n-abort-p *aborted-compilation-units*))))
1821 (let ((,n-abort-p t))
1822 (unwind-protect
1823 (multiple-value-prog1
1824 (,n-fun)
1825 (setq ,n-abort-p nil))
1826 (when ,n-abort-p
1827 (incf *aborted-compilation-units*))))))))

  ViewVC Help
Powered by ViewVC 1.1.5