/[cmucl]/src/code/lispinit.lisp
ViewVC logotype

Contents of /src/code/lispinit.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.46 - (show annotations)
Mon Oct 31 04:11:27 1994 UTC (19 years, 5 months ago) by ram
Branch: MAIN
Changes since 1.45: +1 -3 lines
Fix headed boilerplate.
1 ;;; -*- Mode: Lisp; Package: Lisp; Log: code.log -*-
2 ;;;
3 ;;; **********************************************************************
4 ;;; This code was written as part of the CMU Common Lisp project at
5 ;;; Carnegie Mellon University, and has been placed in the public domain.
6 ;;;
7 (ext:file-comment
8 "$Header: /tiger/var/lib/cvsroots/cmucl/src/code/lispinit.lisp,v 1.46 1994/10/31 04:11:27 ram Exp $")
9 ;;;
10 ;;; **********************************************************************
11 ;;;
12 ;;; Initialization stuff for CMU Common Lisp, plus some other random functions
13 ;;; that we don't have any better place for.
14 ;;;
15 ;;; Written by Skef Wholey and Rob MacLachlan.
16 ;;;
17 (in-package :lisp)
18
19 (export '(most-positive-fixnum most-negative-fixnum sleep
20 ++ +++ ** *** // ///))
21
22 (in-package :system)
23 (export '(compiler-version scrub-control-stack))
24
25 (in-package :extensions)
26 (export '(quit *prompt*))
27
28 (in-package :lisp)
29
30 ;;; Make the error system enable interrupts.
31
32 (defconstant most-positive-fixnum #.vm:target-most-positive-fixnum
33 "The fixnum closest in value to positive infinity.")
34
35 (defconstant most-negative-fixnum #.vm:target-most-negative-fixnum
36 "The fixnum closest in value to negative infinity.")
37
38
39 ;;; Random information:
40
41 (defvar *lisp-implementation-version* "4.0(?)")
42
43
44 ;;; Must be initialized in %INITIAL-FUNCTION before the DEFVAR runs...
45 (declaim
46 #-gengc
47 (special *gc-inhibit* *already-maybe-gcing*
48 *need-to-collect-garbage* *gc-verbose*
49 *before-gc-hooks* *after-gc-hooks*
50 unix::*interrupts-enabled*
51 unix::*interrupt-pending*
52 *type-system-initialized*)
53 #+gengc
54 (special *gc-verbose* *before-gc-hooks* *after-gc-hooks*
55 *type-system-initialized*))
56
57
58 ;;;; Random magic specials.
59
60
61 ;;; These are filled in by Genesis.
62
63 #-gengc
64 (progn
65
66 (defvar *current-catch-block*)
67 (defvar *current-unwind-block*)
68 (defvar *free-interrupt-context-index*)
69
70 ); #-gengc progn
71
72
73 ;;;; Random stuff that needs to be in the cold load which would otherwise be
74 ;;;; byte-compiled.
75 ;;;;
76 (defvar hi::*in-the-editor* nil)
77
78 ;;;; Called by defmacro expanders...
79
80 ;;; VERIFY-KEYWORDS -- internal
81 ;;;
82 ;;; Determine if key-list is a valid list of keyword/value pairs. Do not
83 ;;; signal the error directly, 'cause we don't know how it should be signaled.
84 ;;;
85 (defun verify-keywords (key-list valid-keys allow-other-keys)
86 (do ((already-processed nil)
87 (unknown-keyword nil)
88 (remaining key-list (cddr remaining)))
89 ((null remaining)
90 (if (and unknown-keyword
91 (not allow-other-keys)
92 (not (lookup-keyword :allow-other-keys key-list)))
93 (values :unknown-keyword (list unknown-keyword valid-keys))
94 (values nil nil)))
95 (cond ((not (and (consp remaining) (listp (cdr remaining))))
96 (return (values :dotted-list key-list)))
97 ((null (cdr remaining))
98 (return (values :odd-length key-list)))
99 ((member (car remaining) already-processed)
100 (return (values :duplicate (car remaining))))
101 ((or (eq (car remaining) :allow-other-keys)
102 (member (car remaining) valid-keys))
103 (push (car remaining) already-processed))
104 (t
105 (setf unknown-keyword (car remaining))))))
106
107 (defun lookup-keyword (keyword key-list)
108 (do ((remaining key-list (cddr remaining)))
109 ((endp remaining))
110 (when (eq keyword (car remaining))
111 (return (cadr remaining)))))
112 ;;;
113 (defun keyword-supplied-p (keyword key-list)
114 (do ((remaining key-list (cddr remaining)))
115 ((endp remaining))
116 (when (eq keyword (car remaining))
117 (return t))))
118
119 (in-package "CONDITIONS")
120
121 (defvar *break-on-signals* nil
122 "When (typep condition *break-on-signals*) is true, then calls to SIGNAL will
123 enter the debugger prior to signalling that condition.")
124
125 (defun signal (datum &rest arguments)
126 "Invokes the signal facility on a condition formed from datum and arguments.
127 If the condition is not handled, nil is returned. If
128 (TYPEP condition *BREAK-ON-SIGNALS*) is true, the debugger is invoked before
129 any signalling is done."
130 (let ((condition (coerce-to-condition datum arguments
131 'simple-condition 'signal))
132 (*handler-clusters* *handler-clusters*))
133 (let ((obos *break-on-signals*)
134 (*break-on-signals* nil))
135 (when (typep condition obos)
136 (break "~A~%Break entered because of *break-on-signals* (now NIL.)"
137 condition)))
138 (loop
139 (unless *handler-clusters* (return))
140 (let ((cluster (pop *handler-clusters*)))
141 (dolist (handler cluster)
142 (when (typep condition (car handler))
143 (funcall (cdr handler) condition)))))
144 nil))
145
146 ;;; COERCE-TO-CONDITION is used in SIGNAL, ERROR, CERROR, WARN, and
147 ;;; INVOKE-DEBUGGER for parsing the hairy argument conventions into a single
148 ;;; argument that's directly usable by all the other routines.
149 ;;;
150 (defun coerce-to-condition (datum arguments default-type function-name)
151 (cond ((typep datum 'condition)
152 (if arguments
153 (cerror "Ignore the additional arguments."
154 'simple-type-error
155 :datum arguments
156 :expected-type 'null
157 :format-control "You may not supply additional arguments ~
158 when giving ~S to ~S."
159 :format-arguments (list datum function-name)))
160 datum)
161 ((symbolp datum) ;Roughly, (subtypep datum 'condition).
162 (apply #'make-condition datum arguments))
163 ((or (stringp datum) (functionp datum))
164 (make-condition default-type
165 :format-control datum
166 :format-arguments arguments))
167 (t
168 (error 'simple-type-error
169 :datum datum
170 :expected-type '(or symbol string)
171 :format-control "Bad argument to ~S: ~S"
172 :format-arguments (list function-name datum)))))
173
174 (defun error (datum &rest arguments)
175 "Invokes the signal facility on a condition formed from datum and arguments.
176 If the condition is not handled, the debugger is invoked."
177 (kernel:infinite-error-protect
178 (let ((condition (coerce-to-condition datum arguments
179 'simple-error 'error))
180 (debug:*stack-top-hint* debug:*stack-top-hint*))
181 (unless (and (condition-function-name condition) debug:*stack-top-hint*)
182 (multiple-value-bind
183 (name frame)
184 (kernel:find-caller-name)
185 (unless (condition-function-name condition)
186 (setf (condition-function-name condition) name))
187 (unless debug:*stack-top-hint*
188 (setf debug:*stack-top-hint* frame))))
189 (let ((debug:*stack-top-hint* nil))
190 (signal condition))
191 (invoke-debugger condition))))
192
193 ;;; CERROR must take care to not use arguments when datum is already a
194 ;;; condition object.
195 ;;;
196 (defun cerror (continue-string datum &rest arguments)
197 (kernel:infinite-error-protect
198 (with-simple-restart
199 (continue "~A" (apply #'format nil continue-string arguments))
200 (let ((condition (if (typep datum 'condition)
201 datum
202 (coerce-to-condition datum arguments
203 'simple-error 'error)))
204 (debug:*stack-top-hint* debug:*stack-top-hint*))
205 (unless (and (condition-function-name condition)
206 debug:*stack-top-hint*)
207 (multiple-value-bind
208 (name frame)
209 (kernel:find-caller-name)
210 (unless (condition-function-name condition)
211 (setf (condition-function-name condition) name))
212 (unless debug:*stack-top-hint*
213 (setf debug:*stack-top-hint* frame))))
214 (with-condition-restarts condition (list (find-restart 'continue))
215 (let ((debug:*stack-top-hint* nil))
216 (signal condition))
217 (invoke-debugger condition)))))
218 nil)
219
220 (defun break (&optional (datum "Break") &rest arguments)
221 "Prints a message and invokes the debugger without allowing any possibility
222 of condition handling occurring."
223 (kernel:infinite-error-protect
224 (with-simple-restart (continue "Return from BREAK.")
225 (let ((debug:*stack-top-hint*
226 (or debug:*stack-top-hint*
227 (nth-value 1 (kernel:find-caller-name)))))
228 (invoke-debugger
229 (coerce-to-condition datum arguments 'simple-condition 'break)))))
230 nil)
231
232 (defun warn (datum &rest arguments)
233 "Warns about a situation by signalling a condition formed by datum and
234 arguments. While the condition is being signaled, a muffle-warning restart
235 exists that causes WARN to immediately return nil."
236 (kernel:infinite-error-protect
237 (let ((condition (coerce-to-condition datum arguments
238 'simple-warning 'warn)))
239 (check-type condition warning "a warning condition")
240 (restart-case (signal condition)
241 (muffle-warning ()
242 :report "Skip warning."
243 (return-from warn nil)))
244 (format *error-output* "~&~@<Warning: ~3i~:_~A~:>~%" condition)))
245 nil)
246
247 (in-package "LISP")
248
249
250 ;;; %Initial-Function is called when a cold system starts up. First we zoom
251 ;;; down the *Lisp-Initialization-Functions* doing things that wanted to happen
252 ;;; at "load time." Then we initialize the various subsystems and call the
253 ;;; read-eval-print loop. The top-level Read-Eval-Print loop is executed until
254 ;;; someone (most likely the Quit function) throws to the tag
255 ;;; %End-Of-The-World. We quit this way so that all outstanding cleanup forms
256 ;;; in Unwind-Protects will get executed.
257
258 (proclaim '(special *lisp-initialization-functions*
259 *load-time-values*))
260
261 (eval-when (compile)
262 (defmacro print-and-call (name)
263 `(progn
264 (%primitive print ,(symbol-name name))
265 (,name))))
266
267 (defun %initial-function ()
268 "Gives the world a shove and hopes it spins."
269 (%primitive print "In initial-function, and running.")
270 #-gengc (setf *already-maybe-gcing* t)
271 #-gengc (setf *gc-inhibit* t)
272 #-gengc (setf *need-to-collect-garbage* nil)
273 (setf *gc-verbose* #-gengc t #+gengc nil)
274 (setf *before-gc-hooks* nil)
275 (setf *after-gc-hooks* nil)
276 #-gengc (setf unix::*interrupts-enabled* t)
277 #-gengc (setf unix::*interrupt-pending* nil)
278 (setf *type-system-initialized* nil)
279 (setf *break-on-signals* nil)
280 #+gengc (setf conditions::*handler-clusters* nil)
281
282 ;; Many top-level forms call INFO, (SETF INFO).
283 (print-and-call c::globaldb-init)
284
285 ;; Set up the fdefn database.
286 (print-and-call fdefn-init)
287
288 ;; Some of the random top-level forms call Make-Array, which calls Subtypep
289 (print-and-call typedef-init)
290 (print-and-call class-init)
291 (print-and-call type-init)
292
293 (let ((funs (nreverse *lisp-initialization-functions*)))
294 (%primitive print "Calling top-level forms.")
295 (dolist (fun funs)
296 (typecase fun
297 (function
298 (funcall fun))
299 (cons
300 (case (car fun)
301 (:load-time-value
302 (setf (svref *load-time-values* (third fun))
303 (funcall (second fun))))
304 (:load-time-value-fixup
305 #-gengc
306 (setf (sap-ref-32 (second fun) 0)
307 (get-lisp-obj-address
308 (svref *load-time-values* (third fun))))
309 #+gengc
310 (do-load-time-value-fixup (second fun) (third fun) (fourth fun)))
311 (t
312 (%primitive print
313 "Bogus fixup in *lisp-initialization-functions*")
314 (%halt))))
315 (t
316 (%primitive print
317 "Bogus function in *lisp-initialization-functions*")
318 (%halt)))))
319 (makunbound '*lisp-initialization-functions*) ; So it gets GC'ed.
320 (makunbound '*load-time-values*)
321
322 ;; Only do this after top level forms have run, 'cause thats where
323 ;; deftypes are.
324 (setf *type-system-initialized* t)
325
326 (print-and-call os-init)
327 (print-and-call filesys-init)
328
329 (print-and-call reader-init)
330 ;; Note: sharpm and backq not yet loaded, so this is not the final RT.
331 (setf *readtable* (copy-readtable std-lisp-readtable))
332
333 (print-and-call stream-init)
334 (print-and-call loader-init)
335 (print-and-call package-init)
336 (print-and-call kernel::signal-init)
337 (setf (alien:extern-alien "internal_errors_enabled" alien:boolean) t)
338 (set-floating-point-modes :traps '(:overflow :underflow :invalid
339 :divide-by-zero))
340 ;; This is necessary because some of the initial top level forms might
341 ;; have changed the compliation policy in strange ways.
342 (print-and-call c::proclaim-init)
343
344 (print-and-call kernel::class-finalize)
345
346 (%primitive print "Done initializing.")
347
348 #-gengc (setf *already-maybe-gcing* nil)
349 #+gengc (setf *gc-verbose* t)
350 (terpri)
351 (princ "CMU Common Lisp kernel core image ")
352 (princ (lisp-implementation-version))
353 (princ ".")
354 (terpri)
355 (princ "[You are in the LISP package.]")
356 (terpri)
357 (catch '%end-of-the-world
358 (loop
359 (%top-level)
360 (write-line "You're certainly a clever child.")))
361 (unix:unix-exit 0))
362
363 #+gengc
364 (defun do-load-time-value-fixup (object offset index)
365 (declare (type index offset))
366 (macrolet ((lose (msg)
367 `(progn
368 (%primitive print ,msg)
369 (%halt))))
370 (let ((value (svref *load-time-values* index)))
371 (typecase object
372 (list
373 (case offset
374 (0 (setf (car object) value))
375 (1 (setf (cdr object) value))
376 (t (lose "Bogus offset in cons cell."))))
377 (instance
378 (setf (%instance-ref object (- offset vm:instance-slots-offset))
379 value))
380 (code-component
381 (setf (code-header-ref object offset) value))
382 (simple-vector
383 (setf (svref object (- offset vm:vector-data-offset)) value))
384 (t
385 (lose "Unknown kind of object for load-time-value fixup."))))))
386
387
388 ;;;; Initialization functions:
389
390 (defun reinit ()
391 (without-interrupts
392 (without-gcing
393 (os-init)
394 (stream-reinit)
395 (kernel::signal-init)
396 (gc-init)
397 (setf (alien:extern-alien "internal_errors_enabled" alien:boolean) t)
398 (set-floating-point-modes :traps
399 '(:overflow :underflow :invalid
400 :divide-by-zero)))))
401
402
403
404 ;;;; Miscellaneous external functions:
405
406 ;;; Quit gets us out, one way or another.
407
408 (defun quit (&optional recklessly-p)
409 "Terminates the current Lisp. Things are cleaned up unless Recklessly-P is
410 non-Nil."
411 (if recklessly-p
412 (unix:unix-exit 0)
413 (throw '%end-of-the-world nil)))
414
415
416 (defun sleep (n)
417 "This function causes execution to be suspended for N seconds. N may
418 be any non-negative, non-complex number."
419 (when (or (not (realp n))
420 (minusp n))
421 (error "Invalid argument to SLEEP: ~S.~%~
422 Must be a non-negative, non-complex number."
423 n))
424 (multiple-value-bind (sec usec)
425 (if (integerp n)
426 (values n 0)
427 (values (truncate n)
428 (truncate (* n 1000000))))
429 (unix:unix-select 0 0 0 0 sec usec))
430 nil)
431
432
433 ;;;; SCRUB-CONTROL-STACK
434
435
436 (defconstant bytes-per-scrub-unit 2048)
437
438 (defun scrub-control-stack ()
439 "Zero the unused portion of the control stack so that old objects are not
440 kept alive because of uninitialized stack variables."
441 (declare (optimize (speed 3) (safety 0))
442 (values (unsigned-byte 20)))
443 (labels
444 ((scrub (ptr offset count)
445 (declare (type system-area-pointer ptr)
446 (type (unsigned-byte 16) offset)
447 (type (unsigned-byte 20) count)
448 (values (unsigned-byte 20)))
449 (cond ((= offset bytes-per-scrub-unit)
450 (look (sap+ ptr bytes-per-scrub-unit) 0 count))
451 (t
452 (setf (sap-ref-32 ptr offset) 0)
453 (scrub ptr (+ offset vm:word-bytes) count))))
454 (look (ptr offset count)
455 (declare (type system-area-pointer ptr)
456 (type (unsigned-byte 16) offset)
457 (type (unsigned-byte 20) count)
458 (values (unsigned-byte 20)))
459 (cond ((= offset bytes-per-scrub-unit)
460 count)
461 ((zerop (sap-ref-32 ptr offset))
462 (look ptr (+ offset vm:word-bytes) count))
463 (t
464 (scrub ptr offset (+ count vm:word-bytes))))))
465 (let* ((csp (sap-int (c::control-stack-pointer-sap)))
466 (initial-offset (logand csp (1- bytes-per-scrub-unit))))
467 (declare (type (unsigned-byte 32) csp))
468 (scrub (int-sap (- csp initial-offset))
469 (* (floor initial-offset vm:word-bytes) vm:word-bytes)
470 0))))
471
472
473
474 ;;;; TOP-LEVEL loop.
475
476 (defvar / nil
477 "Holds a list of all the values returned by the most recent top-level EVAL.")
478 (defvar // nil "Gets the previous value of / when a new value is computed.")
479 (defvar /// nil "Gets the previous value of // when a new value is computed.")
480 (defvar * nil "Holds the value of the most recent top-level EVAL.")
481 (defvar ** nil "Gets the previous value of * when a new value is computed.")
482 (defvar *** nil "Gets the previous value of ** when a new value is computed.")
483 (defvar + nil "Holds the value of the most recent top-level READ.")
484 (defvar ++ nil "Gets the previous value of + when a new value is read.")
485 (defvar +++ nil "Gets the previous value of ++ when a new value is read.")
486 (defvar - nil "Holds the form curently being evaluated.")
487 (defvar *prompt* "* "
488 "The top-level prompt string. This also may be a function of no arguments
489 that returns a simple-string.")
490 (defvar *in-top-level-catcher* nil
491 "True if we are within the Top-Level-Catcher. This is used by interrupt
492 handlers to see whether it is o.k. to throw.")
493
494 (defun interactive-eval (form)
495 "Evaluate FORM, returning whatever it returns but adjust ***, **, *, +++, ++,
496 +, ///, //, /, and -."
497 (setf - form)
498 (let ((results (multiple-value-list (eval form))))
499 (setf /// //
500 // /
501 / results
502 *** **
503 ** *
504 * (car results)))
505 (setf +++ ++
506 ++ +
507 + -)
508 (unless (boundp '*)
509 ;; The bogon returned an unbound marker.
510 (setf * nil)
511 (cerror "Go on with * set to NIL."
512 "EVAL returned an unbound marker."))
513 (values-list /))
514
515
516 (defconstant eofs-before-quit 10)
517
518 (defun %top-level ()
519 "Top-level READ-EVAL-PRINT loop. Do not call this."
520 (let ((* nil) (** nil) (*** nil)
521 (- nil) (+ nil) (++ nil) (+++ nil)
522 (/// nil) (// nil) (/ nil)
523 (magic-eof-cookie (cons :eof nil))
524 (number-of-eofs 0))
525 (loop
526 (with-simple-restart (abort "Return to Top-Level.")
527 (catch 'top-level-catcher
528 (unix:unix-sigsetmask 0)
529 (let ((*in-top-level-catcher* t))
530 (loop
531 (scrub-control-stack)
532 (fresh-line)
533 (princ (if (functionp *prompt*)
534 (funcall *prompt*)
535 *prompt*))
536 (force-output)
537 (let ((form (read *standard-input* nil magic-eof-cookie)))
538 (cond ((not (eq form magic-eof-cookie))
539 (let ((results
540 (multiple-value-list (interactive-eval form))))
541 (dolist (result results)
542 (fresh-line)
543 (prin1 result)))
544 (setf number-of-eofs 0))
545 ((eql (incf number-of-eofs) 1)
546 (let ((stream (make-synonym-stream '*terminal-io*)))
547 (setf *standard-input* stream)
548 (setf *standard-output* stream)
549 (format t "~&Received EOF on *standard-input*, ~
550 switching to *terminal-io*.~%")))
551 ((> number-of-eofs eofs-before-quit)
552 (format t "~&Received more than ~D EOFs; Aborting.~%"
553 eofs-before-quit)
554 (quit))
555 (t
556 (format t "~&Received EOF.~%")))))))))))
557
558
559
560 ;;; %Halt -- Interface
561 ;;;
562 ;;; A convenient way to get into the assembly level debugger.
563 ;;;
564 (defun %halt ()
565 (%primitive halt))

  ViewVC Help
Powered by ViewVC 1.1.5