;;; -*- Log: code.log; Package: Lisp -*-
;;;
;;; **********************************************************************

;;; This code was written as part of the CMU Common Lisp project at
;;; Carnegie Mellon University, and has been placed in the public domain.
;;;
(ext:file-comment

  "$Header: src/code/macros.lisp $")

;;;

;;; **********************************************************************
;;;
;;; This file contains the macros that are part of the standard
;;; Spice Lisp environment.
;;;
;;; Written by Scott Fahlman and Rob MacLachlan.

;;; Modified by Bill Chiles to adhere to the wall.

;;;

(in-package "LISP")

(intl:textdomain "cmucl")

(export '(defvar defparameter defconstant when unless setf

	  defsetf psetf shiftf rotatef push pushnew pop

	  incf decf remf case typecase with-open-file
	  with-open-stream with-input-from-string with-output-to-string
	  locally etypecase ctypecase ecase ccase

	  get-setf-expansion define-setf-expander

          define-modify-macro destructuring-bind nth-value

          otherwise ; Sacred to CASE and related macros.

	  define-compiler-macro))

(in-package "EXTENSIONS")
(export '(do-anonymous collect iterate))

(in-package "LISP")


;;; Parse-Body  --  Public
;;;
;;;    Parse out declarations and doc strings, *not* expanding macros.
;;; Eventually the environment arg should be flushed, since macros can't expand
;;; into declarations anymore.
;;;
(defun parse-body (body environment &optional (doc-string-allowed t))

  "This function is to parse the declarations and doc-string out of the body of

  a defun-like form.  Body is the list of stuff which is to be parsed.
  Environment is ignored.  If Doc-String-Allowed is true, then a doc string
  will be parsed out of the body and returned.  If it is false then a string
  will terminate the search for declarations.  Three values are returned: the
  tail of Body after the declarations and doc strings, a list of declare forms,
  and the doc-string, or NIL if none."
  (declare (ignore environment))
  (let ((decls ())
	(doc nil))
    (do ((tail body (cdr tail)))
	((endp tail)
	 (values tail (nreverse decls) doc))
      (let ((form (car tail)))
	(cond ((and (stringp form) (cdr tail))
	       (if doc-string-allowed

		   (setq doc form
			 ;; Only one doc string is allowed.
			 doc-string-allowed nil)

		   (return (values tail (nreverse decls) doc))))
	      ((not (and (consp form) (symbolp (car form))))
	       (return (values tail (nreverse decls) doc)))
	      ((eq (car form) 'declare)
	       (push form decls))
	      (t
	       (return (values tail (nreverse decls) doc))))))))


;;;; DEFMACRO:

;;; Defmacro  --  Public
;;;
;;;    Parse the definition and make an expander function.  The actual
;;; definition is done by %defmacro which we expand into.
;;;
(defmacro defmacro (name lambda-list &body body)

  (when lisp::*enable-package-locked-errors*

    (multiple-value-bind (valid block-name)
        (ext:valid-function-name-p name)
      (declare (ignore valid))
      (let ((package (symbol-package block-name)))
        (when package
          (when (ext:package-definition-lock package)
            (restart-case

                (error 'lisp::package-locked-error

                       :package package

                       :format-control (intl:gettext "defining macro ~A")

                       :format-arguments (list name))
              (continue ()

                :report (lambda (stream)

			  (write-string (intl:gettext "Ignore the lock and continue") stream)))

              (unlock-package ()

                :report (lambda (stream)

			  (write-string (intl:gettext "Disable the package's definition-lock then continue") stream))

                (setf (ext:package-definition-lock package) nil))
              (unlock-all ()

                :report (lambda (stream)

			  (write-string (intl:gettext "Unlock all packages, then continue") stream))

                (lisp::unlock-all-packages))))))))

  (let ((whole (gensym "WHOLE-"))
	(environment (gensym "ENV-")))

    (multiple-value-bind
	(body local-decs doc)

	(parse-defmacro lambda-list whole body name 'defmacro
			:environment environment)

      (when doc
	(intl::note-translatable intl::*default-domain* doc))

      (let ((def `(lambda (,whole ,environment)
		    ,@local-decs
		    (block ,name
		      ,body))))

	`(progn
	   (eval-when (:compile-toplevel)
	     (c::do-macro-compile-time ',name #',def))
	   (eval-when (:load-toplevel :execute)
	     (c::%defmacro ',name #',def ',lambda-list ,doc)))))))

;;; %Defmacro, %%Defmacro  --  Internal
;;;
;;;    Defmacro expands into %Defmacro which is a function that is treated
;;; magically the compiler.  After the compiler has gotten the information it
;;; wants out of macro definition, it compiles a call to %%Defmacro which
;;; happens at load time.  We have a %Defmacro function which just calls
;;; %%Defmacro in order to keep the interpreter happy.
;;;
;;;    Eventually %%Defmacro should deal with clearing old compiler information
;;; for the functional value.
;;;
(defun c::%defmacro (name definition lambda-list doc)

  (assert (eval:interpreted-function-p definition))

  (setf (eval:interpreted-function-name definition) name)

  (setf (eval:interpreted-function-arglist definition) lambda-list)

  (c::%%defmacro name definition doc))
;;;
(defun c::%%defmacro (name definition doc)
  (clear-info function where-from name)

  (setf (macro-function name) definition)

  (setf (documentation name 'function) doc)
  name)


;;;; DEFINE-COMPILER-MACRO

(defmacro define-compiler-macro (name lambda-list &body body)

  "Define a compiler-macro for NAME."

  (let ((whole (gensym "WHOLE-"))
	(environment (gensym "ENV-")))

    (multiple-value-bind (validp block-name)
	(valid-function-name-p name)
      (unless validp
	(simple-program-error (intl:gettext "~S is not a valid function name.") name))
      (multiple-value-bind
	    (body local-decs doc)
	  (parse-defmacro lambda-list whole body name 'define-compiler-macro
			  :environment environment)
	(when doc
	  (intl::note-translatable intl::*default-domain* doc))
	(let ((def `(lambda (,whole ,environment)
		      ,@local-decs
		      (block ,block-name
			,body))))
	  `(progn
	     (eval-when (:compile-toplevel)
	       (c::do-compiler-macro-compile-time ',name #',def))
	     (eval-when (:load-toplevel :execute)
	       (c::%define-compiler-macro ',name #',def ',lambda-list ,doc))))))))

(defun c::%define-compiler-macro (name definition lambda-list doc)
  (assert (eval:interpreted-function-p definition))
  (setf (eval:interpreted-function-name definition)
	(let ((*print-case* :upcase))
	  (format nil "DEFINE-COMPILER-MACRO ~S" name)))
  (setf (eval:interpreted-function-arglist definition) lambda-list)
  (c::%%define-compiler-macro name definition doc))
;;;
(defun c::%%define-compiler-macro (name definition doc)
  (setf (compiler-macro-function name) definition)
  (setf (documentation name 'compiler-macro) doc)
  name)


;;;; DEFINE-SYMBOL-MACRO

;;; define-symbol-macro  --  Public
;;;
(defmacro define-symbol-macro (name expansion)

  `(eval-when (:compile-toplevel :load-toplevel :execute)

     (%define-symbol-macro ',name ',expansion (c::source-location))))

;;;

(defun %define-symbol-macro (name expansion source-location)

  (unless (symbolp name)
    (error 'simple-type-error :datum name :expected-type 'symbol

	   :format-control (intl:gettext "Symbol macro name is not a symbol: ~S.")

	   :format-arguments (list name)))
  (ecase (info variable kind name)
    ((:macro :global nil)
     (setf (info variable kind name) :macro)

     (setf (info variable macro-expansion name) expansion)
     (set-defvar-source-location name source-location))

    (:special
     (error 'simple-program-error

	    :format-control (intl:gettext "Symbol macro name already declared special: ~S.")

	    :format-arguments (list name)))
    (:constant
     (error 'simple-program-error

	    :format-control (intl:gettext "Symbol macro name already declared constant: ~S.")

	    :format-arguments (list name))))
  name)
    


;;; DEFTYPE is a lot like DEFMACRO.

(defmacro deftype (name arglist &body body)

  "Syntax like DEFMACRO, but defines a new type."

  (unless (symbolp name)

    (simple-program-error (intl:gettext "~S -- Type name not a symbol.") name))

  (and lisp::*enable-package-locked-errors*

       (symbol-package name)
       (ext:package-definition-lock (symbol-package name))
       (restart-case

           (error 'lisp::package-locked-error

                  :package (symbol-package name)

                  :format-control (intl:gettext "defining type ~A")

                  :format-arguments (list name))
         (continue ()

           :report (lambda (stream)

		     (write-string (intl:gettext "Ignore the lock and continue") stream)))

         (unlock-package ()

           :report (lambda (stream)

		     (write-string (intl:gettext "Disable package's definition-lock then continue") stream))

           (setf (ext:package-definition-lock (symbol-package name)) nil))
         (unlock-all ()

           :report (lambda (stream)

		     (write-string (intl:gettext "Unlock all packages, then continue") stream))

           (lisp::unlock-all-packages))))

  (let ((whole (gensym "WHOLE-")))

    (multiple-value-bind (body local-decs doc)

			 (parse-defmacro arglist whole body name 'deftype
					 :default-default ''*)

      (when doc
	(intl::note-translatable intl::*default-domain* doc))

      `(eval-when (:compile-toplevel :load-toplevel :execute)

	 (set-defvar-source-location ',name (c::source-location))

	 (%deftype ',name
		   #'(lambda (,whole)
		       ,@local-decs
		       (block ,name ,body))
		   ,@(when doc `(,doc)))))))

;;;
(defun %deftype (name expander &optional doc)

  (when (info declaration recognized name)

    (error (intl:gettext "Deftype already names a declaration: ~S.") name))

  (ecase (info type kind name)
    (:primitive

     (when *type-system-initialized*

       (error (intl:gettext "Illegal to redefine standard type: ~S.") name)))

    (:instance

     (warn (intl:gettext "Redefining class ~S to be a DEFTYPE.") name)

     (undefine-structure (layout-info (%class-layout (kernel::find-class name))))

     (setf (class-cell-class (find-class-cell name)) nil)

     (setf (info type compiler-layout name) nil)
     (setf (info type kind name) :defined))
    (:defined)
    ((nil)
     (setf (info type kind name) :defined)))

  (setf (info type expander name) expander)

  (when doc
    (setf (documentation name 'type) doc))

  ;; ### Bootstrap hack -- we need to define types before %note-type-defined
  ;; is defined.

  (when (fboundp 'c::%note-type-defined)

    (c::%note-type-defined name))

  name)

;;; And so is DEFINE-SETF-EXPANDER.

(defparameter defsetf-error-string "Setf expander for ~S cannot be called with ~S args.")

(defmacro define-setf-expander (access-fn lambda-list &body body)

  "Syntax like DEFMACRO, but creates a Setf-Expansion generator.  The body

  must be a form that returns the five magical values."
  (unless (symbolp access-fn)

    (simple-program-error (intl:gettext "~S -- Access-function name not a symbol in DEFINE-SETF-EXPANDER.")

	   access-fn))

  (let ((whole (gensym "WHOLE-"))
	(environment (gensym "ENV-")))

    (multiple-value-bind (body local-decs doc)
			 (parse-defmacro lambda-list whole body access-fn

					 'define-setf-expander

					 :environment environment)

      (when doc
	(intl::note-translatable intl::*default-domain* doc))

      `(eval-when (:compile-toplevel :load-toplevel :execute)

	 (%define-setf-macro
	  ',access-fn
	  #'(lambda (,whole ,environment)
	      ,@local-decs
	      (block ,access-fn ,body))
	  nil
	  ',doc)))))

(defmacro define-setf-method (&rest stuff)

  "Obsolete, use define-setf-expander."

  `(define-setf-expander ,@stuff))

;;; %DEFINE-SETF-MACRO  --  Internal
;;;
;;;    Do stuff for defining a setf macro.
;;;
(defun %define-setf-macro (name expander inverse doc)
  (cond ((not (fboundp `(setf ,name))))
	((info function accessor-for name)

	 (warn (intl:gettext "Defining setf macro for destruct slot accessor; redefining as ~
	        a normal function:~%  ~S")

	       name)
	 (c::define-function-name name))
	((not (eq (symbol-package name) (symbol-package 'aref)))

	 (warn (intl:gettext "Defining setf macro for ~S, but ~S is fbound.")

	       name `(setf ,name))))
  (when (or inverse (info setf inverse name))
    (setf (info setf inverse name) inverse))
  (when (or expander (info setf expander name))
    (setf (info setf expander name) expander))
  (when doc
    (setf (documentation name 'setf) doc))
  name)
  


;;;; Destructuring-bind

(defmacro destructuring-bind (lambda-list arg-list &rest body)

  "Bind the variables in LAMBDA-LIST to the contents of ARG-LIST."

  (let* ((arg-list-name (gensym "ARG-LIST-")))
    (multiple-value-bind

	(body local-decls)

	(parse-defmacro lambda-list arg-list-name body nil 'destructuring-bind

			:annonymousp t :doc-string-allowed nil)
      `(let ((,arg-list-name ,arg-list))

	 ,@local-decls

	 ,body))))


;;;; Defun, Defvar, Defparameter, Defconstant:

;;; Defun  --  Public
;;;
;;;    Very similar to Defmacro, but simpler.  We don't have to parse the
;;; lambda-list.
;;;

(defmacro defun (&whole source name lambda-list &parse-body (body decls doc))

  (multiple-value-bind (valid block-name)
      (valid-function-name-p name)

    (declare (ignore valid))

    (when doc
      (intl::note-translatable intl::*default-domain* doc))

    (let ((def `(lambda ,lambda-list
		  ,@decls
		  (block ,block-name ,@body))))
      `(c::%defun ',name #',def ,doc ',source))))

;;; %Defun, %%Defun  --  Internal
;;;
;;;    Similar to %Defmacro, ...
;;;
(defun c::%%defun (name def doc &optional inline-expansion)

  (c::define-function-name name)

  (setf (fdefinition name) def)
  (when doc
    (if (and (consp name) (eq (first name) 'setf))
	(setf (documentation (second name) 'setf) doc)
	(setf (documentation name 'function) doc)))

  (when (eq (info function where-from name) :assumed)
    (setf (info function where-from name) :defined)
    (when (info function assumed-type name)
      (setf (info function assumed-type name) nil)))

  (when (or inline-expansion
	    (info function inline-expansion name))
    (setf (info function inline-expansion name) inline-expansion))
  name)

(defun c::%defun (name def doc source)
  (declare (ignore source))

  (assert (eval:interpreted-function-p def))
  (setf (eval:interpreted-function-name def) name)

  (let ((inline-expansion nil))
    (when (memq (info function inlinep name) '(:inline :maybe-inline))
      (multiple-value-bind (lambda-expression closure-p)
	  (function-lambda-expression def)
	(unless closure-p
	  (setq inline-expansion lambda-expression))))
    (c::%%defun name def doc inline-expansion)))

(defun set-defvar-textdomain (name domain)
  (setf (c::info variable textdomain name) domain))

;;; DEFCONSTANT  --  Public
;;;
(defmacro defconstant (var val &optional doc)

  "For defining global constants at top level.  The DEFCONSTANT says that the

  value is constant and may be compiled into code.  If the variable already has
  a value, and this is not equal to the init, an error is signalled.  The third
  argument is an optional documentation string for the variable."

  (when doc
    (intl::note-translatable intl::*default-domain* doc))

  `(progn
     (eval-when (:compile-toplevel)
       (c::do-defconstant-compile-time ',var ,val ',doc))
     (eval-when (:load-toplevel :execute)

       (set-defvar-textdomain ',var ,intl::*default-domain*)

       (c::%%defconstant ',var ,val ',doc (c::source-location)))))

(defun set-defvar-source-location (name source-location)
  (setf (info :source-location :defvar name) source-location))

;;; %Defconstant, %%Defconstant  --  Internal
;;;
;;;    Like the other %mumbles except that we currently actually do something
;;; interesting at load time, namely checking if the constant is being
;;; redefined.
;;;
(defun c::%defconstant (name value doc)

  (c::%%defconstant name value doc nil))

;;;

(defun c::%%defconstant (name value doc source-location)

  (when doc
    (setf (documentation name 'variable) doc))
  (when (boundp name)
    (unless (equalp (symbol-value name) value)

      (cerror (intl:gettext "Go ahead and change the value.")
	      (intl:gettext "Constant ~S being redefined.") name)))

  (setf (symbol-value name) value)
  (setf (info variable kind name) :constant)
  (clear-info variable constant-value name)

  (set-defvar-source-location name source-location)

  name)

(defmacro defvar (var &optional (val nil valp) (doc nil docp))

  "For defining global variables at top level.  Declares the variable

  SPECIAL and, optionally, initializes it.  If the variable already has a
  value, the old value is not clobbered.  The third argument is an optional
  documentation string for the variable."

  (when docp
    (intl::note-translatable intl::*default-domain* doc))

  `(progn

    (declaim (special ,var))

     ,@(when valp
	 `((unless (boundp ',var)
	     (setq ,var ,val))))
    ,@(when docp

	`((setf (documentation ',var 'variable) ',doc)
	  (eval-when (:load-toplevel :execute)

	    (set-defvar-textdomain ',var ,intl::*default-domain*))))

    (set-defvar-source-location ',var (c::source-location))

    ',var))

(defmacro defparameter (var val &optional (doc nil docp))

  "Defines a parameter that is not normally changed by the program,

  but that may be changed without causing an error.  Declares the
  variable special and sets its value to VAL.  The third argument is
  an optional documentation string for the parameter."

  (when docp
    (intl::note-translatable intl::*default-domain* doc))

  `(progn

    (declaim (special ,var))

    (setq ,var ,val)
    ,@(when docp

	`((setf (documentation ',var 'variable) ',doc)
	  (eval-when (:load-toplevel :execute)

	    (set-defvar-textdomain ',var ,intl::*default-domain*))))

    (set-defvar-source-location ',var (c::source-location))

    ',var))


;;;; ASSORTED CONTROL STRUCTURES


(defmacro when (test &body forms)

  "First arg is a predicate.  If it is non-null, the rest of the forms are

  evaluated as a PROGN."
  `(cond (,test nil ,@forms)))

(defmacro unless (test &rest forms)

  "First arg is a predicate.  If it is null, the rest of the forms are

  evaluated as a PROGN."
  `(cond ((not ,test) nil ,@forms)))


(defmacro return (&optional (value nil))
  `(return-from nil ,value))

(defmacro prog (varlist &parse-body (body decls))

  `(block nil
     (let ,varlist
       ,@decls
       (tagbody ,@body))))

(defmacro prog* (varlist &parse-body (body decls))

  `(block nil
     (let* ,varlist
       ,@decls
       (tagbody ,@body))))


;;; Prog1, Prog2  --  Public
;;;
;;;    These just turn into a Let.
;;;
(defmacro prog1 (result &rest body)
  (let ((n-result (gensym)))
    `(let ((,n-result ,result))
       ,@body
       ,n-result)))
;;;
(defmacro prog2 (form1 result &rest body)
  `(prog1 (progn ,form1 ,result) ,@body))


;;; And, Or  --  Public
;;;
;;;    AND and OR are defined in terms of IF.
;;;
(defmacro and (&rest forms)
  (cond ((endp forms) t)
	((endp (rest forms)) (first forms))
	(t
	 `(if ,(first forms)
	      (and ,@(rest forms))
	      nil))))
;;;
(defmacro or (&rest forms)
  (cond ((endp forms) nil)
	((endp (rest forms)) (first forms))
	(t
	 (let ((n-result (gensym)))
	   `(let ((,n-result ,(first forms)))
	      (if ,n-result
		  ,n-result
		  (or ,@(rest forms))))))))


;;; Cond  --  Public
;;;
;;;    COND also turns into IF.
;;;
(defmacro cond (&rest clauses)
  (if (endp clauses)
      nil
      (let ((clause (first clauses)))
	(when (atom clause)

	  (error (intl:gettext "Cond clause should be a non-empty list: ~S.") clause))

	(let ((test (first clause))
	      (forms (rest clause)))
	  (if (endp forms)
	      (let ((n-result (gensym)))
		`(let ((,n-result ,test))
		   (if ,n-result
		       ,n-result
		       (cond ,@(rest clauses)))))
	      `(if ,test
		   (progn ,@forms)
		   (cond ,@(rest clauses))))))))


;;;; Multiple value macros:

;;; Multiple-Value-XXX  --  Public
;;;
;;;    All the multiple-value receiving forms are defined in terms of
;;; Multiple-Value-Call.
;;;

(defmacro multiple-value-setq (varlist value-form)
  (unless (and (listp varlist) (every #'symbolp varlist))

    (simple-program-error (intl:gettext "Varlist is not a list of symbols: ~S.") varlist))

  (if varlist
      `(values (setf (values ,@varlist) ,value-form))
      `(values ,value-form)))

;;;
(defmacro multiple-value-bind (varlist value-form &body body)
  (unless (and (listp varlist) (every #'symbolp varlist))

    (simple-program-error  (intl:gettext "Varlist is not a list of symbols: ~S.") varlist))

  (if (= (length varlist) 1)
      `(let ((,(car varlist) ,value-form))
	 ,@body)
      (let ((ignore (gensym)))

	`(multiple-value-call #'(lambda (&optional ,@(mapcar #'list varlist) &rest ,ignore)

				  (declare (ignore ,ignore))
				  ,@body)
	   ,value-form))))
;;;
(defmacro multiple-value-list (value-form)
  `(multiple-value-call #'list ,value-form))

(defmacro nth-value (n form)

  "Evaluates FORM and returns the Nth value (zero based).  This involves no

  consing when N is a trivial constant integer."
  (if (integerp n)
      (let ((dummy-list nil)

            (keeper (gensym "KEEPER-")))

        ;; We build DUMMY-LIST, a list of variables to bind to useless
        ;; values, then we explicitly IGNORE those bindings and return

        ;; KEEPER, the only thing we're really interested in right now.

        (dotimes (i n)

          (push (gensym "IGNORE-") dummy-list))
        `(multiple-value-bind (,@dummy-list ,keeper)

                              ,form
           (declare (ignore ,@dummy-list))

           ,keeper))
      (once-only ((n n))

	`(case (the (values fixnum &rest t) ,n)

	   (0 (nth-value 0 ,form))
	   (1 (nth-value 1 ,form))
	   (2 (nth-value 2 ,form))

	   (T (nth (the (values fixnum &rest t) ,n)
			(multiple-value-list ,form)))))))


;;;; SETF and friends.

;;; Note: The expansions for SETF and friends sometimes create needless
;;; LET-bindings of argument values.  The compiler will remove most of
;;; these spurious bindings, so SETF doesn't worry too much about creating
;;; them. 

;;; The inverse for a generalized-variable reference function is stored in
;;; one of two ways:
;;;

;;; A SETF inverse property corresponds to the short form of DEFSETF.  It is

;;; the name of a function takes the same args as the reference form, plus a
;;; new-value arg at the end.
;;;

;;; A SETF method expander is created by the long form of DEFSETF or

;;; by DEFINE-SETF-EXPANDER.  It is a function that is called on the reference

;;; form and that produces five values: a list of temporary variables, a list
;;; of value forms, a list of the single store-value form, a storing function,
;;; and an accessing function.

(defun get-setf-expansion (form &optional environment)

  "Returns five values needed by the SETF machinery: a list of temporary

   variables, a list of values with which to fill them, a list of temporaries
   for the new values, the setting function, and the accessing function."

  (let (temp)
    (cond ((symbolp form)

	   (multiple-value-bind
	       (expansion expanded)
	       (macroexpand-1 form environment)
	     (if expanded

		 (get-setf-expansion expansion environment)

		 (let ((new-var (gensym)))
		   (values nil nil (list new-var)
			   `(setq ,form ,new-var) form)))))

	  ;;

	  ;; Local functions inhibit global setf methods...
	  ((and environment

		(let ((name (car form)))
		  (dolist (x (c::lexenv-functions environment) nil)
		    (when (and (eq (car x) name)
			       (not (c::defined-function-p (cdr x))))
		      (return t)))))