/[climacs]/climacs/climacs-lisp-syntax.lisp
ViewVC logotype

Contents of /climacs/climacs-lisp-syntax.lisp

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations)
Tue Dec 11 18:46:53 2007 UTC (6 years, 4 months ago) by thenriksen
Branch: MAIN
Changes since 1.6: +1 -1 lines
I broke the Swank-using code, now unbroke it.
1 ;;; -*- Mode: Lisp; Package: DREI-LISP-SYNTAX -*-
2
3 ;;; (c) copyright 2005 by
4 ;;; Robert Strandh (strandh@labri.fr)
5 ;;; (c) copyright 2006 by
6 ;;; Troels Henriksen (athas@sigkill.dk)
7 ;;;
8 ;;; This library is free software; you can redistribute it and/or
9 ;;; modify it under the terms of the GNU Library General Public
10 ;;; License as published by the Free Software Foundation; either
11 ;;; version 2 of the License, or (at your option) any later version.
12 ;;;
13 ;;; This library is distributed in the hope that it will be useful,
14 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
16 ;;; Library General Public License for more details.
17 ;;;
18 ;;; You should have received a copy of the GNU Library General Public
19 ;;; License along with this library; if not, write to the
20 ;;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
21 ;;; Boston, MA 02111-1307 USA.
22
23 ;;; Add Climacs-dependent functionality to the stock Lisp syntax.
24
25 (in-package :drei-lisp-syntax)
26
27 (defmethod frame-clear-completions ((frame climacs-gui:climacs))
28 (let ((completions-pane
29 (when (typep *application-frame* 'esa-frame-mixin)
30 (find "Completions" (windows *application-frame*)
31 :key #'pane-name
32 :test #'string=))))
33 (unless (null completions-pane)
34 (climacs-gui:delete-window completions-pane)
35 (setf completions-pane nil))))
36
37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
38 ;;;
39 ;;; Compiler note hyperlinking
40
41 (defclass location ()()
42 (:documentation "The base for all locations."))
43
44 (defclass error-location (location)
45 ((error-message :initarg :error-message :accessor error-message)))
46
47 (defclass actual-location (location)
48 ((source-position :initarg :position :accessor source-position)
49 (snippet :initarg :snippet :accessor snippet :initform nil))
50 (:documentation "The base for all non-error locations."))
51
52 (defclass view-location (actual-location)
53 ((view-name :initarg :view :accessor view-name)))
54
55 (defclass file-location (actual-location)
56 ((file-name :initarg :file :accessor file-name)))
57
58 (defclass source-location (actual-location)
59 ((source-form :initarg :source-form :accessor source-form)))
60
61 (defclass basic-position () ()
62 (:documentation "The base for all positions."))
63
64 (defclass char-position (basic-position)
65 ((char-position :initarg :position :accessor char-position)
66 (align-p :initarg :align-p :initform nil :accessor align-p)))
67
68 (defun make-char-position (position-list)
69 (make-instance 'char-position :position (second position-list)
70 :align-p (third position-list)))
71
72 (defclass line-position (basic-position)
73 ((start-line :initarg :line :accessor start-line)
74 (end-line :initarg :end-line :initform nil :accessor end-line)))
75
76 (defun make-line-position (position-list)
77 (make-instance 'line-position :line (second position-list)
78 :end-line (third position-list)))
79
80 (defclass function-name-position (basic-position)
81 ((function-name :initarg :function-name)))
82
83 (defun make-function-name-position (position-list)
84 (make-instance 'function-name-position :function-name (second position-list)))
85
86 (defclass source-path-position (basic-position)
87 ((path :initarg :source-path :accessor path)
88 (start-position :initarg :start-position :accessor start-position)))
89
90 (defun make-source-path-position (position-list)
91 (make-instance 'source-path-position :source-path (second position-list)
92 :start-position (third position-list)))
93
94 (defclass text-anchored-position (basic-position)
95 ((start :initarg :text-anchored :accessor start)
96 (text :initarg :text :accessor text)
97 (delta :initarg :delta :accessor delta)))
98
99 (defun make-text-anchored-position (position-list)
100 (make-instance 'text-anchored-position :text-anchored (second position-list)
101 :text (third position-list)
102 :delta (fourth position-list)))
103
104 (defclass method-position (basic-position)
105 ((name :initarg :method :accessor name)
106 (specializers :initarg :specializers :accessor specializers)
107 (qualifiers :initarg :qualifiers :accessor qualifiers)))
108
109 (defun make-method-position (position-list)
110 (make-instance 'method-position :method (second position-list)
111 :specializers (third position-list)
112 :qualifiers (last position-list)))
113
114 (defun make-location (location-list)
115 (ecase (first location-list)
116 (:error (make-instance 'error-location :error-message (second location-list)))
117 (:location
118 (destructuring-bind (l buf pos hints) location-list
119 (declare (ignore l))
120 (let ((location
121 (apply #'make-instance
122 (ecase (first buf)
123 (:file 'file-location)
124 (:buffer 'view-location)
125 (:source-form 'source-location))
126 buf))
127 (position
128 (funcall
129 (ecase (first pos)
130 (:position #'make-char-position)
131 (:line #'make-line-position)
132 (:function-name #'make-function-name-position)
133 (:source-path #'make-source-path-position)
134 (:text-anchored #'make-text-anchored-position)
135 (:method #'make-method-position))
136 pos)))
137 (setf (source-position location) position)
138 (when hints
139 (setf (snippet location) (rest hints)))
140 location)))))
141
142 (defmethod initialize-instance :after ((note compiler-note) &rest args)
143 (declare (ignore args))
144 (setf (location note) (make-location (location note))))
145
146 (defun show-note-counts (notes &optional seconds)
147 (loop with nerrors = 0
148 with nwarnings = 0
149 with nstyle-warnings = 0
150 with nnotes = 0
151 for note in notes
152 do (etypecase note
153 (error-compiler-note (incf nerrors))
154 (read-error-compiler-note (incf nerrors))
155 (warning-compiler-note (incf nwarnings))
156 (style-warning-compiler-note (incf nstyle-warnings))
157 (note-compiler-note (incf nnotes)))
158 finally
159 (esa:display-message "Compilation finished: ~D error~:P ~
160 ~D warning~:P ~D style-warning~:P ~D note~:P ~
161 ~@[[~D secs]~]"
162 nerrors nwarnings nstyle-warnings nnotes seconds)))
163
164 (defun one-line-ify (string)
165 "Return a single-line version of STRING.
166 Each newline and following whitespace is replaced by a single space."
167 (loop with count = 0
168 while (< count (length string))
169 with new-string = (make-array 0 :element-type 'character :adjustable t
170 :fill-pointer 0)
171 when (char= (char string count) #\Newline)
172 do (loop while (and (< count (length string))
173 (whitespacep (current-syntax) (char string count)))
174 do (incf count)
175 ;; Just ignore whitespace if it is last in the
176 ;; string.
177 finally (when (< count (length string))
178 (vector-push-extend #\Space new-string)))
179 else
180 do (vector-push-extend (char string count) new-string)
181 (incf count)
182 finally (return new-string)))
183
184 (defgeneric print-for-menu (object stream))
185
186 (defun print-note-for-menu (note stream severity ink)
187 (with-accessors ((message message) (short-message short-message)) note
188 (with-drawing-options (stream :ink ink
189 :text-style (make-text-style :sans-serif :italic nil))
190 (princ severity stream)
191 (princ " " stream))
192 (princ (if short-message
193 (one-line-ify short-message)
194 (one-line-ify message))
195 stream)))
196
197 (defmacro def-print-for-menu (class name colour)
198 `(defmethod print-for-menu ((object ,class) stream)
199 (print-note-for-menu object stream ,name ,colour)))
200
201 (def-print-for-menu error-compiler-note "Error" +red+)
202 (def-print-for-menu read-error-compiler-note "Read Error" +red+)
203 (def-print-for-menu warning-compiler-note "Warning" +dark-red+)
204 (def-print-for-menu style-warning-compiler-note "Style Warning" +brown+)
205 (def-print-for-menu note-compiler-note "Note" +brown+)
206
207 (defun show-notes (notes view-name definition)
208 (let ((stream (climacs-gui:typeout-window
209 (format nil "~10TCompiler Notes: ~A ~A" view-name definition))))
210 (loop for note in notes
211 do (with-output-as-presentation (stream note 'compiler-note)
212 (print-for-menu note stream))
213 (terpri stream)
214 count note into length
215 finally (change-space-requirements stream
216 :height (* length (stream-line-height stream)))
217 (scroll-extent stream 0 0))))
218
219 (defgeneric goto-location (location))
220
221 (defmethod goto-location ((location error-location))
222 (esa:display-message (error-message location)))
223
224 (defmethod goto-location ((location view-location))
225 (let ((view (find (view-name location)
226 (climacs-gui:views *esa-instance*)
227 :test #'string= :key #'name)))
228 (unless view
229 (esa:display-message "No view ~A" (view-name location))
230 (beep)
231 (return-from goto-location))
232 (climacs-core:switch-to-view (current-window) view)
233 (goto-position (point)
234 (char-position (source-position location)))))
235
236 (defmethod goto-location ((location file-location))
237 (let ((view (find (file-name location)
238 (views *application-frame*)
239 :test #'string= :key #'(lambda (view)
240 (let ((path (filepath view)))
241 (when path
242 (namestring path)))))))
243 (if view
244 (climacs-core:switch-to-view (current-window) view)
245 (find-file (file-name location)))
246 (goto-position (point (current-window))
247 (char-position (source-position location)))))
248
249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
250 ;;;
251 ;;; Macroexpansion and evaluation
252
253 (defun macroexpand-token (syntax token &optional (all nil))
254 (with-syntax-package (syntax (start-offset token))
255 (let* ((string (form-string syntax token))
256 (expression (read-from-string string))
257 (expansion (macroexpand-for-drei (get-usable-image syntax)
258 expression
259 all))
260 (expansion-string (with-output-to-string (s)
261 (pprint expansion s))))
262 (let ((view (climacs-core:switch-to-view (current-window) "*Macroexpansion*")))
263 (set-syntax view "Lisp"))
264 (let ((header-string (one-line-ify (subseq string 0
265 (min 40 (length string))))))
266 (end-of-buffer (point))
267 (unless (beginning-of-buffer-p (point))
268 (insert-object (point) #\Newline))
269 (insert-sequence (point)
270 (format nil ";;; Macroexpand-~:[1~;all~] ~A...~%"
271 all header-string))
272 (insert-sequence (point) expansion-string)
273 (insert-object (point) #\Newline)))))
274
275 (defun compile-definition-interactively (view mark)
276 (let* ((syntax (syntax view))
277 (token (definition-at-mark syntax mark))
278 (string (form-string syntax token))
279 (m (clone-mark mark))
280 (*read-base* (base syntax)))
281 (with-syntax-package (syntax mark)
282 (forward-definition m syntax 1 nil)
283 (if (backward-definition m syntax 1 nil)
284 (multiple-value-bind (result notes)
285 (compile-form-for-drei (get-usable-image syntax)
286 (form-to-object syntax token
287 :read t
288 :package (package-at-mark syntax mark))
289 view m)
290 (show-note-counts notes (second result))
291 (when (not (null notes))
292 (show-notes notes (name view)
293 (one-line-ify (subseq string 0 (min (length string) 20))))))
294 (display-message "No definition at point")))))
295
296 (defun compile-file-interactively (view &optional load-p)
297 (let ((buffer (buffer view)))
298 (cond ((null (filepath buffer))
299 (esa:display-message "View ~A is not associated with a file" (name view)))
300 (t
301 (when (and (needs-saving buffer)
302 (accept 'boolean :prompt (format nil "Save buffer ~A ?" (name view))))
303 (climacs-core:save-buffer buffer))
304 (let ((*read-base* (base (syntax view))))
305 (multiple-value-bind (result notes)
306 (compile-file-for-drei (get-usable-image (syntax view))
307 (filepath buffer)
308 (package-at-mark (syntax view) 0) load-p)
309 (show-note-counts notes (second result))
310 (when notes (show-notes notes (name view) ""))))))))
311
312 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
313 ;;;
314 ;;; Definition editing
315
316 (defparameter *find-definition-stack* '())
317
318 (defun pop-find-definition-stack ()
319 (unless (null *find-definition-stack*)
320 (let* ((offset+view (pop *find-definition-stack*))
321 (offset (first offset+view))
322 (view (second offset+view)))
323 (if (find view (views *esa-instance*))
324 (progn (climacs-core:switch-to-view (current-window) view)
325 (goto-position (point) offset))
326 (pop-find-definition-stack)))))
327
328 ;; KLUDGE: We need to put more info in the definition objects to begin
329 ;; with.
330 (defun definition-type (definition)
331 (let ((data (read-from-string (first definition))))
332 (case (first data)
333 ((cl:defclass)
334 'cl:class)
335 ((cl:defgeneric
336 cl:defmethod
337 cl:defun
338 cl:defmacro)
339 'cl:function)
340 (t t))))
341
342 (defun edit-definition (symbol &optional type)
343 (let ((all-definitions (find-definitions-for-drei
344 (get-usable-image (current-syntax))
345 symbol)))
346 (let ((definitions (if (not type)
347 all-definitions
348 (remove-if-not #'(lambda (definition)
349 (eq (definition-type definition) type))
350 all-definitions))))
351 (cond ((null definitions)
352 (esa:display-message "No known definitions for: ~A" symbol)
353 (beep))
354 (t
355 (goto-definition symbol definitions))))))
356
357 (defun goto-definition (name definitions)
358 (push (list (offset (point)) (current-view)) *find-definition-stack*)
359 (cond ((null (cdr definitions))
360 (let* ((def (car definitions))
361 (xref (make-xref def)))
362 (goto-location xref)))
363 (t
364 (let ((xref (show-definitions name definitions)))
365 (when xref (goto-location xref))))))
366
367 (defclass xref ()
368 ((dspec :initarg :dspec :accessor dspec)
369 (location :initarg :location :accessor location)))
370
371 (defun make-xref (xref-list)
372 (destructuring-bind (dspec location) xref-list
373 (make-instance 'xref
374 :dspec dspec
375 :location (make-location location))))
376
377 (defmethod goto-location ((xref xref))
378 (goto-location (location xref)))
379
380 (defun show-definitions (name definitions)
381 (show-xrefs (loop for xref-list in definitions
382 collect (make-xref xref-list))
383 'definition name))
384
385 (defun show-xrefs (xrefs type symbol)
386 (cond ((null xrefs)
387 (esa:display-message "No references found for ~A." symbol)
388 (beep))
389 (t
390 (flet ((printer (item stream)
391 (with-drawing-options (stream :ink +dark-blue+
392 :text-style (make-text-style :fixed nil nil))
393 (princ (dspec item) stream))))
394 (let ((stream (climacs-gui:typeout-window
395 (format nil "~10T~A ~A" type symbol))))
396 (loop for xref in xrefs
397 do (with-output-as-presentation (stream xref 'xref)
398 (printer xref stream))
399 (terpri stream)
400 count xref into length
401 finally (change-space-requirements stream
402 :height (* length (stream-line-height stream)))
403 (scroll-extent stream 0 0)))))))
404
405 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
406 ;;;
407 ;;; Some group support
408
409 ;; WARNING, using this group can be dangerous, as Climacs is not
410 ;; really suited to opening up a large amount of buffers that each
411 ;; require a full syntax reparse.
412 (climacs-core:define-group "ASDF System Files" (group (system (asdf:find-system (accept 'symbol :prompt "System"))))
413 (declare (ignore group))
414 (when system
415 (mapcar #'asdf:component-pathname
416 (remove-if-not (lambda (c)
417 (typep c 'asdf:cl-source-file))
418 (asdf:module-components system)))))

  ViewVC Help
Powered by ViewVC 1.1.5