/[cmucl]/src/code/extensions.lisp
ViewVC logotype

Contents of /src/code/extensions.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations)
Wed Apr 24 21:04:12 1991 UTC (23 years ago) by ram
Branch: MAIN
Changes since 1.9: +12 -19 lines
Rewrote ONCE-ONLY to be less twisted so that I could make it sequential.
1 ;;; -*- Log: code.log; Package: Extensions -*-
2 ;;;
3 ;;; **********************************************************************
4 ;;; This code was written as part of the CMU Common Lisp project at
5 ;;; Carnegie Mellon University, and has been placed in the public domain.
6 ;;; If you want to use this code or any part of CMU Common Lisp, please contact
7 ;;; Scott Fahlman or slisp-group@cs.cmu.edu.
8 ;;;
9 (ext:file-comment
10 "$Header: /tiger/var/lib/cvsroots/cmucl/src/code/extensions.lisp,v 1.10 1991/04/24 21:04:12 ram Exp $")
11 ;;;
12 ;;; **********************************************************************
13 ;;;
14 ;;; Spice Lisp extensions to the language.
15 ;;;
16 ;;; Letf written by Steven Handerson.
17 ;;;
18 ;;; **********************************************************************
19 (in-package "EXTENSIONS")
20
21 (export '(letf* letf dovector deletef indenting-further file-comment
22 read-char-no-edit listen-skip-whitespace concat-pnames
23 iterate once-only collect do-anonymous undefined-value
24 required-argument define-hash-cache defun-cached
25 cache-hash-eq))
26
27 (import 'lisp::whitespace-char-p)
28
29
30
31 ;;; Undefined-Value -- Public
32 ;;;
33 ;;; This is here until we figure out what to do with it.
34 ;;;
35 (proclaim '(inline undefined-value))
36 (defun undefined-value ()
37 '%undefined%)
38
39 ;;; REQUIRED-ARGUMENT -- Public
40 ;;;
41 (proclaim '(ftype (function () nil) required-argument))
42 (defun required-argument ()
43 "This function can be used as the default value for keyword arguments that
44 must be always be supplied. Since it is known by the compiler to never
45 return, it will avoid any compile-time type warnings that would result from a
46 default value inconsistent with the declared type. When this function is
47 called, it signals an error indicating that a required keyword argument was
48 not supplied. This function is also useful for DEFSTRUCT slot defaults
49 corresponding to required arguments."
50 (error "A required keyword argument was not supplied."))
51
52
53 ;;; FILE-COMMENT -- Public
54 ;;;
55 (defmacro file-comment (string)
56 "FILE-COMMENT String
57 When COMPILE-FILE sees this form at top-level, it places the constant string
58 in the run-time source location information. DESCRIBE will print the file
59 comment for the file that a function was defined in. The string is also
60 textually present in the FASL, so the RCS \"ident\" command can find it,
61 etc."
62 (declare (ignore string))
63 '(undefined-value))
64
65
66 (defun skip-whitespace (&optional (stream *standard-input*))
67 (loop (let ((char (read-char stream)))
68 (if (not (lisp::whitespacep char))
69 (return (unread-char char stream))))))
70
71
72 (defun listen-skip-whitespace (&optional (stream *standard-input*))
73 "See listen. Any whitespace in the input stream will be flushed."
74 (do ((char (read-char-no-hang stream nil nil nil)
75 (read-char-no-hang stream nil nil nil)))
76 ((null char) nil)
77 (cond ((not (whitespace-char-p char))
78 (unread-char char stream)
79 (return T)))))
80
81 ;;; These macros waste time as opposed to space.
82
83 (defmacro letf* (bindings &body body &environment env)
84 "Does what one might expect, saving the old values and setting the generalized
85 variables to the new values in sequence. Unwind-protects and get-setf-method
86 are used to preserve the semantics one might expect in analogy to let*,
87 and the once-only evaluation of subforms."
88 (labels ((do-bindings
89 (bindings)
90 (cond ((null bindings) body)
91 (t (multiple-value-bind (dummies vals newval setter getter)
92 (lisp::foo-get-setf-method (caar bindings) env)
93 (let ((save (gensym)))
94 `((let* (,@(mapcar #'list dummies vals)
95 (,(car newval) ,(cadar bindings))
96 (,save ,getter))
97 (unwind-protect
98 (progn ,setter
99 ,@(do-bindings (cdr bindings)))
100 (setq ,(car newval) ,save)
101 ,setter)))))))))
102 (car (do-bindings bindings))))
103
104
105 (defmacro letf (bindings &body body &environment env)
106 "Like letf*, but evaluates all the implicit subforms and new values of all
107 the implied setfs before altering any values. However, the store forms
108 (see get-setf-method) must still be evaluated in sequence. Uses unwind-
109 protects to protect the environment."
110 (let (temps)
111 (labels
112 ((do-bindings
113 (bindings)
114 (cond ((null bindings) body)
115 (t (let ((binding (car bindings)))
116 (multiple-value-bind (dummies vals newval setter getter)
117 (lisp::foo-get-setf-method (car binding) env)
118 (let ((save (gensym)))
119 (mapcar #'(lambda (a b) (push (list a b) temps))
120 dummies vals)
121 (push (list save getter) temps)
122 (push (list (car newval) (cadr binding)) temps)
123 `((unwind-protect
124 (progn ,setter
125 ,@(do-bindings (cdr bindings)))
126 (setq ,(car newval) ,save)
127 ,setter)))))))))
128 (let ((form (car (do-bindings bindings))))
129 `(let* ,(nreverse temps)
130 ,form)))))
131
132
133 (define-setf-method logbitp (index int &environment env)
134 (multiple-value-bind (temps vals stores store-form access-form)
135 (lisp::foo-get-setf-method int env)
136 (let ((ind (gensym))
137 (store (gensym))
138 (stemp (first stores)))
139 (values `(,ind ,@temps)
140 `(,index
141 ,@vals)
142 (list store)
143 `(let ((,stemp
144 (dpb (if ,store 1 0) (byte 1 ,ind) ,access-form)))
145 ,store-form
146 ,store)
147 `(logbitp ,ind ,access-form)))))
148
149
150 ;;; Indenting-Further is a user-level macro which may be used to locally increment
151 ;;; the indentation of a stream.
152
153 (defmacro indenting-further (stream more &rest body)
154 "Causes the output of the indenting Stream to indent More spaces. More is
155 evaluated twice."
156 `(unwind-protect
157 (progn
158 (incf (lisp::indenting-stream-indentation ,stream) ,more)
159 ,@body)
160 (decf (lisp::indenting-stream-indentation ,stream) ,more)))
161
162
163 ;;; Deletef
164
165 (defmacro deletef (elt list &rest keys &environment env)
166 (multiple-value-bind (dummies vals newval setter getter)
167 (lisp::foo-get-setf-method list env)
168 (let ((eltsym (gensym))
169 (listsym (gensym)))
170 `(let* ((,eltsym ,elt)
171 ,@(mapcar #'list dummies vals)
172 (,listsym ,getter)
173 (,(car newval) (delete ,eltsym ,listsym ,@keys)))
174 ,setter))))
175
176
177 (defmacro dovector ((elt vector) &rest forms)
178 "Just like dolist, but with one-dimensional arrays."
179 (let ((index (gensym))
180 (length (gensym))
181 (vec (gensym)))
182 `(let ((,vec ,vector))
183 (do ((,index 0 (1+ ,index))
184 (,length (length ,vec)))
185 ((>= ,index ,length) nil)
186 (let ((,elt (aref ,vec ,index)))
187 ,@forms)))))
188
189
190 (eval-when (compile load eval)
191 (defun concat-pnames (name1 name2)
192 (if name1
193 (intern (concatenate 'simple-string (symbol-name name1)
194 (symbol-name name2)))
195 name2)))
196
197
198 ;;; Iterate -- Public
199 ;;;
200 ;;; The ultimate iteration macro...
201 ;;;
202 (defmacro iterate (name binds &body body)
203 "Iterate Name ({(Var Initial-Value)}*) Declaration* Form*
204 This is syntactic sugar for Labels. It creates a local function Name with
205 the specified Vars as its arguments and the Declarations and Forms as its
206 body. This function is then called with the Initial-Values, and the result
207 of the call is return from the macro."
208 (dolist (x binds)
209 (unless (and (listp x)
210 (= (length x) 2))
211 (error "Malformed iterate variable spec: ~S." x)))
212
213 `(labels ((,name ,(mapcar #'first binds) ,@body))
214 (,name ,@(mapcar #'second binds))))
215
216
217 ;;;; The Collect macro:
218
219 ;;; Collect-Normal-Expander -- Internal
220 ;;;
221 ;;; This function does the real work of macroexpansion for normal collection
222 ;;; macros. N-Value is the name of the variable which holds the current
223 ;;; value. Fun is the function which does collection. Forms is the list of
224 ;;; forms whose values we are supposed to collect.
225 ;;;
226 (defun collect-normal-expander (n-value fun forms)
227 `(progn
228 ,@(mapcar #'(lambda (form) `(setq ,n-value (,fun ,form ,n-value))) forms)
229 ,n-value))
230
231 ;;; Collect-List-Expander -- Internal
232 ;;;
233 ;;; This function deals with the list collection case. N-Tail is the pointer
234 ;;; to the current tail of the list, which is NIL if the list is empty.
235 ;;;
236 (defun collect-list-expander (n-value n-tail forms)
237 (let ((n-res (gensym)))
238 `(progn
239 ,@(mapcar #'(lambda (form)
240 `(let ((,n-res (cons ,form nil)))
241 (cond (,n-tail
242 (setf (cdr ,n-tail) ,n-res)
243 (setq ,n-tail ,n-res))
244 (t
245 (setq ,n-tail ,n-res ,n-value ,n-res)))))
246 forms)
247 ,n-value)))
248
249
250 ;;; Collect -- Public
251 ;;;
252 ;;; The ultimate collection macro...
253 ;;;
254 (defmacro collect (collections &body body)
255 "Collect ({(Name [Initial-Value] [Function])}*) {Form}*
256 Collect some values somehow. Each of the collections specifies a bunch of
257 things which collected during the evaluation of the body of the form. The
258 name of the collection is used to define a local macro, a la MACROLET.
259 Within the body, this macro will evaluate each of its arguments and collect
260 the result, returning the current value after the collection is done. The
261 body is evaluated as a PROGN; to get the final values when you are done, just
262 call the collection macro with no arguments.
263
264 Initial-Value is the value that the collection starts out with, which
265 defaults to NIL. Function is the function which does the collection. It is
266 a function which will accept two arguments: the value to be collected and the
267 current collection. The result of the function is made the new value for the
268 collection. As a totally magical special-case, the Function may be Collect,
269 which tells us to build a list in forward order; this is the default. If an
270 Initial-Value is supplied for Collect, the stuff will be rplacd'd onto the
271 end. Note that Function may be anything that can appear in the functional
272 position, including macros and lambdas."
273
274 (let ((macros ())
275 (binds ()))
276 (dolist (spec collections)
277 (unless (<= 1 (length spec) 3)
278 (error "Malformed collection specifier: ~S." spec))
279 (let ((n-value (gensym))
280 (name (first spec))
281 (default (second spec))
282 (kind (or (third spec) 'collect)))
283 (push `(,n-value ,default) binds)
284 (if (eq kind 'collect)
285 (let ((n-tail (gensym)))
286 (if default
287 (push `(,n-tail (last ,n-value)) binds)
288 (push n-tail binds))
289 (push `(,name (&rest args)
290 (collect-list-expander ',n-value ',n-tail args))
291 macros))
292 (push `(,name (&rest args)
293 (collect-normal-expander ',n-value ',kind args))
294 macros))))
295 `(macrolet ,macros (let* ,(nreverse binds) ,@body))))
296
297
298 ;;;; The Once-Only macro:
299
300 ;;; Once-Only -- Interface
301 ;;;
302 ;;; Once-Only is a utility useful in writing source transforms and macros.
303 ;;; It provides an easy way to wrap a let around some code to ensure that some
304 ;;; forms are only evaluated once.
305 ;;;
306 (defmacro once-only (specs &body body)
307 "Once-Only ({(Var Value-Expression)}*) Form*
308 Create a Let* which evaluates each Value-Expression, binding a temporary
309 variable to the result, and wrapping the Let* around the result of the
310 evaluation of Body. Within the body, each Var is bound to the corresponding
311 temporary variable."
312 (collect ((gensym-binds)
313 (temp-binds))
314 (dolist (spec specs)
315 (when (/= (length spec) 2)
316 (error "Malformed Once-Only binding spec: ~S." spec))
317 (let ((name (first spec))
318 (exp (second spec)))
319 (gensym-binds `(,name (gensym "OO-")))
320 (temp-binds ``(,,name ,,exp))))
321 `(let ,(gensym-binds)
322 (list 'let* (list ,@(temp-binds)) (progn ,@body)))))
323
324
325 ;;;; DO-ANONYMOUS:
326
327 ;;; ### Bootstrap hack... Renamed to avoid clobbering function in bootstrap
328 ;;; environment.
329 ;;;
330 (defun lisp::do-do-body (varlist endlist code decl bind step name block)
331 (let* ((inits ())
332 (steps ())
333 (l1 (gensym))
334 (l2 (gensym)))
335 ;; Check for illegal old-style do.
336 (when (or (not (listp varlist)) (atom endlist))
337 (error "Ill-formed ~S -- possibly illegal old style DO?" name))
338 ;; Parse the varlist to get inits and steps.
339 (dolist (v varlist)
340 (cond ((symbolp v) (push v inits))
341 ((listp v)
342 (unless (symbolp (first v))
343 (error "~S step variable is not a symbol: ~S" name (first v)))
344 (case (length v)
345 (1 (push (first v) inits))
346 (2 (push v inits))
347 (3 (push (list (first v) (second v)) inits)
348 (setq steps (list* (third v) (first v) steps)))
349 (t (error "~S is an illegal form for a ~S varlist." v name))))
350 (t (error "~S is an illegal form for a ~S varlist." v name))))
351 ;; And finally construct the new form.
352 `(block ,BLOCK
353 (,bind ,(nreverse inits)
354 ,@decl
355 (tagbody
356 (go ,L2)
357 ,L1
358 ,@code
359 (,step ,@(nreverse steps))
360 ,L2
361 (unless ,(car endlist) (go ,L1))
362 (return-from ,BLOCK (progn ,@(cdr endlist))))))))
363
364
365 (defmacro do-anonymous (varlist endlist &body (body decls))
366 "DO-ANONYMOUS ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
367 Like DO, but has no implicit NIL block. Each Var is initialized in parallel
368 to the value of the specified Init form. On subsequent iterations, the Vars
369 are assigned the value of the Step form (if any) in paralell. The Test is
370 evaluated before each evaluation of the body Forms. When the Test is true,
371 the the Exit-Forms are evaluated as a PROGN, with the result being the value
372 of the DO."
373 (lisp::do-do-body varlist endlist body decls 'let 'psetq
374 'do-anonymous (gensym)))
375
376
377 ;;;; Hash cache utility:
378
379 ;;; DEFINE-HASH-CACHE -- Public
380 ;;;
381 (defmacro define-hash-cache (name args &key hash-function hash-bits default
382 (values 1))
383 "DEFINE-HASH-CACHE Name ({(Arg-Name Test-Function)}*) {Key Value}*
384 Define a hash cache that associates some number of argument values to a
385 result value. The Test-Function paired with each Arg-Name is used to compare
386 the value for that arg in a cache entry with a supplied arg. The
387 Test-Function must not error when passed NIL as its first arg, but need not
388 return any particular value. Test-Function may be any thing that can be
389 place in CAR position.
390
391 Name is used to define functions these functions:
392
393 <name>-CACHE-LOOKUP Arg*
394 See if there is an entry for the specified Args in the cache. The if not
395 present, the :DEFAULT keyword (default NIL) determines the result(s).
396
397 <name>-CACHE-ENTER Arg* Value*
398 Encache the association of the specified args with Value.
399
400 <name>-CACHE-FLUSH-<arg-name> Arg
401 Flush all entries from the cache that have the value Arg for the named
402 arg.
403
404 <name>-CACHE-CLEAR
405 Reinitialize the cache, invalidating all entries and allowing the
406 arguments and result values to be GC'd.
407
408 These other keywords are defined:
409
410 :HASH-BITS <n>
411 The size of the cache as a power of 2.
412
413 :HASH-FUNCTION function
414 Some thing that can be placed in CAR position which will compute a value
415 between 0 and (1- (expt 2 <hash-bits>)).
416
417 :VALUES <n>
418 The number of values cached."
419
420 (let* ((var-name (symbolicate "*" name "-CACHE-VECTOR*"))
421 (nargs (length args))
422 (entry-size (+ nargs values))
423 (size (ash 1 hash-bits))
424 (total-size (* entry-size size))
425 (default-values (if (and (consp default) (eq (car default) 'values))
426 (cdr default)
427 (list default)))
428 (n-index (gensym))
429 (n-cache (gensym)))
430
431 (unless (= (length default-values) values)
432 (error "Number of default values ~S differs from :VALUES ~D."
433 default values))
434
435 (collect ((inlines)
436 (forms)
437 (tests)
438 (sets)
439 (arg-vars)
440 (values-indices)
441 (values-names))
442 (dotimes (i values)
443 (values-indices `(+ ,n-index ,(+ nargs i)))
444 (values-names (gensym)))
445
446 (let ((n 0))
447 (dolist (arg args)
448 (unless (= (length arg) 2)
449 (error "Bad arg spec: ~S." arg))
450 (let ((arg-name (first arg))
451 (test (second arg)))
452 (arg-vars arg-name)
453 (tests `(,test (svref ,n-cache (+ ,n-index ,n)) ,arg-name))
454 (sets `(setf (svref ,n-cache (+ ,n-index ,n)) ,arg-name))
455
456 (let ((fun-name (symbolicate name "-CACHE-FLUSH-" arg-name)))
457 (forms
458 `(defun ,fun-name (,arg-name)
459 (do ((,n-index ,(+ (- total-size entry-size) n)
460 (- ,n-index ,entry-size))
461 (,n-cache ,var-name))
462 ((minusp ,n-index))
463 (declare (type fixnum ,n-index))
464 (when (,test (svref ,n-cache ,n-index) ,arg-name)
465 (let ((,n-index (- ,n-index ,n)))
466 ,@(mapcar #'(lambda (i val)
467 `(setf (svref ,n-cache ,i) ,val))
468 (values-indices)
469 default-values))))
470 (undefined-value)))))
471 (incf n)))
472
473 (let ((fun-name (symbolicate name "-CACHE-LOOKUP")))
474 (inlines fun-name)
475 (forms
476 `(defun ,fun-name ,(arg-vars)
477 (let ((,n-index (* (,hash-function ,@(arg-vars)) ,entry-size))
478 (,n-cache ,var-name))
479 (declare (type fixnum ,n-index))
480 (if (and ,@(tests))
481 (values ,@(mapcar #'(lambda (x) `(svref ,n-cache ,x))
482 (values-indices)))
483 ,default)))))
484
485 (let ((fun-name (symbolicate name "-CACHE-ENTER")))
486 (inlines fun-name)
487 (forms
488 `(defun ,fun-name (,@(arg-vars) ,@(values-names))
489 (let ((,n-index (* (,hash-function ,@(arg-vars)) ,entry-size))
490 (,n-cache ,var-name))
491 (declare (type fixnum ,n-index))
492 ,@(sets)
493 ,@(mapcar #'(lambda (i val)
494 `(setf (svref ,n-cache ,i) ,val))
495 (values-indices)
496 (values-names))
497 (undefined-value)))))
498
499 (let ((fun-name (symbolicate name "-CACHE-CLEAR")))
500 (forms
501 `(defun ,fun-name ()
502 (do ((,n-index ,(- total-size entry-size) (- ,n-index ,entry-size))
503 (,n-cache ,var-name))
504 ((minusp ,n-index))
505 (declare (type fixnum ,n-index))
506 ,@(collect ((arg-sets))
507 (dotimes (i nargs)
508 (arg-sets `(setf (svref ,n-cache (+ ,n-index ,i)) nil)))
509 (arg-sets))
510 ,@(mapcar #'(lambda (i val)
511 `(setf (svref ,n-cache ,i) ,val))
512 (values-indices)
513 default-values))
514 (undefined-value)))
515 (forms `(,fun-name)))
516
517 `(progn
518 (defvar ,var-name (make-array ,total-size))
519 (proclaim '(type (simple-vector ,total-size) ,var-name))
520 (proclaim '(inline ,@(inlines)))
521 ,@(forms)
522 ',name))))
523
524
525 ;;; DEFUN-CACHED -- Public
526 ;;;
527 (defmacro defun-cached ((name &rest options &key (values 1) default
528 &allow-other-keys)
529 args &body (body decls doc))
530 "DEFUN-CACHED (Name {Key Value}*) ({(Arg-Name Test-Function)}*) Form*
531 Some syntactic sugar for defining a function whose values are cached by
532 DEFINE-HASH-CACHE."
533 (let ((default-values (if (and (consp default) (eq (car default) 'values))
534 (cdr default)
535 (list default)))
536 (arg-names (mapcar #'car args)))
537 (collect ((values-names))
538 (dotimes (i values)
539 (values-names (gensym)))
540 `(progn
541 (define-hash-cache ,name ,args ,@options)
542 (defun ,name ,arg-names
543 ,@decls
544 ,doc
545 (multiple-value-bind
546 ,(values-names)
547 (,(symbolicate name "-CACHE-LOOKUP") ,@arg-names)
548 (if (and ,@(mapcar #'(lambda (val def)
549 `(eq ,val ,def))
550 (values-names) default-values))
551 (multiple-value-bind ,(values-names)
552 (progn ,@body)
553 (,(symbolicate name "-CACHE-ENTER") ,@arg-names
554 ,@(values-names))
555 (values ,@(values-names)))
556 (values ,@(values-names)))))))))
557
558
559 ;;; CACHE-HASH-EQ -- Public
560 ;;;
561 (proclaim '(inline cache-hash-eq))
562 (defun cache-hash-eq (x)
563 "Return an EQ hash of X. The value of this hash for any given object can (of
564 course) change at arbitary times."
565 (the fixnum (ash (truly-the fixnum (%primitive lisp::make-fixnum x)) -3)))
566

  ViewVC Help
Powered by ViewVC 1.1.5